configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 TELEPATHY_GLIB_REQUIRED=0.11.7
  41 TELEPATHY_LOGGER=0.1.2
  42 UNIQUE_REQUIRED=1.1.2
  43
  44 # Optionnal deps
  45 CLUTTER_GTK_REQUIRED=0.10
  46 ENCHANT_REQUIRED=1.2.0
  47 GEOCLUE_REQUIRED=0.11
  48 ISO_CODES_REQUIRED=0.35
  49 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  50 LIBCHAMPLAIN_REQUIRED=0.4
  51 NAUTILUS_SENDTO_REQUIRED=2.28.1
  52 NETWORK_MANAGER_REQUIRED=0.7.0
  53 WEBKIT_REQUIRED=1.1.15
  54
  55 # Use --enable-maintainer-mode to disable deprecated symbols,
  56 # disable single include and enable GSEAL. If this is not a released empathy,
  57 # maintainer mode is forced
  58 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  59 GNOME_MAINTAINER_MODE_DEFINES
  60
  61 AC_CONFIG_MACRO_DIR([m4])
  62 AC_CONFIG_HEADERS([config.h])
  63 AC_CONFIG_SRCDIR([configure.ac])
  64 AC_CONFIG_AUX_DIR(.)
  65
  66 GNOME_COMMON_INIT
  67
  68 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  69
  70 # Support silent build rules, requires at least automake-1.11. Disable
  71 # by either passing --disable-silent-rules to configure or passing V=1
  72 # to make
  73 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  74
  75 AC_ISC_POSIX
  76 AC_PROG_CC
  77 AC_HEADER_STDC
  78 AM_PROG_LIBTOOL
  79 AM_PROG_MKDIR_P
  80 AM_PATH_GLIB_2_0
  81 AC_PATH_XTRA
  82 IT_PROG_INTLTOOL([0.35.0])
  83 GNOME_DOC_INIT([0.17.3])
  84 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  85 GLIB_GSETTINGS
  86 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  87 AC_SUBST(GLIB_GENMARSHAL)
  88 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  89 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  90
  91 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  92 if test -z "$XSLTPROC"; then
  93   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  94 fi
  95 AM_PATH_PYTHON([2.3])
  96
  97 EMPATHY_ARG_VALGRIND
  98
  99
 100 # -----------------------------------------------------------
 101 # Error flags
 102 # -----------------------------------------------------------
 103 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 104 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 105
 106 AC_ARG_ENABLE(Werror,
 107   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 108     werror=$enableval, :)
 109
 110 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 111 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 112         wno_missing_field_initializers=yes,
 113         wno_missing_field_initializers=no)
 114 AS_COMPILER_FLAG(-Wno-unused-parameter,
 115         wno_unused_parameter=yes,
 116         wno_unused_parameter=no)
 117
 118 ifelse(empathy_released, 1, [],
 119     [
 120         if test x$werror = xyes; then
 121             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 122         fi
 123         if test x$wextra = xyes -a \
 124             x$wno_missing_field_initializers = xyes -a \
 125             x$wno_unused_parameter = xyes; then
 126             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 127         fi
 128     ])
 129
 130 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 131 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 132 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 133 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 134 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 135 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 136
 137 AC_SUBST(ERROR_CFLAGS)
 138
 139 # -----------------------------------------------------------
 140 # Pkg-Config dependency checks
 141 # -----------------------------------------------------------
 142
 143 PKG_CHECK_MODULES(EMPATHY,
 144 [
 145    dbus-glib-1
 146    farsight2-0.10
 147    gconf-2.0 >= $GCONF_REQUIRED
 148    gdk-x11-2.0
 149    gio-2.0 >= $GLIB_REQUIRED
 150    gio-unix-2.0 >= $GLIB_REQUIRED
 151    gnome-keyring-1 >= $KEYRING_REQUIRED
 152    gobject-2.0
 153    gstreamer-0.10
 154    gstreamer-interfaces-0.10
 155    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    unique-1.0 >= $UNIQUE_REQUIRED
 162    x11
 163 ])
 164
 165 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 166
 167 # -----------------------------------------------------------
 168 # GTK+
 169 # -----------------------------------------------------------
 170 AC_ARG_ENABLE(gtk3,
 171               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 172                              [build with GTK+3]), ,
 173                              enable_gtk3=auto)
 174
 175 # Try to use GTK+3 if available
 176 if test "x$enable_gtk3" != "xno"; then
 177   PKG_CHECK_MODULES(GTK, [gtk+-3.0 >= $GTK_REQUIRED],
 178       enable_gtk3="yes", enable_gtk3="no")
 179 fi
 180
 181 # ...if not use GTK+2
 182 if test "x$enable_gtk3" == "xno"; then
 183   enable_gtk3=no
 184   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 185
 186   # Enable GSEAL checks if needed
 187   if test $USE_MAINTAINER_MODE = yes; then
 188     AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 189   fi
 190 fi
 191
 192 # -----------------------------------------------------------
 193 # Enable debug
 194 # -----------------------------------------------------------
 195
 196 AC_ARG_ENABLE(debug,
 197   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 198     enable_debug=$enableval, enable_debug=yes )
 199
 200 if test x$enable_debug = xyes; then
 201   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 202 fi
 203
 204 # -----------------------------------------------------------
 205 # Language Support
 206 # -----------------------------------------------------------
 207
 208 GETTEXT_PACKAGE=empathy
 209 AC_SUBST(GETTEXT_PACKAGE)
 210 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 211
 212 AM_GLIB_GNU_GETTEXT
 213
 214 # -----------------------------------------------------------
 215 # Connectivity integration
 216 # -----------------------------------------------------------
 217 AC_ARG_WITH(connectivity,
 218               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 219                              [build with connectivity support]), ,
 220                              with_connectivity=auto)
 221
 222 if test "x$with_connectivity" = "xno"; then
 223    have_nm=no
 224    have_connman=no
 225
 226 elif test "x$with_connectivity" = "xconnman"; then
 227
 228    PKG_CHECK_MODULES(CONNMAN,
 229    [
 230       dbus-glib-1
 231    ], have_connman="yes", have_connman="no")
 232
 233    if test "x$have_connman" = "xyes"; then
 234       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 235       have_nm=no
 236    fi
 237
 238 else
 239
 240    PKG_CHECK_MODULES(NETWORK_MANAGER,
 241    [
 242       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 243    ], have_nm="yes", have_nm="no")
 244
 245    if test "x$have_nm" = "xyes"; then
 246       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 247       have_connman=no
 248    else
 249       PKG_CHECK_MODULES(NETWORK_MANAGER,
 250       [
 251           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 252       ], have_nm="yes", have_nm="no")
 253
 254       if test "x$have_nm" = "xyes"; then
 255       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 256       have_connman=no
 257       fi
 258    fi
 259 fi
 260
 261 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 262    AC_MSG_ERROR([Couldn't find connman dependencies.])
 263 fi
 264
 265 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 266    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 267 fi
 268
 269 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 270 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 271
 272 # -----------------------------------------------------------
 273 # Webkit
 274 # -----------------------------------------------------------
 275 AC_ARG_ENABLE(webkit,
 276               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 277                              [build with webkit support]), ,
 278                              enable_webkit=auto)
 279
 280 if test "x$enable_webkit" != "xno"; then
 281    PKG_CHECK_MODULES(WEBKIT,
 282    [
 283       webkit-1.0 >= $WEBKIT_REQUIRED
 284    ], have_webkit="yes", have_webkit="no")
 285
 286    if test "x$have_webkit" = "xyes"; then
 287       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 288    fi
 289 else
 290    have_webkit=no
 291 fi
 292
 293 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 294    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 295 fi
 296 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 297
 298 # -----------------------------------------------------------
 299 # spellchecking checks: enchant and iso-codes
 300 # -----------------------------------------------------------
 301 AC_ARG_ENABLE(spell,
 302               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 303                              [Enable spell checking]), ,
 304                              enable_spell=auto)
 305
 306 if test "x$enable_spell" != "xno"; then
 307    PKG_CHECK_MODULES(ENCHANT,
 308    [
 309       enchant >= $ENCHANT_REQUIRED,
 310       iso-codes >= $ISO_CODES_REQUIRED
 311    ], have_enchant="yes", have_enchant="no")
 312
 313    if test "x$have_enchant" = "xyes"; then
 314       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 315       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 316          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 317             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 318             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 319             result=yes
 320       else
 321             result=no
 322             have_enchant="no"
 323       fi
 324       AC_MSG_RESULT([$result])
 325    fi
 326 else
 327    have_enchant=no
 328 fi
 329
 330 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 331    AC_MSG_ERROR([Couldn't find spell dependencies.])
 332 fi
 333
 334 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 335
 336 # -----------------------------------------------------------
 337 # Map view checks: libchamplain
 338 # -----------------------------------------------------------
 339 AC_ARG_ENABLE(map,
 340               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 341                              [Enable map view]), ,
 342                              enable_map=auto)
 343
 344 if test "x$enable_map" != "xno"; then
 345    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 346    [
 347       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 348       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 349       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 350    ], have_libchamplain="yes", have_libchamplain="no")
 351
 352    if test "x$have_libchamplain" = "xyes"; then
 353       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 354    fi
 355 else
 356    have_libchamplain=no
 357 fi
 358
 359 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 360    AC_MSG_ERROR([Couldn't find map view dependencies.])
 361 fi
 362
 363 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 364
 365 # -----------------------------------------------------------
 366 # location checks: geoclue
 367 # -----------------------------------------------------------
 368 AC_ARG_ENABLE(location,
 369               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 370                              [Enable location awareness]), ,
 371                              enable_location=auto)
 372
 373 if test "x$enable_location" != "xno"; then
 374    PKG_CHECK_MODULES(GEOCLUE,
 375    [
 376       geoclue >= $GEOCLUE_REQUIRED
 377    ], have_geoclue="yes", have_geoclue="no")
 378
 379    if test "x$have_geoclue" = "xyes"; then
 380       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 381    fi
 382 else
 383    have_geoclue="no"
 384 fi
 385
 386 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 387    AC_MSG_ERROR([Couldn't find location dependencies.])
 388 fi
 389
 390 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 391 AC_SUBST(GEOCLUE_CFLAGS)
 392 AC_SUBST(GEOCLUE_LIBS)
 393
 394 # -----------------------------------------------------------
 395 # meego widgets support
 396 # -----------------------------------------------------------
 397 AC_ARG_ENABLE(meego,
 398               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 399                              [Enable meego widgets]), ,
 400                              enable_meego=no)
 401
 402 if test "x$enable_meego" != "xno"; then
 403     PKG_CHECK_MODULES(MEEGO,
 404     [
 405        mx-gtk-1.0
 406     ], have_meego="yes", have_meego="no")
 407
 408     if test "x$have_meego" = "xyes"; then
 409        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 410     fi
 411 else
 412    have_meego="no"
 413 fi
 414
 415 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 416    AC_MSG_ERROR([Couldn't find meego dependencies.])
 417 fi
 418
 419 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 420 AC_SUBST(MEEGO_CFLAGS)
 421 AC_SUBST(MEEGO_LIBS)
 422
 423 # -----------------------------------------------------------
 424 # nautilus-sendto
 425 # -----------------------------------------------------------
 426 AC_ARG_ENABLE(nautilus-sendto,
 427               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 428                              [build nautilus-sendto plugin]), ,
 429                              enable_nautilus_sendto=auto)
 430
 431 if test "x$enable_nautilus_sendto" != "xno"; then
 432    PKG_CHECK_MODULES(NST,
 433    [
 434       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 435    ], have_nst="yes", have_nst="no")
 436 else
 437    have_nst=no
 438 fi
 439
 440 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 441    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 442 fi
 443
 444 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 445
 446 # -----------------------------------------------------------
 447 # new, single-window control center
 448 # -----------------------------------------------------------
 449 AC_ARG_ENABLE(control_center_embedding,
 450               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 451                              [Enable support for single-window control center]),
 452                              , enable_control_center_embedding=auto)
 453
 454 if test "x$enable_control_center_embedding" != "xno"; then
 455    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 456    [
 457       libgnome-control-center-extension
 458    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 459
 460    if test "x$have_control_center_embedding" = "xyes"; then
 461       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 462    fi
 463 else
 464    have_control_center_embedding="no"
 465 fi
 466
 467 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 468    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 469 fi
 470
 471 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 472 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 473 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 474
 475 # -----------------------------------------------------------
 476 # Coding style checks
 477 # -----------------------------------------------------------
 478 AC_ARG_ENABLE(coding-style-checks,
 479   AC_HELP_STRING([--disable-coding-style-checks],
 480                  [don't check coding style using grep]),
 481     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 482
 483 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 484 # -----------------------------------------------------------
 485
 486 AC_OUTPUT([
 487    Makefile
 488    data/Makefile
 489    data/empathy.desktop.in
 490    data/empathy-accounts.desktop.in
 491    data/icons/Makefile
 492    extensions/Makefile
 493    po/Makefile.in
 494    libempathy/Makefile
 495    libempathy-gtk/Makefile
 496    src/Makefile
 497    nautilus-sendto-plugin/Makefile
 498    help/Makefile
 499    tests/Makefile
 500    tests/interactive/Makefile
 501    tests/xml/Makefile
 502    tools/Makefile
 503 ])
 504
 505 echo "
 506 Configure summary:
 507
 508         Compiler....................:  ${CC}
 509         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 510         Prefix......................:  ${prefix}
 511         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 512         Use GTK+3...................:  ${enable_gtk3}
 513
 514     Features:
 515         Spell checking (enchant)....:  ${have_enchant}
 516         Display maps (libchamplain).:  ${have_libchamplain}
 517         Location awareness (Geoclue):  ${have_geoclue}
 518         Adium themes (Webkit).......:  ${have_webkit}
 519         Meego widgets ..............:  ${have_meego}
 520         Control center embedding....:  ${have_control_center_embedding}
 521
 522     Connectivity:
 523         NetworkManager integration..:  ${have_nm}
 524         ConnMan integration.........:  ${have_connman}
 525
 526     Extras:
 527         Nautilus-sendto plugin......:  ${have_nst}
 528 "