configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  42 TELEPATHY_GLIB_REQUIRED=0.11.7
  43 TELEPATHY_LOGGER=0.1.2
  44 UNIQUE_REQUIRED=1.1.2
  45
  46 # Optionnal deps
  47 CLUTTER_GTK_REQUIRED=0.10
  48 ENCHANT_REQUIRED=1.2.0
  49 GEOCLUE_REQUIRED=0.11
  50 ISO_CODES_REQUIRED=0.35
  51 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  52 LIBCHAMPLAIN_REQUIRED=0.4
  53 NAUTILUS_SENDTO_REQUIRED=2.28.1
  54 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  55 NETWORK_MANAGER_REQUIRED=0.7.0
  56 WEBKIT_REQUIRED=1.1.15
  57
  58 # Use --enable-maintainer-mode to disable deprecated symbols,
  59 # disable single include and enable GSEAL. If this is not a released empathy,
  60 # maintainer mode is forced
  61 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  62 GNOME_MAINTAINER_MODE_DEFINES
  63
  64 AC_CONFIG_MACRO_DIR([m4])
  65 AC_CONFIG_HEADERS([config.h])
  66 AC_CONFIG_SRCDIR([configure.ac])
  67 AC_CONFIG_AUX_DIR(.)
  68
  69 GNOME_COMMON_INIT
  70
  71 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  72
  73 # Support silent build rules, requires at least automake-1.11. Disable
  74 # by either passing --disable-silent-rules to configure or passing V=1
  75 # to make
  76 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  77
  78 AC_ISC_POSIX
  79 AC_PROG_CC
  80 AC_HEADER_STDC
  81 AM_PROG_LIBTOOL
  82 AM_PROG_MKDIR_P
  83 AM_PATH_GLIB_2_0
  84 AC_PATH_XTRA
  85 IT_PROG_INTLTOOL([0.35.0])
  86 GNOME_DOC_INIT([0.17.3])
  87 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  88 GLIB_GSETTINGS
  89 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  90 AC_SUBST(GLIB_GENMARSHAL)
  91 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  92 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  93
  94 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  95 if test -z "$XSLTPROC"; then
  96   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  97 fi
  98 AM_PATH_PYTHON([2.3])
  99
 100 EMPATHY_ARG_VALGRIND
 101
 102
 103 # -----------------------------------------------------------
 104 # Error flags
 105 # -----------------------------------------------------------
 106 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 107 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 108
 109 AC_ARG_ENABLE(Werror,
 110   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 111     werror=$enableval, :)
 112
 113 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 114 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 115         wno_missing_field_initializers=yes,
 116         wno_missing_field_initializers=no)
 117 AS_COMPILER_FLAG(-Wno-unused-parameter,
 118         wno_unused_parameter=yes,
 119         wno_unused_parameter=no)
 120
 121 ifelse(empathy_released, 1, [],
 122     [
 123         if test x$werror = xyes; then
 124             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 125         fi
 126         if test x$wextra = xyes -a \
 127             x$wno_missing_field_initializers = xyes -a \
 128             x$wno_unused_parameter = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 130         fi
 131     ])
 132
 133 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 134 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 135 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 136 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 137 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 138 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 139
 140 AC_SUBST(ERROR_CFLAGS)
 141
 142 # -----------------------------------------------------------
 143 # Pkg-Config dependency checks
 144 # -----------------------------------------------------------
 145
 146 PKG_CHECK_MODULES(EMPATHY,
 147 [
 148    dbus-glib-1
 149    farsight2-0.10
 150    gconf-2.0 >= $GCONF_REQUIRED
 151    gio-2.0 >= $GLIB_REQUIRED
 152    gio-unix-2.0 >= $GLIB_REQUIRED
 153    gnome-keyring-1 >= $KEYRING_REQUIRED
 154    gobject-2.0
 155    gstreamer-0.10
 156    gstreamer-interfaces-0.10
 157    libebook-1.2
 158    libxml-2.0
 159    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 160    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 161    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 162    x11
 163 ])
 164
 165 # -----------------------------------------------------------
 166 # GTK+
 167 # -----------------------------------------------------------
 168 AC_ARG_ENABLE(gtk3,
 169               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 170                              [build with GTK+3]), ,
 171                              enable_gtk3=auto)
 172
 173 # Try to use GTK+3 if available
 174 if test "x$enable_gtk3" != "xno"; then
 175    PKG_CHECK_MODULES(GTK,
 176    [
 177       gtk+-3.0 >= $GTK_REQUIRED
 178    ], have_gtk3="yes", have_gtk3="no")
 179 else
 180    have_gtk3="no"
 181 fi
 182
 183 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 184    AC_MSG_ERROR([Couldn't find gtk3 dependencies.])
 185 fi
 186
 187 if test "x$have_gtk3" == "xyes"; then
 188    # GTK3 specific deps
 189    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 190    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 191    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 192 else
 193    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 194
 195    # GTK2 specific deps
 196    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 197    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 198    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 199
 200    # Enable GSEAL checks if needed
 201    if test $USE_MAINTAINER_MODE = yes; then
 202       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 203    fi
 204 fi
 205
 206 # -----------------------------------------------------------
 207 # Enable debug
 208 # -----------------------------------------------------------
 209
 210 AC_ARG_ENABLE(debug,
 211   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 212     enable_debug=$enableval, enable_debug=yes )
 213
 214 if test x$enable_debug = xyes; then
 215   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 216 fi
 217
 218 # -----------------------------------------------------------
 219 # Language Support
 220 # -----------------------------------------------------------
 221
 222 GETTEXT_PACKAGE=empathy
 223 AC_SUBST(GETTEXT_PACKAGE)
 224 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 225
 226 AM_GLIB_GNU_GETTEXT
 227
 228 # -----------------------------------------------------------
 229 # Connectivity integration
 230 # -----------------------------------------------------------
 231 AC_ARG_WITH(connectivity,
 232               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 233                              [build with connectivity support]), ,
 234                              with_connectivity=auto)
 235
 236 if test "x$with_connectivity" = "xno"; then
 237    have_nm=no
 238    have_connman=no
 239
 240 elif test "x$with_connectivity" = "xconnman"; then
 241    have_nm=no
 242
 243    PKG_CHECK_MODULES(CONNMAN,
 244    [
 245       dbus-glib-1
 246    ], have_connman="yes", have_connman="no")
 247
 248    if test "x$have_connman" = "xyes"; then
 249       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 250    fi
 251
 252 else
 253    have_connman=no
 254
 255    PKG_CHECK_MODULES(NETWORK_MANAGER,
 256    [
 257       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 258    ], have_nm="yes", have_nm="no")
 259
 260    if test "x$have_nm" = "xyes"; then
 261       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 262    fi
 263 fi
 264
 265 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 266    AC_MSG_ERROR([Couldn't find connman dependencies.])
 267 fi
 268
 269 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 270    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 271 fi
 272
 273 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 274 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 275
 276 # -----------------------------------------------------------
 277 # Webkit
 278 # -----------------------------------------------------------
 279 AC_ARG_ENABLE(webkit,
 280               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 281                              [build with webkit support]), ,
 282                              enable_webkit=auto)
 283
 284 if test "x$enable_webkit" != "xno"; then
 285
 286    if test "x$have_gtk3" == "xno"; then
 287       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 288           have_webkit="yes", have_webkit="no")
 289    else
 290       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 291           have_webkit="yes", have_webkit="no")
 292    fi
 293
 294    if test "x$have_webkit" = "xyes"; then
 295       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 296    fi
 297 else
 298    have_webkit=no
 299 fi
 300
 301 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 302    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 303 fi
 304 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 305
 306 # -----------------------------------------------------------
 307 # spellchecking checks: enchant and iso-codes
 308 # -----------------------------------------------------------
 309 AC_ARG_ENABLE(spell,
 310               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 311                              [Enable spell checking]), ,
 312                              enable_spell=auto)
 313
 314 if test "x$enable_spell" != "xno"; then
 315    PKG_CHECK_MODULES(ENCHANT,
 316    [
 317       enchant >= $ENCHANT_REQUIRED,
 318       iso-codes >= $ISO_CODES_REQUIRED
 319    ], have_enchant="yes", have_enchant="no")
 320
 321    if test "x$have_enchant" = "xyes"; then
 322       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 323       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 324          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 325             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 326             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 327             result=yes
 328       else
 329             result=no
 330             have_enchant="no"
 331       fi
 332       AC_MSG_RESULT([$result])
 333    fi
 334 else
 335    have_enchant=no
 336 fi
 337
 338 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 339    AC_MSG_ERROR([Couldn't find spell dependencies.])
 340 fi
 341
 342 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 343
 344 # -----------------------------------------------------------
 345 # Map view checks: libchamplain
 346 # -----------------------------------------------------------
 347 AC_ARG_ENABLE(map,
 348               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 349                              [Enable map view]), ,
 350                              enable_map=auto)
 351
 352 if test "x$enable_map" != "xno"; then
 353
 354    if test "x$have_gtk3" == "xno"; then
 355       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 356       [
 357          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 358          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 359          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 360       ], have_libchamplain="yes", have_libchamplain="no")
 361    else
 362       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 363       have_libchamplain="no"
 364    fi
 365
 366    if test "x$have_libchamplain" = "xyes"; then
 367       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 368    fi
 369 else
 370    have_libchamplain=no
 371 fi
 372
 373 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 374    AC_MSG_ERROR([Couldn't find map view dependencies.])
 375 fi
 376
 377 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 378
 379 # -----------------------------------------------------------
 380 # location checks: geoclue
 381 # -----------------------------------------------------------
 382 AC_ARG_ENABLE(location,
 383               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 384                              [Enable location awareness]), ,
 385                              enable_location=auto)
 386
 387 if test "x$enable_location" != "xno"; then
 388    PKG_CHECK_MODULES(GEOCLUE,
 389    [
 390       geoclue >= $GEOCLUE_REQUIRED
 391    ], have_geoclue="yes", have_geoclue="no")
 392
 393    if test "x$have_geoclue" = "xyes"; then
 394       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 395    fi
 396 else
 397    have_geoclue="no"
 398 fi
 399
 400 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 401    AC_MSG_ERROR([Couldn't find location dependencies.])
 402 fi
 403
 404 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 405 AC_SUBST(GEOCLUE_CFLAGS)
 406 AC_SUBST(GEOCLUE_LIBS)
 407
 408 # -----------------------------------------------------------
 409 # meego widgets support
 410 # -----------------------------------------------------------
 411 AC_ARG_ENABLE(meego,
 412               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 413                              [Enable meego widgets]), ,
 414                              enable_meego=no)
 415
 416 if test "x$enable_meego" != "xno"; then
 417     PKG_CHECK_MODULES(MEEGO,
 418     [
 419        mx-gtk-1.0
 420     ], have_meego="yes", have_meego="no")
 421
 422     if test "x$have_meego" = "xyes"; then
 423        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 424     fi
 425 else
 426    have_meego="no"
 427 fi
 428
 429 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 430    AC_MSG_ERROR([Couldn't find meego dependencies.])
 431 fi
 432
 433 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 434 AC_SUBST(MEEGO_CFLAGS)
 435 AC_SUBST(MEEGO_LIBS)
 436
 437 # -----------------------------------------------------------
 438 # nautilus-sendto
 439 # -----------------------------------------------------------
 440 AC_ARG_ENABLE(nautilus-sendto,
 441               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 442                              [build nautilus-sendto plugin]), ,
 443                              enable_nautilus_sendto=auto)
 444
 445 if test "x$enable_nautilus_sendto" != "xno"; then
 446    if test "x$have_gtk3" == "xno"; then
 447       # Newer NST requires GTK+3 so we can't use it
 448       PKG_CHECK_MODULES(NST,
 449       [
 450          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 451          nautilus-sendto < 2.90.0
 452       ], have_nst="yes", have_nst="no")
 453
 454       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 455    else
 456       PKG_CHECK_MODULES(NST,
 457       [
 458          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 459       ], have_nst="yes", have_nst="no")
 460    fi
 461 else
 462    have_nst=no
 463 fi
 464
 465 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 466    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 467 fi
 468
 469 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 470
 471 # -----------------------------------------------------------
 472 # new, single-window control center
 473 # -----------------------------------------------------------
 474 AC_ARG_ENABLE(control_center_embedding,
 475               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 476                              [Enable support for single-window control center]),
 477                              , enable_control_center_embedding=auto)
 478
 479 if test "x$enable_control_center_embedding" != "xno"; then
 480    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 481    [
 482       libgnome-control-center-extension
 483    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 484
 485    if test "x$have_control_center_embedding" = "xyes"; then
 486       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 487    fi
 488 else
 489    have_control_center_embedding="no"
 490 fi
 491
 492 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 493    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 494 fi
 495
 496 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 497 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 498 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 499
 500 # -----------------------------------------------------------
 501 # Coding style checks
 502 # -----------------------------------------------------------
 503 AC_ARG_ENABLE(coding-style-checks,
 504   AC_HELP_STRING([--disable-coding-style-checks],
 505                  [don't check coding style using grep]),
 506     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 507
 508 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 509 # -----------------------------------------------------------
 510
 511 AC_OUTPUT([
 512    Makefile
 513    data/Makefile
 514    data/empathy.desktop.in
 515    data/empathy-accounts.desktop.in
 516    data/icons/Makefile
 517    extensions/Makefile
 518    po/Makefile.in
 519    libempathy/Makefile
 520    libempathy-gtk/Makefile
 521    src/Makefile
 522    nautilus-sendto-plugin/Makefile
 523    help/Makefile
 524    tests/Makefile
 525    tests/interactive/Makefile
 526    tests/xml/Makefile
 527    tools/Makefile
 528 ])
 529
 530 echo "
 531 Configure summary:
 532
 533         Compiler....................:  ${CC}
 534         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 535         Prefix......................:  ${prefix}
 536         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 537         Use GTK+3...................:  ${have_gtk3}
 538
 539     Features:
 540         Spell checking (enchant)....:  ${have_enchant}
 541         Display maps (libchamplain).:  ${have_libchamplain}
 542         Location awareness (Geoclue):  ${have_geoclue}
 543         Adium themes (Webkit).......:  ${have_webkit}
 544         Meego widgets ..............:  ${have_meego}
 545         Control center embedding....:  ${have_control_center_embedding}
 546
 547     Connectivity:
 548         NetworkManager integration..:  ${have_nm}
 549         ConnMan integration.........:  ${have_connman}
 550
 551     Extras:
 552         Nautilus-sendto plugin......:  ${have_nst}
 553 "