configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [1])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.5.1
  35 GLIB_REQUIRED=2.28.0
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=3.0.2
  38 GSTREAMER_REQUIRED=0.10.32
  39 KEYRING_REQUIRED=2.26.0
  40 GCR_REQUIRED=2.91.4
  41 LIBCANBERRA_GTK_REQUIRED=0.25
  42 LIBNOTIFY_REQUIRED=0.7.0
  43 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  44 TELEPATHY_GLIB_REQUIRED=0.15.1
  45 TELEPATHY_LOGGER=0.2.0
  46
  47 # Optional deps
  48 CLUTTER_GTK_REQUIRED=0.90.3
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  53 LIBCHAMPLAIN_REQUIRED=0.9
  54 NAUTILUS_SENDTO_REQUIRED=2.90.0
  55 NETWORK_MANAGER_REQUIRED=0.7.0
  56 WEBKIT_REQUIRED=1.3.2
  57 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  58
  59 # Use --enable-maintainer-mode to disable deprecated symbols,
  60 # disable single include and enable GSEAL. If this is not a released empathy,
  61 # maintainer mode is forced
  62 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  63 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  64 #GNOME_MAINTAINER_MODE_DEFINES
  65
  66 # telepathy-yell
  67 prev_top_build_prefix=$ac_top_build_prefix
  68 AX_CONFIG_DIR([telepathy-yell])
  69 ac_top_build_prefix=$prev_top_build_prefix
  70 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  71
  72 AC_CONFIG_MACRO_DIR([m4])
  73 AC_CONFIG_HEADERS([config.h])
  74 AC_CONFIG_SRCDIR([configure.ac])
  75 AC_CONFIG_AUX_DIR(.)
  76
  77 GNOME_COMMON_INIT
  78
  79 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  80
  81 # Support silent build rules, requires at least automake-1.11. Disable
  82 # by either passing --disable-silent-rules to configure or passing V=1
  83 # to make
  84 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  85
  86 AC_ISC_POSIX
  87 AC_PROG_CC
  88 AC_HEADER_STDC
  89 AM_PROG_LIBTOOL
  90 AM_PROG_MKDIR_P
  91 AM_PATH_GLIB_2_0
  92 AC_PATH_XTRA
  93 IT_PROG_INTLTOOL([0.35.0])
  94 GNOME_DOC_INIT([0.17.3])
  95 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  96 GLIB_GSETTINGS
  97 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  98 AC_SUBST(GLIB_GENMARSHAL)
  99
 100 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 101 if test -z "$XSLTPROC"; then
 102   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 103 fi
 104 AM_PATH_PYTHON([2.3])
 105
 106 EMPATHY_ARG_VALGRIND
 107
 108
 109 # -----------------------------------------------------------
 110 # Error flags
 111 # -----------------------------------------------------------
 112 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 113 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 114
 115 AC_ARG_ENABLE(Werror,
 116   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 117     werror=$enableval, :)
 118
 119 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 120 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 121         wno_missing_field_initializers=yes,
 122         wno_missing_field_initializers=no)
 123 AS_COMPILER_FLAG(-Wno-unused-parameter,
 124         wno_unused_parameter=yes,
 125         wno_unused_parameter=no)
 126
 127 ifelse(empathy_released, 1, [],
 128     [
 129         if test x$werror = xyes; then
 130             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 131         fi
 132         if test x$wextra = xyes -a \
 133             x$wno_missing_field_initializers = xyes -a \
 134             x$wno_unused_parameter = xyes; then
 135             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 136         fi
 137     ])
 138
 139 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 140 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 141 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 142 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 143 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 144
 145 AC_SUBST(ERROR_CFLAGS)
 146
 147 # -----------------------------------------------------------
 148 # Pkg-Config dependency checks
 149 # -----------------------------------------------------------
 150
 151 PKG_CHECK_MODULES(EMPATHY,
 152 [
 153    dbus-glib-1
 154    folks >= $FOLKS_REQUIRED
 155    folks-telepathy >= $FOLKS_REQUIRED
 156    glib-2.0 >= $GLIB_REQUIRED
 157    gio-2.0 >= $GLIB_REQUIRED
 158    gio-unix-2.0 >= $GLIB_REQUIRED
 159    gnome-keyring-1 >= $KEYRING_REQUIRED
 160    gnutls >= $GNUTLS_REQUIRED
 161    gmodule-export-2.0
 162    gobject-2.0
 163    gsettings-desktop-schemas
 164    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 165    gstreamer-interfaces-0.10
 166    libxml-2.0
 167    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 168    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 169    x11
 170    gtk+-3.0 >= $GTK_REQUIRED
 171    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 172    libnotify >= $LIBNOTIFY_REQUIRED
 173    gcr-3 >= $GCR_REQUIRED
 174 ])
 175
 176 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 177
 178 PKG_CHECK_MODULES(EMPATHY_AV,
 179 [
 180    farsight2-0.10
 181    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 182 ])
 183
 184 # -----------------------------------------------------------
 185 # Call interface
 186 # -----------------------------------------------------------
 187 AC_ARG_WITH(call,
 188             AC_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 189             [build with Call interface support]),,
 190             [with_call=auto])
 191 if test "x$with_call" != "xno" ; then
 192    PKG_CHECK_MODULES(EMPATHY_CALL,
 193    [
 194       farsight2-0.10
 195       telepathy-farstream
 196    ], have_farstream="yes", have_farstream="no" )
 197
 198    if test "x$have_farstream" = "xyes"; then
 199       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 200    fi
 201 else
 202   have_farstream=no
 203 fi
 204
 205 if test "x$with_call" = "xyes" -a "x$have_farstream" != "xyes"; then
 206    AC_MSG_ERROR([Could not find Call handler dependencies.])
 207 fi
 208 AM_CONDITIONAL(HAVE_CALL, test "x$have_farstream" = "xyes")
 209
 210 # -----------------------------------------------------------
 211 # evolution-data-server (about-me)
 212 # -----------------------------------------------------------
 213 AC_ARG_WITH(eds,
 214             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 215             [with_eds=yes])
 216 if test x"$with_eds" = x"yes" ; then
 217    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 218    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 219 fi
 220
 221 # -----------------------------------------------------------
 222 # Enable debug
 223 # -----------------------------------------------------------
 224
 225 AC_ARG_ENABLE(debug,
 226   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 227     enable_debug=$enableval, enable_debug=yes )
 228
 229 if test x$enable_debug = xyes; then
 230   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 231 fi
 232
 233 # -----------------------------------------------------------
 234 # Language Support
 235 # -----------------------------------------------------------
 236
 237 GETTEXT_PACKAGE=empathy
 238 AC_SUBST(GETTEXT_PACKAGE)
 239 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 240
 241 AM_GLIB_GNU_GETTEXT
 242
 243 # -----------------------------------------------------------
 244 # Connectivity integration
 245 # -----------------------------------------------------------
 246 AC_ARG_WITH(connectivity,
 247               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 248                              [build with connectivity support]), ,
 249                              with_connectivity=auto)
 250
 251 if test "x$with_connectivity" = "xno"; then
 252    have_nm=no
 253    have_connman=no
 254
 255 elif test "x$with_connectivity" = "xconnman"; then
 256    have_nm=no
 257
 258    PKG_CHECK_MODULES(CONNMAN,
 259    [
 260       dbus-glib-1
 261    ], have_connman="yes", have_connman="no")
 262
 263    if test "x$have_connman" = "xyes"; then
 264       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 265    fi
 266
 267 else
 268    have_connman=no
 269
 270    PKG_CHECK_MODULES(NETWORK_MANAGER,
 271    [
 272       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 273    ], have_nm="yes", have_nm="no")
 274
 275    if test "x$have_nm" = "xyes"; then
 276       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 277    fi
 278 fi
 279
 280 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 281    AC_MSG_ERROR([Couldn't find connman dependencies.])
 282 fi
 283
 284 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 285    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 286 fi
 287
 288 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 289 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 290
 291 # -----------------------------------------------------------
 292 # Webkit
 293 # -----------------------------------------------------------
 294 AC_ARG_ENABLE(webkit,
 295               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 296                              [build with webkit support]), ,
 297                              enable_webkit=auto)
 298
 299 if test "x$enable_webkit" != "xno"; then
 300    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 301         have_webkit="yes", have_webkit="no")
 302
 303    if test "x$have_webkit" = "xyes"; then
 304       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 305    fi
 306 else
 307    have_webkit=no
 308 fi
 309
 310 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 311    AC_MSG_ERROR([Could not find webkit dependencies.])
 312 fi
 313 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 314
 315 # -----------------------------------------------------------
 316 # spellchecking checks: enchant and iso-codes
 317 # -----------------------------------------------------------
 318 AC_ARG_ENABLE(spell,
 319               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 320                              [Enable spell checking]), ,
 321                              enable_spell=auto)
 322
 323 if test "x$enable_spell" != "xno"; then
 324    PKG_CHECK_MODULES(ENCHANT,
 325    [
 326       enchant >= $ENCHANT_REQUIRED,
 327       iso-codes >= $ISO_CODES_REQUIRED
 328    ], have_enchant="yes", have_enchant="no")
 329
 330    if test "x$have_enchant" = "xyes"; then
 331       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 332       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 333          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 334             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 335             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 336             result=yes
 337       else
 338             result=no
 339             have_enchant="no"
 340       fi
 341       AC_MSG_RESULT([$result])
 342    fi
 343 else
 344    have_enchant=no
 345 fi
 346
 347 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 348    AC_MSG_ERROR([Could not find spell dependencies.])
 349 fi
 350
 351 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 352
 353 # -----------------------------------------------------------
 354 # Map view checks: libchamplain
 355 # -----------------------------------------------------------
 356 AC_ARG_ENABLE(map,
 357               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 358                              [Enable map view]), ,
 359                              enable_map=auto)
 360
 361 if test "x$enable_map" != "xno"; then
 362
 363    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 364     [
 365        clutter-gtk-1.0
 366        champlain-gtk-0.10
 367        champlain-0.10
 368     ], have_libchamplain="yes", have_libchamplain="no")
 369
 370    if test "x$have_libchamplain" = "xyes"; then
 371       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 372    fi
 373 else
 374    have_libchamplain=no
 375 fi
 376
 377 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 378    AC_MSG_ERROR([Could not find map view dependencies.])
 379 fi
 380
 381 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 382
 383 # -----------------------------------------------------------
 384 # location checks: geoclue
 385 # -----------------------------------------------------------
 386 AC_ARG_ENABLE(location,
 387               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 388                              [Enable location awareness]), ,
 389                              enable_location=auto)
 390
 391 if test "x$enable_location" != "xno"; then
 392    PKG_CHECK_MODULES(GEOCLUE,
 393    [
 394       geoclue >= $GEOCLUE_REQUIRED
 395    ], have_geoclue="yes", have_geoclue="no")
 396
 397    if test "x$have_geoclue" = "xyes"; then
 398       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 399    fi
 400 else
 401    have_geoclue="no"
 402 fi
 403
 404 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 405    AC_MSG_ERROR([Could not find location dependencies.])
 406 fi
 407
 408 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 409 AC_SUBST(GEOCLUE_CFLAGS)
 410 AC_SUBST(GEOCLUE_LIBS)
 411
 412 # -----------------------------------------------------------
 413 # meego widgets support
 414 # -----------------------------------------------------------
 415 AC_ARG_ENABLE(meego,
 416               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 417                              [Enable meego widgets]), ,
 418                              enable_meego=no)
 419
 420 if test "x$enable_meego" != "xno"; then
 421     PKG_CHECK_MODULES(MEEGO,
 422     [
 423        mx-gtk-1.0
 424        gio-unix-2.0
 425     ], have_meego="yes", have_meego="no")
 426
 427     if test "x$have_meego" = "xyes"; then
 428        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 429     fi
 430 else
 431    have_meego="no"
 432 fi
 433
 434 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 435    AC_MSG_ERROR([Could not find meego dependencies.])
 436 fi
 437
 438 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 439 AC_SUBST(MEEGO_CFLAGS)
 440 AC_SUBST(MEEGO_LIBS)
 441
 442 # -----------------------------------------------------------
 443 # nautilus-sendto
 444 # -----------------------------------------------------------
 445 AC_ARG_ENABLE(nautilus-sendto,
 446               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 447                              [build nautilus-sendto plugin]), ,
 448                              enable_nautilus_sendto=auto)
 449
 450 if test "x$enable_nautilus_sendto" != "xno"; then
 451    PKG_CHECK_MODULES(NST,
 452     [
 453        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 454     ], have_nst="yes", have_nst="no")
 455 else
 456    have_nst=no
 457 fi
 458
 459 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 460    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 461 fi
 462
 463 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 464
 465 # -----------------------------------------------------------
 466 # new, single-window control center
 467 # -----------------------------------------------------------
 468 AC_ARG_ENABLE(control_center_embedding,
 469               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 470                              [Enable support for single-window control center]),
 471                              , enable_control_center_embedding=auto)
 472
 473 if test "x$enable_control_center_embedding" != "xno"; then
 474
 475    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 476         have_control_center_embedding="yes", have_control_center_embedding="no")
 477
 478    if test "x$have_control_center_embedding" = "xyes"; then
 479       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 480
 481       AC_MSG_CHECKING([gnome-control-center extension dir])
 482       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 483       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 484           AC_MSG_ERROR([Could not determine extensiondir])
 485       else
 486           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 487       fi
 488       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 489    fi
 490 else
 491    have_control_center_embedding="no"
 492 fi
 493
 494 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 495    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 496 fi
 497
 498 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 499 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 500 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 501
 502 # Optional dependency for avatar selection
 503 AC_ARG_WITH([cheese],
 504             AS_HELP_STRING([--with-cheese], [enable cheese webcam support]),,
 505             with_cheese=auto)
 506
 507 if test x"$with_cheese" != x"no" ; then
 508    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 509    if test x${have_cheese} = xyes; then
 510      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 511    fi
 512    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 513      AC_MSG_ERROR([Cheese configured but not found])
 514    fi
 515 else
 516    have_cheese=no
 517 fi
 518 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 519
 520
 521 # -----------------------------------------------------------
 522 # Coding style checks
 523 # -----------------------------------------------------------
 524 AC_ARG_ENABLE(coding-style-checks,
 525   AC_HELP_STRING([--disable-coding-style-checks],
 526                  [do not check coding style using grep]),
 527     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 528
 529 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 530 # -----------------------------------------------------------
 531
 532 AC_OUTPUT([
 533    Makefile
 534    data/Makefile
 535    data/empathy.desktop.in
 536    data/empathy-accounts.desktop.in
 537    data/icons/Makefile
 538    extensions/Makefile
 539    po/Makefile.in
 540    libempathy/Makefile
 541    libempathy-gtk/Makefile
 542    src/Makefile
 543    nautilus-sendto-plugin/Makefile
 544    help/Makefile
 545    tests/Makefile
 546    tests/interactive/Makefile
 547    tests/xml/Makefile
 548    tools/Makefile
 549 ])
 550
 551 echo "
 552 Configure summary:
 553
 554         Compiler....................:  ${CC}
 555         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 556         Prefix......................:  ${prefix}
 557         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 558
 559     Features:
 560         Spell checking (enchant)....:  ${have_enchant}
 561         Display maps (libchamplain).:  ${have_libchamplain}
 562         Location awareness (Geoclue):  ${have_geoclue}
 563         Adium themes (Webkit).......:  ${have_webkit}
 564         Meego widgets...............:  ${have_meego}
 565         Control center embedding....:  ${have_control_center_embedding}
 566         Cheese webcam support ......:  ${have_cheese}
 567
 568     Connectivity:
 569         NetworkManager integration..:  ${have_nm}
 570         ConnMan integration.........:  ${have_connman}
 571
 572     Extras:
 573         Nautilus-sendto plugin......:  ${have_nst}
 574         Salut E-D-S support.........:  ${with_eds}
 575         Exp. Call channel handler...:  ${have_farstream}
 576 "