configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.0
  38 GLIB_REQUIRED=2.28.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  47 TELEPATHY_GLIB_REQUIRED=0.15.3
  48 TELEPATHY_LOGGER=0.2.10
  49
  50 # Optional deps
  51 CLUTTER_GTK_REQUIRED=0.90.3
  52 ENCHANT_REQUIRED=1.2.0
  53 GEOCLUE_REQUIRED=0.11
  54 ISO_CODES_REQUIRED=0.35
  55 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  56 LIBCHAMPLAIN_REQUIRED=0.9
  57 NAUTILUS_SENDTO_REQUIRED=2.90.0
  58 NETWORK_MANAGER_REQUIRED=0.7.0
  59 WEBKIT_REQUIRED=1.3.13
  60 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # telepathy-yell
  70 prev_top_build_prefix=$ac_top_build_prefix
  71 prev_ac_configure_args=$ac_configure_args
  72 ac_configure_args="$ac_configure_args --disable-shared-library"
  73 AX_CONFIG_DIR([telepathy-yell])
  74 ac_top_build_prefix=$prev_top_build_prefix
  75 ac_configure_args=$prev_ac_configure_args
  76 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 GNOME_DOC_INIT([0.17.3])
 102 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 103 GLIB_GSETTINGS
 104 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 105 AC_SUBST(GLIB_GENMARSHAL)
 106
 107 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 108 if test -z "$XSLTPROC"; then
 109   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 110 fi
 111 AM_PATH_PYTHON([2.3])
 112
 113 EMPATHY_ARG_VALGRIND
 114
 115
 116 # -----------------------------------------------------------
 117 # Error flags
 118 # -----------------------------------------------------------
 119 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 120 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 121
 122 AC_ARG_ENABLE(Werror,
 123   AS_HELP_STRING([--disable-Werror],
 124                  [compile without -Werror (normally enabled in development builds)]),
 125     werror=$enableval, :)
 126
 127 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 128 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 129         wno_missing_field_initializers=yes,
 130         wno_missing_field_initializers=no)
 131 AS_COMPILER_FLAG(-Wno-unused-parameter,
 132         wno_unused_parameter=yes,
 133         wno_unused_parameter=no)
 134
 135 ifelse(empathy_released, 1, [],
 136     [
 137         if test x$werror = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 139         fi
 140         if test x$wextra = xyes -a \
 141             x$wno_missing_field_initializers = xyes -a \
 142             x$wno_unused_parameter = xyes; then
 143             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 144         fi
 145     ])
 146
 147 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 148 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 149 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 150 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 151 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 152
 153 AC_SUBST(ERROR_CFLAGS)
 154
 155 # -----------------------------------------------------------
 156 # Pkg-Config dependency checks
 157 # -----------------------------------------------------------
 158
 159 PKG_CHECK_MODULES(EMPATHY,
 160 [
 161    dbus-glib-1
 162    folks >= $FOLKS_REQUIRED
 163    folks-telepathy >= $FOLKS_REQUIRED
 164    glib-2.0 >= $GLIB_REQUIRED
 165    gio-2.0 >= $GLIB_REQUIRED
 166    gio-unix-2.0 >= $GLIB_REQUIRED
 167    gnome-keyring-1 >= $KEYRING_REQUIRED
 168    gnutls >= $GNUTLS_REQUIRED
 169    gmodule-export-2.0
 170    gobject-2.0
 171    gsettings-desktop-schemas
 172    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 173    gstreamer-interfaces-0.10
 174    libxml-2.0
 175    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 176    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 177    x11
 178    gtk+-3.0 >= $GTK_REQUIRED
 179    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 180    libnotify >= $LIBNOTIFY_REQUIRED
 181    gcr-3 >= $GCR_REQUIRED
 182    libpulse
 183    libpulse-mainloop-glib
 184 ])
 185
 186 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 187
 188 PKG_CHECK_MODULES(EMPATHY_AV,
 189 [
 190    farsight2-0.10
 191    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 192 ])
 193
 194 # -----------------------------------------------------------
 195 # Call interface
 196 # -----------------------------------------------------------
 197 AC_ARG_ENABLE(call,
 198             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 199             [build with Call interface support]),,
 200             [enable_call=auto])
 201 if test "x$enable_call" != "xno" ; then
 202    PKG_CHECK_MODULES(EMPATHY_CALL,
 203    [
 204       farsight2-0.10
 205       telepathy-farstream
 206       clutter-1.0
 207       clutter-gtk-1.0
 208       clutter-gst-1.0
 209    ], have_call="yes", have_call="no" )
 210
 211    if test "x$have_call" = "xyes"; then
 212       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 213    fi
 214 else
 215   have_call=no
 216 fi
 217
 218 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 219    AC_MSG_ERROR([Could not find Call handler dependencies.])
 220 fi
 221 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 222
 223
 224 # -----------------------------------------------------------
 225 # Call support in tp-logger
 226 # -----------------------------------------------------------
 227 AC_ARG_ENABLE(call-logs,
 228             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 229             [build with call logs support]),,
 230             [enable_call_logs=auto])
 231 if test "x$enable_call_logs" != "xno" ; then
 232    SAVE_CFLAGS=$CFLAGS
 233    SAVE_CPPFLAGS=$CPPFLAGS
 234    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 235    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 236
 237    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 238       have_call_logs="yes", have_call_logs="no")
 239
 240    CFLAGS=$SAVE_CFLAGS
 241    CPPFLAGS=$SAVE_CPPFLAGS
 242
 243    if test "x$have_call_logs" = "xyes"; then
 244       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 245    fi
 246 else
 247   have_call_logs=no
 248 fi
 249
 250 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 251    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 252                  built with --enable-call])
 253 fi
 254
 255 # -----------------------------------------------------------
 256 # evolution-data-server (about-me)
 257 # -----------------------------------------------------------
 258 AC_ARG_WITH(eds,
 259             AS_HELP_STRING([--with-eds],
 260                            [build with evolution-data-server support]),,
 261             [with_eds=yes])
 262 if test x"$with_eds" = x"yes" ; then
 263    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 264    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 265 fi
 266
 267 # -----------------------------------------------------------
 268 # Enable debug
 269 # -----------------------------------------------------------
 270
 271 AC_ARG_ENABLE(debug,
 272   AS_HELP_STRING([--disable-debug],
 273                  [compile without debug code]),
 274     enable_debug=$enableval, enable_debug=yes )
 275
 276 if test x$enable_debug = xyes; then
 277   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 278 fi
 279
 280 # -----------------------------------------------------------
 281 # Language Support
 282 # -----------------------------------------------------------
 283 IT_PROG_INTLTOOL([0.40.0])
 284
 285 AM_GNU_GETTEXT_VERSION([0.17])
 286 AM_GNU_GETTEXT([external])
 287
 288 GETTEXT_PACKAGE=empathy
 289 AC_SUBST(GETTEXT_PACKAGE)
 290 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 291
 292 # -----------------------------------------------------------
 293 # Connectivity integration
 294 # -----------------------------------------------------------
 295 AC_ARG_WITH(connectivity,
 296               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 297                              [build with connectivity support]), ,
 298                              with_connectivity=auto)
 299
 300 if test "x$with_connectivity" = "xno"; then
 301    have_nm=no
 302    have_connman=no
 303
 304 elif test "x$with_connectivity" = "xconnman"; then
 305    have_nm=no
 306
 307    PKG_CHECK_MODULES(CONNMAN,
 308    [
 309       dbus-glib-1
 310    ], have_connman="yes", have_connman="no")
 311
 312    if test "x$have_connman" = "xyes"; then
 313       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 314    fi
 315
 316 else
 317    have_connman=no
 318
 319    PKG_CHECK_MODULES(NETWORK_MANAGER,
 320    [
 321       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 322    ], have_nm="yes", have_nm="no")
 323
 324    if test "x$have_nm" = "xyes"; then
 325       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 326    fi
 327 fi
 328
 329 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 330    AC_MSG_ERROR([Couldn't find connman dependencies.])
 331 fi
 332
 333 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 334    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 335 fi
 336
 337 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 338 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 339
 340 # -----------------------------------------------------------
 341 # Webkit
 342 # -----------------------------------------------------------
 343 AC_ARG_ENABLE(webkit,
 344               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 345                              [build with webkit support]), ,
 346                              enable_webkit=auto)
 347
 348 if test "x$enable_webkit" != "xno"; then
 349    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 350         have_webkit="yes", have_webkit="no")
 351
 352    if test "x$have_webkit" = "xyes"; then
 353       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 354    fi
 355 else
 356    have_webkit=no
 357 fi
 358
 359 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 360    AC_MSG_ERROR([Could not find webkit dependencies.])
 361 fi
 362 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 363
 364 # -----------------------------------------------------------
 365 # gudev
 366 # -----------------------------------------------------------
 367 AC_ARG_ENABLE(gudev,
 368               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 369                              [build with gudev support]), ,
 370                              enable_gudev=auto)
 371
 372 if test "x$enable_gudev" != "xno"; then
 373
 374    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 375         have_gudev="yes", have_gudev="no")
 376
 377    if test "x$have_gudev" = "xyes"; then
 378       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 379    fi
 380 else
 381    have_gudev=no
 382 fi
 383
 384 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 385    AC_MSG_ERROR([Could not find gudev dependencies.])
 386 fi
 387 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 388
 389 # -----------------------------------------------------------
 390 # spellchecking checks: enchant and iso-codes
 391 # -----------------------------------------------------------
 392 AC_ARG_ENABLE(spell,
 393               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 394                              [Enable spell checking]), ,
 395                              enable_spell=auto)
 396
 397 if test "x$enable_spell" != "xno"; then
 398    PKG_CHECK_MODULES(ENCHANT,
 399    [
 400       enchant >= $ENCHANT_REQUIRED,
 401       iso-codes >= $ISO_CODES_REQUIRED
 402    ], have_enchant="yes", have_enchant="no")
 403
 404    if test "x$have_enchant" = "xyes"; then
 405       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 406       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 407          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 408             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 409             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 410             result=yes
 411       else
 412             result=no
 413             have_enchant="no"
 414       fi
 415       AC_MSG_RESULT([$result])
 416    fi
 417 else
 418    have_enchant=no
 419 fi
 420
 421 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 422    AC_MSG_ERROR([Could not find spell dependencies.])
 423 fi
 424
 425 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 426
 427 # -----------------------------------------------------------
 428 # Map view checks: libchamplain
 429 # -----------------------------------------------------------
 430 AC_ARG_ENABLE(map,
 431               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 432                              [Enable map view]), ,
 433                              enable_map=auto)
 434
 435 if test "x$enable_map" != "xno"; then
 436
 437    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 438     [
 439        clutter-gtk-1.0
 440        champlain-gtk-0.10
 441        champlain-0.10
 442     ], have_libchamplain="yes", have_libchamplain="no")
 443
 444    if test "x$have_libchamplain" = "xyes"; then
 445       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 446    fi
 447 else
 448    have_libchamplain=no
 449 fi
 450
 451 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 452    AC_MSG_ERROR([Could not find map view dependencies.])
 453 fi
 454
 455 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 456
 457 # -----------------------------------------------------------
 458 # location checks: geoclue
 459 # -----------------------------------------------------------
 460 AC_ARG_ENABLE(location,
 461               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 462                              [Enable location awareness]), ,
 463                              enable_location=auto)
 464
 465 if test "x$enable_location" != "xno"; then
 466    PKG_CHECK_MODULES(GEOCLUE,
 467    [
 468       geoclue >= $GEOCLUE_REQUIRED
 469    ], have_geoclue="yes", have_geoclue="no")
 470
 471    if test "x$have_geoclue" = "xyes"; then
 472       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 473    fi
 474 else
 475    have_geoclue="no"
 476 fi
 477
 478 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 479    AC_MSG_ERROR([Could not find location dependencies.])
 480 fi
 481
 482 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 483 AC_SUBST(GEOCLUE_CFLAGS)
 484 AC_SUBST(GEOCLUE_LIBS)
 485
 486 # -----------------------------------------------------------
 487 # location checks: geocode-glib
 488 # -----------------------------------------------------------
 489 AC_ARG_ENABLE(geocode,
 490               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 491                              [Enable geocode support]), ,
 492                              enable_geocode=auto)
 493
 494 if test "x$enable_geocode" != "xno"; then
 495    PKG_CHECK_MODULES(GEOCODE,
 496    [
 497       geocode-glib
 498    ], have_geocode="yes", have_geocode="no")
 499
 500    if test "x$have_geocode" = "xyes"; then
 501       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 502    fi
 503 else
 504    have_geocode="no"
 505 fi
 506
 507 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 508    AC_MSG_ERROR([Could not find geocode dependencies.])
 509 fi
 510
 511 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 512 AC_SUBST(GEOCODE_CFLAGS)
 513 AC_SUBST(GEOCODE_LIBS)
 514
 515 # -----------------------------------------------------------
 516 # meego widgets support
 517 # -----------------------------------------------------------
 518 AC_ARG_ENABLE(meego,
 519               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 520                              [Enable meego widgets]), ,
 521                              enable_meego=no)
 522
 523 if test "x$enable_meego" != "xno"; then
 524     PKG_CHECK_MODULES(MEEGO,
 525     [
 526        mx-gtk-1.0
 527        gio-unix-2.0
 528     ], have_meego="yes", have_meego="no")
 529
 530     if test "x$have_meego" = "xyes"; then
 531        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 532     fi
 533 else
 534    have_meego="no"
 535 fi
 536
 537 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 538    AC_MSG_ERROR([Could not find meego dependencies.])
 539 fi
 540
 541 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 542 AC_SUBST(MEEGO_CFLAGS)
 543 AC_SUBST(MEEGO_LIBS)
 544
 545 # -----------------------------------------------------------
 546 # nautilus-sendto
 547 # -----------------------------------------------------------
 548 AC_ARG_ENABLE(nautilus-sendto,
 549               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 550                              [build nautilus-sendto plugin]), ,
 551                              enable_nautilus_sendto=auto)
 552
 553 if test "x$enable_nautilus_sendto" != "xno"; then
 554    PKG_CHECK_MODULES(NST,
 555     [
 556        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 557     ], have_nst="yes", have_nst="no")
 558 else
 559    have_nst=no
 560 fi
 561
 562 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 563    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 564 fi
 565
 566 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 567
 568 # -----------------------------------------------------------
 569 # new, single-window control center
 570 # -----------------------------------------------------------
 571 AC_ARG_ENABLE(control_center_embedding,
 572               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 573                              [Enable support for single-window control center]),
 574                              , enable_control_center_embedding=auto)
 575
 576 if test "x$enable_control_center_embedding" != "xno"; then
 577
 578    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 579         have_control_center_embedding="yes", have_control_center_embedding="no")
 580
 581    if test "x$have_control_center_embedding" = "xyes"; then
 582       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 583
 584       AC_MSG_CHECKING([gnome-control-center extension dir])
 585       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 586       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 587           AC_MSG_ERROR([Could not determine extensiondir])
 588       else
 589           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 590       fi
 591       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 592    fi
 593 else
 594    have_control_center_embedding="no"
 595 fi
 596
 597 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 598    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 599 fi
 600
 601 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 602 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 603 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 604
 605 # Optional dependency for avatar selection
 606 AC_ARG_WITH([cheese],
 607             AS_HELP_STRING([--with-cheese],
 608                            [enable cheese webcam support]),,
 609             with_cheese=auto)
 610
 611 if test x"$with_cheese" != x"no" ; then
 612    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 613    if test x${have_cheese} = xyes; then
 614      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 615    fi
 616    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 617      AC_MSG_ERROR([Cheese configured but not found])
 618    fi
 619 else
 620    have_cheese=no
 621 fi
 622 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 623
 624
 625 # -----------------------------------------------------------
 626 # Coding style checks
 627 # -----------------------------------------------------------
 628 AC_ARG_ENABLE(coding-style-checks,
 629   AS_HELP_STRING([--disable-coding-style-checks],
 630                  [do not check coding style using grep]),
 631     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 632     [ENABLE_CODING_STYLE_CHECKS=yes])
 633
 634 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 635 # -----------------------------------------------------------
 636
 637 AC_CONFIG_FILES([
 638    Makefile
 639    data/Makefile
 640    data/empathy.desktop.in
 641    data/empathy-accounts.desktop.in
 642    data/icons/Makefile
 643    extensions/Makefile
 644    po/Makefile.in
 645    libempathy/Makefile
 646    libempathy-gtk/Makefile
 647    src/Makefile
 648    nautilus-sendto-plugin/Makefile
 649    help/Makefile
 650    tests/Makefile
 651    tests/interactive/Makefile
 652    tests/xml/Makefile
 653    tools/Makefile
 654 ])
 655 AC_OUTPUT
 656
 657 echo "
 658 Configure summary:
 659
 660         Compiler....................:  ${CC}
 661         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 662         Prefix......................:  ${prefix}
 663         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 664
 665     Features:
 666         Spell checking (enchant)....:  ${have_enchant}
 667         Display maps (libchamplain).:  ${have_libchamplain}
 668         Location awareness (Geoclue):  ${have_geoclue}
 669         Geocode support (Geoclue)...:  ${have_geocode}
 670         Adium themes (Webkit).......:  ${have_webkit}
 671         Meego widgets...............:  ${have_meego}
 672         Control center embedding....:  ${have_control_center_embedding}
 673         Cheese webcam support ......:  ${have_cheese}
 674         Camera monitoring...........:  ${have_gudev}
 675
 676     Connectivity:
 677         NetworkManager integration..:  ${have_nm}
 678         ConnMan integration.........:  ${have_connman}
 679
 680     Extras:
 681         Nautilus-sendto plugin......:  ${have_nst}
 682         Salut E-D-S support.........:  ${with_eds}
 683         Exp. Call channel handler...:  ${have_call}
 684         Exp. Call log support.......:  ${have_call_logs}
 685 "