configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 1)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [91])
   6 m4_define([empathy_micro_version], [0])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.15
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GNUTLS_REQUIRED=2.8.5
  38 GTK_REQUIRED=2.91.0
  39 KEYRING_REQUIRED=2.26.0
  40 LIBCANBERRA_GTK_REQUIRED=0.25
  41 LIBNOTIFY_REQUIRED=0.5.1
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.11.16
  44 TELEPATHY_LOGGER=0.1.5
  45 UNIQUE_REQUIRED=1.1.2
  46
  47 # Optionnal deps
  48 CLUTTER_GTK_REQUIRED=0.90.3
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  53 LIBCHAMPLAIN_REQUIRED=0.7.1
  54 NAUTILUS_SENDTO_REQUIRED=2.90.0
  55 NETWORK_MANAGER_REQUIRED=0.7.0
  56 WEBKIT_REQUIRED=1.3.2
  57 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  58
  59 # Use --enable-maintainer-mode to disable deprecated symbols,
  60 # disable single include and enable GSEAL. If this is not a released empathy,
  61 # maintainer mode is forced
  62 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 GNOME_MAINTAINER_MODE_DEFINES
  64
  65 AC_CONFIG_MACRO_DIR([m4])
  66 AC_CONFIG_HEADERS([config.h])
  67 AC_CONFIG_SRCDIR([configure.ac])
  68 AC_CONFIG_AUX_DIR(.)
  69
  70 GNOME_COMMON_INIT
  71
  72 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  73
  74 # Support silent build rules, requires at least automake-1.11. Disable
  75 # by either passing --disable-silent-rules to configure or passing V=1
  76 # to make
  77 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  78
  79 AC_ISC_POSIX
  80 AC_PROG_CC
  81 AC_HEADER_STDC
  82 AM_PROG_LIBTOOL
  83 AM_PROG_MKDIR_P
  84 AM_PATH_GLIB_2_0
  85 AC_PATH_XTRA
  86 IT_PROG_INTLTOOL([0.35.0])
  87 GNOME_DOC_INIT([0.17.3])
  88 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  89 GLIB_GSETTINGS
  90 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  91 AC_SUBST(GLIB_GENMARSHAL)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    farsight2-0.10
 149    folks >= $FOLKS_REQUIRED
 150    folks-telepathy >= $FOLKS_REQUIRED
 151    gconf-2.0 >= $GCONF_REQUIRED
 152    gio-2.0 >= $GLIB_REQUIRED
 153    gio-unix-2.0 >= $GLIB_REQUIRED
 154    gnome-keyring-1 >= $KEYRING_REQUIRED
 155    gnutls >= $GNUTLS_REQUIRED
 156    gmodule-export-2.0
 157    gobject-2.0
 158    gstreamer-0.10
 159    gstreamer-interfaces-0.10
 160    libxml-2.0
 161    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 162    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 163    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 164    x11
 165 ])
 166
 167 # -----------------------------------------------------------
 168 # evolution-data-server (about-me)
 169 # -----------------------------------------------------------
 170 AC_ARG_WITH(eds,
 171             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 172             [with_eds=yes])
 173 if test x"$with_eds" = x"yes" ; then
 174    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 175    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 176 fi
 177
 178 # -----------------------------------------------------------
 179 # GTK+
 180 # -----------------------------------------------------------
 181 PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED)
 182
 183 PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 184 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 185 PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 186 PKG_CHECK_MODULES(GCR, gcr-3 >= $KEYRING_REQUIRED)
 187
 188 # -----------------------------------------------------------
 189 # Enable debug
 190 # -----------------------------------------------------------
 191
 192 AC_ARG_ENABLE(debug,
 193   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 194     enable_debug=$enableval, enable_debug=yes )
 195
 196 if test x$enable_debug = xyes; then
 197   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 198 fi
 199
 200 # -----------------------------------------------------------
 201 # Language Support
 202 # -----------------------------------------------------------
 203
 204 GETTEXT_PACKAGE=empathy
 205 AC_SUBST(GETTEXT_PACKAGE)
 206 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 207
 208 AM_GLIB_GNU_GETTEXT
 209
 210 # -----------------------------------------------------------
 211 # Connectivity integration
 212 # -----------------------------------------------------------
 213 AC_ARG_WITH(connectivity,
 214               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 215                              [build with connectivity support]), ,
 216                              with_connectivity=auto)
 217
 218 if test "x$with_connectivity" = "xno"; then
 219    have_nm=no
 220    have_connman=no
 221
 222 elif test "x$with_connectivity" = "xconnman"; then
 223    have_nm=no
 224
 225    PKG_CHECK_MODULES(CONNMAN,
 226    [
 227       dbus-glib-1
 228    ], have_connman="yes", have_connman="no")
 229
 230    if test "x$have_connman" = "xyes"; then
 231       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 232    fi
 233
 234 else
 235    have_connman=no
 236
 237    PKG_CHECK_MODULES(NETWORK_MANAGER,
 238    [
 239       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 240    ], have_nm="yes", have_nm="no")
 241
 242    if test "x$have_nm" = "xyes"; then
 243       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 244    fi
 245 fi
 246
 247 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 248    AC_MSG_ERROR([Couldn't find connman dependencies.])
 249 fi
 250
 251 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 252    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 253 fi
 254
 255 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 256 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 257
 258 # -----------------------------------------------------------
 259 # Webkit
 260 # -----------------------------------------------------------
 261 AC_ARG_ENABLE(webkit,
 262               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 263                              [build with webkit support]), ,
 264                              enable_webkit=auto)
 265
 266 if test "x$enable_webkit" != "xno"; then
 267    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 268         have_webkit="yes", have_webkit="no")
 269
 270    if test "x$have_webkit" = "xyes"; then
 271       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 272    fi
 273 else
 274    have_webkit=no
 275 fi
 276
 277 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 278    AC_MSG_ERROR([Could not find webkit dependencies.])
 279 fi
 280 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 281
 282 # -----------------------------------------------------------
 283 # spellchecking checks: enchant and iso-codes
 284 # -----------------------------------------------------------
 285 AC_ARG_ENABLE(spell,
 286               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 287                              [Enable spell checking]), ,
 288                              enable_spell=auto)
 289
 290 if test "x$enable_spell" != "xno"; then
 291    PKG_CHECK_MODULES(ENCHANT,
 292    [
 293       enchant >= $ENCHANT_REQUIRED,
 294       iso-codes >= $ISO_CODES_REQUIRED
 295    ], have_enchant="yes", have_enchant="no")
 296
 297    if test "x$have_enchant" = "xyes"; then
 298       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 299       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 300          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 301             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 302             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 303             result=yes
 304       else
 305             result=no
 306             have_enchant="no"
 307       fi
 308       AC_MSG_RESULT([$result])
 309    fi
 310 else
 311    have_enchant=no
 312 fi
 313
 314 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 315    AC_MSG_ERROR([Could not find spell dependencies.])
 316 fi
 317
 318 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 319
 320 # -----------------------------------------------------------
 321 # Map view checks: libchamplain
 322 # -----------------------------------------------------------
 323 AC_ARG_ENABLE(map,
 324               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 325                              [Enable map view]), ,
 326                              enable_map=auto)
 327
 328 if test "x$enable_map" != "xno"; then
 329
 330    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 331     [
 332        champlain-0.8 >= $LIBCHAMPLAIN_REQUIRED,
 333 # champplain-gtk3 doesn't exist. Fix the name once bgo #631009
 334        champlain-gtk3-0.8 >= $LIBCHAMPLAIN_GTK_REQUIRED
 335        clutter-gtk >= $CLUTTER_GTK_REQUIRED
 336     ], have_libchamplain="yes", have_libchamplain="no")
 337
 338    if test "x$have_libchamplain" = "xyes"; then
 339       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 340    fi
 341 else
 342    have_libchamplain=no
 343 fi
 344
 345 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 346    AC_MSG_ERROR([Could not find map view dependencies.])
 347 fi
 348
 349 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 350
 351 # -----------------------------------------------------------
 352 # location checks: geoclue
 353 # -----------------------------------------------------------
 354 AC_ARG_ENABLE(location,
 355               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 356                              [Enable location awareness]), ,
 357                              enable_location=auto)
 358
 359 if test "x$enable_location" != "xno"; then
 360    PKG_CHECK_MODULES(GEOCLUE,
 361    [
 362       geoclue >= $GEOCLUE_REQUIRED
 363    ], have_geoclue="yes", have_geoclue="no")
 364
 365    if test "x$have_geoclue" = "xyes"; then
 366       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 367    fi
 368 else
 369    have_geoclue="no"
 370 fi
 371
 372 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 373    AC_MSG_ERROR([Could not find location dependencies.])
 374 fi
 375
 376 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 377 AC_SUBST(GEOCLUE_CFLAGS)
 378 AC_SUBST(GEOCLUE_LIBS)
 379
 380 # -----------------------------------------------------------
 381 # meego widgets support
 382 # -----------------------------------------------------------
 383 AC_ARG_ENABLE(meego,
 384               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 385                              [Enable meego widgets]), ,
 386                              enable_meego=no)
 387
 388 if test "x$enable_meego" != "xno"; then
 389     PKG_CHECK_MODULES(MEEGO,
 390     [
 391        mx-gtk-1.0
 392     ], have_meego="yes", have_meego="no")
 393
 394     if test "x$have_meego" = "xyes"; then
 395        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 396     fi
 397 else
 398    have_meego="no"
 399 fi
 400
 401 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 402    AC_MSG_ERROR([Could not find meego dependencies.])
 403 fi
 404
 405 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 406 AC_SUBST(MEEGO_CFLAGS)
 407 AC_SUBST(MEEGO_LIBS)
 408
 409 # -----------------------------------------------------------
 410 # nautilus-sendto
 411 # -----------------------------------------------------------
 412 AC_ARG_ENABLE(nautilus-sendto,
 413               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 414                              [build nautilus-sendto plugin]), ,
 415                              enable_nautilus_sendto=auto)
 416
 417 if test "x$enable_nautilus_sendto" != "xno"; then
 418    PKG_CHECK_MODULES(NST,
 419     [
 420        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 421     ], have_nst="yes", have_nst="no")
 422 else
 423    have_nst=no
 424 fi
 425
 426 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 427    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 428 fi
 429
 430 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 431
 432 # -----------------------------------------------------------
 433 # new, single-window control center
 434 # -----------------------------------------------------------
 435 AC_ARG_ENABLE(control_center_embedding,
 436               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 437                              [Enable support for single-window control center]),
 438                              , enable_control_center_embedding=auto)
 439
 440 if test "x$enable_control_center_embedding" != "xno"; then
 441
 442    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 443         have_control_center_embedding="yes", have_control_center_embedding="no")
 444
 445    if test "x$have_control_center_embedding" = "xyes"; then
 446       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 447
 448       AC_MSG_CHECKING([gnome-control-center extension dir])
 449       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 450       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 451           AC_MSG_ERROR([Could not determine extensiondir])
 452       else
 453           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 454       fi
 455       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 456    fi
 457 else
 458    have_control_center_embedding="no"
 459 fi
 460
 461 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 462    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 463 fi
 464
 465 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 466 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 467 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 468
 469 # -----------------------------------------------------------
 470 # Coding style checks
 471 # -----------------------------------------------------------
 472 AC_ARG_ENABLE(coding-style-checks,
 473   AC_HELP_STRING([--disable-coding-style-checks],
 474                  [do not check coding style using grep]),
 475     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 476
 477 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 478 # -----------------------------------------------------------
 479
 480 AC_OUTPUT([
 481    Makefile
 482    data/Makefile
 483    data/empathy.desktop.in
 484    data/empathy-accounts.desktop.in
 485    data/icons/Makefile
 486    extensions/Makefile
 487    po/Makefile.in
 488    libempathy/Makefile
 489    libempathy-gtk/Makefile
 490    src/Makefile
 491    nautilus-sendto-plugin/Makefile
 492    help/Makefile
 493    tests/Makefile
 494    tests/interactive/Makefile
 495    tests/xml/Makefile
 496    tools/Makefile
 497 ])
 498
 499 echo "
 500 Configure summary:
 501
 502         Compiler....................:  ${CC}
 503         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 504         Prefix......................:  ${prefix}
 505         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 506
 507     Features:
 508         Spell checking (enchant)....:  ${have_enchant}
 509         Display maps (libchamplain).:  ${have_libchamplain}
 510         Location awareness (Geoclue):  ${have_geoclue}
 511         Adium themes (Webkit).......:  ${have_webkit}
 512         Meego widgets ..............:  ${have_meego}
 513         Control center embedding....:  ${have_control_center_embedding}
 514
 515     Connectivity:
 516         NetworkManager integration..:  ${have_nm}
 517         ConnMan integration.........:  ${have_connman}
 518
 519     Extras:
 520         Nautilus-sendto plugin......:  ${have_nst}
 521         Salut E-D-S support.........:  ${with_eds}
 522 "