configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.0
  38 GLIB_REQUIRED=2.28.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  47 TELEPATHY_GLIB_REQUIRED=0.15.5
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50
  51 # Optional deps
  52 CLUTTER_GTK_REQUIRED=0.90.3
  53 ENCHANT_REQUIRED=1.2.0
  54 GEOCLUE_REQUIRED=0.11
  55 ISO_CODES_REQUIRED=0.35
  56 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  57 LIBCHAMPLAIN_REQUIRED=0.9
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # telepathy-yell
  70 prev_top_build_prefix=$ac_top_build_prefix
  71 prev_ac_configure_args=$ac_configure_args
  72 ac_configure_args="$ac_configure_args --disable-shared-library"
  73 AX_CONFIG_DIR([telepathy-yell])
  74 ac_top_build_prefix=$prev_top_build_prefix
  75 ac_configure_args=$prev_ac_configure_args
  76 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 GNOME_DOC_INIT([0.17.3])
 102 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 103 GLIB_GSETTINGS
 104 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 105 AC_SUBST(GLIB_GENMARSHAL)
 106
 107 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 108 if test -z "$XSLTPROC"; then
 109   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 110 fi
 111 AM_PATH_PYTHON([2.3])
 112
 113 EMPATHY_ARG_VALGRIND
 114
 115
 116 # -----------------------------------------------------------
 117 # Error flags
 118 # -----------------------------------------------------------
 119 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 120 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 121
 122 AC_ARG_ENABLE(Werror,
 123   AS_HELP_STRING([--disable-Werror],
 124                  [compile without -Werror (normally enabled in development builds)]),
 125     werror=$enableval, :)
 126
 127 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 128 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 129         wno_missing_field_initializers=yes,
 130         wno_missing_field_initializers=no)
 131 AS_COMPILER_FLAG(-Wno-unused-parameter,
 132         wno_unused_parameter=yes,
 133         wno_unused_parameter=no)
 134
 135 ifelse(empathy_released, 1, [],
 136     [
 137         if test x$werror = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 139         fi
 140         if test x$wextra = xyes -a \
 141             x$wno_missing_field_initializers = xyes -a \
 142             x$wno_unused_parameter = xyes; then
 143             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 144         fi
 145     ])
 146
 147 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 148 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 149 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 150 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 151 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 152
 153 AC_SUBST(ERROR_CFLAGS)
 154
 155 # -----------------------------------------------------------
 156 # Pkg-Config dependency checks
 157 # -----------------------------------------------------------
 158
 159 PKG_CHECK_MODULES(EMPATHY,
 160 [
 161    dbus-glib-1
 162    folks >= $FOLKS_REQUIRED
 163    folks-telepathy >= $FOLKS_REQUIRED
 164    glib-2.0 >= $GLIB_REQUIRED
 165    gio-2.0 >= $GLIB_REQUIRED
 166    gio-unix-2.0 >= $GLIB_REQUIRED
 167    gnome-keyring-1 >= $KEYRING_REQUIRED
 168    gnutls >= $GNUTLS_REQUIRED
 169    gmodule-export-2.0
 170    gobject-2.0
 171    gsettings-desktop-schemas
 172    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 173    gstreamer-interfaces-0.10
 174    libxml-2.0
 175    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 176    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 177    x11
 178    gtk+-3.0 >= $GTK_REQUIRED
 179    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 180    libnotify >= $LIBNOTIFY_REQUIRED
 181    gcr-3 >= $GCR_REQUIRED
 182    libpulse
 183    libpulse-mainloop-glib
 184    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 185 ])
 186
 187 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 188
 189 PKG_CHECK_MODULES(EMPATHY_AV,
 190 [
 191    farsight2-0.10
 192    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 193 ])
 194
 195 # -----------------------------------------------------------
 196 # Call interface
 197 # -----------------------------------------------------------
 198 AC_ARG_ENABLE(call,
 199             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 200             [build with Call interface support]),,
 201             [enable_call=auto])
 202 if test "x$enable_call" != "xno" ; then
 203    PKG_CHECK_MODULES(EMPATHY_CALL,
 204    [
 205       farsight2-0.10
 206       telepathy-farstream
 207       clutter-1.0
 208       clutter-gtk-1.0
 209       clutter-gst-1.0
 210    ], have_call="yes", have_call="no" )
 211
 212    if test "x$have_call" = "xyes"; then
 213       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 214    fi
 215 else
 216   have_call=no
 217 fi
 218
 219 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 220    AC_MSG_ERROR([Could not find Call handler dependencies.])
 221 fi
 222 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 223
 224
 225 # -----------------------------------------------------------
 226 # Call support in tp-logger
 227 # -----------------------------------------------------------
 228 AC_ARG_ENABLE(call-logs,
 229             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 230             [build with call logs support]),,
 231             [enable_call_logs=auto])
 232 if test "x$enable_call_logs" != "xno" ; then
 233    SAVE_CFLAGS=$CFLAGS
 234    SAVE_CPPFLAGS=$CPPFLAGS
 235    SAVE_LDFLAGS=$LDFLAGS
 236    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 237    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 238    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 239
 240    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 241       have_call_logs="yes", have_call_logs="no")
 242
 243    CFLAGS=$SAVE_CFLAGS
 244    CPPFLAGS=$SAVE_CPPFLAGS
 245    LDFLAGS=$SAVE_LDFLAGS
 246
 247    if test "x$have_call_logs" = "xyes"; then
 248       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 249    fi
 250 else
 251   have_call_logs=no
 252 fi
 253
 254 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 255    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 256                  built with --enable-call])
 257 fi
 258
 259 # -----------------------------------------------------------
 260 # evolution-data-server (about-me)
 261 # -----------------------------------------------------------
 262 AC_ARG_WITH(eds,
 263             AS_HELP_STRING([--with-eds],
 264                            [build with evolution-data-server support]),,
 265             [with_eds=yes])
 266 if test x"$with_eds" = x"yes" ; then
 267    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 268    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 269 fi
 270
 271 # -----------------------------------------------------------
 272 # Enable debug
 273 # -----------------------------------------------------------
 274
 275 AC_ARG_ENABLE(debug,
 276   AS_HELP_STRING([--disable-debug],
 277                  [compile without debug code]),
 278     enable_debug=$enableval, enable_debug=yes )
 279
 280 if test x$enable_debug = xyes; then
 281   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 282 fi
 283
 284 # -----------------------------------------------------------
 285 # Language Support
 286 # -----------------------------------------------------------
 287 IT_PROG_INTLTOOL([0.40.0])
 288
 289 AM_GNU_GETTEXT_VERSION([0.17])
 290 AM_GNU_GETTEXT([external])
 291
 292 GETTEXT_PACKAGE=empathy
 293 AC_SUBST(GETTEXT_PACKAGE)
 294 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 295
 296 # -----------------------------------------------------------
 297 # Connectivity integration
 298 # -----------------------------------------------------------
 299 AC_ARG_WITH(connectivity,
 300               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 301                              [build with connectivity support]), ,
 302                              with_connectivity=auto)
 303
 304 if test "x$with_connectivity" = "xno"; then
 305    have_nm=no
 306    have_connman=no
 307
 308 elif test "x$with_connectivity" = "xconnman"; then
 309    have_nm=no
 310
 311    PKG_CHECK_MODULES(CONNMAN,
 312    [
 313       dbus-glib-1
 314    ], have_connman="yes", have_connman="no")
 315
 316    if test "x$have_connman" = "xyes"; then
 317       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 318    fi
 319
 320 else
 321    have_connman=no
 322
 323    PKG_CHECK_MODULES(NETWORK_MANAGER,
 324    [
 325       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 326    ], have_nm="yes", have_nm="no")
 327
 328    if test "x$have_nm" = "xyes"; then
 329       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 330    fi
 331 fi
 332
 333 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 334    AC_MSG_ERROR([Couldn't find connman dependencies.])
 335 fi
 336
 337 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 338    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 339 fi
 340
 341 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 342 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 343
 344 # -----------------------------------------------------------
 345 # gudev
 346 # -----------------------------------------------------------
 347 AC_ARG_ENABLE(gudev,
 348               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 349                              [build with gudev support]), ,
 350                              enable_gudev=auto)
 351
 352 if test "x$enable_gudev" != "xno"; then
 353
 354    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 355         have_gudev="yes", have_gudev="no")
 356
 357    if test "x$have_gudev" = "xyes"; then
 358       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 359    fi
 360 else
 361    have_gudev=no
 362 fi
 363
 364 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 365    AC_MSG_ERROR([Could not find gudev dependencies.])
 366 fi
 367 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 368
 369 # -----------------------------------------------------------
 370 # spellchecking checks: enchant and iso-codes
 371 # -----------------------------------------------------------
 372 AC_ARG_ENABLE(spell,
 373               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 374                              [Enable spell checking]), ,
 375                              enable_spell=auto)
 376
 377 if test "x$enable_spell" != "xno"; then
 378    PKG_CHECK_MODULES(ENCHANT,
 379    [
 380       enchant >= $ENCHANT_REQUIRED,
 381       iso-codes >= $ISO_CODES_REQUIRED
 382    ], have_enchant="yes", have_enchant="no")
 383
 384    if test "x$have_enchant" = "xyes"; then
 385       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 386       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 387          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 388             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 389             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 390             result=yes
 391       else
 392             result=no
 393             have_enchant="no"
 394       fi
 395       AC_MSG_RESULT([$result])
 396    fi
 397 else
 398    have_enchant=no
 399 fi
 400
 401 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 402    AC_MSG_ERROR([Could not find spell dependencies.])
 403 fi
 404
 405 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 406
 407 # -----------------------------------------------------------
 408 # Map view checks: libchamplain
 409 # -----------------------------------------------------------
 410 AC_ARG_ENABLE(map,
 411               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 412                              [Enable map view]), ,
 413                              enable_map=auto)
 414
 415 if test "x$enable_map" != "xno"; then
 416
 417    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 418     [
 419        clutter-gtk-1.0
 420        champlain-gtk-0.10
 421        champlain-0.10
 422     ], have_libchamplain="yes", have_libchamplain="no")
 423
 424    if test "x$have_libchamplain" = "xyes"; then
 425       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 426    fi
 427 else
 428    have_libchamplain=no
 429 fi
 430
 431 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 432    AC_MSG_ERROR([Could not find map view dependencies.])
 433 fi
 434
 435 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 436
 437 # -----------------------------------------------------------
 438 # location checks: geoclue
 439 # -----------------------------------------------------------
 440 AC_ARG_ENABLE(location,
 441               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 442                              [Enable location awareness]), ,
 443                              enable_location=auto)
 444
 445 if test "x$enable_location" != "xno"; then
 446    PKG_CHECK_MODULES(GEOCLUE,
 447    [
 448       geoclue >= $GEOCLUE_REQUIRED
 449    ], have_geoclue="yes", have_geoclue="no")
 450
 451    if test "x$have_geoclue" = "xyes"; then
 452       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 453    fi
 454 else
 455    have_geoclue="no"
 456 fi
 457
 458 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 459    AC_MSG_ERROR([Could not find location dependencies.])
 460 fi
 461
 462 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 463 AC_SUBST(GEOCLUE_CFLAGS)
 464 AC_SUBST(GEOCLUE_LIBS)
 465
 466 # -----------------------------------------------------------
 467 # location checks: geocode-glib
 468 # -----------------------------------------------------------
 469 AC_ARG_ENABLE(geocode,
 470               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 471                              [Enable geocode support]), ,
 472                              enable_geocode=auto)
 473
 474 if test "x$enable_geocode" != "xno"; then
 475    PKG_CHECK_MODULES(GEOCODE,
 476    [
 477       geocode-glib
 478    ], have_geocode="yes", have_geocode="no")
 479
 480    if test "x$have_geocode" = "xyes"; then
 481       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 482    fi
 483 else
 484    have_geocode="no"
 485 fi
 486
 487 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 488    AC_MSG_ERROR([Could not find geocode dependencies.])
 489 fi
 490
 491 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 492 AC_SUBST(GEOCODE_CFLAGS)
 493 AC_SUBST(GEOCODE_LIBS)
 494
 495 # -----------------------------------------------------------
 496 # meego widgets support
 497 # -----------------------------------------------------------
 498 AC_ARG_ENABLE(meego,
 499               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 500                              [Enable meego widgets]), ,
 501                              enable_meego=no)
 502
 503 if test "x$enable_meego" != "xno"; then
 504     PKG_CHECK_MODULES(MEEGO,
 505     [
 506        mx-gtk-1.0
 507        gio-unix-2.0
 508     ], have_meego="yes", have_meego="no")
 509
 510     if test "x$have_meego" = "xyes"; then
 511        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 512     fi
 513 else
 514    have_meego="no"
 515 fi
 516
 517 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 518    AC_MSG_ERROR([Could not find meego dependencies.])
 519 fi
 520
 521 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 522 AC_SUBST(MEEGO_CFLAGS)
 523 AC_SUBST(MEEGO_LIBS)
 524
 525 # -----------------------------------------------------------
 526 # nautilus-sendto
 527 # -----------------------------------------------------------
 528 AC_ARG_ENABLE(nautilus-sendto,
 529               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 530                              [build nautilus-sendto plugin]), ,
 531                              enable_nautilus_sendto=auto)
 532
 533 if test "x$enable_nautilus_sendto" != "xno"; then
 534    PKG_CHECK_MODULES(NST,
 535     [
 536        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 537     ], have_nst="yes", have_nst="no")
 538 else
 539    have_nst=no
 540 fi
 541
 542 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 543    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 544 fi
 545
 546 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 547
 548 # -----------------------------------------------------------
 549 # new, single-window control center
 550 # -----------------------------------------------------------
 551 AC_ARG_ENABLE(control_center_embedding,
 552               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 553                              [Enable support for single-window control center]),
 554                              , enable_control_center_embedding=auto)
 555
 556 if test "x$enable_control_center_embedding" != "xno"; then
 557
 558    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 559         have_control_center_embedding="yes", have_control_center_embedding="no")
 560
 561    if test "x$have_control_center_embedding" = "xyes"; then
 562       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 563
 564       AC_MSG_CHECKING([gnome-control-center extension dir])
 565       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 566       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 567           AC_MSG_ERROR([Could not determine extensiondir])
 568       else
 569           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 570       fi
 571       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 572    fi
 573 else
 574    have_control_center_embedding="no"
 575 fi
 576
 577 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 578    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 579 fi
 580
 581 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 582 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 583 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 584
 585 # Optional dependency for avatar selection
 586 AC_ARG_WITH([cheese],
 587             AS_HELP_STRING([--with-cheese],
 588                            [enable cheese webcam support]),,
 589             with_cheese=auto)
 590
 591 if test x"$with_cheese" != x"no" ; then
 592    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 593    if test x${have_cheese} = xyes; then
 594      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 595    fi
 596    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 597      AC_MSG_ERROR([Cheese configured but not found])
 598    fi
 599 else
 600    have_cheese=no
 601 fi
 602 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 603
 604
 605 # -----------------------------------------------------------
 606 # Coding style checks
 607 # -----------------------------------------------------------
 608 AC_ARG_ENABLE(coding-style-checks,
 609   AS_HELP_STRING([--disable-coding-style-checks],
 610                  [do not check coding style using grep]),
 611     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 612     [ENABLE_CODING_STYLE_CHECKS=yes])
 613
 614 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 615 # -----------------------------------------------------------
 616
 617 AC_CONFIG_FILES([
 618    Makefile
 619    data/Makefile
 620    data/empathy.desktop.in
 621    data/empathy-accounts.desktop.in
 622    data/icons/Makefile
 623    extensions/Makefile
 624    po/Makefile.in
 625    libempathy/Makefile
 626    libempathy-gtk/Makefile
 627    src/Makefile
 628    nautilus-sendto-plugin/Makefile
 629    help/Makefile
 630    tests/Makefile
 631    tests/interactive/Makefile
 632    tests/xml/Makefile
 633    tools/Makefile
 634 ])
 635 AC_OUTPUT
 636
 637 echo "
 638 Configure summary:
 639
 640         Compiler....................:  ${CC}
 641         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 642         Prefix......................:  ${prefix}
 643         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 644
 645     Features:
 646         Spell checking (enchant)....:  ${have_enchant}
 647         Display maps (libchamplain).:  ${have_libchamplain}
 648         Location awareness (Geoclue):  ${have_geoclue}
 649         Geocode support (Geoclue)...:  ${have_geocode}
 650         Meego widgets...............:  ${have_meego}
 651         Control center embedding....:  ${have_control_center_embedding}
 652         Cheese webcam support ......:  ${have_cheese}
 653         Camera monitoring...........:  ${have_gudev}
 654
 655     Connectivity:
 656         NetworkManager integration..:  ${have_nm}
 657         ConnMan integration.........:  ${have_connman}
 658
 659     Extras:
 660         Nautilus-sendto plugin......:  ${have_nst}
 661         Salut E-D-S support.........:  ${with_eds}
 662         Exp. Call channel handler...:  ${have_call}
 663         Exp. Call log support.......:  ${have_call_logs}
 664 "