configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [30])
   6 m4_define([empathy_micro_version], [1])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.22.0
  33 GTK_REQUIRED=2.18.0
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.11.1
  36 TELEPATHY_LOGGER=0.1.1
  37 ENCHANT_REQUIRED=1.2.0
  38 ISO_CODES_REQUIRED=0.35
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBCHAMPLAIN_REQUIRED=0.4
  42 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  43 CLUTTER_GTK_REQUIRED=0.10
  44 GEOCLUE_REQUIRED=0.11
  45 WEBKIT_REQUIRED=1.1.15
  46 KEYRING_REQUIRED=2.22
  47 NETWORK_MANAGER_REQUIRED=0.7.0
  48 NAUTILUS_SENDTO_REQUIRED=2.28.1
  49
  50 # Use --enable-maintainer-mode to disable deprecated symbols and single include.
  51 # If this is not a released empathy, maintainer mode is forced
  52 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  53 GNOME_MAINTAINER_MODE_DEFINES
  54
  55 AC_CONFIG_MACRO_DIR([m4])
  56 AC_CONFIG_HEADERS([config.h])
  57 AC_CONFIG_SRCDIR([configure.ac])
  58 AC_CONFIG_AUX_DIR(.)
  59
  60 GNOME_COMMON_INIT
  61
  62 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 AC_ISC_POSIX
  70 AC_PROG_CC
  71 AC_HEADER_STDC
  72 AM_PROG_LIBTOOL
  73 AM_PROG_MKDIR_P
  74 AM_PATH_GLIB_2_0
  75 AC_PATH_XTRA
  76 IT_PROG_INTLTOOL([0.35.0])
  77 GNOME_DOC_INIT([0.17.3])
  78 IDT_COMPILE_WARNINGS
  79 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  80 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  81 AM_GCONF_SOURCE_2
  82 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  83 AC_SUBST(GLIB_GENMARSHAL)
  84 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  85 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  86
  87 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  88 if test -z "$XSLTPROC"; then
  89   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  90 fi
  91 AM_PATH_PYTHON([2.3])
  92
  93 EMPATHY_ARG_VALGRIND
  94
  95
  96 # -----------------------------------------------------------
  97 # Error flags
  98 # -----------------------------------------------------------
  99 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 100 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 101
 102 AC_ARG_ENABLE(Werror,
 103   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 104     werror=$enableval, :)
 105
 106 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 107 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 108         wno_missing_field_initializers=yes,
 109         wno_missing_field_initializers=no)
 110 AS_COMPILER_FLAG(-Wno-unused-parameter,
 111         wno_unused_parameter=yes,
 112         wno_unused_parameter=no)
 113
 114 ifelse(empathy_released, 1, [],
 115     [
 116         if test x$werror = xyes; then
 117             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 118         fi
 119         if test x$wextra = xyes -a \
 120             x$wno_missing_field_initializers = xyes -a \
 121             x$wno_unused_parameter = xyes; then
 122             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 123         fi
 124     ])
 125
 126 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 127 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 128 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 129 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 130 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 131 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 132
 133 AC_SUBST(ERROR_CFLAGS)
 134
 135 # -----------------------------------------------------------
 136 # Enable TPL
 137 # -----------------------------------------------------------
 138
 139 # It needs to be defined before PKG_CHECK_MODULES calls
 140 AC_ARG_ENABLE(tpl,
 141   AC_HELP_STRING([--enable-tpl],[enable telepathy-logger code and disable the
 142     empathy logger]), enable_tpl=$enableval, enable_tpl=no )
 143 AM_CONDITIONAL(ENABLE_TPL, test "x$enable_tpl" = "xyes")
 144
 145 if test x${enable_tpl} = xyes; then
 146   AC_DEFINE(ENABLE_TPL, [], [Enable TPL code])
 147 fi
 148
 149 if test "x$enable_tpl" = "xyes"; then
 150   PKG_CHECK_MODULES(TPL,
 151   [
 152      telepathy-logger = $TELEPATHY_LOGGER
 153   ])
 154   AC_SUBST(TPL_CFLAGS)
 155   AC_SUBST(TPL_LIBS)
 156 fi
 157
 158
 159 # -----------------------------------------------------------
 160 # Pkg-Config dependency checks
 161 # -----------------------------------------------------------
 162
 163 PKG_CHECK_MODULES(LIBEMPATHY,
 164 [
 165    glib-2.0 >= $GLIB_REQUIRED
 166    gobject-2.0
 167    gio-2.0 >= $GLIB_REQUIRED
 168    gio-unix-2.0 >= $GLIB_REQUIRED
 169    libxml-2.0
 170    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 171    telepathy-farsight
 172    farsight2-0.10
 173    gstreamer-0.10
 174 ])
 175
 176 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 177 [
 178    glib-2.0 >= $GLIB_REQUIRED
 179    gobject-2.0
 180    gio-2.0 >= $GLIB_REQUIRED
 181    gconf-2.0 >= $GCONF_REQUIRED
 182    x11
 183    gtk+-2.0 >= $GTK_REQUIRED
 184    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 185    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 186    farsight2-0.10
 187    gstreamer-0.10
 188    gstreamer-interfaces-0.10
 189 ])
 190
 191 PKG_CHECK_MODULES(EMPATHY,
 192 [
 193    glib-2.0 >= $GLIB_REQUIRED
 194    gobject-2.0
 195    gio-2.0 >= $GLIB_REQUIRED
 196    gdk-x11-2.0
 197    gtk+-2.0 >= $GTK_REQUIRED
 198    libebook-1.2
 199    dbus-glib-1
 200    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 201    telepathy-farsight
 202    farsight2-0.10
 203    gstreamer-0.10
 204    unique-1.0
 205    gnome-keyring-1 >= $KEYRING_REQUIRED
 206 ])
 207
 208 PKG_CHECK_MODULES(LIBEMPATHY_ACCOUNTS_PANEL,
 209 [
 210    glib-2.0 >= $GLIB_REQUIRED
 211    gobject-2.0
 212    gio-2.0 >= $GLIB_REQUIRED
 213    gdk-x11-2.0
 214    gtk+-2.0 >= $GTK_REQUIRED
 215    libebook-1.2
 216    dbus-glib-1
 217    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 218    unique-1.0
 219    gnome-keyring-1 >= $KEYRING_REQUIRED
 220 ])
 221
 222 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 223
 224 # -----------------------------------------------------------
 225 # Enable debug
 226 # -----------------------------------------------------------
 227
 228 AC_ARG_ENABLE(debug,
 229   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 230     enable_debug=$enableval, enable_debug=yes )
 231
 232 if test x$enable_debug = xyes; then
 233   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 234 fi
 235
 236 # -----------------------------------------------------------
 237 # Language Support
 238 # -----------------------------------------------------------
 239
 240 GETTEXT_PACKAGE=empathy
 241 AC_SUBST(GETTEXT_PACKAGE)
 242 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 243
 244 AM_GLIB_GNU_GETTEXT
 245
 246 # -----------------------------------------------------------
 247 # Connectivity integration
 248 # -----------------------------------------------------------
 249 AC_ARG_WITH(connectivity,
 250               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 251                              [build with connectivity support]), ,
 252                              with_connectivity=auto)
 253
 254 if test "x$with_connectivity" = "xno"; then
 255    have_nm=no
 256    have_connman=no
 257
 258 elif test "x$with_connectivity" = "xconnman"; then
 259
 260    PKG_CHECK_MODULES(CONNMAN,
 261    [
 262       dbus-glib-1
 263    ], have_connman="yes", have_connman="no")
 264
 265    if test "x$have_connman" = "xyes"; then
 266       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 267       have_nm=no
 268    fi
 269
 270 else
 271
 272    PKG_CHECK_MODULES(NETWORK_MANAGER,
 273    [
 274       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 275    ], have_nm="yes", have_nm="no")
 276
 277    if test "x$have_nm" = "xyes"; then
 278       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 279       have_connman=no
 280    else
 281       PKG_CHECK_MODULES(NETWORK_MANAGER,
 282       [
 283           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 284       ], have_nm="yes", have_nm="no")
 285
 286       if test "x$have_nm" = "xyes"; then
 287       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 288       have_connman=no
 289       fi
 290    fi
 291 fi
 292
 293 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 294    AC_MSG_ERROR([Couldn't find connman dependencies.])
 295 fi
 296
 297 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 298    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 299 fi
 300
 301 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 302 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 303
 304 # -----------------------------------------------------------
 305 # Webkit
 306 # -----------------------------------------------------------
 307 AC_ARG_ENABLE(webkit,
 308               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 309                              [build with webkit support]), ,
 310                              enable_webkit=auto)
 311
 312 if test "x$enable_webkit" != "xno"; then
 313    PKG_CHECK_MODULES(WEBKIT,
 314    [
 315       webkit-1.0 >= $WEBKIT_REQUIRED
 316    ], have_webkit="yes", have_webkit="no")
 317
 318    if test "x$have_webkit" = "xyes"; then
 319       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 320    fi
 321 else
 322    have_webkit=no
 323 fi
 324
 325 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 326    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 327 fi
 328 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 329
 330 # -----------------------------------------------------------
 331 # spellchecking checks: enchant and iso-codes
 332 # -----------------------------------------------------------
 333 AC_ARG_ENABLE(spell,
 334               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 335                              [Enable spell checking]), ,
 336                              enable_spell=auto)
 337
 338 if test "x$enable_spell" != "xno"; then
 339    PKG_CHECK_MODULES(ENCHANT,
 340    [
 341       enchant >= $ENCHANT_REQUIRED,
 342       iso-codes >= $ISO_CODES_REQUIRED
 343    ], have_enchant="yes", have_enchant="no")
 344
 345    if test "x$have_enchant" = "xyes"; then
 346       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 347       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 348          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 349             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 350             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 351             result=yes
 352       else
 353             result=no
 354             have_enchant="no"
 355       fi
 356       AC_MSG_RESULT([$result])
 357    fi
 358 else
 359    have_enchant=no
 360 fi
 361
 362 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 363    AC_MSG_ERROR([Couldn't find spell dependencies.])
 364 fi
 365
 366 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 367
 368 # -----------------------------------------------------------
 369 # Map view checks: libchamplain
 370 # -----------------------------------------------------------
 371 AC_ARG_ENABLE(map,
 372               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 373                              [Enable map view]), ,
 374                              enable_map=auto)
 375
 376 if test "x$enable_map" != "xno"; then
 377    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 378    [
 379       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 380       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 381       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 382    ], have_libchamplain="yes", have_libchamplain="no")
 383
 384    if test "x$have_libchamplain" = "xyes"; then
 385       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 386    fi
 387 else
 388    have_libchamplain=no
 389 fi
 390
 391 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 392    AC_MSG_ERROR([Couldn't find map view dependencies.])
 393 fi
 394
 395 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 396
 397 # -----------------------------------------------------------
 398 # location checks: geoclue
 399 # -----------------------------------------------------------
 400 AC_ARG_ENABLE(location,
 401               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 402                              [Enable location awareness]), ,
 403                              enable_location=auto)
 404
 405 if test "x$enable_location" != "xno"; then
 406    PKG_CHECK_MODULES(GEOCLUE,
 407    [
 408       geoclue >= $GEOCLUE_REQUIRED
 409    ], have_geoclue="yes", have_geoclue="no")
 410
 411    if test "x$have_geoclue" = "xyes"; then
 412       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 413    fi
 414 else
 415    have_geoclue="no"
 416 fi
 417
 418 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 419    AC_MSG_ERROR([Couldn't find location dependencies.])
 420 fi
 421
 422 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 423 AC_SUBST(GEOCLUE_CFLAGS)
 424 AC_SUBST(GEOCLUE_LIBS)
 425
 426 # -----------------------------------------------------------
 427 # meego widgets support
 428 # -----------------------------------------------------------
 429 AC_ARG_ENABLE(meego,
 430               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 431                              [Enable meego widgets]), ,
 432                              enable_meego=no)
 433
 434 if test "x$enable_meego" != "xno"; then
 435     PKG_CHECK_MODULES(MEEGO,
 436     [
 437        mx-gtk-1.0
 438     ], have_meego="yes", have_meego="no")
 439
 440     if test "x$have_meego" = "xyes"; then
 441        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 442        chain_enable_favourite_contacts="yes"
 443     fi
 444 else
 445    have_meego="no"
 446 fi
 447
 448 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 449    AC_MSG_ERROR([Couldn't find meego dependencies.])
 450 fi
 451
 452 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 453 AC_SUBST(MEEGO_CFLAGS)
 454 AC_SUBST(MEEGO_LIBS)
 455
 456 # -----------------------------------------------------------
 457 # favourite contacts support
 458 # -----------------------------------------------------------
 459 AC_ARG_ENABLE(favourite_contacts,
 460               AS_HELP_STRING([--enable-favourite-contacts=@<:no/yes@:>@],
 461                              [Enable favourite contacts]), ,
 462                              enable_favourite_contacts=no)
 463
 464 if test "x$enable_favourite_contacts" != "xno" -o "x$chain_enable_favourite_contacts" == "xyes"; then
 465     PKG_CHECK_MODULES(TELEPATHY_LOGGER,
 466     [
 467        telepathy-logger
 468     ], have_telepathy_logger="yes", have_telepathy_logger="no")
 469
 470     if test "x$have_telepathy_logger" = "xyes"; then
 471        have_favourite_contacts="yes"
 472        AC_DEFINE(HAVE_FAVOURITE_CONTACTS, 1, [Define if you want favourite contacts support])
 473     fi
 474 else
 475    have_favourite_contacts="no"
 476 fi
 477
 478 if test "x$enable_favourite_contacts" = "xyes" -a "x$have_favourite_contacts" != "xyes"; then
 479    AC_MSG_ERROR([Couldn't find favourite contacts dependencies.])
 480 fi
 481
 482 AM_CONDITIONAL(HAVE_FAVOURITE_CONTACTS, test "x$have_telepathy_logger" = "xyes")
 483
 484 # -----------------------------------------------------------
 485 # nautilus-sendto
 486 # -----------------------------------------------------------
 487 AC_ARG_ENABLE(nautilus-sendto,
 488               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 489                              [build nautilus-sendto plugin]), ,
 490                              enable_nautilus_sendto=auto)
 491
 492 if test "x$enable_nautilus_sendto" != "xno"; then
 493    PKG_CHECK_MODULES(NST,
 494    [
 495       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 496    ], have_nst="yes", have_nst="no")
 497 else
 498    have_nst=no
 499 fi
 500
 501 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 502    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 503 fi
 504
 505 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 506
 507 # -----------------------------------------------------------
 508 # new, single-window control center
 509 # -----------------------------------------------------------
 510 AC_ARG_ENABLE(control_center_embedding,
 511               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 512                              [Enable support for single-window control center]),
 513                              , enable_control_center_embedding=auto)
 514
 515 if test "x$enable_control_center_embedding" != "xno"; then
 516    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 517    [
 518       libgnome-control-center-extension
 519    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 520
 521    if test "x$have_control_center_embedding" = "xyes"; then
 522       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 523    fi
 524 else
 525    have_control_center_embedding="no"
 526 fi
 527
 528 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 529    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 530 fi
 531
 532 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 533 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 534 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 535
 536 # -----------------------------------------------------------
 537 # Coding style checks
 538 # -----------------------------------------------------------
 539 AC_ARG_ENABLE(coding-style-checks,
 540   AC_HELP_STRING([--disable-coding-style-checks],
 541                  [don't check coding style using grep]),
 542     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 543
 544 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 545 # -----------------------------------------------------------
 546
 547 AC_OUTPUT([
 548    Makefile
 549    data/Makefile
 550    data/empathy.desktop.in
 551    data/empathy-accounts.desktop.in
 552    data/icons/Makefile
 553    extensions/Makefile
 554    po/Makefile.in
 555    libempathy/Makefile
 556    libempathy-gtk/Makefile
 557    src/Makefile
 558    nautilus-sendto-plugin/Makefile
 559    help/Makefile
 560    tests/Makefile
 561    tests/interactive/Makefile
 562    tests/xml/Makefile
 563    tools/Makefile
 564 ])
 565
 566 echo "
 567 Configure summary:
 568
 569         Compiler....................:  ${CC}
 570         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 571         Prefix......................:  ${prefix}
 572         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 573
 574     Features:
 575         Spell checking (enchant)....:  ${have_enchant}
 576         Display maps (libchamplain).:  ${have_libchamplain}
 577         Location awareness (Geoclue):  ${have_geoclue}
 578         Adium themes (Webkit).......:  ${have_webkit}
 579         Meego widgets ..............:  ${have_meego}
 580         Favourite contacts .........:  ${have_favourite_contacts}
 581         Control center embedding....:  ${have_control_center_embedding}
 582
 583     Logging:
 584         Telepathy Logger............:  ${enable_tpl}
 585
 586     Connectivity:
 587         NetworkManager integration..:  ${have_nm}
 588         ConnMan integration.........:  ${have_connman}
 589
 590     Extras:
 591         Nautilus-sendto plugin......:  ${have_nst}
 592 "