configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [1])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.5.1
  35 GLIB_REQUIRED=2.28.0
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=3.0.2
  38 KEYRING_REQUIRED=2.26.0
  39 GCR_REQUIRED=2.91.4
  40 LIBCANBERRA_GTK_REQUIRED=0.25
  41 LIBNOTIFY_REQUIRED=0.7.0
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.15.1
  44 TELEPATHY_LOGGER=0.2.0
  45
  46 # Optional deps
  47 CLUTTER_GTK_REQUIRED=0.90.3
  48 ENCHANT_REQUIRED=1.2.0
  49 GEOCLUE_REQUIRED=0.11
  50 ISO_CODES_REQUIRED=0.35
  51 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  52 LIBCHAMPLAIN_REQUIRED=0.9
  53 NAUTILUS_SENDTO_REQUIRED=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.3.2
  56 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  57
  58 # Use --enable-maintainer-mode to disable deprecated symbols,
  59 # disable single include and enable GSEAL. If this is not a released empathy,
  60 # maintainer mode is forced
  61 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  62 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 #GNOME_MAINTAINER_MODE_DEFINES
  64
  65 # telepathy-yell
  66 prev_top_build_prefix=$ac_top_build_prefix
  67 AX_CONFIG_DIR([telepathy-yell])
  68 ac_top_build_prefix=$prev_top_build_prefix
  69 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  70
  71 AC_CONFIG_MACRO_DIR([m4])
  72 AC_CONFIG_HEADERS([config.h])
  73 AC_CONFIG_SRCDIR([configure.ac])
  74 AC_CONFIG_AUX_DIR(.)
  75
  76 GNOME_COMMON_INIT
  77
  78 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  79
  80 # Support silent build rules, requires at least automake-1.11. Disable
  81 # by either passing --disable-silent-rules to configure or passing V=1
  82 # to make
  83 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  84
  85 AC_ISC_POSIX
  86 AC_PROG_CC
  87 AC_HEADER_STDC
  88 AM_PROG_LIBTOOL
  89 AM_PROG_MKDIR_P
  90 AM_PATH_GLIB_2_0
  91 AC_PATH_XTRA
  92 IT_PROG_INTLTOOL([0.35.0])
  93 GNOME_DOC_INIT([0.17.3])
  94 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  95 GLIB_GSETTINGS
  96 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  97 AC_SUBST(GLIB_GENMARSHAL)
  98
  99 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 100 if test -z "$XSLTPROC"; then
 101   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 102 fi
 103 AM_PATH_PYTHON([2.3])
 104
 105 EMPATHY_ARG_VALGRIND
 106
 107
 108 # -----------------------------------------------------------
 109 # Error flags
 110 # -----------------------------------------------------------
 111 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 112 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 113
 114 AC_ARG_ENABLE(Werror,
 115   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 116     werror=$enableval, :)
 117
 118 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 119 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 120         wno_missing_field_initializers=yes,
 121         wno_missing_field_initializers=no)
 122 AS_COMPILER_FLAG(-Wno-unused-parameter,
 123         wno_unused_parameter=yes,
 124         wno_unused_parameter=no)
 125
 126 ifelse(empathy_released, 1, [],
 127     [
 128         if test x$werror = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 130         fi
 131         if test x$wextra = xyes -a \
 132             x$wno_missing_field_initializers = xyes -a \
 133             x$wno_unused_parameter = xyes; then
 134             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 135         fi
 136     ])
 137
 138 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 139 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 140 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 141 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 142 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 143
 144 AC_SUBST(ERROR_CFLAGS)
 145
 146 # -----------------------------------------------------------
 147 # Pkg-Config dependency checks
 148 # -----------------------------------------------------------
 149
 150 PKG_CHECK_MODULES(EMPATHY,
 151 [
 152    dbus-glib-1
 153    folks >= $FOLKS_REQUIRED
 154    folks-telepathy >= $FOLKS_REQUIRED
 155    glib-2.0 >= $GLIB_REQUIRED
 156    gio-2.0 >= $GLIB_REQUIRED
 157    gio-unix-2.0 >= $GLIB_REQUIRED
 158    gnome-keyring-1 >= $KEYRING_REQUIRED
 159    gnutls >= $GNUTLS_REQUIRED
 160    gmodule-export-2.0
 161    gobject-2.0
 162    gsettings-desktop-schemas
 163    gstreamer-0.10
 164    gstreamer-interfaces-0.10
 165    libxml-2.0
 166    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 167    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 168    x11
 169    gtk+-3.0 >= $GTK_REQUIRED
 170    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 171    libnotify >= $LIBNOTIFY_REQUIRED
 172    gcr-3 >= $GCR_REQUIRED
 173 ])
 174
 175 PKG_CHECK_MODULES(EMPATHY_AV,
 176 [
 177    farsight2-0.10
 178    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 179 ])
 180
 181 # -----------------------------------------------------------
 182 # Call interface
 183 # -----------------------------------------------------------
 184 AC_ARG_WITH(call,
 185             AC_HELP_STRING([--with-call], [build with Call interface support]),,
 186             [with_call=yes])
 187 if test "x$with_call" = "xyes" ; then
 188    PKG_CHECK_MODULES(YELL, [telepathy-yell])
 189    PKG_CHECK_MODULES(EMPATHY_CALL,
 190    [
 191       farsight2-0.10
 192       telepathy-farstream
 193    ])
 194    AC_DEFINE(HAVE_CALL, 1, [Define if we have Call interface support])
 195 fi
 196 AM_CONDITIONAL(HAVE_CALL, test "x$with_call" = "xyes")
 197
 198 # -----------------------------------------------------------
 199 # evolution-data-server (about-me)
 200 # -----------------------------------------------------------
 201 AC_ARG_WITH(eds,
 202             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 203             [with_eds=yes])
 204 if test x"$with_eds" = x"yes" ; then
 205    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 206    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 207 fi
 208
 209 # -----------------------------------------------------------
 210 # Enable debug
 211 # -----------------------------------------------------------
 212
 213 AC_ARG_ENABLE(debug,
 214   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 215     enable_debug=$enableval, enable_debug=yes )
 216
 217 if test x$enable_debug = xyes; then
 218   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 219 fi
 220
 221 # -----------------------------------------------------------
 222 # Language Support
 223 # -----------------------------------------------------------
 224
 225 GETTEXT_PACKAGE=empathy
 226 AC_SUBST(GETTEXT_PACKAGE)
 227 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 228
 229 AM_GLIB_GNU_GETTEXT
 230
 231 # -----------------------------------------------------------
 232 # Connectivity integration
 233 # -----------------------------------------------------------
 234 AC_ARG_WITH(connectivity,
 235               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 236                              [build with connectivity support]), ,
 237                              with_connectivity=auto)
 238
 239 if test "x$with_connectivity" = "xno"; then
 240    have_nm=no
 241    have_connman=no
 242
 243 elif test "x$with_connectivity" = "xconnman"; then
 244    have_nm=no
 245
 246    PKG_CHECK_MODULES(CONNMAN,
 247    [
 248       dbus-glib-1
 249    ], have_connman="yes", have_connman="no")
 250
 251    if test "x$have_connman" = "xyes"; then
 252       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 253    fi
 254
 255 else
 256    have_connman=no
 257
 258    PKG_CHECK_MODULES(NETWORK_MANAGER,
 259    [
 260       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 261    ], have_nm="yes", have_nm="no")
 262
 263    if test "x$have_nm" = "xyes"; then
 264       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 265    fi
 266 fi
 267
 268 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 269    AC_MSG_ERROR([Couldn't find connman dependencies.])
 270 fi
 271
 272 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 273    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 274 fi
 275
 276 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 277 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 278
 279 # -----------------------------------------------------------
 280 # Webkit
 281 # -----------------------------------------------------------
 282 AC_ARG_ENABLE(webkit,
 283               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 284                              [build with webkit support]), ,
 285                              enable_webkit=auto)
 286
 287 if test "x$enable_webkit" != "xno"; then
 288    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 289         have_webkit="yes", have_webkit="no")
 290
 291    if test "x$have_webkit" = "xyes"; then
 292       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 293    fi
 294 else
 295    have_webkit=no
 296 fi
 297
 298 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 299    AC_MSG_ERROR([Could not find webkit dependencies.])
 300 fi
 301 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 302
 303 # -----------------------------------------------------------
 304 # spellchecking checks: enchant and iso-codes
 305 # -----------------------------------------------------------
 306 AC_ARG_ENABLE(spell,
 307               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 308                              [Enable spell checking]), ,
 309                              enable_spell=auto)
 310
 311 if test "x$enable_spell" != "xno"; then
 312    PKG_CHECK_MODULES(ENCHANT,
 313    [
 314       enchant >= $ENCHANT_REQUIRED,
 315       iso-codes >= $ISO_CODES_REQUIRED
 316    ], have_enchant="yes", have_enchant="no")
 317
 318    if test "x$have_enchant" = "xyes"; then
 319       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 320       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 321          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 322             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 323             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 324             result=yes
 325       else
 326             result=no
 327             have_enchant="no"
 328       fi
 329       AC_MSG_RESULT([$result])
 330    fi
 331 else
 332    have_enchant=no
 333 fi
 334
 335 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 336    AC_MSG_ERROR([Could not find spell dependencies.])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 340
 341 # -----------------------------------------------------------
 342 # Map view checks: libchamplain
 343 # -----------------------------------------------------------
 344 AC_ARG_ENABLE(map,
 345               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 346                              [Enable map view]), ,
 347                              enable_map=auto)
 348
 349 if test "x$enable_map" != "xno"; then
 350
 351    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 352     [
 353        clutter-gtk-1.0
 354        champlain-gtk-0.10
 355        champlain-0.10
 356     ], have_libchamplain="yes", have_libchamplain="no")
 357
 358    if test "x$have_libchamplain" = "xyes"; then
 359       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 360    fi
 361 else
 362    have_libchamplain=no
 363 fi
 364
 365 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 366    AC_MSG_ERROR([Could not find map view dependencies.])
 367 fi
 368
 369 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 370
 371 # -----------------------------------------------------------
 372 # location checks: geoclue
 373 # -----------------------------------------------------------
 374 AC_ARG_ENABLE(location,
 375               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 376                              [Enable location awareness]), ,
 377                              enable_location=auto)
 378
 379 if test "x$enable_location" != "xno"; then
 380    PKG_CHECK_MODULES(GEOCLUE,
 381    [
 382       geoclue >= $GEOCLUE_REQUIRED
 383    ], have_geoclue="yes", have_geoclue="no")
 384
 385    if test "x$have_geoclue" = "xyes"; then
 386       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 387    fi
 388 else
 389    have_geoclue="no"
 390 fi
 391
 392 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 393    AC_MSG_ERROR([Could not find location dependencies.])
 394 fi
 395
 396 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 397 AC_SUBST(GEOCLUE_CFLAGS)
 398 AC_SUBST(GEOCLUE_LIBS)
 399
 400 # -----------------------------------------------------------
 401 # meego widgets support
 402 # -----------------------------------------------------------
 403 AC_ARG_ENABLE(meego,
 404               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 405                              [Enable meego widgets]), ,
 406                              enable_meego=no)
 407
 408 if test "x$enable_meego" != "xno"; then
 409     PKG_CHECK_MODULES(MEEGO,
 410     [
 411        mx-gtk-1.0
 412        gio-unix-2.0
 413     ], have_meego="yes", have_meego="no")
 414
 415     if test "x$have_meego" = "xyes"; then
 416        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 417     fi
 418 else
 419    have_meego="no"
 420 fi
 421
 422 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 423    AC_MSG_ERROR([Could not find meego dependencies.])
 424 fi
 425
 426 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 427 AC_SUBST(MEEGO_CFLAGS)
 428 AC_SUBST(MEEGO_LIBS)
 429
 430 # -----------------------------------------------------------
 431 # nautilus-sendto
 432 # -----------------------------------------------------------
 433 AC_ARG_ENABLE(nautilus-sendto,
 434               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 435                              [build nautilus-sendto plugin]), ,
 436                              enable_nautilus_sendto=auto)
 437
 438 if test "x$enable_nautilus_sendto" != "xno"; then
 439    PKG_CHECK_MODULES(NST,
 440     [
 441        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 442     ], have_nst="yes", have_nst="no")
 443 else
 444    have_nst=no
 445 fi
 446
 447 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 448    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 449 fi
 450
 451 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 452
 453 # -----------------------------------------------------------
 454 # new, single-window control center
 455 # -----------------------------------------------------------
 456 AC_ARG_ENABLE(control_center_embedding,
 457               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 458                              [Enable support for single-window control center]),
 459                              , enable_control_center_embedding=auto)
 460
 461 if test "x$enable_control_center_embedding" != "xno"; then
 462
 463    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 464         have_control_center_embedding="yes", have_control_center_embedding="no")
 465
 466    if test "x$have_control_center_embedding" = "xyes"; then
 467       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 468
 469       AC_MSG_CHECKING([gnome-control-center extension dir])
 470       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 471       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 472           AC_MSG_ERROR([Could not determine extensiondir])
 473       else
 474           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 475       fi
 476       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 477    fi
 478 else
 479    have_control_center_embedding="no"
 480 fi
 481
 482 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 483    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 484 fi
 485
 486 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 487 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 488 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 489
 490 # Optional dependency for avatar selection
 491 AC_ARG_WITH([cheese],
 492             AS_HELP_STRING([--with-cheese], [enable cheese webcam support]),,
 493             with_cheese=auto)
 494
 495 if test x"$with_cheese" != x"no" ; then
 496    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 497    if test x${have_cheese} = xyes; then
 498      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 499    fi
 500    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 501      AC_MSG_ERROR([Cheese configured but not found])
 502    fi
 503 else
 504    have_cheese=no
 505 fi
 506 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 507
 508
 509 # -----------------------------------------------------------
 510 # Coding style checks
 511 # -----------------------------------------------------------
 512 AC_ARG_ENABLE(coding-style-checks,
 513   AC_HELP_STRING([--disable-coding-style-checks],
 514                  [do not check coding style using grep]),
 515     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 516
 517 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 518 # -----------------------------------------------------------
 519
 520 AC_OUTPUT([
 521    Makefile
 522    data/Makefile
 523    data/empathy.desktop.in
 524    data/empathy-accounts.desktop.in
 525    data/icons/Makefile
 526    extensions/Makefile
 527    po/Makefile.in
 528    libempathy/Makefile
 529    libempathy-gtk/Makefile
 530    src/Makefile
 531    nautilus-sendto-plugin/Makefile
 532    help/Makefile
 533    tests/Makefile
 534    tests/interactive/Makefile
 535    tests/xml/Makefile
 536    tools/Makefile
 537 ])
 538
 539 echo "
 540 Configure summary:
 541
 542         Compiler....................:  ${CC}
 543         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 544         Prefix......................:  ${prefix}
 545         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 546
 547     Features:
 548         Spell checking (enchant)....:  ${have_enchant}
 549         Display maps (libchamplain).:  ${have_libchamplain}
 550         Location awareness (Geoclue):  ${have_geoclue}
 551         Adium themes (Webkit).......:  ${have_webkit}
 552         Meego widgets ..............:  ${have_meego}
 553         Control center embedding....:  ${have_control_center_embedding}
 554         Cheese webcam support ......:  ${have_cheese}
 555
 556     Connectivity:
 557         NetworkManager integration..:  ${have_nm}
 558         ConnMan integration.........:  ${have_connman}
 559
 560     Extras:
 561         Nautilus-sendto plugin......:  ${have_nst}
 562         Salut E-D-S support.........:  ${with_eds}
 563 "