configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.0
  38 GLIB_REQUIRED=2.28.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  47 TELEPATHY_GLIB_REQUIRED=0.15.5
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50
  51 # Optional deps
  52 CLUTTER_GTK_REQUIRED=0.90.3
  53 ENCHANT_REQUIRED=1.2.0
  54 GEOCLUE_REQUIRED=0.11
  55 ISO_CODES_REQUIRED=0.35
  56 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  57 LIBCHAMPLAIN_REQUIRED=0.9
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # telepathy-yell
  70 prev_top_build_prefix=$ac_top_build_prefix
  71 prev_ac_configure_args=$ac_configure_args
  72 ac_configure_args="$ac_configure_args --disable-shared-library"
  73 AX_CONFIG_DIR([telepathy-yell])
  74 ac_top_build_prefix=$prev_top_build_prefix
  75 ac_configure_args=$prev_ac_configure_args
  76 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 GNOME_DOC_INIT([0.17.3])
 102 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 103 GLIB_GSETTINGS
 104 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 105 AC_SUBST(GLIB_GENMARSHAL)
 106
 107 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 108 if test -z "$XSLTPROC"; then
 109   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 110 fi
 111 AM_PATH_PYTHON([2.3])
 112
 113 EMPATHY_ARG_VALGRIND
 114
 115
 116 # -----------------------------------------------------------
 117 # Error flags
 118 # -----------------------------------------------------------
 119 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 120 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 121
 122 AC_ARG_ENABLE(Werror,
 123   AS_HELP_STRING([--disable-Werror],
 124                  [compile without -Werror (normally enabled in development builds)]),
 125     werror=$enableval, :)
 126
 127 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 128 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 129         wno_missing_field_initializers=yes,
 130         wno_missing_field_initializers=no)
 131 AS_COMPILER_FLAG(-Wno-unused-parameter,
 132         wno_unused_parameter=yes,
 133         wno_unused_parameter=no)
 134
 135 ifelse(empathy_released, 1, [],
 136     [
 137         if test x$werror = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 139         fi
 140         if test x$wextra = xyes -a \
 141             x$wno_missing_field_initializers = xyes -a \
 142             x$wno_unused_parameter = xyes; then
 143             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 144         fi
 145     ])
 146
 147 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 148 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 149 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 150 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 151 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 152
 153 AC_SUBST(ERROR_CFLAGS)
 154
 155 AC_ARG_ENABLE(gprof,
 156             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 157             [build with support for gprof]),,
 158             [enable_gprof=no])
 159 if test "x$enable_gprof" != "xno" ; then
 160     CFLAGS="$CFLAGS -pg"
 161     LDFLAGS="$LDFLAGS -pg"
 162 fi
 163
 164 AC_SUBST(LDFLAGS)
 165
 166 # -----------------------------------------------------------
 167 # Pkg-Config dependency checks
 168 # -----------------------------------------------------------
 169
 170 PKG_CHECK_MODULES(EMPATHY,
 171 [
 172    dbus-glib-1
 173    folks >= $FOLKS_REQUIRED
 174    folks-telepathy >= $FOLKS_REQUIRED
 175    glib-2.0 >= $GLIB_REQUIRED
 176    gio-2.0 >= $GLIB_REQUIRED
 177    gio-unix-2.0 >= $GLIB_REQUIRED
 178    gnome-keyring-1 >= $KEYRING_REQUIRED
 179    gnutls >= $GNUTLS_REQUIRED
 180    gmodule-export-2.0
 181    gobject-2.0
 182    gsettings-desktop-schemas
 183    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 184    gstreamer-interfaces-0.10
 185    libxml-2.0
 186    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 187    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 188    x11
 189    gtk+-3.0 >= $GTK_REQUIRED
 190    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 191    libnotify >= $LIBNOTIFY_REQUIRED
 192    gcr-3 >= $GCR_REQUIRED
 193    libpulse
 194    libpulse-mainloop-glib
 195    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 196 ])
 197
 198 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 199
 200 PKG_CHECK_MODULES(EMPATHY_AV,
 201 [
 202    farsight2-0.10
 203    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 204 ])
 205
 206 # -----------------------------------------------------------
 207 # Call interface
 208 # -----------------------------------------------------------
 209 AC_ARG_ENABLE(call,
 210             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 211             [build with Call interface support]),,
 212             [enable_call=auto])
 213 if test "x$enable_call" != "xno" ; then
 214    PKG_CHECK_MODULES(EMPATHY_CALL,
 215    [
 216       farsight2-0.10
 217       telepathy-farstream
 218       clutter-1.0
 219       clutter-gtk-1.0
 220       clutter-gst-1.0
 221    ], have_call="yes", have_call="no" )
 222
 223    if test "x$have_call" = "xyes"; then
 224       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 225    fi
 226 else
 227   have_call=no
 228 fi
 229
 230 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 231    AC_MSG_ERROR([Could not find Call handler dependencies.])
 232 fi
 233 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 234
 235
 236 # -----------------------------------------------------------
 237 # Call support in tp-logger
 238 # -----------------------------------------------------------
 239 AC_ARG_ENABLE(call-logs,
 240             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 241             [build with call logs support]),,
 242             [enable_call_logs=auto])
 243 if test "x$enable_call_logs" != "xno" ; then
 244    SAVE_CFLAGS=$CFLAGS
 245    SAVE_CPPFLAGS=$CPPFLAGS
 246    SAVE_LDFLAGS=$LDFLAGS
 247    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 248    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 249    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 250
 251    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 252       have_call_logs="yes", have_call_logs="no")
 253
 254    CFLAGS=$SAVE_CFLAGS
 255    CPPFLAGS=$SAVE_CPPFLAGS
 256    LDFLAGS=$SAVE_LDFLAGS
 257
 258    if test "x$have_call_logs" = "xyes"; then
 259       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 260    fi
 261 else
 262   have_call_logs=no
 263 fi
 264
 265 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 266    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 267                  built with --enable-call])
 268 fi
 269
 270 # -----------------------------------------------------------
 271 # evolution-data-server (about-me)
 272 # -----------------------------------------------------------
 273 AC_ARG_WITH(eds,
 274             AS_HELP_STRING([--with-eds],
 275                            [build with evolution-data-server support]),,
 276             [with_eds=yes])
 277 if test x"$with_eds" = x"yes" ; then
 278    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 279    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 280 fi
 281
 282 # -----------------------------------------------------------
 283 # Enable debug
 284 # -----------------------------------------------------------
 285
 286 AC_ARG_ENABLE(debug,
 287   AS_HELP_STRING([--disable-debug],
 288                  [compile without debug code]),
 289     enable_debug=$enableval, enable_debug=yes )
 290
 291 if test x$enable_debug = xyes; then
 292   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 293 fi
 294
 295 # -----------------------------------------------------------
 296 # Language Support
 297 # -----------------------------------------------------------
 298 IT_PROG_INTLTOOL([0.40.0])
 299
 300 AM_GNU_GETTEXT_VERSION([0.17])
 301 AM_GNU_GETTEXT([external])
 302
 303 GETTEXT_PACKAGE=empathy
 304 AC_SUBST(GETTEXT_PACKAGE)
 305 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 306
 307 # -----------------------------------------------------------
 308 # Connectivity integration
 309 # -----------------------------------------------------------
 310 AC_ARG_WITH(connectivity,
 311               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 312                              [build with connectivity support]), ,
 313                              with_connectivity=auto)
 314
 315 if test "x$with_connectivity" = "xno"; then
 316    have_nm=no
 317    have_connman=no
 318
 319 elif test "x$with_connectivity" = "xconnman"; then
 320    have_nm=no
 321
 322    PKG_CHECK_MODULES(CONNMAN,
 323    [
 324       dbus-glib-1
 325    ], have_connman="yes", have_connman="no")
 326
 327    if test "x$have_connman" = "xyes"; then
 328       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 329    fi
 330
 331 else
 332    have_connman=no
 333
 334    PKG_CHECK_MODULES(NETWORK_MANAGER,
 335    [
 336       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 337    ], have_nm="yes", have_nm="no")
 338
 339    if test "x$have_nm" = "xyes"; then
 340       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 341    fi
 342 fi
 343
 344 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 345    AC_MSG_ERROR([Couldn't find connman dependencies.])
 346 fi
 347
 348 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 349    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 350 fi
 351
 352 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 353 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 354
 355 # -----------------------------------------------------------
 356 # gudev
 357 # -----------------------------------------------------------
 358 AC_ARG_ENABLE(gudev,
 359               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 360                              [build with gudev support]), ,
 361                              enable_gudev=auto)
 362
 363 if test "x$enable_gudev" != "xno"; then
 364
 365    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 366         have_gudev="yes", have_gudev="no")
 367
 368    if test "x$have_gudev" = "xyes"; then
 369       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 370    fi
 371 else
 372    have_gudev=no
 373 fi
 374
 375 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 376    AC_MSG_ERROR([Could not find gudev dependencies.])
 377 fi
 378 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 379
 380 # -----------------------------------------------------------
 381 # spellchecking checks: enchant and iso-codes
 382 # -----------------------------------------------------------
 383 AC_ARG_ENABLE(spell,
 384               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 385                              [Enable spell checking]), ,
 386                              enable_spell=auto)
 387
 388 if test "x$enable_spell" != "xno"; then
 389    PKG_CHECK_MODULES(ENCHANT,
 390    [
 391       enchant >= $ENCHANT_REQUIRED,
 392       iso-codes >= $ISO_CODES_REQUIRED
 393    ], have_enchant="yes", have_enchant="no")
 394
 395    if test "x$have_enchant" = "xyes"; then
 396       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 397       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 398          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 399             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 400             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 401             result=yes
 402       else
 403             result=no
 404             have_enchant="no"
 405       fi
 406       AC_MSG_RESULT([$result])
 407    fi
 408 else
 409    have_enchant=no
 410 fi
 411
 412 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 413    AC_MSG_ERROR([Could not find spell dependencies.])
 414 fi
 415
 416 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 417
 418 # -----------------------------------------------------------
 419 # Map view checks: libchamplain
 420 # -----------------------------------------------------------
 421 AC_ARG_ENABLE(map,
 422               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 423                              [Enable map view]), ,
 424                              enable_map=auto)
 425
 426 if test "x$enable_map" != "xno"; then
 427
 428    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 429     [
 430        clutter-gtk-1.0
 431        champlain-gtk-0.10
 432        champlain-0.10
 433     ], have_libchamplain="yes", have_libchamplain="no")
 434
 435    if test "x$have_libchamplain" = "xyes"; then
 436       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 437    fi
 438 else
 439    have_libchamplain=no
 440 fi
 441
 442 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 443    AC_MSG_ERROR([Could not find map view dependencies.])
 444 fi
 445
 446 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 447
 448 # -----------------------------------------------------------
 449 # location checks: geoclue
 450 # -----------------------------------------------------------
 451 AC_ARG_ENABLE(location,
 452               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 453                              [Enable location awareness]), ,
 454                              enable_location=auto)
 455
 456 if test "x$enable_location" != "xno"; then
 457    PKG_CHECK_MODULES(GEOCLUE,
 458    [
 459       geoclue >= $GEOCLUE_REQUIRED
 460    ], have_geoclue="yes", have_geoclue="no")
 461
 462    if test "x$have_geoclue" = "xyes"; then
 463       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 464    fi
 465 else
 466    have_geoclue="no"
 467 fi
 468
 469 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 470    AC_MSG_ERROR([Could not find location dependencies.])
 471 fi
 472
 473 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 474 AC_SUBST(GEOCLUE_CFLAGS)
 475 AC_SUBST(GEOCLUE_LIBS)
 476
 477 # -----------------------------------------------------------
 478 # location checks: geocode-glib
 479 # -----------------------------------------------------------
 480 AC_ARG_ENABLE(geocode,
 481               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 482                              [Enable geocode support]), ,
 483                              enable_geocode=auto)
 484
 485 if test "x$enable_geocode" != "xno"; then
 486    PKG_CHECK_MODULES(GEOCODE,
 487    [
 488       geocode-glib
 489    ], have_geocode="yes", have_geocode="no")
 490
 491    if test "x$have_geocode" = "xyes"; then
 492       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 493    fi
 494 else
 495    have_geocode="no"
 496 fi
 497
 498 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 499    AC_MSG_ERROR([Could not find geocode dependencies.])
 500 fi
 501
 502 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 503 AC_SUBST(GEOCODE_CFLAGS)
 504 AC_SUBST(GEOCODE_LIBS)
 505
 506 # -----------------------------------------------------------
 507 # meego widgets support
 508 # -----------------------------------------------------------
 509 AC_ARG_ENABLE(meego,
 510               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 511                              [Enable meego widgets]), ,
 512                              enable_meego=no)
 513
 514 if test "x$enable_meego" != "xno"; then
 515     PKG_CHECK_MODULES(MEEGO,
 516     [
 517        mx-gtk-1.0
 518        gio-unix-2.0
 519     ], have_meego="yes", have_meego="no")
 520
 521     if test "x$have_meego" = "xyes"; then
 522        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 523     fi
 524 else
 525    have_meego="no"
 526 fi
 527
 528 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 529    AC_MSG_ERROR([Could not find meego dependencies.])
 530 fi
 531
 532 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 533 AC_SUBST(MEEGO_CFLAGS)
 534 AC_SUBST(MEEGO_LIBS)
 535
 536 # -----------------------------------------------------------
 537 # nautilus-sendto
 538 # -----------------------------------------------------------
 539 AC_ARG_ENABLE(nautilus-sendto,
 540               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 541                              [build nautilus-sendto plugin]), ,
 542                              enable_nautilus_sendto=auto)
 543
 544 if test "x$enable_nautilus_sendto" != "xno"; then
 545    PKG_CHECK_MODULES(NST,
 546     [
 547        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 548     ], have_nst="yes", have_nst="no")
 549 else
 550    have_nst=no
 551 fi
 552
 553 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 554    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 555 fi
 556
 557 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 558
 559 # -----------------------------------------------------------
 560 # new, single-window control center
 561 # -----------------------------------------------------------
 562 AC_ARG_ENABLE(control_center_embedding,
 563               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 564                              [Enable support for single-window control center]),
 565                              , enable_control_center_embedding=auto)
 566
 567 if test "x$enable_control_center_embedding" != "xno"; then
 568
 569    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 570         have_control_center_embedding="yes", have_control_center_embedding="no")
 571
 572    if test "x$have_control_center_embedding" = "xyes"; then
 573       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 574
 575       AC_MSG_CHECKING([gnome-control-center extension dir])
 576       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 577       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 578           AC_MSG_ERROR([Could not determine extensiondir])
 579       else
 580           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 581       fi
 582       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 583    fi
 584 else
 585    have_control_center_embedding="no"
 586 fi
 587
 588 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 589    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 590 fi
 591
 592 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 593 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 594 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 595
 596 # Optional dependency for avatar selection
 597 AC_ARG_WITH([cheese],
 598             AS_HELP_STRING([--with-cheese],
 599                            [enable cheese webcam support]),,
 600             with_cheese=auto)
 601
 602 if test x"$with_cheese" != x"no" ; then
 603    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 604    if test x${have_cheese} = xyes; then
 605      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 606    fi
 607    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 608      AC_MSG_ERROR([Cheese configured but not found])
 609    fi
 610 else
 611    have_cheese=no
 612 fi
 613 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 614
 615
 616 # -----------------------------------------------------------
 617 # Coding style checks
 618 # -----------------------------------------------------------
 619 AC_ARG_ENABLE(coding-style-checks,
 620   AS_HELP_STRING([--disable-coding-style-checks],
 621                  [do not check coding style using grep]),
 622     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 623     [ENABLE_CODING_STYLE_CHECKS=yes])
 624
 625 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 626 # -----------------------------------------------------------
 627
 628 AC_CONFIG_FILES([
 629    Makefile
 630    data/Makefile
 631    data/empathy.desktop.in
 632    data/empathy-accounts.desktop.in
 633    data/icons/Makefile
 634    extensions/Makefile
 635    po/Makefile.in
 636    libempathy/Makefile
 637    libempathy-gtk/Makefile
 638    src/Makefile
 639    nautilus-sendto-plugin/Makefile
 640    help/Makefile
 641    tests/Makefile
 642    tests/interactive/Makefile
 643    tests/xml/Makefile
 644    tools/Makefile
 645 ])
 646 AC_OUTPUT
 647
 648 echo "
 649 Configure summary:
 650
 651         Compiler....................:  ${CC}
 652         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 653         Linker Flags................:  ${LDFLAGS}
 654         Prefix......................:  ${prefix}
 655         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 656
 657     Features:
 658         Spell checking (enchant)....:  ${have_enchant}
 659         Display maps (libchamplain).:  ${have_libchamplain}
 660         Location awareness (Geoclue):  ${have_geoclue}
 661         Geocode support (Geoclue)...:  ${have_geocode}
 662         Meego widgets...............:  ${have_meego}
 663         Control center embedding....:  ${have_control_center_embedding}
 664         Cheese webcam support ......:  ${have_cheese}
 665         Camera monitoring...........:  ${have_gudev}
 666
 667     Connectivity:
 668         NetworkManager integration..:  ${have_nm}
 669         ConnMan integration.........:  ${have_connman}
 670
 671     Extras:
 672         Nautilus-sendto plugin......:  ${have_nst}
 673         Salut E-D-S support.........:  ${with_eds}
 674         Exp. Call channel handler...:  ${have_call}
 675         Exp. Call log support.......:  ${have_call_logs}
 676 "