configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.0
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GTK_REQUIRED=2.21.2
  38 KEYRING_REQUIRED=2.22
  39 LIBCANBERRA_GTK_REQUIRED=0.4
  40 LIBNOTIFY_REQUIRED=0.4.4
  41 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.11.7
  44 TELEPATHY_LOGGER=0.1.2
  45 UNIQUE_REQUIRED=1.1.2
  46
  47 # Optionnal deps
  48 CLUTTER_GTK_REQUIRED=0.10
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  53 LIBCHAMPLAIN_REQUIRED=0.4
  54 NAUTILUS_SENDTO_REQUIRED=2.28.1
  55 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  56 NETWORK_MANAGER_REQUIRED=0.7.0
  57 WEBKIT_REQUIRED=1.1.15
  58
  59 # Use --enable-maintainer-mode to disable deprecated symbols,
  60 # disable single include and enable GSEAL. If this is not a released empathy,
  61 # maintainer mode is forced
  62 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 GNOME_MAINTAINER_MODE_DEFINES
  64
  65 AC_CONFIG_MACRO_DIR([m4])
  66 AC_CONFIG_HEADERS([config.h])
  67 AC_CONFIG_SRCDIR([configure.ac])
  68 AC_CONFIG_AUX_DIR(.)
  69
  70 GNOME_COMMON_INIT
  71
  72 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  73
  74 # Support silent build rules, requires at least automake-1.11. Disable
  75 # by either passing --disable-silent-rules to configure or passing V=1
  76 # to make
  77 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  78
  79 AC_ISC_POSIX
  80 AC_PROG_CC
  81 AC_HEADER_STDC
  82 AM_PROG_LIBTOOL
  83 AM_PROG_MKDIR_P
  84 AM_PATH_GLIB_2_0
  85 AC_PATH_XTRA
  86 IT_PROG_INTLTOOL([0.35.0])
  87 GNOME_DOC_INIT([0.17.3])
  88 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  89 GLIB_GSETTINGS
  90 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  91 AC_SUBST(GLIB_GENMARSHAL)
  92 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  93 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  94
  95 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  96 if test -z "$XSLTPROC"; then
  97   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  98 fi
  99 AM_PATH_PYTHON([2.3])
 100
 101 EMPATHY_ARG_VALGRIND
 102
 103
 104 # -----------------------------------------------------------
 105 # Error flags
 106 # -----------------------------------------------------------
 107 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 108 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 109
 110 AC_ARG_ENABLE(Werror,
 111   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 112     werror=$enableval, :)
 113
 114 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 115 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 116         wno_missing_field_initializers=yes,
 117         wno_missing_field_initializers=no)
 118 AS_COMPILER_FLAG(-Wno-unused-parameter,
 119         wno_unused_parameter=yes,
 120         wno_unused_parameter=no)
 121
 122 ifelse(empathy_released, 1, [],
 123     [
 124         if test x$werror = xyes; then
 125             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 126         fi
 127         if test x$wextra = xyes -a \
 128             x$wno_missing_field_initializers = xyes -a \
 129             x$wno_unused_parameter = xyes; then
 130             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 131         fi
 132     ])
 133
 134 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 135 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 136 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 137 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 138 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 139 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 140
 141 AC_SUBST(ERROR_CFLAGS)
 142
 143 # -----------------------------------------------------------
 144 # Enable TPL
 145 # -----------------------------------------------------------
 146
 147 # It needs to be defined before PKG_CHECK_MODULES calls
 148 AC_ARG_ENABLE(tpl,
 149   AC_HELP_STRING([--enable-tpl],[enable telepathy-logger code and disable the
 150     empathy logger]), enable_tpl=$enableval, enable_tpl=no )
 151 AM_CONDITIONAL(ENABLE_TPL, test "x$enable_tpl" = "xyes")
 152
 153 if test x${enable_tpl} = xyes; then
 154   AC_DEFINE(ENABLE_TPL, [], [Enable TPL code])
 155 fi
 156
 157 if test "x$enable_tpl" = "xyes"; then
 158   PKG_CHECK_MODULES(TPL,
 159   [
 160      telepathy-logger = $TELEPATHY_LOGGER
 161   ])
 162   AC_SUBST(TPL_CFLAGS)
 163   AC_SUBST(TPL_LIBS)
 164 fi
 165
 166
 167
 168 # -----------------------------------------------------------
 169 # Pkg-Config dependency checks
 170 # -----------------------------------------------------------
 171
 172 PKG_CHECK_MODULES(EMPATHY,
 173 [
 174    dbus-glib-1
 175    farsight2-0.10
 176    folks >= $FOLKS_REQUIRED
 177    folks-telepathy >= $FOLKS_REQUIRED
 178    gconf-2.0 >= $GCONF_REQUIRED
 179    gio-2.0 >= $GLIB_REQUIRED
 180    gio-unix-2.0 >= $GLIB_REQUIRED
 181    gnome-keyring-1 >= $KEYRING_REQUIRED
 182    gobject-2.0
 183    gstreamer-0.10
 184    gstreamer-interfaces-0.10
 185    libebook-1.2
 186    libxml-2.0
 187    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 188    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 189    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 190    x11
 191 ])
 192
 193 # -----------------------------------------------------------
 194 # GTK+
 195 # -----------------------------------------------------------
 196 AC_ARG_ENABLE(gtk3,
 197               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 198                              [build with GTK+3]), ,
 199                              enable_gtk3=auto)
 200
 201 # Try to use GTK+3 if available
 202 if test "x$enable_gtk3" != "xno"; then
 203    PKG_CHECK_MODULES(GTK,
 204    [
 205       gtk+-3.0 >= $GTK_REQUIRED
 206    ], have_gtk3="yes", have_gtk3="no")
 207 else
 208    have_gtk3="no"
 209 fi
 210
 211 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 212    AC_MSG_ERROR([Couldn't find gtk3 dependencies.])
 213 fi
 214
 215 if test "x$have_gtk3" == "xyes"; then
 216    # GTK3 specific deps
 217    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 218    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 219    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 220 else
 221    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 222
 223    # GTK2 specific deps
 224    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 225    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 226    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 227
 228    # Enable GSEAL checks if needed
 229    if test $USE_MAINTAINER_MODE = yes; then
 230       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 231    fi
 232 fi
 233
 234 # -----------------------------------------------------------
 235 # Enable debug
 236 # -----------------------------------------------------------
 237
 238 AC_ARG_ENABLE(debug,
 239   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 240     enable_debug=$enableval, enable_debug=yes )
 241
 242 if test x$enable_debug = xyes; then
 243   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 244 fi
 245
 246 # -----------------------------------------------------------
 247 # Language Support
 248 # -----------------------------------------------------------
 249
 250 GETTEXT_PACKAGE=empathy
 251 AC_SUBST(GETTEXT_PACKAGE)
 252 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 253
 254 AM_GLIB_GNU_GETTEXT
 255
 256 # -----------------------------------------------------------
 257 # Connectivity integration
 258 # -----------------------------------------------------------
 259 AC_ARG_WITH(connectivity,
 260               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 261                              [build with connectivity support]), ,
 262                              with_connectivity=auto)
 263
 264 if test "x$with_connectivity" = "xno"; then
 265    have_nm=no
 266    have_connman=no
 267
 268 elif test "x$with_connectivity" = "xconnman"; then
 269    have_nm=no
 270
 271    PKG_CHECK_MODULES(CONNMAN,
 272    [
 273       dbus-glib-1
 274    ], have_connman="yes", have_connman="no")
 275
 276    if test "x$have_connman" = "xyes"; then
 277       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 278    fi
 279
 280 else
 281    have_connman=no
 282
 283    PKG_CHECK_MODULES(NETWORK_MANAGER,
 284    [
 285       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 286    ], have_nm="yes", have_nm="no")
 287
 288    if test "x$have_nm" = "xyes"; then
 289       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 290    fi
 291 fi
 292
 293 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 294    AC_MSG_ERROR([Couldn't find connman dependencies.])
 295 fi
 296
 297 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 298    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 299 fi
 300
 301 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 302 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 303
 304 # -----------------------------------------------------------
 305 # Webkit
 306 # -----------------------------------------------------------
 307 AC_ARG_ENABLE(webkit,
 308               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 309                              [build with webkit support]), ,
 310                              enable_webkit=auto)
 311
 312 if test "x$enable_webkit" != "xno"; then
 313
 314    if test "x$have_gtk3" == "xno"; then
 315       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 316           have_webkit="yes", have_webkit="no")
 317    else
 318       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 319           have_webkit="yes", have_webkit="no")
 320    fi
 321
 322    if test "x$have_webkit" = "xyes"; then
 323       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 324    fi
 325 else
 326    have_webkit=no
 327 fi
 328
 329 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 330    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 331 fi
 332 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 333
 334 # -----------------------------------------------------------
 335 # spellchecking checks: enchant and iso-codes
 336 # -----------------------------------------------------------
 337 AC_ARG_ENABLE(spell,
 338               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 339                              [Enable spell checking]), ,
 340                              enable_spell=auto)
 341
 342 if test "x$enable_spell" != "xno"; then
 343    PKG_CHECK_MODULES(ENCHANT,
 344    [
 345       enchant >= $ENCHANT_REQUIRED,
 346       iso-codes >= $ISO_CODES_REQUIRED
 347    ], have_enchant="yes", have_enchant="no")
 348
 349    if test "x$have_enchant" = "xyes"; then
 350       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 351       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 352          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 353             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 354             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 355             result=yes
 356       else
 357             result=no
 358             have_enchant="no"
 359       fi
 360       AC_MSG_RESULT([$result])
 361    fi
 362 else
 363    have_enchant=no
 364 fi
 365
 366 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 367    AC_MSG_ERROR([Couldn't find spell dependencies.])
 368 fi
 369
 370 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 371
 372 # -----------------------------------------------------------
 373 # Map view checks: libchamplain
 374 # -----------------------------------------------------------
 375 AC_ARG_ENABLE(map,
 376               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 377                              [Enable map view]), ,
 378                              enable_map=auto)
 379
 380 if test "x$enable_map" != "xno"; then
 381
 382    if test "x$have_gtk3" == "xno"; then
 383       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 384       [
 385          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 386          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 387          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 388       ], have_libchamplain="yes", have_libchamplain="no")
 389    else
 390       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 391       have_libchamplain="no"
 392    fi
 393
 394    if test "x$have_libchamplain" = "xyes"; then
 395       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 396    fi
 397 else
 398    have_libchamplain=no
 399 fi
 400
 401 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 402    AC_MSG_ERROR([Couldn't find map view dependencies.])
 403 fi
 404
 405 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 406
 407 # -----------------------------------------------------------
 408 # location checks: geoclue
 409 # -----------------------------------------------------------
 410 AC_ARG_ENABLE(location,
 411               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 412                              [Enable location awareness]), ,
 413                              enable_location=auto)
 414
 415 if test "x$enable_location" != "xno"; then
 416    PKG_CHECK_MODULES(GEOCLUE,
 417    [
 418       geoclue >= $GEOCLUE_REQUIRED
 419    ], have_geoclue="yes", have_geoclue="no")
 420
 421    if test "x$have_geoclue" = "xyes"; then
 422       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 423    fi
 424 else
 425    have_geoclue="no"
 426 fi
 427
 428 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 429    AC_MSG_ERROR([Couldn't find location dependencies.])
 430 fi
 431
 432 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 433 AC_SUBST(GEOCLUE_CFLAGS)
 434 AC_SUBST(GEOCLUE_LIBS)
 435
 436 # -----------------------------------------------------------
 437 # meego widgets support
 438 # -----------------------------------------------------------
 439 AC_ARG_ENABLE(meego,
 440               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 441                              [Enable meego widgets]), ,
 442                              enable_meego=no)
 443
 444 if test "x$enable_meego" != "xno"; then
 445     PKG_CHECK_MODULES(MEEGO,
 446     [
 447        mx-gtk-1.0
 448     ], have_meego="yes", have_meego="no")
 449
 450     if test "x$have_meego" = "xyes"; then
 451        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 452     fi
 453 else
 454    have_meego="no"
 455 fi
 456
 457 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 458    AC_MSG_ERROR([Couldn't find meego dependencies.])
 459 fi
 460
 461 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 462 AC_SUBST(MEEGO_CFLAGS)
 463 AC_SUBST(MEEGO_LIBS)
 464
 465 # -----------------------------------------------------------
 466 # nautilus-sendto
 467 # -----------------------------------------------------------
 468 AC_ARG_ENABLE(nautilus-sendto,
 469               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 470                              [build nautilus-sendto plugin]), ,
 471                              enable_nautilus_sendto=auto)
 472
 473 if test "x$enable_nautilus_sendto" != "xno"; then
 474    if test "x$have_gtk3" == "xno"; then
 475       # Newer NST requires GTK+3 so we can't use it
 476       PKG_CHECK_MODULES(NST,
 477       [
 478          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 479          nautilus-sendto < 2.90.0
 480       ], have_nst="yes", have_nst="no")
 481
 482       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 483    else
 484       PKG_CHECK_MODULES(NST,
 485       [
 486          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 487       ], have_nst="yes", have_nst="no")
 488    fi
 489 else
 490    have_nst=no
 491 fi
 492
 493 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 494    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 495 fi
 496
 497 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 498
 499 # -----------------------------------------------------------
 500 # new, single-window control center
 501 # -----------------------------------------------------------
 502 AC_ARG_ENABLE(control_center_embedding,
 503               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 504                              [Enable support for single-window control center]),
 505                              , enable_control_center_embedding=auto)
 506
 507 if test "x$enable_control_center_embedding" != "xno"; then
 508    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 509    [
 510       libgnome-control-center-extension
 511    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 512
 513    if test "x$have_control_center_embedding" = "xyes"; then
 514       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 515    fi
 516 else
 517    have_control_center_embedding="no"
 518 fi
 519
 520 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 521    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 522 fi
 523
 524 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 525 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 526 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 527
 528 # -----------------------------------------------------------
 529 # Coding style checks
 530 # -----------------------------------------------------------
 531 AC_ARG_ENABLE(coding-style-checks,
 532   AC_HELP_STRING([--disable-coding-style-checks],
 533                  [don't check coding style using grep]),
 534     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 535
 536 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 537 # -----------------------------------------------------------
 538
 539 AC_OUTPUT([
 540    Makefile
 541    data/Makefile
 542    data/empathy.desktop.in
 543    data/empathy-accounts.desktop.in
 544    data/icons/Makefile
 545    extensions/Makefile
 546    po/Makefile.in
 547    libempathy/Makefile
 548    libempathy-gtk/Makefile
 549    src/Makefile
 550    nautilus-sendto-plugin/Makefile
 551    help/Makefile
 552    tests/Makefile
 553    tests/interactive/Makefile
 554    tests/xml/Makefile
 555    tools/Makefile
 556 ])
 557
 558 echo "
 559 Configure summary:
 560
 561         Compiler....................:  ${CC}
 562         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 563         Prefix......................:  ${prefix}
 564         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 565         Use GTK+3...................:  ${have_gtk3}
 566
 567     Features:
 568         Spell checking (enchant)....:  ${have_enchant}
 569         Display maps (libchamplain).:  ${have_libchamplain}
 570         Location awareness (Geoclue):  ${have_geoclue}
 571         Adium themes (Webkit).......:  ${have_webkit}
 572         Meego widgets ..............:  ${have_meego}
 573         Control center embedding....:  ${have_control_center_embedding}
 574
 575     Connectivity:
 576         NetworkManager integration..:  ${have_nm}
 577         ConnMan integration.........:  ${have_connman}
 578
 579     Extras:
 580         Nautilus-sendto plugin......:  ${have_nst}
 581 "