configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_GLIB_REQUIRED=0.11.7
  42 TELEPATHY_LOGGER=0.1.2
  43 UNIQUE_REQUIRED=1.1.2
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.10
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  51 LIBCHAMPLAIN_REQUIRED=0.4
  52 NAUTILUS_SENDTO_REQUIRED=2.28.1
  53 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.1.15
  56
  57 # Use --enable-maintainer-mode to disable deprecated symbols,
  58 # disable single include and enable GSEAL. If this is not a released empathy,
  59 # maintainer mode is forced
  60 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  61 GNOME_MAINTAINER_MODE_DEFINES
  62
  63 AC_CONFIG_MACRO_DIR([m4])
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_SRCDIR([configure.ac])
  66 AC_CONFIG_AUX_DIR(.)
  67
  68 GNOME_COMMON_INIT
  69
  70 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  71
  72 # Support silent build rules, requires at least automake-1.11. Disable
  73 # by either passing --disable-silent-rules to configure or passing V=1
  74 # to make
  75 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  76
  77 AC_ISC_POSIX
  78 AC_PROG_CC
  79 AC_HEADER_STDC
  80 AM_PROG_LIBTOOL
  81 AM_PROG_MKDIR_P
  82 AM_PATH_GLIB_2_0
  83 AC_PATH_XTRA
  84 IT_PROG_INTLTOOL([0.35.0])
  85 GNOME_DOC_INIT([0.17.3])
  86 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  87 GLIB_GSETTINGS
  88 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  91 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    farsight2-0.10
 149    gconf-2.0 >= $GCONF_REQUIRED
 150    gio-2.0 >= $GLIB_REQUIRED
 151    gio-unix-2.0 >= $GLIB_REQUIRED
 152    gnome-keyring-1 >= $KEYRING_REQUIRED
 153    gobject-2.0
 154    gstreamer-0.10
 155    gstreamer-interfaces-0.10
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    x11
 162 ])
 163
 164 # -----------------------------------------------------------
 165 # GTK+
 166 # -----------------------------------------------------------
 167 AC_ARG_ENABLE(gtk3,
 168               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 169                              [build with GTK+3]), ,
 170                              enable_gtk3=auto)
 171
 172 # Try to use GTK+3 if available
 173 if test "x$enable_gtk3" != "xno"; then
 174    PKG_CHECK_MODULES(GTK,
 175    [
 176       gtk+-3.0 >= $GTK_REQUIRED
 177    ], have_gtk3="yes", have_gtk3="no")
 178 else
 179    have_gtk3="no"
 180 fi
 181
 182 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 183    AC_MSG_ERROR([Couldn't find gtk3 dependencies.])
 184 fi
 185
 186 if test "x$have_gtk3" == "xyes"; then
 187    # GTK3 specific deps
 188    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 189    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 190    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 191 else
 192    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 193
 194    # GTK2 specific deps
 195    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 196    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 197    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 198
 199    # Enable GSEAL checks if needed
 200    if test $USE_MAINTAINER_MODE = yes; then
 201       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 202    fi
 203 fi
 204
 205 # -----------------------------------------------------------
 206 # Enable debug
 207 # -----------------------------------------------------------
 208
 209 AC_ARG_ENABLE(debug,
 210   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 211     enable_debug=$enableval, enable_debug=yes )
 212
 213 if test x$enable_debug = xyes; then
 214   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 215 fi
 216
 217 # -----------------------------------------------------------
 218 # Language Support
 219 # -----------------------------------------------------------
 220
 221 GETTEXT_PACKAGE=empathy
 222 AC_SUBST(GETTEXT_PACKAGE)
 223 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 224
 225 AM_GLIB_GNU_GETTEXT
 226
 227 # -----------------------------------------------------------
 228 # Connectivity integration
 229 # -----------------------------------------------------------
 230 AC_ARG_WITH(connectivity,
 231               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 232                              [build with connectivity support]), ,
 233                              with_connectivity=auto)
 234
 235 if test "x$with_connectivity" = "xno"; then
 236    have_nm=no
 237    have_connman=no
 238
 239 elif test "x$with_connectivity" = "xconnman"; then
 240    have_nm=no
 241
 242    PKG_CHECK_MODULES(CONNMAN,
 243    [
 244       dbus-glib-1
 245    ], have_connman="yes", have_connman="no")
 246
 247    if test "x$have_connman" = "xyes"; then
 248       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 249    fi
 250
 251 else
 252    have_connman=no
 253
 254    PKG_CHECK_MODULES(NETWORK_MANAGER,
 255    [
 256       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 257    ], have_nm="yes", have_nm="no")
 258
 259    if test "x$have_nm" = "xyes"; then
 260       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 261    fi
 262 fi
 263
 264 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 265    AC_MSG_ERROR([Couldn't find connman dependencies.])
 266 fi
 267
 268 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 269    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 270 fi
 271
 272 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 273 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 274
 275 # -----------------------------------------------------------
 276 # Webkit
 277 # -----------------------------------------------------------
 278 AC_ARG_ENABLE(webkit,
 279               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 280                              [build with webkit support]), ,
 281                              enable_webkit=auto)
 282
 283 if test "x$enable_webkit" != "xno"; then
 284
 285    if test "x$have_gtk3" == "xno"; then
 286       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 287           have_webkit="yes", have_webkit="no")
 288    else
 289       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 290           have_webkit="yes", have_webkit="no")
 291    fi
 292
 293    if test "x$have_webkit" = "xyes"; then
 294       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 295    fi
 296 else
 297    have_webkit=no
 298 fi
 299
 300 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 301    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 302 fi
 303 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 304
 305 # -----------------------------------------------------------
 306 # spellchecking checks: enchant and iso-codes
 307 # -----------------------------------------------------------
 308 AC_ARG_ENABLE(spell,
 309               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 310                              [Enable spell checking]), ,
 311                              enable_spell=auto)
 312
 313 if test "x$enable_spell" != "xno"; then
 314    PKG_CHECK_MODULES(ENCHANT,
 315    [
 316       enchant >= $ENCHANT_REQUIRED,
 317       iso-codes >= $ISO_CODES_REQUIRED
 318    ], have_enchant="yes", have_enchant="no")
 319
 320    if test "x$have_enchant" = "xyes"; then
 321       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 322       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 323          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 324             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 325             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 326             result=yes
 327       else
 328             result=no
 329             have_enchant="no"
 330       fi
 331       AC_MSG_RESULT([$result])
 332    fi
 333 else
 334    have_enchant=no
 335 fi
 336
 337 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 338    AC_MSG_ERROR([Couldn't find spell dependencies.])
 339 fi
 340
 341 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 342
 343 # -----------------------------------------------------------
 344 # Map view checks: libchamplain
 345 # -----------------------------------------------------------
 346 AC_ARG_ENABLE(map,
 347               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 348                              [Enable map view]), ,
 349                              enable_map=auto)
 350
 351 if test "x$enable_map" != "xno"; then
 352
 353    if test "x$have_gtk3" == "xno"; then
 354       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 355       [
 356          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 357          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 358          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 359       ], have_libchamplain="yes", have_libchamplain="no")
 360    else
 361       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 362       have_libchamplain="no"
 363    fi
 364
 365    if test "x$have_libchamplain" = "xyes"; then
 366       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 367    fi
 368 else
 369    have_libchamplain=no
 370 fi
 371
 372 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 373    AC_MSG_ERROR([Couldn't find map view dependencies.])
 374 fi
 375
 376 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 377
 378 # -----------------------------------------------------------
 379 # location checks: geoclue
 380 # -----------------------------------------------------------
 381 AC_ARG_ENABLE(location,
 382               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 383                              [Enable location awareness]), ,
 384                              enable_location=auto)
 385
 386 if test "x$enable_location" != "xno"; then
 387    PKG_CHECK_MODULES(GEOCLUE,
 388    [
 389       geoclue >= $GEOCLUE_REQUIRED
 390    ], have_geoclue="yes", have_geoclue="no")
 391
 392    if test "x$have_geoclue" = "xyes"; then
 393       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 394    fi
 395 else
 396    have_geoclue="no"
 397 fi
 398
 399 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 400    AC_MSG_ERROR([Couldn't find location dependencies.])
 401 fi
 402
 403 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 404 AC_SUBST(GEOCLUE_CFLAGS)
 405 AC_SUBST(GEOCLUE_LIBS)
 406
 407 # -----------------------------------------------------------
 408 # meego widgets support
 409 # -----------------------------------------------------------
 410 AC_ARG_ENABLE(meego,
 411               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 412                              [Enable meego widgets]), ,
 413                              enable_meego=no)
 414
 415 if test "x$enable_meego" != "xno"; then
 416     PKG_CHECK_MODULES(MEEGO,
 417     [
 418        mx-gtk-1.0
 419     ], have_meego="yes", have_meego="no")
 420
 421     if test "x$have_meego" = "xyes"; then
 422        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 423     fi
 424 else
 425    have_meego="no"
 426 fi
 427
 428 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 429    AC_MSG_ERROR([Couldn't find meego dependencies.])
 430 fi
 431
 432 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 433 AC_SUBST(MEEGO_CFLAGS)
 434 AC_SUBST(MEEGO_LIBS)
 435
 436 # -----------------------------------------------------------
 437 # nautilus-sendto
 438 # -----------------------------------------------------------
 439 AC_ARG_ENABLE(nautilus-sendto,
 440               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 441                              [build nautilus-sendto plugin]), ,
 442                              enable_nautilus_sendto=auto)
 443
 444 if test "x$enable_nautilus_sendto" != "xno"; then
 445    if test "x$have_gtk3" == "xno"; then
 446       # Newer NST requires GTK+3 so we can't use it
 447       PKG_CHECK_MODULES(NST,
 448       [
 449          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 450          nautilus-sendto < 2.90.0
 451       ], have_nst="yes", have_nst="no")
 452
 453       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 454    else
 455       PKG_CHECK_MODULES(NST,
 456       [
 457          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 458       ], have_nst="yes", have_nst="no")
 459    fi
 460 else
 461    have_nst=no
 462 fi
 463
 464 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 465    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 466 fi
 467
 468 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 469
 470 # -----------------------------------------------------------
 471 # new, single-window control center
 472 # -----------------------------------------------------------
 473 AC_ARG_ENABLE(control_center_embedding,
 474               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 475                              [Enable support for single-window control center]),
 476                              , enable_control_center_embedding=auto)
 477
 478 if test "x$enable_control_center_embedding" != "xno"; then
 479    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 480    [
 481       libgnome-control-center-extension
 482    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 483
 484    if test "x$have_control_center_embedding" = "xyes"; then
 485       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 486    fi
 487 else
 488    have_control_center_embedding="no"
 489 fi
 490
 491 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 492    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 493 fi
 494
 495 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 496 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 497 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 498
 499 # -----------------------------------------------------------
 500 # Coding style checks
 501 # -----------------------------------------------------------
 502 AC_ARG_ENABLE(coding-style-checks,
 503   AC_HELP_STRING([--disable-coding-style-checks],
 504                  [don't check coding style using grep]),
 505     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 506
 507 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 508 # -----------------------------------------------------------
 509
 510 AC_OUTPUT([
 511    Makefile
 512    data/Makefile
 513    data/empathy.desktop.in
 514    data/empathy-accounts.desktop.in
 515    data/icons/Makefile
 516    extensions/Makefile
 517    po/Makefile.in
 518    libempathy/Makefile
 519    libempathy-gtk/Makefile
 520    src/Makefile
 521    nautilus-sendto-plugin/Makefile
 522    help/Makefile
 523    tests/Makefile
 524    tests/interactive/Makefile
 525    tests/xml/Makefile
 526    tools/Makefile
 527 ])
 528
 529 echo "
 530 Configure summary:
 531
 532         Compiler....................:  ${CC}
 533         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 534         Prefix......................:  ${prefix}
 535         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 536         Use GTK+3...................:  ${have_gtk3}
 537
 538     Features:
 539         Spell checking (enchant)....:  ${have_enchant}
 540         Display maps (libchamplain).:  ${have_libchamplain}
 541         Location awareness (Geoclue):  ${have_geoclue}
 542         Adium themes (Webkit).......:  ${have_webkit}
 543         Meego widgets ..............:  ${have_meego}
 544         Control center embedding....:  ${have_control_center_embedding}
 545
 546     Connectivity:
 547         NetworkManager integration..:  ${have_nm}
 548         ConnMan integration.........:  ${have_connman}
 549
 550     Extras:
 551         Nautilus-sendto plugin......:  ${have_nst}
 552 "