configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [3])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.25.9
  33 GTK_REQUIRED=2.21.2
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.11.7
  36 TELEPATHY_LOGGER=0.1.2
  37 ENCHANT_REQUIRED=1.2.0
  38 ISO_CODES_REQUIRED=0.35
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBCHAMPLAIN_REQUIRED=0.4
  42 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  43 CLUTTER_GTK_REQUIRED=0.10
  44 GEOCLUE_REQUIRED=0.11
  45 WEBKIT_REQUIRED=1.1.15
  46 KEYRING_REQUIRED=2.22
  47 NETWORK_MANAGER_REQUIRED=0.7.0
  48 NAUTILUS_SENDTO_REQUIRED=2.28.1
  49 UNIQUE_REQUIRED=1.1.2
  50
  51 # Use --enable-maintainer-mode to disable deprecated symbols,
  52 # disable single include and enable GSEAL. If this is not a released empathy,
  53 # maintainer mode is forced
  54 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  55 GNOME_MAINTAINER_MODE_DEFINES
  56 if test $USE_MAINTAINER_MODE = yes; then
  57   AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
  58 fi
  59
  60 AC_CONFIG_MACRO_DIR([m4])
  61 AC_CONFIG_HEADERS([config.h])
  62 AC_CONFIG_SRCDIR([configure.ac])
  63 AC_CONFIG_AUX_DIR(.)
  64
  65 GNOME_COMMON_INIT
  66
  67 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  68
  69 # Support silent build rules, requires at least automake-1.11. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  73
  74 AC_ISC_POSIX
  75 AC_PROG_CC
  76 AC_HEADER_STDC
  77 AM_PROG_LIBTOOL
  78 AM_PROG_MKDIR_P
  79 AM_PATH_GLIB_2_0
  80 AC_PATH_XTRA
  81 IT_PROG_INTLTOOL([0.35.0])
  82 GNOME_DOC_INIT([0.17.3])
  83 IDT_COMPILE_WARNINGS
  84 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  85 GLIB_GSETTINGS
  86 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  87 AC_SUBST(GLIB_GENMARSHAL)
  88 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  89 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  90
  91 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  92 if test -z "$XSLTPROC"; then
  93   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  94 fi
  95 AM_PATH_PYTHON([2.3])
  96
  97 EMPATHY_ARG_VALGRIND
  98
  99
 100 # -----------------------------------------------------------
 101 # Error flags
 102 # -----------------------------------------------------------
 103 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 104 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 105
 106 AC_ARG_ENABLE(Werror,
 107   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 108     werror=$enableval, :)
 109
 110 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 111 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 112         wno_missing_field_initializers=yes,
 113         wno_missing_field_initializers=no)
 114 AS_COMPILER_FLAG(-Wno-unused-parameter,
 115         wno_unused_parameter=yes,
 116         wno_unused_parameter=no)
 117
 118 ifelse(empathy_released, 1, [],
 119     [
 120         if test x$werror = xyes; then
 121             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 122         fi
 123         if test x$wextra = xyes -a \
 124             x$wno_missing_field_initializers = xyes -a \
 125             x$wno_unused_parameter = xyes; then
 126             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 127         fi
 128     ])
 129
 130 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 131 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 132 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 133 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 134 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 135 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 136
 137 AC_SUBST(ERROR_CFLAGS)
 138
 139 # -----------------------------------------------------------
 140 # Pkg-Config dependency checks
 141 # -----------------------------------------------------------
 142
 143 PKG_CHECK_MODULES(LIBEMPATHY,
 144 [
 145    glib-2.0 >= $GLIB_REQUIRED
 146    gobject-2.0
 147    gio-2.0 >= $GLIB_REQUIRED
 148    gio-unix-2.0 >= $GLIB_REQUIRED
 149    libxml-2.0
 150    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 151    telepathy-farsight
 152    farsight2-0.10
 153    gstreamer-0.10
 154    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 155 ])
 156
 157 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 158 [
 159    glib-2.0 >= $GLIB_REQUIRED
 160    gobject-2.0
 161    gio-2.0 >= $GLIB_REQUIRED
 162    gconf-2.0 >= $GCONF_REQUIRED
 163    x11
 164    gtk+-2.0 >= $GTK_REQUIRED
 165    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 166    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 167    farsight2-0.10
 168    gstreamer-0.10
 169    gstreamer-interfaces-0.10
 170    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 171 ])
 172
 173 PKG_CHECK_MODULES(EMPATHY,
 174 [
 175    glib-2.0 >= $GLIB_REQUIRED
 176    gobject-2.0
 177    gio-2.0 >= $GLIB_REQUIRED
 178    gdk-x11-2.0
 179    gtk+-2.0 >= $GTK_REQUIRED
 180    libebook-1.2
 181    dbus-glib-1
 182    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 183    telepathy-farsight
 184    farsight2-0.10
 185    gstreamer-0.10
 186    unique-1.0 >= $UNIQUE_REQUIRED
 187    gnome-keyring-1 >= $KEYRING_REQUIRED
 188    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 189 ])
 190
 191 PKG_CHECK_MODULES(LIBEMPATHY_ACCOUNTS_PANEL,
 192 [
 193    glib-2.0 >= $GLIB_REQUIRED
 194    gobject-2.0
 195    gio-2.0 >= $GLIB_REQUIRED
 196    gdk-x11-2.0
 197    gtk+-2.0 >= $GTK_REQUIRED
 198    libebook-1.2
 199    dbus-glib-1
 200    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 201    unique-1.0 >= $UNIQUE_REQUIRED
 202    gnome-keyring-1 >= $KEYRING_REQUIRED
 203    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 204 ])
 205
 206 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 207
 208 # -----------------------------------------------------------
 209 # Enable debug
 210 # -----------------------------------------------------------
 211
 212 AC_ARG_ENABLE(debug,
 213   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 214     enable_debug=$enableval, enable_debug=yes )
 215
 216 if test x$enable_debug = xyes; then
 217   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 218 fi
 219
 220 # -----------------------------------------------------------
 221 # Language Support
 222 # -----------------------------------------------------------
 223
 224 GETTEXT_PACKAGE=empathy
 225 AC_SUBST(GETTEXT_PACKAGE)
 226 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 227
 228 AM_GLIB_GNU_GETTEXT
 229
 230 # -----------------------------------------------------------
 231 # Connectivity integration
 232 # -----------------------------------------------------------
 233 AC_ARG_WITH(connectivity,
 234               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 235                              [build with connectivity support]), ,
 236                              with_connectivity=auto)
 237
 238 if test "x$with_connectivity" = "xno"; then
 239    have_nm=no
 240    have_connman=no
 241
 242 elif test "x$with_connectivity" = "xconnman"; then
 243
 244    PKG_CHECK_MODULES(CONNMAN,
 245    [
 246       dbus-glib-1
 247    ], have_connman="yes", have_connman="no")
 248
 249    if test "x$have_connman" = "xyes"; then
 250       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 251       have_nm=no
 252    fi
 253
 254 else
 255
 256    PKG_CHECK_MODULES(NETWORK_MANAGER,
 257    [
 258       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 259    ], have_nm="yes", have_nm="no")
 260
 261    if test "x$have_nm" = "xyes"; then
 262       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 263       have_connman=no
 264    else
 265       PKG_CHECK_MODULES(NETWORK_MANAGER,
 266       [
 267           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 268       ], have_nm="yes", have_nm="no")
 269
 270       if test "x$have_nm" = "xyes"; then
 271       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 272       have_connman=no
 273       fi
 274    fi
 275 fi
 276
 277 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 278    AC_MSG_ERROR([Couldn't find connman dependencies.])
 279 fi
 280
 281 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 282    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 283 fi
 284
 285 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 286 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 287
 288 # -----------------------------------------------------------
 289 # Webkit
 290 # -----------------------------------------------------------
 291 AC_ARG_ENABLE(webkit,
 292               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 293                              [build with webkit support]), ,
 294                              enable_webkit=auto)
 295
 296 if test "x$enable_webkit" != "xno"; then
 297    PKG_CHECK_MODULES(WEBKIT,
 298    [
 299       webkit-1.0 >= $WEBKIT_REQUIRED
 300    ], have_webkit="yes", have_webkit="no")
 301
 302    if test "x$have_webkit" = "xyes"; then
 303       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 304    fi
 305 else
 306    have_webkit=no
 307 fi
 308
 309 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 310    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 311 fi
 312 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 313
 314 # -----------------------------------------------------------
 315 # spellchecking checks: enchant and iso-codes
 316 # -----------------------------------------------------------
 317 AC_ARG_ENABLE(spell,
 318               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 319                              [Enable spell checking]), ,
 320                              enable_spell=auto)
 321
 322 if test "x$enable_spell" != "xno"; then
 323    PKG_CHECK_MODULES(ENCHANT,
 324    [
 325       enchant >= $ENCHANT_REQUIRED,
 326       iso-codes >= $ISO_CODES_REQUIRED
 327    ], have_enchant="yes", have_enchant="no")
 328
 329    if test "x$have_enchant" = "xyes"; then
 330       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 331       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 332          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 333             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 334             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 335             result=yes
 336       else
 337             result=no
 338             have_enchant="no"
 339       fi
 340       AC_MSG_RESULT([$result])
 341    fi
 342 else
 343    have_enchant=no
 344 fi
 345
 346 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 347    AC_MSG_ERROR([Couldn't find spell dependencies.])
 348 fi
 349
 350 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 351
 352 # -----------------------------------------------------------
 353 # Map view checks: libchamplain
 354 # -----------------------------------------------------------
 355 AC_ARG_ENABLE(map,
 356               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 357                              [Enable map view]), ,
 358                              enable_map=auto)
 359
 360 if test "x$enable_map" != "xno"; then
 361    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 362    [
 363       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 364       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 365       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 366    ], have_libchamplain="yes", have_libchamplain="no")
 367
 368    if test "x$have_libchamplain" = "xyes"; then
 369       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 370    fi
 371 else
 372    have_libchamplain=no
 373 fi
 374
 375 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 376    AC_MSG_ERROR([Couldn't find map view dependencies.])
 377 fi
 378
 379 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 380
 381 # -----------------------------------------------------------
 382 # location checks: geoclue
 383 # -----------------------------------------------------------
 384 AC_ARG_ENABLE(location,
 385               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 386                              [Enable location awareness]), ,
 387                              enable_location=auto)
 388
 389 if test "x$enable_location" != "xno"; then
 390    PKG_CHECK_MODULES(GEOCLUE,
 391    [
 392       geoclue >= $GEOCLUE_REQUIRED
 393    ], have_geoclue="yes", have_geoclue="no")
 394
 395    if test "x$have_geoclue" = "xyes"; then
 396       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 397    fi
 398 else
 399    have_geoclue="no"
 400 fi
 401
 402 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 403    AC_MSG_ERROR([Couldn't find location dependencies.])
 404 fi
 405
 406 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 407 AC_SUBST(GEOCLUE_CFLAGS)
 408 AC_SUBST(GEOCLUE_LIBS)
 409
 410 # -----------------------------------------------------------
 411 # meego widgets support
 412 # -----------------------------------------------------------
 413 AC_ARG_ENABLE(meego,
 414               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 415                              [Enable meego widgets]), ,
 416                              enable_meego=no)
 417
 418 if test "x$enable_meego" != "xno"; then
 419     PKG_CHECK_MODULES(MEEGO,
 420     [
 421        mx-gtk-1.0
 422     ], have_meego="yes", have_meego="no")
 423
 424     if test "x$have_meego" = "xyes"; then
 425        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 426        chain_enable_favourite_contacts="yes"
 427     fi
 428 else
 429    have_meego="no"
 430 fi
 431
 432 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 433    AC_MSG_ERROR([Couldn't find meego dependencies.])
 434 fi
 435
 436 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 437 AC_SUBST(MEEGO_CFLAGS)
 438 AC_SUBST(MEEGO_LIBS)
 439
 440 # -----------------------------------------------------------
 441 # favourite contacts support
 442 # -----------------------------------------------------------
 443 AC_ARG_ENABLE(favourite_contacts,
 444               AS_HELP_STRING([--enable-favourite-contacts=@<:no/yes@:>@],
 445                              [Enable favourite contacts]), ,
 446                              enable_favourite_contacts=no)
 447
 448 if test "x$enable_favourite_contacts" != "xno" || test "x$chain_enable_favourite_contacts" = "xyes"; then
 449     PKG_CHECK_MODULES(TELEPATHY_LOGGER,
 450     [
 451        telepathy-logger
 452     ], have_telepathy_logger="yes", have_telepathy_logger="no")
 453
 454     if test "x$have_telepathy_logger" = "xyes"; then
 455        have_favourite_contacts="yes"
 456        AC_DEFINE(HAVE_FAVOURITE_CONTACTS, 1, [Define if you want favourite contacts support])
 457     fi
 458 else
 459    have_favourite_contacts="no"
 460 fi
 461
 462 if test "x$enable_favourite_contacts" = "xyes" && test "x$have_favourite_contacts" != "xyes"; then
 463    AC_MSG_ERROR([Couldn't find favourite contacts dependencies.])
 464 fi
 465
 466 AM_CONDITIONAL(HAVE_FAVOURITE_CONTACTS, test "x$have_telepathy_logger" = "xyes")
 467
 468 # -----------------------------------------------------------
 469 # nautilus-sendto
 470 # -----------------------------------------------------------
 471 AC_ARG_ENABLE(nautilus-sendto,
 472               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 473                              [build nautilus-sendto plugin]), ,
 474                              enable_nautilus_sendto=auto)
 475
 476 if test "x$enable_nautilus_sendto" != "xno"; then
 477    PKG_CHECK_MODULES(NST,
 478    [
 479       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 480    ], have_nst="yes", have_nst="no")
 481 else
 482    have_nst=no
 483 fi
 484
 485 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 486    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 487 fi
 488
 489 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 490
 491 # -----------------------------------------------------------
 492 # new, single-window control center
 493 # -----------------------------------------------------------
 494 AC_ARG_ENABLE(control_center_embedding,
 495               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 496                              [Enable support for single-window control center]),
 497                              , enable_control_center_embedding=auto)
 498
 499 if test "x$enable_control_center_embedding" != "xno"; then
 500    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 501    [
 502       libgnome-control-center-extension
 503    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 504
 505    if test "x$have_control_center_embedding" = "xyes"; then
 506       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 507    fi
 508 else
 509    have_control_center_embedding="no"
 510 fi
 511
 512 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 513    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 514 fi
 515
 516 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 517 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 518 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 519
 520 # -----------------------------------------------------------
 521 # Coding style checks
 522 # -----------------------------------------------------------
 523 AC_ARG_ENABLE(coding-style-checks,
 524   AC_HELP_STRING([--disable-coding-style-checks],
 525                  [don't check coding style using grep]),
 526     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 527
 528 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 529 # -----------------------------------------------------------
 530
 531 AC_OUTPUT([
 532    Makefile
 533    data/Makefile
 534    data/empathy.desktop.in
 535    data/empathy-accounts.desktop.in
 536    data/icons/Makefile
 537    extensions/Makefile
 538    po/Makefile.in
 539    libempathy/Makefile
 540    libempathy-gtk/Makefile
 541    src/Makefile
 542    nautilus-sendto-plugin/Makefile
 543    help/Makefile
 544    tests/Makefile
 545    tests/interactive/Makefile
 546    tests/xml/Makefile
 547    tools/Makefile
 548 ])
 549
 550 echo "
 551 Configure summary:
 552
 553         Compiler....................:  ${CC}
 554         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 555         Prefix......................:  ${prefix}
 556         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 557
 558     Features:
 559         Spell checking (enchant)....:  ${have_enchant}
 560         Display maps (libchamplain).:  ${have_libchamplain}
 561         Location awareness (Geoclue):  ${have_geoclue}
 562         Adium themes (Webkit).......:  ${have_webkit}
 563         Meego widgets ..............:  ${have_meego}
 564         Favourite contacts .........:  ${have_favourite_contacts}
 565         Control center embedding....:  ${have_control_center_embedding}
 566
 567     Connectivity:
 568         NetworkManager integration..:  ${have_nm}
 569         ConnMan integration.........:  ${have_connman}
 570
 571     Extras:
 572         Nautilus-sendto plugin......:  ${have_nst}
 573 "