configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GLIB_REQUIRED=2.30.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.18
  47 TELEPATHY_FARSTREAM_REQUIRED=0.2.1
  48 TELEPATHY_GLIB_REQUIRED=0.17.5
  49 TELEPATHY_LOGGER=0.2.10
  50 WEBKIT_REQUIRED=1.3.13
  51 GOA_REQUIRED=3.3.0
  52
  53 # Optional deps
  54 CLUTTER_REQUIRED=1.7.14
  55 CLUTTER_GTK_REQUIRED=0.90.3
  56 ENCHANT_REQUIRED=1.2.0
  57 GEOCLUE_REQUIRED=0.11
  58 ISO_CODES_REQUIRED=0.35
  59 NAUTILUS_SENDTO_REQUIRED=2.90.0
  60 NETWORK_MANAGER_REQUIRED=0.7.0
  61 CHAMPLAIN_REQUIRED=0.12.1
  62
  63 # Use --enable-maintainer-mode to disable deprecated symbols,
  64 # disable single include and enable GSEAL. If this is not a released empathy,
  65 # maintainer mode is forced
  66 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  67 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  68 #GNOME_MAINTAINER_MODE_DEFINES
  69
  70 # Disable GLib deprecation warnings for now; we don't want to bump the GLib dep
  71 # and make things harder for contributiors without good reason. We'll re-enable
  72 # those warnings later during the cycle (bgo #662662)
  73 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
  74
  75 # FIXME: bgo #669673
  76 AC_DEFINE(CLUTTER_DISABLE_DEPRECATION_WARNINGS, 1, [Build with Clutter deprecated])
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 102 GLIB_GSETTINGS
 103 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 104 AC_SUBST(GLIB_GENMARSHAL)
 105
 106 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 107 if test -z "$XSLTPROC"; then
 108   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 109 fi
 110 AM_PATH_PYTHON([2.3])
 111
 112 EMPATHY_ARG_VALGRIND
 113
 114
 115 # -----------------------------------------------------------
 116 # Error flags
 117 # -----------------------------------------------------------
 118 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 119 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 120
 121 AC_ARG_ENABLE(Werror,
 122   AS_HELP_STRING([--disable-Werror],
 123                  [compile without -Werror (normally enabled in development builds)]),
 124     werror=$enableval, :)
 125
 126 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 127 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 128         wno_missing_field_initializers=yes,
 129         wno_missing_field_initializers=no)
 130 AS_COMPILER_FLAG(-Wno-unused-parameter,
 131         wno_unused_parameter=yes,
 132         wno_unused_parameter=no)
 133
 134 ifelse(empathy_released, 1, [],
 135     [
 136         if test x$werror = xyes; then
 137             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 138         fi
 139         if test x$wextra = xyes -a \
 140             x$wno_missing_field_initializers = xyes -a \
 141             x$wno_unused_parameter = xyes; then
 142             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 143         fi
 144     ])
 145
 146 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 147 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 148 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 149 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 150 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 151
 152 AC_SUBST(ERROR_CFLAGS)
 153
 154 AC_ARG_ENABLE(gprof,
 155             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 156             [build with support for gprof]),,
 157             [enable_gprof=no])
 158 if test "x$enable_gprof" != "xno" ; then
 159     CFLAGS="$CFLAGS -pg"
 160     LDFLAGS="$LDFLAGS -pg"
 161 fi
 162
 163 AC_SUBST(LDFLAGS)
 164
 165 # -----------------------------------------------------------
 166 # Pkg-Config dependency checks
 167 # -----------------------------------------------------------
 168
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 PKG_CHECK_MODULES(EMPATHY,
 173 [
 174    dbus-glib-1
 175    folks >= $FOLKS_REQUIRED
 176    folks-telepathy >= $FOLKS_REQUIRED
 177    glib-2.0 >= $GLIB_REQUIRED
 178    gio-2.0 >= $GLIB_REQUIRED
 179    gio-unix-2.0 >= $GLIB_REQUIRED
 180    gnome-keyring-1 >= $KEYRING_REQUIRED
 181    gnutls >= $GNUTLS_REQUIRED
 182    gmodule-export-2.0
 183    gobject-2.0
 184    gsettings-desktop-schemas
 185    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 186    gstreamer-interfaces-0.10
 187    libxml-2.0
 188    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 189    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 190    x11
 191    gtk+-3.0 >= $GTK_REQUIRED
 192    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 193    libnotify >= $LIBNOTIFY_REQUIRED
 194    gcr-3 >= $GCR_REQUIRED
 195    libpulse
 196    libpulse-mainloop-glib
 197    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 198    libsoup-2.4
 199 ])
 200
 201 PKG_CHECK_MODULES(EMPATHY_AV,
 202 [
 203    farsight2-0.10
 204    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 205 ])
 206
 207 PKG_CHECK_MODULES(EMPATHY_CALL,
 208 [
 209    farstream-0.1
 210    telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 211    clutter-1.0 >= $CLUTTER_REQUIRED
 212    clutter-gtk-1.0
 213    clutter-gst-1.0
 214 ])
 215
 216 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 217    [Name of provider for accounts imported from GOA])
 218
 219 # -----------------------------------------------------------
 220 # Call support in tp-logger
 221 # -----------------------------------------------------------
 222 AC_ARG_ENABLE(call-logs,
 223             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 224             [build with call logs support]),,
 225             [enable_call_logs=auto])
 226 if test "x$enable_call_logs" != "xno" ; then
 227    SAVE_CFLAGS=$CFLAGS
 228    SAVE_CPPFLAGS=$CPPFLAGS
 229    SAVE_LDFLAGS=$LDFLAGS
 230    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 231    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 232    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 233
 234    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 235       have_call_logs="yes", have_call_logs="no")
 236
 237    CFLAGS=$SAVE_CFLAGS
 238    CPPFLAGS=$SAVE_CPPFLAGS
 239    LDFLAGS=$SAVE_LDFLAGS
 240
 241    if test "x$have_call_logs" = "xyes"; then
 242       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 243    fi
 244 else
 245   have_call_logs=no
 246 fi
 247
 248 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 249    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 250                  built with --enable-call])
 251 fi
 252
 253 # -----------------------------------------------------------
 254 # evolution-data-server (about-me)
 255 # -----------------------------------------------------------
 256 AC_ARG_WITH(eds,
 257             AS_HELP_STRING([--with-eds],
 258                            [build with evolution-data-server support]),,
 259             [with_eds=yes])
 260 if test x"$with_eds" = x"yes" ; then
 261    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 262    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 263 fi
 264
 265 # -----------------------------------------------------------
 266 # Enable debug
 267 # -----------------------------------------------------------
 268
 269 AC_ARG_ENABLE(debug,
 270   AS_HELP_STRING([--disable-debug],
 271                  [compile without debug code]),
 272     enable_debug=$enableval, enable_debug=yes )
 273
 274 if test x$enable_debug = xyes; then
 275   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 276 fi
 277
 278 # -----------------------------------------------------------
 279 # Language Support
 280 # -----------------------------------------------------------
 281 IT_PROG_INTLTOOL([0.40.0])
 282
 283 AM_GNU_GETTEXT_VERSION([0.17])
 284 AM_GNU_GETTEXT([external])
 285
 286 GETTEXT_PACKAGE=empathy
 287 AC_SUBST(GETTEXT_PACKAGE)
 288 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 289
 290 # -----------------------------------------------------------
 291 # Connectivity integration
 292 # -----------------------------------------------------------
 293 AC_ARG_WITH(connectivity,
 294               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 295                              [build with connectivity support]), ,
 296                              with_connectivity=auto)
 297
 298 if test "x$with_connectivity" = "xno"; then
 299    have_nm=no
 300    have_connman=no
 301
 302 elif test "x$with_connectivity" = "xconnman"; then
 303    have_nm=no
 304
 305    PKG_CHECK_MODULES(CONNMAN,
 306    [
 307       dbus-glib-1
 308    ], have_connman="yes", have_connman="no")
 309
 310    if test "x$have_connman" = "xyes"; then
 311       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 312    fi
 313
 314 else
 315    have_connman=no
 316
 317    PKG_CHECK_MODULES(NETWORK_MANAGER,
 318    [
 319       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 320    ], have_nm="yes", have_nm="no")
 321
 322    if test "x$have_nm" = "xyes"; then
 323       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 324    fi
 325 fi
 326
 327 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 328    AC_MSG_ERROR([Couldn't find connman dependencies:
 329
 330 $CONNMAN_PKG_ERRORS])
 331 fi
 332
 333 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 334    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 335
 336 $NETWORK_MANAGER_PKG_ERRORS])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 340 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 341
 342 # -----------------------------------------------------------
 343 # gudev
 344 # -----------------------------------------------------------
 345 AC_ARG_ENABLE(gudev,
 346               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 347                              [build with gudev support]), ,
 348                              enable_gudev=auto)
 349
 350 if test "x$enable_gudev" != "xno"; then
 351
 352    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 353         have_gudev="yes", have_gudev="no")
 354
 355    if test "x$have_gudev" = "xyes"; then
 356       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 357    fi
 358 else
 359    have_gudev=no
 360 fi
 361
 362 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 363    AC_MSG_ERROR([Could not find gudev dependencies:
 364
 365 $UDEV_PKG_ERRORS])
 366 fi
 367 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 368
 369 # -----------------------------------------------------------
 370 # spellchecking checks: enchant and iso-codes
 371 # -----------------------------------------------------------
 372 AC_ARG_ENABLE(spell,
 373               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 374                              [Enable spell checking]), ,
 375                              enable_spell=auto)
 376
 377 if test "x$enable_spell" != "xno"; then
 378    PKG_CHECK_MODULES(ENCHANT,
 379    [
 380       enchant >= $ENCHANT_REQUIRED,
 381       iso-codes >= $ISO_CODES_REQUIRED
 382    ], have_enchant="yes", have_enchant="no")
 383
 384    if test "x$have_enchant" = "xyes"; then
 385       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 386       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 387          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 388             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 389             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 390             result=yes
 391       else
 392             result=no
 393             have_enchant="no"
 394       fi
 395       AC_MSG_RESULT([$result])
 396    fi
 397 else
 398    have_enchant=no
 399 fi
 400
 401 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 402    AC_MSG_ERROR([Could not find spell-checking dependencies:
 403
 404 $ENCHANT_PKG_ERRORS])
 405 fi
 406
 407 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 408
 409 # -----------------------------------------------------------
 410 # Map view checks: libchamplain
 411 # -----------------------------------------------------------
 412 AC_ARG_ENABLE(map,
 413               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 414                              [Enable map view]), ,
 415                              enable_map=auto)
 416
 417 if test "x$enable_map" != "xno"; then
 418
 419    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 420     [
 421        clutter-gtk-1.0
 422        champlain-gtk-0.12
 423        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 424     ], have_libchamplain="yes", have_libchamplain="no")
 425
 426    if test "x$have_libchamplain" = "xyes"; then
 427       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 428    fi
 429 else
 430    have_libchamplain=no
 431 fi
 432
 433 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 434    AC_MSG_ERROR([Could not find map view dependencies:
 435
 436 $LIBCHAMPLAIN_PKG_ERRORS])
 437 fi
 438
 439 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 440
 441 # -----------------------------------------------------------
 442 # location checks: geoclue
 443 # -----------------------------------------------------------
 444 AC_ARG_ENABLE(location,
 445               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 446                              [Enable location awareness]), ,
 447                              enable_location=auto)
 448
 449 if test "x$enable_location" != "xno"; then
 450    PKG_CHECK_MODULES(GEOCLUE,
 451    [
 452       geoclue >= $GEOCLUE_REQUIRED
 453    ], have_geoclue="yes", have_geoclue="no")
 454
 455    if test "x$have_geoclue" = "xyes"; then
 456       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 457    fi
 458 else
 459    have_geoclue="no"
 460 fi
 461
 462 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 463    AC_MSG_ERROR([Could not find location dependencies:
 464
 465 $GEOCLUE_PKG_ERRORS])
 466 fi
 467
 468 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 469 AC_SUBST(GEOCLUE_CFLAGS)
 470 AC_SUBST(GEOCLUE_LIBS)
 471
 472 # -----------------------------------------------------------
 473 # location checks: geocode-glib
 474 # -----------------------------------------------------------
 475 AC_ARG_ENABLE(geocode,
 476               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 477                              [Enable geocode support]), ,
 478                              enable_geocode=auto)
 479
 480 if test "x$enable_geocode" != "xno"; then
 481    PKG_CHECK_MODULES(GEOCODE,
 482    [
 483       geocode-glib
 484    ], have_geocode="yes", have_geocode="no")
 485
 486    if test "x$have_geocode" = "xyes"; then
 487       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 488    fi
 489 else
 490    have_geocode="no"
 491 fi
 492
 493 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 494    AC_MSG_ERROR([Could not find geocode dependencies:
 495
 496 $GEOCODE_PKG_ERRORS])
 497 fi
 498
 499 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 500 AC_SUBST(GEOCODE_CFLAGS)
 501 AC_SUBST(GEOCODE_LIBS)
 502
 503 # -----------------------------------------------------------
 504 # meego widgets support
 505 # -----------------------------------------------------------
 506 AC_ARG_ENABLE(meego,
 507               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 508                              [Enable meego widgets]), ,
 509                              enable_meego=no)
 510
 511 if test "x$enable_meego" != "xno"; then
 512     PKG_CHECK_MODULES(MEEGO,
 513     [
 514        mx-gtk-1.0
 515        gio-unix-2.0
 516     ], have_meego="yes", have_meego="no")
 517
 518     if test "x$have_meego" = "xyes"; then
 519        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 520     fi
 521 else
 522    have_meego="no"
 523 fi
 524
 525 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 526    AC_MSG_ERROR([Could not find meego dependencies:
 527
 528 $MEEGO_PKG_ERRORS])
 529 fi
 530
 531 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 532 AC_SUBST(MEEGO_CFLAGS)
 533 AC_SUBST(MEEGO_LIBS)
 534
 535 # -----------------------------------------------------------
 536 # nautilus-sendto
 537 # -----------------------------------------------------------
 538 AC_ARG_ENABLE(nautilus-sendto,
 539               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 540                              [build nautilus-sendto plugin]), ,
 541                              enable_nautilus_sendto=auto)
 542
 543 if test "x$enable_nautilus_sendto" != "xno"; then
 544    PKG_CHECK_MODULES(NST,
 545     [
 546        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 547     ], have_nst="yes", have_nst="no")
 548 else
 549    have_nst=no
 550 fi
 551
 552 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 553    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 554
 555 $NST_PKG_ERRORS])
 556 fi
 557
 558 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 559
 560 # -----------------------------------------------------------
 561 # goa-mc-plugin
 562 # -----------------------------------------------------------
 563 AC_ARG_ENABLE(goa,
 564               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 565                              [build GOA MC plugin]), ,
 566                              enable_goa=auto)
 567
 568 if test "x$enable_goa" != "xno"; then
 569    PKG_CHECK_MODULES(GOA,
 570     [
 571        mission-control-plugins
 572        goa-1.0 >= $GOA_REQUIRED
 573     ], have_goa="yes", have_goa="no")
 574
 575    AC_MSG_CHECKING([Mission Control plugins dir])
 576    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 577
 578    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 579    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 580 else
 581    have_goa=no
 582 fi
 583
 584 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 585    AC_MSG_ERROR([Could not find GOA dependencies.])
 586 fi
 587
 588 if test "x$have_goa" = "xyes"; then
 589    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 590 fi
 591
 592 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 593
 594 # Optional dependency for avatar selection
 595 AC_ARG_WITH([cheese],
 596             AS_HELP_STRING([--with-cheese],
 597                            [enable cheese webcam support]),,
 598             with_cheese=auto)
 599
 600 if test x"$with_cheese" != x"no" ; then
 601    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 602    if test x${have_cheese} = xyes; then
 603      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 604    fi
 605    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 606      AC_MSG_ERROR([Cheese configured but not found:
 607
 608 $CHEESE_PKG_ERRORS])
 609    fi
 610 else
 611    have_cheese=no
 612 fi
 613 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 614
 615 # Help documentation
 616 YELP_HELP_INIT
 617
 618 # -----------------------------------------------------------
 619 # Coding style checks
 620 # -----------------------------------------------------------
 621 AC_ARG_ENABLE(coding-style-checks,
 622   AS_HELP_STRING([--disable-coding-style-checks],
 623                  [do not check coding style using grep]),
 624     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 625     [ENABLE_CODING_STYLE_CHECKS=yes])
 626
 627 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 628 # -----------------------------------------------------------
 629
 630 AC_CONFIG_FILES([
 631    Makefile
 632    data/Makefile
 633    data/empathy.desktop.in
 634    data/empathy-accounts.desktop.in
 635    data/icons/Makefile
 636    extensions/Makefile
 637    po/Makefile.in
 638    libempathy/Makefile
 639    libempathy-gtk/Makefile
 640    src/Makefile
 641    nautilus-sendto-plugin/Makefile
 642    goa-mc-plugin/Makefile
 643    help/Makefile
 644    tests/Makefile
 645    tests/interactive/Makefile
 646    tests/xml/Makefile
 647    tools/Makefile
 648 ])
 649 AC_OUTPUT
 650
 651 echo "
 652 Configure summary:
 653
 654         Compiler....................:  ${CC}
 655         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 656         Linker Flags................:  ${LDFLAGS}
 657         Prefix......................:  ${prefix}
 658         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 659
 660     Features:
 661         Spell checking (enchant)....:  ${have_enchant}
 662         Display maps (libchamplain).:  ${have_libchamplain}
 663         Location awareness (Geoclue):  ${have_geoclue}
 664         Geocode support (Geocode)...:  ${have_geocode}
 665         Meego widgets...............:  ${have_meego}
 666         Cheese webcam support ......:  ${have_cheese}
 667         Camera monitoring...........:  ${have_gudev}
 668
 669     Connectivity:
 670         NetworkManager integration..:  ${have_nm}
 671         ConnMan integration.........:  ${have_connman}
 672
 673     Extras:
 674         Nautilus-sendto plugin......:  ${have_nst}
 675         GOA MC plugin...............:  ${have_goa}
 676         Salut E-D-S support.........:  ${with_eds}
 677         Exp. Call log support.......:  ${have_call_logs}
 678 "