configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.13
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GNUTLS_REQUIRED=2.8.5
  38 GTK_REQUIRED=2.21.2
  39 KEYRING_REQUIRED=2.26.0
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBNOTIFY_REQUIRED=0.4.4
  42 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  43 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  44 TELEPATHY_GLIB_REQUIRED=0.11.13
  45 TELEPATHY_LOGGER=0.1.5
  46 UNIQUE_REQUIRED=1.1.2
  47
  48 # Optionnal deps
  49 CLUTTER_GTK_REQUIRED=0.10
  50 ENCHANT_REQUIRED=1.2.0
  51 GEOCLUE_REQUIRED=0.11
  52 ISO_CODES_REQUIRED=0.35
  53 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  54 LIBCHAMPLAIN_REQUIRED=0.7.1
  55 NAUTILUS_SENDTO_REQUIRED=2.28.1
  56 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  57 NETWORK_MANAGER_REQUIRED=0.7.0
  58 WEBKIT_REQUIRED=1.1.15
  59 GNOME_CONTROL_CENTER_GTK3_REQUIRED=2.31.4
  60
  61 # Use --enable-maintainer-mode to disable deprecated symbols,
  62 # disable single include and enable GSEAL. If this is not a released empathy,
  63 # maintainer mode is forced
  64 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  65 GNOME_MAINTAINER_MODE_DEFINES
  66
  67 AC_CONFIG_MACRO_DIR([m4])
  68 AC_CONFIG_HEADERS([config.h])
  69 AC_CONFIG_SRCDIR([configure.ac])
  70 AC_CONFIG_AUX_DIR(.)
  71
  72 GNOME_COMMON_INIT
  73
  74 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  75
  76 # Support silent build rules, requires at least automake-1.11. Disable
  77 # by either passing --disable-silent-rules to configure or passing V=1
  78 # to make
  79 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  80
  81 AC_ISC_POSIX
  82 AC_PROG_CC
  83 AC_HEADER_STDC
  84 AM_PROG_LIBTOOL
  85 AM_PROG_MKDIR_P
  86 AM_PATH_GLIB_2_0
  87 AC_PATH_XTRA
  88 IT_PROG_INTLTOOL([0.35.0])
  89 GNOME_DOC_INIT([0.17.3])
  90 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  91 GLIB_GSETTINGS
  92 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  93 AC_SUBST(GLIB_GENMARSHAL)
  94
  95 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  96 if test -z "$XSLTPROC"; then
  97   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  98 fi
  99 AM_PATH_PYTHON([2.3])
 100
 101 EMPATHY_ARG_VALGRIND
 102
 103
 104 # -----------------------------------------------------------
 105 # Error flags
 106 # -----------------------------------------------------------
 107 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 108 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 109
 110 AC_ARG_ENABLE(Werror,
 111   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 112     werror=$enableval, :)
 113
 114 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 115 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 116         wno_missing_field_initializers=yes,
 117         wno_missing_field_initializers=no)
 118 AS_COMPILER_FLAG(-Wno-unused-parameter,
 119         wno_unused_parameter=yes,
 120         wno_unused_parameter=no)
 121
 122 ifelse(empathy_released, 1, [],
 123     [
 124         if test x$werror = xyes; then
 125             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 126         fi
 127         if test x$wextra = xyes -a \
 128             x$wno_missing_field_initializers = xyes -a \
 129             x$wno_unused_parameter = xyes; then
 130             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 131         fi
 132     ])
 133
 134 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 135 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 136 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 137 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 138 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 139 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 140
 141 AC_SUBST(ERROR_CFLAGS)
 142
 143 # -----------------------------------------------------------
 144 # Pkg-Config dependency checks
 145 # -----------------------------------------------------------
 146
 147 PKG_CHECK_MODULES(EMPATHY,
 148 [
 149    dbus-glib-1
 150    farsight2-0.10
 151    folks >= $FOLKS_REQUIRED
 152    folks-telepathy >= $FOLKS_REQUIRED
 153    gconf-2.0 >= $GCONF_REQUIRED
 154    gcr-0 >= $KEYRING_REQUIRED
 155    gio-2.0 >= $GLIB_REQUIRED
 156    gio-unix-2.0 >= $GLIB_REQUIRED
 157    gnome-keyring-1 >= $KEYRING_REQUIRED
 158    gnutls >= $GNUTLS_REQUIRED
 159    gmodule-export-2.0
 160    gobject-2.0
 161    gstreamer-0.10
 162    gstreamer-interfaces-0.10
 163    libxml-2.0
 164    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 165    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 166    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 167    x11
 168 ])
 169
 170 # -----------------------------------------------------------
 171 # evolution-data-server (about-me)
 172 # -----------------------------------------------------------
 173 AC_ARG_WITH(eds,
 174             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 175             [with_eds=yes])
 176 if test x"$with_eds" = x"yes" ; then
 177    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 178    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 179 fi
 180
 181 # -----------------------------------------------------------
 182 # GTK+
 183 # -----------------------------------------------------------
 184 AC_ARG_ENABLE(gtk3,
 185               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 186                              [build with GTK+3]), ,
 187                              enable_gtk3=auto)
 188
 189 # Try to use GTK+3 if available
 190 if test "x$enable_gtk3" != "xno"; then
 191    PKG_CHECK_MODULES(GTK,
 192    [
 193       gtk+-3.0 >= $GTK_REQUIRED
 194    ], have_gtk3="yes", have_gtk3="no")
 195 else
 196    have_gtk3="no"
 197 fi
 198
 199 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 200    AC_MSG_ERROR([Could not find gtk3 dependencies.])
 201 fi
 202
 203 if test "x$have_gtk3" == "xyes"; then
 204    # GTK3 specific deps
 205    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 206    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 207    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 208 else
 209    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 210
 211    # GTK2 specific deps
 212    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 213    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 214    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 215
 216    # Enable GSEAL checks if needed
 217    if test $USE_MAINTAINER_MODE = yes; then
 218       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 219    fi
 220 fi
 221
 222 # -----------------------------------------------------------
 223 # Enable debug
 224 # -----------------------------------------------------------
 225
 226 AC_ARG_ENABLE(debug,
 227   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 228     enable_debug=$enableval, enable_debug=yes )
 229
 230 if test x$enable_debug = xyes; then
 231   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 232 fi
 233
 234 # -----------------------------------------------------------
 235 # Language Support
 236 # -----------------------------------------------------------
 237
 238 GETTEXT_PACKAGE=empathy
 239 AC_SUBST(GETTEXT_PACKAGE)
 240 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 241
 242 AM_GLIB_GNU_GETTEXT
 243
 244 # -----------------------------------------------------------
 245 # Connectivity integration
 246 # -----------------------------------------------------------
 247 AC_ARG_WITH(connectivity,
 248               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 249                              [build with connectivity support]), ,
 250                              with_connectivity=auto)
 251
 252 if test "x$with_connectivity" = "xno"; then
 253    have_nm=no
 254    have_connman=no
 255
 256 elif test "x$with_connectivity" = "xconnman"; then
 257    have_nm=no
 258
 259    PKG_CHECK_MODULES(CONNMAN,
 260    [
 261       dbus-glib-1
 262    ], have_connman="yes", have_connman="no")
 263
 264    if test "x$have_connman" = "xyes"; then
 265       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 266    fi
 267
 268 else
 269    have_connman=no
 270
 271    PKG_CHECK_MODULES(NETWORK_MANAGER,
 272    [
 273       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 274    ], have_nm="yes", have_nm="no")
 275
 276    if test "x$have_nm" = "xyes"; then
 277       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 278    fi
 279 fi
 280
 281 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 282    AC_MSG_ERROR([Couldn't find connman dependencies.])
 283 fi
 284
 285 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 286    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 287 fi
 288
 289 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 290 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 291
 292 # -----------------------------------------------------------
 293 # Webkit
 294 # -----------------------------------------------------------
 295 AC_ARG_ENABLE(webkit,
 296               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 297                              [build with webkit support]), ,
 298                              enable_webkit=auto)
 299
 300 if test "x$enable_webkit" != "xno"; then
 301
 302    if test "x$have_gtk3" == "xno"; then
 303       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 304           have_webkit="yes", have_webkit="no")
 305    else
 306       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 307           have_webkit="yes", have_webkit="no")
 308    fi
 309
 310    if test "x$have_webkit" = "xyes"; then
 311       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 312    fi
 313 else
 314    have_webkit=no
 315 fi
 316
 317 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 318    AC_MSG_ERROR([Could not find webkit dependencies.])
 319 fi
 320 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 321
 322 # -----------------------------------------------------------
 323 # spellchecking checks: enchant and iso-codes
 324 # -----------------------------------------------------------
 325 AC_ARG_ENABLE(spell,
 326               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 327                              [Enable spell checking]), ,
 328                              enable_spell=auto)
 329
 330 if test "x$enable_spell" != "xno"; then
 331    PKG_CHECK_MODULES(ENCHANT,
 332    [
 333       enchant >= $ENCHANT_REQUIRED,
 334       iso-codes >= $ISO_CODES_REQUIRED
 335    ], have_enchant="yes", have_enchant="no")
 336
 337    if test "x$have_enchant" = "xyes"; then
 338       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 339       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 340          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 341             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 342             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 343             result=yes
 344       else
 345             result=no
 346             have_enchant="no"
 347       fi
 348       AC_MSG_RESULT([$result])
 349    fi
 350 else
 351    have_enchant=no
 352 fi
 353
 354 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 355    AC_MSG_ERROR([Could not find spell dependencies.])
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 359
 360 # -----------------------------------------------------------
 361 # Map view checks: libchamplain
 362 # -----------------------------------------------------------
 363 AC_ARG_ENABLE(map,
 364               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 365                              [Enable map view]), ,
 366                              enable_map=auto)
 367
 368 if test "x$enable_map" != "xno"; then
 369
 370    if test "x$have_gtk3" == "xno"; then
 371       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 372       [
 373          champlain-0.8 >= $LIBCHAMPLAIN_REQUIRED,
 374          champlain-gtk-0.8 >= $LIBCHAMPLAIN_GTK_REQUIRED
 375          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 376       ], have_libchamplain="yes", have_libchamplain="no")
 377    else
 378       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 379       have_libchamplain="no"
 380    fi
 381
 382    if test "x$have_libchamplain" = "xyes"; then
 383       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 384    fi
 385 else
 386    have_libchamplain=no
 387 fi
 388
 389 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 390    AC_MSG_ERROR([Could not find map view dependencies.])
 391 fi
 392
 393 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 394
 395 # -----------------------------------------------------------
 396 # location checks: geoclue
 397 # -----------------------------------------------------------
 398 AC_ARG_ENABLE(location,
 399               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 400                              [Enable location awareness]), ,
 401                              enable_location=auto)
 402
 403 if test "x$enable_location" != "xno"; then
 404    PKG_CHECK_MODULES(GEOCLUE,
 405    [
 406       geoclue >= $GEOCLUE_REQUIRED
 407    ], have_geoclue="yes", have_geoclue="no")
 408
 409    if test "x$have_geoclue" = "xyes"; then
 410       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 411    fi
 412 else
 413    have_geoclue="no"
 414 fi
 415
 416 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 417    AC_MSG_ERROR([Could not find location dependencies.])
 418 fi
 419
 420 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 421 AC_SUBST(GEOCLUE_CFLAGS)
 422 AC_SUBST(GEOCLUE_LIBS)
 423
 424 # -----------------------------------------------------------
 425 # meego widgets support
 426 # -----------------------------------------------------------
 427 AC_ARG_ENABLE(meego,
 428               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 429                              [Enable meego widgets]), ,
 430                              enable_meego=no)
 431
 432 if test "x$enable_meego" != "xno"; then
 433     PKG_CHECK_MODULES(MEEGO,
 434     [
 435        mx-gtk-1.0
 436     ], have_meego="yes", have_meego="no")
 437
 438     if test "x$have_meego" = "xyes"; then
 439        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 440     fi
 441 else
 442    have_meego="no"
 443 fi
 444
 445 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 446    AC_MSG_ERROR([Could not find meego dependencies.])
 447 fi
 448
 449 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 450 AC_SUBST(MEEGO_CFLAGS)
 451 AC_SUBST(MEEGO_LIBS)
 452
 453 # -----------------------------------------------------------
 454 # nautilus-sendto
 455 # -----------------------------------------------------------
 456 AC_ARG_ENABLE(nautilus-sendto,
 457               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 458                              [build nautilus-sendto plugin]), ,
 459                              enable_nautilus_sendto=auto)
 460
 461 if test "x$enable_nautilus_sendto" != "xno"; then
 462    if test "x$have_gtk3" == "xno"; then
 463       # Newer NST requires GTK+3 so we can't use it
 464       PKG_CHECK_MODULES(NST,
 465       [
 466          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 467          nautilus-sendto < 2.90.0
 468       ], have_nst="yes", have_nst="no")
 469
 470       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 471    else
 472       PKG_CHECK_MODULES(NST,
 473       [
 474          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 475       ], have_nst="yes", have_nst="no")
 476    fi
 477 else
 478    have_nst=no
 479 fi
 480
 481 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 482    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 483 fi
 484
 485 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 486
 487 # -----------------------------------------------------------
 488 # new, single-window control center
 489 # -----------------------------------------------------------
 490 AC_ARG_ENABLE(control_center_embedding,
 491               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 492                              [Enable support for single-window control center]),
 493                              , enable_control_center_embedding=auto)
 494
 495 if test "x$enable_control_center_embedding" != "xno"; then
 496
 497    if test "x$have_gtk3" == "xno"; then
 498       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center < GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 499           have_control_center_embedding="yes", have_control_center_embedding="no")
 500    else
 501       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 502           have_control_center_embedding="yes", have_control_center_embedding="no")
 503    fi
 504
 505    if test "x$have_control_center_embedding" = "xyes"; then
 506       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 507
 508       AC_MSG_CHECKING([gnome-control-center extension dir])
 509       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 510       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 511           AC_MSG_ERROR([Could not determine extensiondir])
 512       else
 513           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 514       fi
 515       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 516    fi
 517 else
 518    have_control_center_embedding="no"
 519 fi
 520
 521 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 522    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 523 fi
 524
 525 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 526 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 527 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 528
 529 # -----------------------------------------------------------
 530 # Coding style checks
 531 # -----------------------------------------------------------
 532 AC_ARG_ENABLE(coding-style-checks,
 533   AC_HELP_STRING([--disable-coding-style-checks],
 534                  [do not check coding style using grep]),
 535     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 536
 537 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 538 # -----------------------------------------------------------
 539
 540 AC_OUTPUT([
 541    Makefile
 542    data/Makefile
 543    data/empathy.desktop.in
 544    data/empathy-accounts.desktop.in
 545    data/icons/Makefile
 546    extensions/Makefile
 547    po/Makefile.in
 548    libempathy/Makefile
 549    libempathy-gtk/Makefile
 550    src/Makefile
 551    nautilus-sendto-plugin/Makefile
 552    help/Makefile
 553    tests/Makefile
 554    tests/interactive/Makefile
 555    tests/xml/Makefile
 556    tools/Makefile
 557 ])
 558
 559 echo "
 560 Configure summary:
 561
 562         Compiler....................:  ${CC}
 563         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 564         Prefix......................:  ${prefix}
 565         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 566         Use GTK+3...................:  ${have_gtk3}
 567
 568     Features:
 569         Spell checking (enchant)....:  ${have_enchant}
 570         Display maps (libchamplain).:  ${have_libchamplain}
 571         Location awareness (Geoclue):  ${have_geoclue}
 572         Adium themes (Webkit).......:  ${have_webkit}
 573         Meego widgets ..............:  ${have_meego}
 574         Control center embedding....:  ${have_control_center_embedding}
 575
 576     Connectivity:
 577         NetworkManager integration..:  ${have_nm}
 578         ConnMan integration.........:  ${have_connman}
 579
 580     Extras:
 581         Nautilus-sendto plugin......:  ${have_nst}
 582         Salut E-D-S support.........:  ${with_eds}
 583 "