configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [5])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.7.1
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53 CLUTTER_GST_REQUIRED=1.5.2
  54
  55 TELEPATHY_GLIB_REQUIRED=0.19.4
  56 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  57 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  58 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  59
  60 GSTREAMER_REQUIRED=0.10.32
  61 KEYRING_REQUIRED=2.26.0
  62 GCR_REQUIRED=2.91.4
  63 LIBCANBERRA_GTK_REQUIRED=0.25
  64 LIBNOTIFY_REQUIRED=0.7.0
  65 TELEPATHY_FARSTREAM_REQUIRED=0.2.1
  66 TELEPATHY_LOGGER=0.2.13
  67 WEBKIT_REQUIRED=1.3.13
  68 GOA_REQUIRED=3.5.1
  69
  70 # Optional deps
  71 ENCHANT_REQUIRED=1.2.0
  72 GEOCLUE_REQUIRED=0.12
  73 ISO_CODES_REQUIRED=0.35
  74 NAUTILUS_SENDTO_REQUIRED=2.90.0
  75 NETWORK_MANAGER_REQUIRED=0.7.0
  76 CHAMPLAIN_REQUIRED=0.12.1
  77 CHEESE_GTK_REQUIRED=3.4.0
  78 LIBACCOUNTS_REQUIRED=1.1
  79 LIBSIGNON_REQUIRED=1.1
  80 MC_PLUGINS_REQUIRED=5.13.0
  81
  82 # Use --enable-maintainer-mode to disable deprecated symbols,
  83 # disable single include and enable GSEAL. If this is not a released empathy,
  84 # maintainer mode is forced
  85 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  86 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  87 #GNOME_MAINTAINER_MODE_DEFINES
  88
  89 # egg-list-box
  90 prev_top_build_prefix=$ac_top_build_prefix
  91 prev_ac_configure_args=$ac_configure_args
  92 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
  93 ac_top_build_prefix=$prev_top_build_prefix
  94 ac_configure_args=$prev_ac_configure_args
  95
  96 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
  97 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
  98
  99 AC_CONFIG_MACRO_DIR([m4])
 100 AC_CONFIG_HEADERS([config.h])
 101 AC_CONFIG_SRCDIR([configure.ac])
 102 AC_CONFIG_AUX_DIR(.)
 103
 104 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 105
 106 # Support silent build rules. Disable
 107 # by either passing --disable-silent-rules to configure or passing V=1
 108 # to make
 109 AM_SILENT_RULES([yes])
 110
 111 # Check for programs
 112 AC_PROG_CC
 113 AC_HEADER_STDC
 114 AM_PROG_MKDIR_P
 115 AM_PATH_GLIB_2_0
 116 AC_PATH_XTRA
 117
 118 # Initialize libtool
 119 LT_PREREQ([2.2])
 120 LT_INIT
 121
 122 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 123 GLIB_GSETTINGS
 124 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 125 AC_SUBST(GLIB_GENMARSHAL)
 126
 127 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 128 if test -z "$XSLTPROC"; then
 129   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 130 fi
 131 AM_PATH_PYTHON([2.3])
 132
 133 EMPATHY_ARG_VALGRIND
 134
 135
 136 # -----------------------------------------------------------
 137 # Error flags
 138 # -----------------------------------------------------------
 139 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 140 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 141
 142 AC_ARG_ENABLE(Werror,
 143   AS_HELP_STRING([--disable-Werror],
 144                  [compile without -Werror (normally enabled in development builds)]),
 145     werror=$enableval, :)
 146
 147 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 148 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 149         wno_missing_field_initializers=yes,
 150         wno_missing_field_initializers=no)
 151 AS_COMPILER_FLAG(-Wno-unused-parameter,
 152         wno_unused_parameter=yes,
 153         wno_unused_parameter=no)
 154
 155 ifelse(empathy_released, 1, [],
 156     [
 157         if test x$werror = xyes; then
 158             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 159         fi
 160         if test x$wextra = xyes -a \
 161             x$wno_missing_field_initializers = xyes -a \
 162             x$wno_unused_parameter = xyes; then
 163             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 164         fi
 165     ])
 166
 167 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 168 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 169 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 170 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 171 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 172
 173 AC_SUBST(ERROR_CFLAGS)
 174
 175 AC_ARG_ENABLE(gprof,
 176             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 177             [build with support for gprof]),,
 178             [enable_gprof=no])
 179 if test "x$enable_gprof" != "xno" ; then
 180     CFLAGS="$CFLAGS -pg"
 181     LDFLAGS="$LDFLAGS -pg"
 182 fi
 183
 184 AC_SUBST(LDFLAGS)
 185
 186 # -----------------------------------------------------------
 187 # Pkg-Config dependency checks
 188 # -----------------------------------------------------------
 189
 190 AC_CHECK_LIBM
 191 AC_SUBST(LIBM)
 192
 193 PKG_CHECK_MODULES(EMPATHY,
 194 [
 195    dbus-glib-1
 196    folks >= $FOLKS_REQUIRED
 197    folks-telepathy >= $FOLKS_REQUIRED
 198    glib-2.0 >= $GLIB_REQUIRED
 199    gio-2.0 >= $GLIB_REQUIRED
 200    gio-unix-2.0 >= $GLIB_REQUIRED
 201    gnome-keyring-1 >= $KEYRING_REQUIRED
 202    gnutls >= $GNUTLS_REQUIRED
 203    gmodule-export-2.0
 204    gobject-2.0
 205    gsettings-desktop-schemas
 206    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 207    gstreamer-interfaces-0.10
 208    libxml-2.0
 209    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 210    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 211    x11
 212    gtk+-3.0 >= $GTK_REQUIRED
 213    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 214    libnotify >= $LIBNOTIFY_REQUIRED
 215    gcr-3 >= $GCR_REQUIRED
 216    libpulse
 217    libpulse-mainloop-glib
 218    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 219    libsoup-2.4
 220    gee-0.8
 221 ])
 222
 223 PKG_CHECK_MODULES(EMPATHY_CALL,
 224 [
 225    farstream-0.1
 226    telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 227    clutter-1.0 >= $CLUTTER_REQUIRED
 228    clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 229    clutter-gst-1.0 >= $CLUTTER_GST_REQUIRED
 230 ])
 231
 232 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 233    [Name of provider for accounts imported from GOA])
 234
 235 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 236     "im.telepathy.Account.Storage.UOA",
 237    [Name of provider for accounts imported from libaccounts])
 238
 239 # -----------------------------------------------------------
 240 # Enable debug
 241 # -----------------------------------------------------------
 242
 243 AC_ARG_ENABLE(debug,
 244   AS_HELP_STRING([--disable-debug],
 245                  [compile without debug code]),
 246     enable_debug=$enableval, enable_debug=yes )
 247
 248 if test x$enable_debug = xyes; then
 249   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 250 fi
 251
 252 # -----------------------------------------------------------
 253 # Language Support
 254 # -----------------------------------------------------------
 255 IT_PROG_INTLTOOL([0.50.0])
 256
 257 GETTEXT_PACKAGE=empathy
 258 AC_SUBST(GETTEXT_PACKAGE)
 259 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 260
 261 # -----------------------------------------------------------
 262 # gudev
 263 # -----------------------------------------------------------
 264 AC_ARG_ENABLE(gudev,
 265               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 266                              [build with gudev support]), ,
 267                              enable_gudev=auto)
 268
 269 if test "x$enable_gudev" != "xno"; then
 270
 271    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 272         have_gudev="yes", have_gudev="no")
 273
 274    if test "x$have_gudev" = "xyes"; then
 275       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 276    fi
 277 else
 278    have_gudev=no
 279 fi
 280
 281 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 282    AC_MSG_ERROR([Could not find gudev dependencies:
 283
 284 $UDEV_PKG_ERRORS])
 285 fi
 286 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 287
 288 # -----------------------------------------------------------
 289 # spellchecking checks: enchant and iso-codes
 290 # -----------------------------------------------------------
 291 AC_ARG_ENABLE(spell,
 292               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 293                              [Enable spell checking]), ,
 294                              enable_spell=auto)
 295
 296 if test "x$enable_spell" != "xno"; then
 297    PKG_CHECK_MODULES(ENCHANT,
 298    [
 299       enchant >= $ENCHANT_REQUIRED,
 300       iso-codes >= $ISO_CODES_REQUIRED
 301    ], have_enchant="yes", have_enchant="no")
 302
 303    if test "x$have_enchant" = "xyes"; then
 304       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 305       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 306          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 307             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 308             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 309             result=yes
 310       else
 311             result=no
 312             have_enchant="no"
 313       fi
 314       AC_MSG_RESULT([$result])
 315    fi
 316 else
 317    have_enchant=no
 318 fi
 319
 320 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 321    AC_MSG_ERROR([Could not find spell-checking dependencies:
 322
 323 $ENCHANT_PKG_ERRORS])
 324 fi
 325
 326 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 327
 328 # -----------------------------------------------------------
 329 # Map view checks: libchamplain
 330 # -----------------------------------------------------------
 331 AC_ARG_ENABLE(map,
 332               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 333                              [Enable map view]), ,
 334                              enable_map=auto)
 335
 336 if test "x$enable_map" != "xno"; then
 337
 338    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 339     [
 340        clutter-gtk-1.0
 341        champlain-gtk-0.12
 342        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 343     ], have_libchamplain="yes", have_libchamplain="no")
 344
 345    if test "x$have_libchamplain" = "xyes"; then
 346       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 347    fi
 348 else
 349    have_libchamplain=no
 350 fi
 351
 352 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 353    AC_MSG_ERROR([Could not find map view dependencies:
 354
 355 $LIBCHAMPLAIN_PKG_ERRORS])
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 359
 360 # -----------------------------------------------------------
 361 # location checks: geoclue
 362 # -----------------------------------------------------------
 363 AC_ARG_ENABLE(location,
 364               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 365                              [Enable location awareness]), ,
 366                              enable_location=auto)
 367
 368 if test "x$enable_location" != "xno"; then
 369    PKG_CHECK_MODULES(GEOCLUE,
 370    [
 371       geoclue >= $GEOCLUE_REQUIRED
 372    ], have_geoclue="yes", have_geoclue="no")
 373
 374    if test "x$have_geoclue" = "xyes"; then
 375       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 376    fi
 377 else
 378    have_geoclue="no"
 379 fi
 380
 381 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 382    AC_MSG_ERROR([Could not find location dependencies:
 383
 384 $GEOCLUE_PKG_ERRORS])
 385 fi
 386
 387 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 388 AC_SUBST(GEOCLUE_CFLAGS)
 389 AC_SUBST(GEOCLUE_LIBS)
 390
 391 # -----------------------------------------------------------
 392 # location checks: geocode-glib
 393 # -----------------------------------------------------------
 394 AC_ARG_ENABLE(geocode,
 395               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 396                              [Enable geocode support]), ,
 397                              enable_geocode=auto)
 398
 399 if test "x$enable_geocode" != "xno"; then
 400    PKG_CHECK_MODULES(GEOCODE,
 401    [
 402       geocode-glib
 403    ], have_geocode="yes", have_geocode="no")
 404
 405    if test "x$have_geocode" = "xyes"; then
 406       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 407    fi
 408 else
 409    have_geocode="no"
 410 fi
 411
 412 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 413    AC_MSG_ERROR([Could not find geocode dependencies:
 414
 415 $GEOCODE_PKG_ERRORS])
 416 fi
 417
 418 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 419 AC_SUBST(GEOCODE_CFLAGS)
 420 AC_SUBST(GEOCODE_LIBS)
 421
 422 # -----------------------------------------------------------
 423 # nautilus-sendto
 424 # -----------------------------------------------------------
 425 AC_ARG_ENABLE(nautilus-sendto,
 426               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 427                              [build nautilus-sendto plugin]), ,
 428                              enable_nautilus_sendto=auto)
 429
 430 if test "x$enable_nautilus_sendto" != "xno"; then
 431    PKG_CHECK_MODULES(NST,
 432     [
 433        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 434     ], have_nst="yes", have_nst="no")
 435 else
 436    have_nst=no
 437 fi
 438
 439 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 440    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 441
 442 $NST_PKG_ERRORS])
 443 fi
 444
 445 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 446
 447 # -----------------------------------------------------------
 448 # goa-mc-plugin
 449 # -----------------------------------------------------------
 450 AC_ARG_ENABLE(goa,
 451               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 452                              [build GOA MC plugin]), ,
 453                              enable_goa=auto)
 454
 455 if test "x$enable_goa" != "xno"; then
 456    PKG_CHECK_MODULES(GOA,
 457     [
 458        mission-control-plugins
 459        goa-1.0 >= $GOA_REQUIRED
 460     ], have_goa="yes", have_goa="no")
 461
 462    AC_MSG_CHECKING([Mission Control plugins dir])
 463    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 464
 465    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 466    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 467 else
 468    have_goa=no
 469 fi
 470
 471 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 472    AC_MSG_ERROR([Could not find GOA dependencies:
 473
 474 $GOA_PKG_ERRORS])
 475 fi
 476
 477 if test "x$have_goa" = "xyes"; then
 478    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 479 fi
 480
 481 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 482
 483 # Optional dependency for avatar selection
 484 AC_ARG_WITH([cheese],
 485             AS_HELP_STRING([--with-cheese],
 486                            [enable cheese webcam support]),,
 487             with_cheese=auto)
 488
 489 if test x"$with_cheese" != x"no" ; then
 490    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 491    if test x${have_cheese} = xyes; then
 492      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 493    fi
 494    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 495      AC_MSG_ERROR([Cheese configured but not found:
 496
 497 $CHEESE_PKG_ERRORS])
 498    fi
 499 else
 500    have_cheese=no
 501 fi
 502 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 503
 504 # -----------------------------------------------------------
 505 # ubuntu-online-accounts support
 506 # -----------------------------------------------------------
 507 AC_ARG_ENABLE(ubuntu-online-accounts,
 508               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 509                              [build Ubuntu Online Accounts plugins]), ,
 510                              enable_ubuntu_online_accounts=auto)
 511
 512 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 513    PKG_CHECK_MODULES(UOA,
 514     [
 515        account-plugin
 516        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 517        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 518        libsignon-glib >= $LIBSIGNON_REQUIRED
 519     ], have_uoa="yes", have_uoa="no")
 520
 521    # MC plugins dir
 522    AC_MSG_CHECKING([Mission Control plugins dir])
 523    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 524
 525    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 526    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 527
 528    # provider plugin dir
 529    AC_MSG_CHECKING([Accounts provider plugin dir])
 530    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 531
 532    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 533    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 534
 535    # provider files dir
 536    AC_MSG_CHECKING([Accounts provider files dir])
 537    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 538
 539    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 540    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 541
 542    # service files dir
 543    AC_MSG_CHECKING([Accounts service files dir])
 544    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 545
 546    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 547    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 548 else
 549    have_uoa=no
 550 fi
 551
 552 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 553    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 554
 555 $UOA_PKG_ERRORS])
 556 fi
 557
 558 if test "x$have_uoa" = "xyes"; then
 559    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 560 fi
 561
 562 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 563
 564 # Help documentation
 565 YELP_HELP_INIT
 566
 567 # -----------------------------------------------------------
 568 # Coding style checks
 569 # -----------------------------------------------------------
 570 AC_ARG_ENABLE(coding-style-checks,
 571   AS_HELP_STRING([--disable-coding-style-checks],
 572                  [do not check coding style using grep]),
 573     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 574     [ENABLE_CODING_STYLE_CHECKS=yes])
 575
 576 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 577 # -----------------------------------------------------------
 578
 579 AC_CONFIG_FILES([
 580    Makefile
 581    data/Makefile
 582    data/empathy.desktop.in
 583    data/empathy-accounts.desktop.in
 584    data/icons/Makefile
 585    data/themes/Makefile
 586    extensions/Makefile
 587    po/Makefile.in
 588    libempathy/Makefile
 589    libempathy-gtk/Makefile
 590    src/Makefile
 591    nautilus-sendto-plugin/Makefile
 592    goa-mc-plugin/Makefile
 593    ubuntu-online-accounts/Makefile
 594    ubuntu-online-accounts/mc-plugin/Makefile
 595    help/Makefile
 596    tests/Makefile
 597    tests/interactive/Makefile
 598    tests/xml/Makefile
 599    tests/certificates/Makefile
 600    tools/Makefile
 601 ])
 602 AC_OUTPUT
 603
 604 echo "
 605 Configure summary:
 606
 607         Compiler....................:  ${CC}
 608         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 609         Linker Flags................:  ${LDFLAGS}
 610         Prefix......................:  ${prefix}
 611         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 612
 613     Features:
 614         Spell checking (enchant)....:  ${have_enchant}
 615         Display maps (libchamplain).:  ${have_libchamplain}
 616         Location awareness (Geoclue):  ${have_geoclue}
 617         Geocode support (Geocode)...:  ${have_geocode}
 618         Cheese webcam support ......:  ${have_cheese}
 619         Camera monitoring...........:  ${have_gudev}
 620
 621     Extras:
 622         Nautilus-sendto plugin......:  ${have_nst}
 623         GOA MC plugin...............:  ${have_goa}
 624         Ubuntu Online plugins.......:  ${have_uoa}
 625 "