configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_GLIB_REQUIRED=0.11.7
  42 TELEPATHY_LOGGER=0.1.2
  43 UNIQUE_REQUIRED=1.1.2
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.10
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  51 LIBCHAMPLAIN_REQUIRED=0.4
  52 NAUTILUS_SENDTO_REQUIRED=2.28.1
  53 NETWORK_MANAGER_REQUIRED=0.7.0
  54 WEBKIT_REQUIRED=1.1.15
  55
  56 # Use --enable-maintainer-mode to disable deprecated symbols,
  57 # disable single include and enable GSEAL. If this is not a released empathy,
  58 # maintainer mode is forced
  59 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  60 GNOME_MAINTAINER_MODE_DEFINES
  61
  62 AC_CONFIG_MACRO_DIR([m4])
  63 AC_CONFIG_HEADERS([config.h])
  64 AC_CONFIG_SRCDIR([configure.ac])
  65 AC_CONFIG_AUX_DIR(.)
  66
  67 GNOME_COMMON_INIT
  68
  69 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  70
  71 # Support silent build rules, requires at least automake-1.11. Disable
  72 # by either passing --disable-silent-rules to configure or passing V=1
  73 # to make
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76 AC_ISC_POSIX
  77 AC_PROG_CC
  78 AC_HEADER_STDC
  79 AM_PROG_LIBTOOL
  80 AM_PROG_MKDIR_P
  81 AM_PATH_GLIB_2_0
  82 AC_PATH_XTRA
  83 IT_PROG_INTLTOOL([0.35.0])
  84 GNOME_DOC_INIT([0.17.3])
  85 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  86 GLIB_GSETTINGS
  87 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  88 AC_SUBST(GLIB_GENMARSHAL)
  89 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  90 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  91
  92 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  93 if test -z "$XSLTPROC"; then
  94   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  95 fi
  96 AM_PATH_PYTHON([2.3])
  97
  98 EMPATHY_ARG_VALGRIND
  99
 100
 101 # -----------------------------------------------------------
 102 # Error flags
 103 # -----------------------------------------------------------
 104 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 105 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 106
 107 AC_ARG_ENABLE(Werror,
 108   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 109     werror=$enableval, :)
 110
 111 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 112 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 113         wno_missing_field_initializers=yes,
 114         wno_missing_field_initializers=no)
 115 AS_COMPILER_FLAG(-Wno-unused-parameter,
 116         wno_unused_parameter=yes,
 117         wno_unused_parameter=no)
 118
 119 ifelse(empathy_released, 1, [],
 120     [
 121         if test x$werror = xyes; then
 122             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 123         fi
 124         if test x$wextra = xyes -a \
 125             x$wno_missing_field_initializers = xyes -a \
 126             x$wno_unused_parameter = xyes; then
 127             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 128         fi
 129     ])
 130
 131 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 132 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 133 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 134 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 135 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 136 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 137
 138 AC_SUBST(ERROR_CFLAGS)
 139
 140 # -----------------------------------------------------------
 141 # Pkg-Config dependency checks
 142 # -----------------------------------------------------------
 143
 144 PKG_CHECK_MODULES(EMPATHY,
 145 [
 146    dbus-glib-1
 147    farsight2-0.10
 148    gconf-2.0 >= $GCONF_REQUIRED
 149    gdk-x11-2.0
 150    gio-2.0 >= $GLIB_REQUIRED
 151    gio-unix-2.0 >= $GLIB_REQUIRED
 152    gnome-keyring-1 >= $KEYRING_REQUIRED
 153    gobject-2.0
 154    gstreamer-0.10
 155    gstreamer-interfaces-0.10
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    x11
 162 ])
 163
 164 # -----------------------------------------------------------
 165 # GTK+
 166 # -----------------------------------------------------------
 167 AC_ARG_ENABLE(gtk3,
 168               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 169                              [build with GTK+3]), ,
 170                              enable_gtk3=auto)
 171
 172 # Try to use GTK+3 if available
 173 if test "x$enable_gtk3" != "xno"; then
 174   PKG_CHECK_MODULES(GTK, [gtk+-3.0 >= $GTK_REQUIRED],
 175       enable_gtk3="yes", enable_gtk3="no")
 176
 177   # GTK3 specific deps
 178   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 179   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 180   PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 181 fi
 182
 183 # ...if not use GTK+2
 184 if test "x$enable_gtk3" == "xno"; then
 185   enable_gtk3=no
 186   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 187
 188   # GTK2 specific deps
 189   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 190   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 191   PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 192
 193   # Enable GSEAL checks if needed
 194   if test $USE_MAINTAINER_MODE = yes; then
 195     AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 196   fi
 197 fi
 198
 199 # -----------------------------------------------------------
 200 # Enable debug
 201 # -----------------------------------------------------------
 202
 203 AC_ARG_ENABLE(debug,
 204   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 205     enable_debug=$enableval, enable_debug=yes )
 206
 207 if test x$enable_debug = xyes; then
 208   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 209 fi
 210
 211 # -----------------------------------------------------------
 212 # Language Support
 213 # -----------------------------------------------------------
 214
 215 GETTEXT_PACKAGE=empathy
 216 AC_SUBST(GETTEXT_PACKAGE)
 217 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 218
 219 AM_GLIB_GNU_GETTEXT
 220
 221 # -----------------------------------------------------------
 222 # Connectivity integration
 223 # -----------------------------------------------------------
 224 AC_ARG_WITH(connectivity,
 225               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 226                              [build with connectivity support]), ,
 227                              with_connectivity=auto)
 228
 229 if test "x$with_connectivity" = "xno"; then
 230    have_nm=no
 231    have_connman=no
 232
 233 elif test "x$with_connectivity" = "xconnman"; then
 234
 235    PKG_CHECK_MODULES(CONNMAN,
 236    [
 237       dbus-glib-1
 238    ], have_connman="yes", have_connman="no")
 239
 240    if test "x$have_connman" = "xyes"; then
 241       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 242       have_nm=no
 243    fi
 244
 245 else
 246
 247    PKG_CHECK_MODULES(NETWORK_MANAGER,
 248    [
 249       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 250    ], have_nm="yes", have_nm="no")
 251
 252    if test "x$have_nm" = "xyes"; then
 253       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 254       have_connman=no
 255    else
 256       PKG_CHECK_MODULES(NETWORK_MANAGER,
 257       [
 258           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 259       ], have_nm="yes", have_nm="no")
 260
 261       if test "x$have_nm" = "xyes"; then
 262       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 263       have_connman=no
 264       fi
 265    fi
 266 fi
 267
 268 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 269    AC_MSG_ERROR([Couldn't find connman dependencies.])
 270 fi
 271
 272 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 273    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 274 fi
 275
 276 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 277 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 278
 279 # -----------------------------------------------------------
 280 # Webkit
 281 # -----------------------------------------------------------
 282 AC_ARG_ENABLE(webkit,
 283               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 284                              [build with webkit support]), ,
 285                              enable_webkit=auto)
 286
 287 if test "x$enable_webkit" != "xno"; then
 288    PKG_CHECK_MODULES(WEBKIT,
 289    [
 290       webkit-1.0 >= $WEBKIT_REQUIRED
 291    ], have_webkit="yes", have_webkit="no")
 292
 293    if test "x$have_webkit" = "xyes"; then
 294       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 295    fi
 296 else
 297    have_webkit=no
 298 fi
 299
 300 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 301    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 302 fi
 303 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 304
 305 # -----------------------------------------------------------
 306 # spellchecking checks: enchant and iso-codes
 307 # -----------------------------------------------------------
 308 AC_ARG_ENABLE(spell,
 309               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 310                              [Enable spell checking]), ,
 311                              enable_spell=auto)
 312
 313 if test "x$enable_spell" != "xno"; then
 314    PKG_CHECK_MODULES(ENCHANT,
 315    [
 316       enchant >= $ENCHANT_REQUIRED,
 317       iso-codes >= $ISO_CODES_REQUIRED
 318    ], have_enchant="yes", have_enchant="no")
 319
 320    if test "x$have_enchant" = "xyes"; then
 321       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 322       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 323          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 324             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 325             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 326             result=yes
 327       else
 328             result=no
 329             have_enchant="no"
 330       fi
 331       AC_MSG_RESULT([$result])
 332    fi
 333 else
 334    have_enchant=no
 335 fi
 336
 337 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 338    AC_MSG_ERROR([Couldn't find spell dependencies.])
 339 fi
 340
 341 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 342
 343 # -----------------------------------------------------------
 344 # Map view checks: libchamplain
 345 # -----------------------------------------------------------
 346 AC_ARG_ENABLE(map,
 347               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 348                              [Enable map view]), ,
 349                              enable_map=auto)
 350
 351 if test "x$enable_map" != "xno"; then
 352    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 353    [
 354       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 355       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 356       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 357    ], have_libchamplain="yes", have_libchamplain="no")
 358
 359    if test "x$have_libchamplain" = "xyes"; then
 360       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 361    fi
 362 else
 363    have_libchamplain=no
 364 fi
 365
 366 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 367    AC_MSG_ERROR([Couldn't find map view dependencies.])
 368 fi
 369
 370 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 371
 372 # -----------------------------------------------------------
 373 # location checks: geoclue
 374 # -----------------------------------------------------------
 375 AC_ARG_ENABLE(location,
 376               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 377                              [Enable location awareness]), ,
 378                              enable_location=auto)
 379
 380 if test "x$enable_location" != "xno"; then
 381    PKG_CHECK_MODULES(GEOCLUE,
 382    [
 383       geoclue >= $GEOCLUE_REQUIRED
 384    ], have_geoclue="yes", have_geoclue="no")
 385
 386    if test "x$have_geoclue" = "xyes"; then
 387       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 388    fi
 389 else
 390    have_geoclue="no"
 391 fi
 392
 393 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 394    AC_MSG_ERROR([Couldn't find location dependencies.])
 395 fi
 396
 397 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 398 AC_SUBST(GEOCLUE_CFLAGS)
 399 AC_SUBST(GEOCLUE_LIBS)
 400
 401 # -----------------------------------------------------------
 402 # meego widgets support
 403 # -----------------------------------------------------------
 404 AC_ARG_ENABLE(meego,
 405               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 406                              [Enable meego widgets]), ,
 407                              enable_meego=no)
 408
 409 if test "x$enable_meego" != "xno"; then
 410     PKG_CHECK_MODULES(MEEGO,
 411     [
 412        mx-gtk-1.0
 413     ], have_meego="yes", have_meego="no")
 414
 415     if test "x$have_meego" = "xyes"; then
 416        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 417     fi
 418 else
 419    have_meego="no"
 420 fi
 421
 422 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 423    AC_MSG_ERROR([Couldn't find meego dependencies.])
 424 fi
 425
 426 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 427 AC_SUBST(MEEGO_CFLAGS)
 428 AC_SUBST(MEEGO_LIBS)
 429
 430 # -----------------------------------------------------------
 431 # nautilus-sendto
 432 # -----------------------------------------------------------
 433 AC_ARG_ENABLE(nautilus-sendto,
 434               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 435                              [build nautilus-sendto plugin]), ,
 436                              enable_nautilus_sendto=auto)
 437
 438 if test "x$enable_nautilus_sendto" != "xno"; then
 439    PKG_CHECK_MODULES(NST,
 440    [
 441       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 442    ], have_nst="yes", have_nst="no")
 443 else
 444    have_nst=no
 445 fi
 446
 447 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 448    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 449 fi
 450
 451 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 452
 453 # -----------------------------------------------------------
 454 # new, single-window control center
 455 # -----------------------------------------------------------
 456 AC_ARG_ENABLE(control_center_embedding,
 457               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 458                              [Enable support for single-window control center]),
 459                              , enable_control_center_embedding=auto)
 460
 461 if test "x$enable_control_center_embedding" != "xno"; then
 462    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 463    [
 464       libgnome-control-center-extension
 465    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 466
 467    if test "x$have_control_center_embedding" = "xyes"; then
 468       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 469    fi
 470 else
 471    have_control_center_embedding="no"
 472 fi
 473
 474 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 475    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 476 fi
 477
 478 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 479 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 480 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 481
 482 # -----------------------------------------------------------
 483 # Coding style checks
 484 # -----------------------------------------------------------
 485 AC_ARG_ENABLE(coding-style-checks,
 486   AC_HELP_STRING([--disable-coding-style-checks],
 487                  [don't check coding style using grep]),
 488     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 489
 490 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 491 # -----------------------------------------------------------
 492
 493 AC_OUTPUT([
 494    Makefile
 495    data/Makefile
 496    data/empathy.desktop.in
 497    data/empathy-accounts.desktop.in
 498    data/icons/Makefile
 499    extensions/Makefile
 500    po/Makefile.in
 501    libempathy/Makefile
 502    libempathy-gtk/Makefile
 503    src/Makefile
 504    nautilus-sendto-plugin/Makefile
 505    help/Makefile
 506    tests/Makefile
 507    tests/interactive/Makefile
 508    tests/xml/Makefile
 509    tools/Makefile
 510 ])
 511
 512 echo "
 513 Configure summary:
 514
 515         Compiler....................:  ${CC}
 516         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 517         Prefix......................:  ${prefix}
 518         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 519         Use GTK+3...................:  ${enable_gtk3}
 520
 521     Features:
 522         Spell checking (enchant)....:  ${have_enchant}
 523         Display maps (libchamplain).:  ${have_libchamplain}
 524         Location awareness (Geoclue):  ${have_geoclue}
 525         Adium themes (Webkit).......:  ${have_webkit}
 526         Meego widgets ..............:  ${have_meego}
 527         Control center embedding....:  ${have_control_center_embedding}
 528
 529     Connectivity:
 530         NetworkManager integration..:  ${have_nm}
 531         ConnMan integration.........:  ${have_connman}
 532
 533     Extras:
 534         Nautilus-sendto plugin......:  ${have_nst}
 535 "