configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [7])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.7.3
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.19.9
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58 AC_DEFINE(TP_DISABLE_SINGLE_INCLUDE, 1, [Disable single include header])
  59
  60 GSTREAMER_REQUIRED=0.10.32
  61 TP_FS_REQUIRED=0.6.0
  62 LIBSECRET_REQUIRED=0.5
  63 GCR_REQUIRED=2.91.4
  64 LIBCANBERRA_GTK_REQUIRED=0.25
  65 LIBNOTIFY_REQUIRED=0.7.0
  66 TELEPATHY_LOGGER=0.6.0
  67 WEBKIT_REQUIRED=1.9.1
  68 GOA_REQUIRED=3.5.1
  69
  70 # Optional deps
  71 ENCHANT_REQUIRED=1.2.0
  72 GEOCLUE_REQUIRED=0.12
  73 GEOCODE_GLIB_REQUIRED=0.99.1
  74 ISO_CODES_REQUIRED=0.35
  75 NAUTILUS_SENDTO_REQUIRED=2.90.0
  76 NETWORK_MANAGER_REQUIRED=0.7.0
  77 CHAMPLAIN_REQUIRED=0.12.1
  78 CHEESE_GTK_REQUIRED=3.4.0
  79 LIBACCOUNTS_REQUIRED=1.4
  80 LIBSIGNON_REQUIRED=1.1
  81 MC_PLUGINS_REQUIRED=5.13.1
  82
  83 # Use --enable-maintainer-mode to disable deprecated symbols,
  84 # disable single include and enable GSEAL. If this is not a released empathy,
  85 # maintainer mode is forced
  86 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  87 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  88 #GNOME_MAINTAINER_MODE_DEFINES
  89
  90 # egg-list-box
  91 prev_top_build_prefix=$ac_top_build_prefix
  92 prev_ac_configure_args=$ac_configure_args
  93 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
  94 ac_top_build_prefix=$prev_top_build_prefix
  95 ac_configure_args=$prev_ac_configure_args
  96
  97 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
  98 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
  99
 100 AC_CONFIG_MACRO_DIR([m4])
 101 AC_CONFIG_HEADERS([config.h])
 102 AC_CONFIG_SRCDIR([configure.ac])
 103 AC_CONFIG_AUX_DIR(.)
 104
 105 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 106
 107 # Support silent build rules. Disable
 108 # by either passing --disable-silent-rules to configure or passing V=1
 109 # to make
 110 AM_SILENT_RULES([yes])
 111
 112 # Check for programs
 113 AC_PROG_CC
 114 AC_HEADER_STDC
 115 AM_PROG_MKDIR_P
 116 AM_PATH_GLIB_2_0
 117 AC_PATH_XTRA
 118
 119 # Initialize libtool
 120 LT_PREREQ([2.2])
 121 LT_INIT
 122
 123 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 124 GLIB_GSETTINGS
 125 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 126 AC_SUBST(GLIB_GENMARSHAL)
 127
 128 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 129 if test -z "$XSLTPROC"; then
 130   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 131 fi
 132 AM_PATH_PYTHON([2.3])
 133
 134 EMPATHY_ARG_VALGRIND
 135
 136
 137 # -----------------------------------------------------------
 138 # Error flags
 139 # -----------------------------------------------------------
 140 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 141 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 142
 143 AC_ARG_ENABLE(Werror,
 144   AS_HELP_STRING([--disable-Werror],
 145                  [compile without -Werror (normally enabled in development builds)]),
 146     werror=$enableval, :)
 147
 148 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 149 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 150         wno_missing_field_initializers=yes,
 151         wno_missing_field_initializers=no)
 152 AS_COMPILER_FLAG(-Wno-unused-parameter,
 153         wno_unused_parameter=yes,
 154         wno_unused_parameter=no)
 155
 156 ifelse(empathy_released, 1, [],
 157     [
 158         if test x$werror = xyes; then
 159             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 160         fi
 161         if test x$wextra = xyes -a \
 162             x$wno_missing_field_initializers = xyes -a \
 163             x$wno_unused_parameter = xyes; then
 164             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 165         fi
 166     ])
 167
 168 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 169 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 170 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 171 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 172 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 173
 174 AC_SUBST(ERROR_CFLAGS)
 175
 176 AC_ARG_ENABLE(gprof,
 177             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 178             [build with support for gprof]),,
 179             [enable_gprof=no])
 180 if test "x$enable_gprof" != "xno" ; then
 181     CFLAGS="$CFLAGS -pg"
 182     LDFLAGS="$LDFLAGS -pg"
 183 fi
 184
 185 AC_SUBST(LDFLAGS)
 186
 187 # -----------------------------------------------------------
 188 # Pkg-Config dependency checks
 189 # -----------------------------------------------------------
 190
 191 AC_CHECK_LIBM
 192 AC_SUBST(LIBM)
 193
 194 PKG_CHECK_MODULES(EMPATHY,
 195 [
 196    dbus-glib-1
 197    folks >= $FOLKS_REQUIRED
 198    folks-telepathy >= $FOLKS_REQUIRED
 199    glib-2.0 >= $GLIB_REQUIRED
 200    gio-2.0 >= $GLIB_REQUIRED
 201    gio-unix-2.0 >= $GLIB_REQUIRED
 202    libsecret-1 >= $LIBSECRET_REQUIRED
 203    gnutls >= $GNUTLS_REQUIRED
 204    gmodule-export-2.0
 205    gobject-2.0
 206    gsettings-desktop-schemas
 207    libxml-2.0
 208    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 209    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 210    x11
 211    gtk+-3.0 >= $GTK_REQUIRED
 212    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 213    libnotify >= $LIBNOTIFY_REQUIRED
 214    gcr-3 >= $GCR_REQUIRED
 215    libpulse
 216    libpulse-mainloop-glib
 217    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 218    libsoup-2.4
 219    gee-1.0
 220 ])
 221
 222 # -----------------------------------------------------------
 223 # GStreamer
 224 # -----------------------------------------------------------
 225 AC_ARG_ENABLE(gst-1.0,
 226               AS_HELP_STRING([--enable-gst-1.0=@<:@no/yes/auto@:>@],
 227                              [build with GStreamer 1.0]),
 228                              enable_gst1=$enableval,
 229                              enable_gst1=auto)
 230
 231 # Try to use GStreamer 1.0 if available
 232 have_gst1="no"
 233 if test "x$enable_gst1" != "xno"; then
 234   PKG_CHECK_MODULES(EMPATHY_CALL,
 235   [
 236      farstream-0.2
 237      telepathy-farstream >= $TP_FS_REQUIRED
 238      clutter-1.0 >= $CLUTTER_REQUIRED
 239      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 240      clutter-gst-2.0
 241      gstreamer-1.0
 242      gstreamer-audio-1.0
 243      gstreamer-video-1.0
 244   ], have_gst1="yes", have_gst1="no")
 245
 246   if test "x$have_gst1" = "xyes"; then
 247     AC_DEFINE(HAVE_GST1, 1, [Build with GStreamer 1.0])
 248   fi
 249 fi
 250
 251 if test "x$enable_gst1" = "xyes" -a "x$have_gst1" != "xyes"; then
 252    AC_MSG_ERROR([Could not find GStreamer 1.0 dependencies:
 253
 254 $EMPATHY_CALL_PKG_ERRORS])
 255 fi
 256
 257 if test "x$have_gst1" != "xyes"; then
 258   PKG_CHECK_MODULES(EMPATHY_CALL,
 259   [
 260      farstream-0.1
 261      telepathy-farstream >= $TP_FS_REQUIRED
 262      clutter-1.0 >= $CLUTTER_REQUIRED
 263      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 264      clutter-gst-1.0 >= 1.5.2
 265      gstreamer-0.10 >= $GSTREAMER_REQUIRED
 266      gstreamer-interfaces-0.10
 267   ])
 268 fi
 269
 270 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 271    [Name of provider for accounts imported from GOA])
 272
 273 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 274     "im.telepathy.Account.Storage.UOA",
 275    [Name of provider for accounts imported from libaccounts])
 276
 277 # -----------------------------------------------------------
 278 # Enable debug
 279 # -----------------------------------------------------------
 280
 281 AC_ARG_ENABLE(debug,
 282   AS_HELP_STRING([--disable-debug],
 283                  [compile without debug code]),
 284     enable_debug=$enableval, enable_debug=yes )
 285
 286 if test x$enable_debug = xyes; then
 287   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 288 fi
 289
 290 # -----------------------------------------------------------
 291 # Language Support
 292 # -----------------------------------------------------------
 293 IT_PROG_INTLTOOL([0.50.0])
 294
 295 GETTEXT_PACKAGE=empathy
 296 AC_SUBST(GETTEXT_PACKAGE)
 297 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 298
 299 # -----------------------------------------------------------
 300 # gudev
 301 # -----------------------------------------------------------
 302 AC_ARG_ENABLE(gudev,
 303               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 304                              [build with gudev support]), ,
 305                              enable_gudev=auto)
 306
 307 if test "x$enable_gudev" != "xno"; then
 308
 309    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 310         have_gudev="yes", have_gudev="no")
 311
 312    if test "x$have_gudev" = "xyes"; then
 313       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 314    fi
 315 else
 316    have_gudev=no
 317 fi
 318
 319 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 320    AC_MSG_ERROR([Could not find gudev dependencies:
 321
 322 $UDEV_PKG_ERRORS])
 323 fi
 324 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 325
 326 # -----------------------------------------------------------
 327 # spellchecking checks: enchant and iso-codes
 328 # -----------------------------------------------------------
 329 AC_ARG_ENABLE(spell,
 330               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 331                              [Enable spell checking]), ,
 332                              enable_spell=auto)
 333
 334 if test "x$enable_spell" != "xno"; then
 335    PKG_CHECK_MODULES(ENCHANT,
 336    [
 337       enchant >= $ENCHANT_REQUIRED,
 338       iso-codes >= $ISO_CODES_REQUIRED
 339    ], have_enchant="yes", have_enchant="no")
 340
 341    if test "x$have_enchant" = "xyes"; then
 342       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 343       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 344          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 345             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 346             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 347             result=yes
 348       else
 349             result=no
 350             have_enchant="no"
 351       fi
 352       AC_MSG_RESULT([$result])
 353    fi
 354 else
 355    have_enchant=no
 356 fi
 357
 358 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 359    AC_MSG_ERROR([Could not find spell-checking dependencies:
 360
 361 $ENCHANT_PKG_ERRORS])
 362 fi
 363
 364 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 365
 366 # -----------------------------------------------------------
 367 # Map view checks: libchamplain
 368 # -----------------------------------------------------------
 369 AC_ARG_ENABLE(map,
 370               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 371                              [Enable map view]), ,
 372                              enable_map=auto)
 373
 374 if test "x$enable_map" != "xno"; then
 375
 376    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 377     [
 378        clutter-gtk-1.0
 379        champlain-gtk-0.12
 380        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 381     ], have_libchamplain="yes", have_libchamplain="no")
 382
 383    if test "x$have_libchamplain" = "xyes"; then
 384       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 385    fi
 386 else
 387    have_libchamplain=no
 388 fi
 389
 390 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 391    AC_MSG_ERROR([Could not find map view dependencies:
 392
 393 $LIBCHAMPLAIN_PKG_ERRORS])
 394 fi
 395
 396 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 397
 398 # -----------------------------------------------------------
 399 # location checks: geoclue
 400 # -----------------------------------------------------------
 401 AC_ARG_ENABLE(location,
 402               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 403                              [Enable location awareness]), ,
 404                              enable_location=auto)
 405
 406 if test "x$enable_location" != "xno"; then
 407    PKG_CHECK_MODULES(GEOCLUE,
 408    [
 409       geoclue >= $GEOCLUE_REQUIRED
 410    ], have_geoclue="yes", have_geoclue="no")
 411
 412    if test "x$have_geoclue" = "xyes"; then
 413       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 414    fi
 415 else
 416    have_geoclue="no"
 417 fi
 418
 419 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 420    AC_MSG_ERROR([Could not find location dependencies:
 421
 422 $GEOCLUE_PKG_ERRORS])
 423 fi
 424
 425 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 426 AC_SUBST(GEOCLUE_CFLAGS)
 427 AC_SUBST(GEOCLUE_LIBS)
 428
 429 # -----------------------------------------------------------
 430 # location checks: geocode-glib
 431 # -----------------------------------------------------------
 432 AC_ARG_ENABLE(geocode,
 433               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 434                              [Enable geocode support]), ,
 435                              enable_geocode=auto)
 436
 437 if test "x$enable_geocode" != "xno"; then
 438    PKG_CHECK_MODULES(GEOCODE,
 439    [
 440       geocode-glib >= $GEOCODE_GLIB_REQUIRED
 441    ], have_geocode="yes", have_geocode="no")
 442
 443    if test "x$have_geocode" = "xyes"; then
 444       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 445    fi
 446 else
 447    have_geocode="no"
 448 fi
 449
 450 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 451    AC_MSG_ERROR([Could not find geocode dependencies:
 452
 453 $GEOCODE_PKG_ERRORS])
 454 fi
 455
 456 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 457 AC_SUBST(GEOCODE_CFLAGS)
 458 AC_SUBST(GEOCODE_LIBS)
 459
 460 # -----------------------------------------------------------
 461 # nautilus-sendto
 462 # -----------------------------------------------------------
 463 AC_ARG_ENABLE(nautilus-sendto,
 464               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 465                              [build nautilus-sendto plugin]), ,
 466                              enable_nautilus_sendto=auto)
 467
 468 if test "x$enable_nautilus_sendto" != "xno"; then
 469    PKG_CHECK_MODULES(NST,
 470     [
 471        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 472     ], have_nst="yes", have_nst="no")
 473 else
 474    have_nst=no
 475 fi
 476
 477 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 478    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 479
 480 $NST_PKG_ERRORS])
 481 fi
 482
 483 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 484
 485 # -----------------------------------------------------------
 486 # goa-mc-plugin
 487 # -----------------------------------------------------------
 488 AC_ARG_ENABLE(goa,
 489               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 490                              [build GOA MC plugin]), ,
 491                              enable_goa=auto)
 492
 493 if test "x$enable_goa" != "xno"; then
 494    PKG_CHECK_MODULES(GOA,
 495     [
 496        mission-control-plugins
 497        goa-1.0 >= $GOA_REQUIRED
 498     ], have_goa="yes", have_goa="no")
 499 else
 500    have_goa=no
 501 fi
 502
 503 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 504    AC_MSG_ERROR([Could not find GOA dependencies:
 505
 506 $GOA_PKG_ERRORS])
 507 fi
 508
 509 if test "x$have_goa" = "xyes"; then
 510    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 511 fi
 512
 513 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 514
 515 # Optional dependency for avatar selection
 516 AC_ARG_WITH([cheese],
 517             AS_HELP_STRING([--with-cheese],
 518                            [enable cheese webcam support]),,
 519             with_cheese=auto)
 520
 521 if test x"$with_cheese" != x"no" ; then
 522    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 523    if test x${have_cheese} = xyes; then
 524      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 525    fi
 526    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 527      AC_MSG_ERROR([Cheese configured but not found:
 528
 529 $CHEESE_PKG_ERRORS])
 530    fi
 531 else
 532    have_cheese=no
 533 fi
 534 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 535
 536 # -----------------------------------------------------------
 537 # ubuntu-online-accounts support
 538 # -----------------------------------------------------------
 539 AC_ARG_ENABLE(ubuntu-online-accounts,
 540               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 541                              [build Ubuntu Online Accounts plugins]), ,
 542                              enable_ubuntu_online_accounts=auto)
 543
 544 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 545    PKG_CHECK_MODULES(UOA,
 546     [
 547        account-plugin
 548        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 549        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 550        libsignon-glib >= $LIBSIGNON_REQUIRED
 551     ], have_uoa="yes", have_uoa="no")
 552
 553    # provider plugin dir
 554    AC_MSG_CHECKING([Accounts provider plugin dir])
 555    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 556
 557    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 558    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 559
 560    # app plugin dir
 561    AC_MSG_CHECKING([Accounts provider app plugin dir])
 562    ACCOUNTS_APP_PLUGIN_DIR=`pkg-config --variable=application_plugindir account-plugin`
 563
 564    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 565    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 566
 567    # provider files dir
 568    AC_MSG_CHECKING([Accounts provider files dir])
 569    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 570
 571    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 572    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 573
 574    # service files dir
 575    AC_MSG_CHECKING([Accounts service files dir])
 576    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 577
 578    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 579    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 580
 581    # application files dir
 582    AC_MSG_CHECKING([Accounts applications files dir])
 583    ACCOUNTS_APPLICATION_FILES_DIR=`pkg-config --variable=applicationfilesdir libaccounts-glib`
 584
 585    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 586    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 587
 588 else
 589    have_uoa=no
 590 fi
 591
 592 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 593    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 594
 595 $UOA_PKG_ERRORS])
 596 fi
 597
 598 if test "x$have_uoa" = "xyes"; then
 599    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 600 fi
 601
 602 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 603
 604 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 605    AC_MSG_CHECKING([Mission Control plugins dir])
 606    MISSION_CONTROL_PLUGINS_DIR=${libdir}/mission-control-plugins.`pkg-config --variable=MCP_ABI_VERSION mission-control-plugins`
 607
 608    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 609    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 610 fi
 611
 612
 613 # Help documentation
 614 YELP_HELP_INIT
 615
 616 # -----------------------------------------------------------
 617 # Coding style checks
 618 # -----------------------------------------------------------
 619 AC_ARG_ENABLE(coding-style-checks,
 620   AS_HELP_STRING([--disable-coding-style-checks],
 621                  [do not check coding style using grep]),
 622     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 623     [ENABLE_CODING_STYLE_CHECKS=yes])
 624
 625 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 626 # -----------------------------------------------------------
 627
 628 AC_CONFIG_FILES([
 629    Makefile
 630    data/Makefile
 631    data/empathy.desktop.in
 632    data/icons/Makefile
 633    data/themes/Makefile
 634    extensions/Makefile
 635    po/Makefile.in
 636    libempathy/Makefile
 637    libempathy-gtk/Makefile
 638    src/Makefile
 639    nautilus-sendto-plugin/Makefile
 640    goa-mc-plugin/Makefile
 641    ubuntu-online-accounts/Makefile
 642    ubuntu-online-accounts/mc-plugin/Makefile
 643    ubuntu-online-accounts/cc-plugins/Makefile
 644    ubuntu-online-accounts/cc-plugins/account-plugins/Makefile
 645    ubuntu-online-accounts/cc-plugins/providers/Makefile
 646    ubuntu-online-accounts/cc-plugins/services/Makefile
 647    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 648    help/Makefile
 649    tests/Makefile
 650    tests/interactive/Makefile
 651    tests/xml/Makefile
 652    tests/certificates/Makefile
 653    tools/Makefile
 654 ])
 655 AC_OUTPUT
 656
 657 echo "
 658 Configure summary:
 659
 660         Compiler....................:  ${CC}
 661         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 662         Linker Flags................:  ${LDFLAGS}
 663         Prefix......................:  ${prefix}
 664         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 665         Use GStreamer 1.0...........:  ${have_gst1}
 666
 667     Features:
 668         Spell checking (enchant)....:  ${have_enchant}
 669         Display maps (libchamplain).:  ${have_libchamplain}
 670         Location awareness (Geoclue):  ${have_geoclue}
 671         Geocode support (Geocode)...:  ${have_geocode}
 672         Cheese webcam support ......:  ${have_cheese}
 673         Camera monitoring...........:  ${have_gudev}
 674
 675     Extras:
 676         Nautilus-sendto plugin......:  ${have_nst}
 677         GOA MC plugin...............:  ${have_goa}
 678         Ubuntu Online plugins.......:  ${have_uoa}
 679 "