configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [91])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [2])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.3.3
  35 GLIB_REQUIRED=2.27.2
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=2.91.6
  38 KEYRING_REQUIRED=2.26.0
  39 GCR_REQUIRED=2.91.4
  40 LIBCANBERRA_GTK_REQUIRED=0.25
  41 LIBNOTIFY_REQUIRED=0.7.0
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.13.9
  44 TELEPATHY_LOGGER=0.1.5
  45
  46 # Optional deps
  47 CLUTTER_GTK_REQUIRED=0.90.3
  48 ENCHANT_REQUIRED=1.2.0
  49 GEOCLUE_REQUIRED=0.11
  50 ISO_CODES_REQUIRED=0.35
  51 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  52 LIBCHAMPLAIN_REQUIRED=0.7.1
  53 NAUTILUS_SENDTO_REQUIRED=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.3.2
  56 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  57
  58 # Use --enable-maintainer-mode to disable deprecated symbols,
  59 # disable single include and enable GSEAL. If this is not a released empathy,
  60 # maintainer mode is forced
  61 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  62 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 #GNOME_MAINTAINER_MODE_DEFINES
  64
  65 AC_CONFIG_MACRO_DIR([m4])
  66 AC_CONFIG_HEADERS([config.h])
  67 AC_CONFIG_SRCDIR([configure.ac])
  68 AC_CONFIG_AUX_DIR(.)
  69
  70 GNOME_COMMON_INIT
  71
  72 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  73
  74 # Support silent build rules, requires at least automake-1.11. Disable
  75 # by either passing --disable-silent-rules to configure or passing V=1
  76 # to make
  77 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  78
  79 AC_ISC_POSIX
  80 AC_PROG_CC
  81 AC_HEADER_STDC
  82 AM_PROG_LIBTOOL
  83 AM_PROG_MKDIR_P
  84 AM_PATH_GLIB_2_0
  85 AC_PATH_XTRA
  86 IT_PROG_INTLTOOL([0.35.0])
  87 GNOME_DOC_INIT([0.17.3])
  88 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  89 GLIB_GSETTINGS
  90 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  91 AC_SUBST(GLIB_GENMARSHAL)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    farsight2-0.10
 149    folks >= $FOLKS_REQUIRED
 150    folks-telepathy >= $FOLKS_REQUIRED
 151    gio-2.0 >= $GLIB_REQUIRED
 152    gio-unix-2.0 >= $GLIB_REQUIRED
 153    gnome-keyring-1 >= $KEYRING_REQUIRED
 154    gnutls >= $GNUTLS_REQUIRED
 155    gmodule-export-2.0
 156    gobject-2.0
 157    gsettings-desktop-schemas
 158    gstreamer-0.10
 159    gstreamer-interfaces-0.10
 160    libxml-2.0
 161    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 162    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 163    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 164    x11
 165    gtk+-3.0 >= $GTK_REQUIRED
 166    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 167    libnotify >= $LIBNOTIFY_REQUIRED
 168    gcr-3 >= $GCR_REQUIRED
 169 ])
 170
 171 # -----------------------------------------------------------
 172 # evolution-data-server (about-me)
 173 # -----------------------------------------------------------
 174 AC_ARG_WITH(eds,
 175             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 176             [with_eds=yes])
 177 if test x"$with_eds" = x"yes" ; then
 178    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 179    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 180 fi
 181
 182 # -----------------------------------------------------------
 183 # Enable debug
 184 # -----------------------------------------------------------
 185
 186 AC_ARG_ENABLE(debug,
 187   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 188     enable_debug=$enableval, enable_debug=yes )
 189
 190 if test x$enable_debug = xyes; then
 191   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 192 fi
 193
 194 # -----------------------------------------------------------
 195 # Language Support
 196 # -----------------------------------------------------------
 197
 198 GETTEXT_PACKAGE=empathy
 199 AC_SUBST(GETTEXT_PACKAGE)
 200 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 201
 202 AM_GLIB_GNU_GETTEXT
 203
 204 # -----------------------------------------------------------
 205 # Make CA certificates path configurable
 206 # Stolen from GIO's TLS
 207 # -----------------------------------------------------------
 208 AC_MSG_CHECKING([location of system Certificate Authority list])
 209 AC_ARG_WITH(ca-file,
 210             [AC_HELP_STRING([--with-ca-file=@<:@path@:>@],
 211                             [path to system Certificate Authority list])])
 212 if test "$with_ca_file" = "no"; then
 213     AC_MSG_RESULT([disabled])
 214 else
 215     if test -z "$with_ca_file"; then
 216         for f in /etc/pki/tls/certs/ca-bundle.crt \
 217                  /etc/ssl/certs/ca-certificates.crt; do
 218             if test -f "$f"; then
 219                 with_ca_file="$f"
 220             fi
 221         done
 222         if test -z "$with_ca_file"; then
 223             AC_MSG_ERROR([could not find. Use --with-ca-file=path to set, or --without-ca-file to disable])
 224         fi
 225     fi
 226
 227     AC_MSG_RESULT($with_ca_file)
 228     if ! test -f "$with_ca_file"; then
 229         AC_MSG_ERROR([No such file '$with_ca_file'. Use --with-ca-file=path to set, or --without-ca-file to disable])
 230     fi
 231     GTLS_SYSTEM_CA_FILE="$with_ca_file"
 232
 233     AC_DEFINE_UNQUOTED([GTLS_SYSTEM_CA_FILE], ["$GTLS_SYSTEM_CA_FILE"], [path to system Certificate Authority list])
 234 fi
 235
 236 # -----------------------------------------------------------
 237 # Connectivity integration
 238 # -----------------------------------------------------------
 239 AC_ARG_WITH(connectivity,
 240               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 241                              [build with connectivity support]), ,
 242                              with_connectivity=auto)
 243
 244 if test "x$with_connectivity" = "xno"; then
 245    have_nm=no
 246    have_connman=no
 247
 248 elif test "x$with_connectivity" = "xconnman"; then
 249    have_nm=no
 250
 251    PKG_CHECK_MODULES(CONNMAN,
 252    [
 253       dbus-glib-1
 254    ], have_connman="yes", have_connman="no")
 255
 256    if test "x$have_connman" = "xyes"; then
 257       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 258    fi
 259
 260 else
 261    have_connman=no
 262
 263    PKG_CHECK_MODULES(NETWORK_MANAGER,
 264    [
 265       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 266    ], have_nm="yes", have_nm="no")
 267
 268    if test "x$have_nm" = "xyes"; then
 269       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 270    fi
 271 fi
 272
 273 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 274    AC_MSG_ERROR([Couldn't find connman dependencies.])
 275 fi
 276
 277 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 278    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 279 fi
 280
 281 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 282 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 283
 284 # -----------------------------------------------------------
 285 # Webkit
 286 # -----------------------------------------------------------
 287 AC_ARG_ENABLE(webkit,
 288               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 289                              [build with webkit support]), ,
 290                              enable_webkit=auto)
 291
 292 if test "x$enable_webkit" != "xno"; then
 293    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 294         have_webkit="yes", have_webkit="no")
 295
 296    if test "x$have_webkit" = "xyes"; then
 297       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 298    fi
 299 else
 300    have_webkit=no
 301 fi
 302
 303 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 304    AC_MSG_ERROR([Could not find webkit dependencies.])
 305 fi
 306 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 307
 308 # -----------------------------------------------------------
 309 # spellchecking checks: enchant and iso-codes
 310 # -----------------------------------------------------------
 311 AC_ARG_ENABLE(spell,
 312               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 313                              [Enable spell checking]), ,
 314                              enable_spell=auto)
 315
 316 if test "x$enable_spell" != "xno"; then
 317    PKG_CHECK_MODULES(ENCHANT,
 318    [
 319       enchant >= $ENCHANT_REQUIRED,
 320       iso-codes >= $ISO_CODES_REQUIRED
 321    ], have_enchant="yes", have_enchant="no")
 322
 323    if test "x$have_enchant" = "xyes"; then
 324       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 325       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 326          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 327             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 328             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 329             result=yes
 330       else
 331             result=no
 332             have_enchant="no"
 333       fi
 334       AC_MSG_RESULT([$result])
 335    fi
 336 else
 337    have_enchant=no
 338 fi
 339
 340 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 341    AC_MSG_ERROR([Could not find spell dependencies.])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 345
 346 # -----------------------------------------------------------
 347 # Map view checks: libchamplain
 348 # -----------------------------------------------------------
 349 AC_ARG_ENABLE(map,
 350               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 351                              [Enable map view]), ,
 352                              enable_map=auto)
 353
 354 if test "x$enable_map" != "xno"; then
 355
 356    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 357     [
 358        champlain-0.8 >= $LIBCHAMPLAIN_REQUIRED,
 359 # champplain-gtk3 doesn't exist. Fix the name once bgo #631009
 360        champlain-gtk3-0.8 >= $LIBCHAMPLAIN_GTK_REQUIRED
 361        clutter-gtk >= $CLUTTER_GTK_REQUIRED
 362     ], have_libchamplain="yes", have_libchamplain="no")
 363
 364    if test "x$have_libchamplain" = "xyes"; then
 365       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 366    fi
 367 else
 368    have_libchamplain=no
 369 fi
 370
 371 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 372    AC_MSG_ERROR([Could not find map view dependencies.])
 373 fi
 374
 375 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 376
 377 # -----------------------------------------------------------
 378 # location checks: geoclue
 379 # -----------------------------------------------------------
 380 AC_ARG_ENABLE(location,
 381               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 382                              [Enable location awareness]), ,
 383                              enable_location=auto)
 384
 385 if test "x$enable_location" != "xno"; then
 386    PKG_CHECK_MODULES(GEOCLUE,
 387    [
 388       geoclue >= $GEOCLUE_REQUIRED
 389    ], have_geoclue="yes", have_geoclue="no")
 390
 391    if test "x$have_geoclue" = "xyes"; then
 392       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 393    fi
 394 else
 395    have_geoclue="no"
 396 fi
 397
 398 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 399    AC_MSG_ERROR([Could not find location dependencies.])
 400 fi
 401
 402 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 403 AC_SUBST(GEOCLUE_CFLAGS)
 404 AC_SUBST(GEOCLUE_LIBS)
 405
 406 # -----------------------------------------------------------
 407 # meego widgets support
 408 # -----------------------------------------------------------
 409 AC_ARG_ENABLE(meego,
 410               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 411                              [Enable meego widgets]), ,
 412                              enable_meego=no)
 413
 414 if test "x$enable_meego" != "xno"; then
 415     PKG_CHECK_MODULES(MEEGO,
 416     [
 417        mx-gtk-1.0
 418        gio-unix-2.0
 419     ], have_meego="yes", have_meego="no")
 420
 421     if test "x$have_meego" = "xyes"; then
 422        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 423     fi
 424 else
 425    have_meego="no"
 426 fi
 427
 428 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 429    AC_MSG_ERROR([Could not find meego dependencies.])
 430 fi
 431
 432 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 433 AC_SUBST(MEEGO_CFLAGS)
 434 AC_SUBST(MEEGO_LIBS)
 435
 436 # -----------------------------------------------------------
 437 # nautilus-sendto
 438 # -----------------------------------------------------------
 439 AC_ARG_ENABLE(nautilus-sendto,
 440               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 441                              [build nautilus-sendto plugin]), ,
 442                              enable_nautilus_sendto=auto)
 443
 444 if test "x$enable_nautilus_sendto" != "xno"; then
 445    PKG_CHECK_MODULES(NST,
 446     [
 447        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 448     ], have_nst="yes", have_nst="no")
 449 else
 450    have_nst=no
 451 fi
 452
 453 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 454    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 455 fi
 456
 457 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 458
 459 # -----------------------------------------------------------
 460 # new, single-window control center
 461 # -----------------------------------------------------------
 462 AC_ARG_ENABLE(control_center_embedding,
 463               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 464                              [Enable support for single-window control center]),
 465                              , enable_control_center_embedding=auto)
 466
 467 if test "x$enable_control_center_embedding" != "xno"; then
 468
 469    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 470         have_control_center_embedding="yes", have_control_center_embedding="no")
 471
 472    if test "x$have_control_center_embedding" = "xyes"; then
 473       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 474
 475       AC_MSG_CHECKING([gnome-control-center extension dir])
 476       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 477       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 478           AC_MSG_ERROR([Could not determine extensiondir])
 479       else
 480           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 481       fi
 482       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 483    fi
 484 else
 485    have_control_center_embedding="no"
 486 fi
 487
 488 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 489    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 490 fi
 491
 492 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 493 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 494 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 495
 496 # -----------------------------------------------------------
 497 # Coding style checks
 498 # -----------------------------------------------------------
 499 AC_ARG_ENABLE(coding-style-checks,
 500   AC_HELP_STRING([--disable-coding-style-checks],
 501                  [do not check coding style using grep]),
 502     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 503
 504 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 505 # -----------------------------------------------------------
 506
 507 AC_OUTPUT([
 508    Makefile
 509    data/Makefile
 510    data/empathy.desktop.in
 511    data/empathy-accounts.desktop.in
 512    data/icons/Makefile
 513    extensions/Makefile
 514    po/Makefile.in
 515    libempathy/Makefile
 516    libempathy-gtk/Makefile
 517    src/Makefile
 518    nautilus-sendto-plugin/Makefile
 519    help/Makefile
 520    tests/Makefile
 521    tests/interactive/Makefile
 522    tests/xml/Makefile
 523    tools/Makefile
 524 ])
 525
 526 echo "
 527 Configure summary:
 528
 529         Compiler....................:  ${CC}
 530         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 531         Prefix......................:  ${prefix}
 532         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 533         CA Cert Path................:  ${GTLS_SYSTEM_CA_FILE}
 534
 535     Features:
 536         Spell checking (enchant)....:  ${have_enchant}
 537         Display maps (libchamplain).:  ${have_libchamplain}
 538         Location awareness (Geoclue):  ${have_geoclue}
 539         Adium themes (Webkit).......:  ${have_webkit}
 540         Meego widgets ..............:  ${have_meego}
 541         Control center embedding....:  ${have_control_center_embedding}
 542
 543     Connectivity:
 544         NetworkManager integration..:  ${have_nm}
 545         ConnMan integration.........:  ${have_connman}
 546
 547     Extras:
 548         Nautilus-sendto plugin......:  ${have_nst}
 549         Salut E-D-S support.........:  ${with_eds}
 550 "