m4/gsettings.m4

   1 dnl GLIB_GSETTINGS
   2 dnl Defines GSETTINGS_SCHEMAS_INSTALL which controls whether
   3 dnl the schema should be compiled
   4 dnl
   5
   6 AC_DEFUN([GLIB_GSETTINGS],
   7 [
   8   m4_pattern_allow([AM_V_GEN])
   9   AC_ARG_ENABLE(schemas-compile,
  10                 AC_HELP_STRING([--disable-schemas-compile],
  11                                [Disable regeneration of gschemas.compiled on install]),
  12                 [case ${enableval} in
  13                   yes) GSETTINGS_DISABLE_SCHEMAS_COMPILE=""  ;;
  14                   no)  GSETTINGS_DISABLE_SCHEMAS_COMPILE="1" ;;
  15                   *) AC_MSG_ERROR([bad value ${enableval} for --enable-schemas-compile]) ;;
  16                  esac])
  17   AC_SUBST([GSETTINGS_DISABLE_SCHEMAS_COMPILE])
  18   PKG_PROG_PKG_CONFIG([0.16])
  19   AC_SUBST(gsettingsschemadir, [${datadir}/glib-2.0/schemas])
  20   AC_SUBST(GLIB_COMPILE_SCHEMAS, `$PKG_CONFIG --variable glib_compile_schemas gio-2.0`)
  21   if test "x$GLIB_COMPILE_SCHEMAS" = "x"; then
  22     AC_MSG_ERROR([glib-compile-schemas not found.])
  23   fi
  24
  25   GSETTINGS_RULES='
  26 .PHONY : uninstall-gsettings-schemas install-gsettings-schemas clean-gsettings-schemas
  27
  28 mostlyclean-am: clean-gsettings-schemas
  29
  30 %.gschema.valid: %.gschema.xml
  31         $(AM_V_GEN) if test -f "$^"; then d=; else d="$(srcdir)/"; fi; $(GLIB_COMPILE_SCHEMAS) --dry-run --schema-file=$${d}$^ && touch [$]@
  32
  33 all-am: $(gsettings_SCHEMAS:.xml=.valid)
  34 uninstall-am: uninstall-gsettings-schemas
  35 install-data-am: install-gsettings-schemas
  36
  37 .SECONDARY: $(gsettings_SCHEMAS)
  38
  39 install-gsettings-schemas: $(gsettings_SCHEMAS) $(gsettings__enum_file)
  40         @$(NORMAL_INSTALL)
  41         test -z "$(gsettingsschemadir)" || $(MKDIR_P) "$(DESTDIR)$(gsettingsschemadir)"
  42         $(INSTALL_DATA) $^ "$(DESTDIR)$(gsettingsschemadir)"
  43         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) $(gsettingsschemadir)
  44
  45 uninstall-gsettings-schemas:
  46         @$(NORMAL_UNINSTALL)
  47         @list='\''$(gsettings_SCHEMAS)'\''; test -n "$(gsettingsschemadir)" || list=; \
  48         files=`for p in $$list; do echo $$p; done | sed -e '\''s|^.*/||'\''`; \
  49         test -n "$$files" || exit 0; \
  50         echo " ( cd '\''$(DESTDIR)$(gsettingsschemadir)'\'' && rm -f" $$files ")"; \
  51         cd "$(DESTDIR)$(gsettingsschemadir)" && rm -f $$files
  52         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) --uninstall $(gsettingsschemadir)
  53
  54 clean-gsettings-schemas:
  55         rm -f $(gsettings_SCHEMAS:.xml=.valid)
  56
  57 '
  58   _GSETTINGS_SUBST(GSETTINGS_RULES)
  59 ])
  60
  61 dnl _GSETTINGS_SUBST(VARIABLE)
  62 dnl Abstract macro to do either _AM_SUBST_NOTMAKE or AC_SUBST
  63 AC_DEFUN([_GSETTINGS_SUBST],
  64 [
  65 AC_SUBST([$1])
  66 m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([$1])])
  67 ]
  68 )