configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.25.9
  33 GTK_REQUIRED=2.21.2
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.11.7
  36 TELEPATHY_LOGGER=0.1.2
  37 ENCHANT_REQUIRED=1.2.0
  38 ISO_CODES_REQUIRED=0.35
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBCHAMPLAIN_REQUIRED=0.4
  42 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  43 CLUTTER_GTK_REQUIRED=0.10
  44 GEOCLUE_REQUIRED=0.11
  45 WEBKIT_REQUIRED=1.1.15
  46 KEYRING_REQUIRED=2.22
  47 NETWORK_MANAGER_REQUIRED=0.7.0
  48 NAUTILUS_SENDTO_REQUIRED=2.28.1
  49 UNIQUE_REQUIRED=1.1.2
  50
  51 # Use --enable-maintainer-mode to disable deprecated symbols,
  52 # disable single include and enable GSEAL. If this is not a released empathy,
  53 # maintainer mode is forced
  54 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  55 GNOME_MAINTAINER_MODE_DEFINES
  56 if test $USE_MAINTAINER_MODE = yes; then
  57   AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
  58 fi
  59
  60 AC_CONFIG_MACRO_DIR([m4])
  61 AC_CONFIG_HEADERS([config.h])
  62 AC_CONFIG_SRCDIR([configure.ac])
  63 AC_CONFIG_AUX_DIR(.)
  64
  65 GNOME_COMMON_INIT
  66
  67 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  68
  69 # Support silent build rules, requires at least automake-1.11. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  73
  74 AC_ISC_POSIX
  75 AC_PROG_CC
  76 AC_HEADER_STDC
  77 AM_PROG_LIBTOOL
  78 AM_PROG_MKDIR_P
  79 AM_PATH_GLIB_2_0
  80 AC_PATH_XTRA
  81 IT_PROG_INTLTOOL([0.35.0])
  82 GNOME_DOC_INIT([0.17.3])
  83 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  84 GLIB_GSETTINGS
  85 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  86 AC_SUBST(GLIB_GENMARSHAL)
  87 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  88 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  89
  90 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  91 if test -z "$XSLTPROC"; then
  92   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  93 fi
  94 AM_PATH_PYTHON([2.3])
  95
  96 EMPATHY_ARG_VALGRIND
  97
  98
  99 # -----------------------------------------------------------
 100 # Error flags
 101 # -----------------------------------------------------------
 102 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 103 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 104
 105 AC_ARG_ENABLE(Werror,
 106   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 107     werror=$enableval, :)
 108
 109 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 110 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 111         wno_missing_field_initializers=yes,
 112         wno_missing_field_initializers=no)
 113 AS_COMPILER_FLAG(-Wno-unused-parameter,
 114         wno_unused_parameter=yes,
 115         wno_unused_parameter=no)
 116
 117 ifelse(empathy_released, 1, [],
 118     [
 119         if test x$werror = xyes; then
 120             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 121         fi
 122         if test x$wextra = xyes -a \
 123             x$wno_missing_field_initializers = xyes -a \
 124             x$wno_unused_parameter = xyes; then
 125             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 126         fi
 127     ])
 128
 129 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 130 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 131 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 132 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 133 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 134 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 135
 136 AC_SUBST(ERROR_CFLAGS)
 137
 138 # -----------------------------------------------------------
 139 # Pkg-Config dependency checks
 140 # -----------------------------------------------------------
 141
 142 PKG_CHECK_MODULES(EMPATHY,
 143 [
 144    dbus-glib-1
 145    farsight2-0.10
 146    gconf-2.0 >= $GCONF_REQUIRED
 147    gdk-x11-2.0
 148    gio-2.0 >= $GLIB_REQUIRED
 149    gio-unix-2.0 >= $GLIB_REQUIRED
 150    gnome-keyring-1 >= $KEYRING_REQUIRED
 151    gobject-2.0
 152    gstreamer-0.10
 153    gstreamer-interfaces-0.10
 154    gtk+-2.0 >= $GTK_REQUIRED
 155    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    unique-1.0 >= $UNIQUE_REQUIRED
 162    x11
 163 ])
 164
 165 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 166
 167 # -----------------------------------------------------------
 168 # Enable debug
 169 # -----------------------------------------------------------
 170
 171 AC_ARG_ENABLE(debug,
 172   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 173     enable_debug=$enableval, enable_debug=yes )
 174
 175 if test x$enable_debug = xyes; then
 176   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 177 fi
 178
 179 # -----------------------------------------------------------
 180 # Language Support
 181 # -----------------------------------------------------------
 182
 183 GETTEXT_PACKAGE=empathy
 184 AC_SUBST(GETTEXT_PACKAGE)
 185 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 186
 187 AM_GLIB_GNU_GETTEXT
 188
 189 # -----------------------------------------------------------
 190 # Connectivity integration
 191 # -----------------------------------------------------------
 192 AC_ARG_WITH(connectivity,
 193               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 194                              [build with connectivity support]), ,
 195                              with_connectivity=auto)
 196
 197 if test "x$with_connectivity" = "xno"; then
 198    have_nm=no
 199    have_connman=no
 200
 201 elif test "x$with_connectivity" = "xconnman"; then
 202
 203    PKG_CHECK_MODULES(CONNMAN,
 204    [
 205       dbus-glib-1
 206    ], have_connman="yes", have_connman="no")
 207
 208    if test "x$have_connman" = "xyes"; then
 209       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 210       have_nm=no
 211    fi
 212
 213 else
 214
 215    PKG_CHECK_MODULES(NETWORK_MANAGER,
 216    [
 217       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 218    ], have_nm="yes", have_nm="no")
 219
 220    if test "x$have_nm" = "xyes"; then
 221       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 222       have_connman=no
 223    else
 224       PKG_CHECK_MODULES(NETWORK_MANAGER,
 225       [
 226           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 227       ], have_nm="yes", have_nm="no")
 228
 229       if test "x$have_nm" = "xyes"; then
 230       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 231       have_connman=no
 232       fi
 233    fi
 234 fi
 235
 236 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 237    AC_MSG_ERROR([Couldn't find connman dependencies.])
 238 fi
 239
 240 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 241    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 242 fi
 243
 244 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 245 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 246
 247 # -----------------------------------------------------------
 248 # Webkit
 249 # -----------------------------------------------------------
 250 AC_ARG_ENABLE(webkit,
 251               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 252                              [build with webkit support]), ,
 253                              enable_webkit=auto)
 254
 255 if test "x$enable_webkit" != "xno"; then
 256    PKG_CHECK_MODULES(WEBKIT,
 257    [
 258       webkit-1.0 >= $WEBKIT_REQUIRED
 259    ], have_webkit="yes", have_webkit="no")
 260
 261    if test "x$have_webkit" = "xyes"; then
 262       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 263    fi
 264 else
 265    have_webkit=no
 266 fi
 267
 268 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 269    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 270 fi
 271 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 272
 273 # -----------------------------------------------------------
 274 # spellchecking checks: enchant and iso-codes
 275 # -----------------------------------------------------------
 276 AC_ARG_ENABLE(spell,
 277               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 278                              [Enable spell checking]), ,
 279                              enable_spell=auto)
 280
 281 if test "x$enable_spell" != "xno"; then
 282    PKG_CHECK_MODULES(ENCHANT,
 283    [
 284       enchant >= $ENCHANT_REQUIRED,
 285       iso-codes >= $ISO_CODES_REQUIRED
 286    ], have_enchant="yes", have_enchant="no")
 287
 288    if test "x$have_enchant" = "xyes"; then
 289       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 290       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 291          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 292             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 293             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 294             result=yes
 295       else
 296             result=no
 297             have_enchant="no"
 298       fi
 299       AC_MSG_RESULT([$result])
 300    fi
 301 else
 302    have_enchant=no
 303 fi
 304
 305 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 306    AC_MSG_ERROR([Couldn't find spell dependencies.])
 307 fi
 308
 309 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 310
 311 # -----------------------------------------------------------
 312 # Map view checks: libchamplain
 313 # -----------------------------------------------------------
 314 AC_ARG_ENABLE(map,
 315               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 316                              [Enable map view]), ,
 317                              enable_map=auto)
 318
 319 if test "x$enable_map" != "xno"; then
 320    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 321    [
 322       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 323       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 324       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 325    ], have_libchamplain="yes", have_libchamplain="no")
 326
 327    if test "x$have_libchamplain" = "xyes"; then
 328       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 329    fi
 330 else
 331    have_libchamplain=no
 332 fi
 333
 334 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 335    AC_MSG_ERROR([Couldn't find map view dependencies.])
 336 fi
 337
 338 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 339
 340 # -----------------------------------------------------------
 341 # location checks: geoclue
 342 # -----------------------------------------------------------
 343 AC_ARG_ENABLE(location,
 344               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 345                              [Enable location awareness]), ,
 346                              enable_location=auto)
 347
 348 if test "x$enable_location" != "xno"; then
 349    PKG_CHECK_MODULES(GEOCLUE,
 350    [
 351       geoclue >= $GEOCLUE_REQUIRED
 352    ], have_geoclue="yes", have_geoclue="no")
 353
 354    if test "x$have_geoclue" = "xyes"; then
 355       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 356    fi
 357 else
 358    have_geoclue="no"
 359 fi
 360
 361 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 362    AC_MSG_ERROR([Couldn't find location dependencies.])
 363 fi
 364
 365 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 366 AC_SUBST(GEOCLUE_CFLAGS)
 367 AC_SUBST(GEOCLUE_LIBS)
 368
 369 # -----------------------------------------------------------
 370 # meego widgets support
 371 # -----------------------------------------------------------
 372 AC_ARG_ENABLE(meego,
 373               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 374                              [Enable meego widgets]), ,
 375                              enable_meego=no)
 376
 377 if test "x$enable_meego" != "xno"; then
 378     PKG_CHECK_MODULES(MEEGO,
 379     [
 380        mx-gtk-1.0
 381     ], have_meego="yes", have_meego="no")
 382
 383     if test "x$have_meego" = "xyes"; then
 384        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 385     fi
 386 else
 387    have_meego="no"
 388 fi
 389
 390 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 391    AC_MSG_ERROR([Couldn't find meego dependencies.])
 392 fi
 393
 394 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 395 AC_SUBST(MEEGO_CFLAGS)
 396 AC_SUBST(MEEGO_LIBS)
 397
 398 # -----------------------------------------------------------
 399 # nautilus-sendto
 400 # -----------------------------------------------------------
 401 AC_ARG_ENABLE(nautilus-sendto,
 402               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 403                              [build nautilus-sendto plugin]), ,
 404                              enable_nautilus_sendto=auto)
 405
 406 if test "x$enable_nautilus_sendto" != "xno"; then
 407    PKG_CHECK_MODULES(NST,
 408    [
 409       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 410    ], have_nst="yes", have_nst="no")
 411 else
 412    have_nst=no
 413 fi
 414
 415 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 416    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 417 fi
 418
 419 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 420
 421 # -----------------------------------------------------------
 422 # new, single-window control center
 423 # -----------------------------------------------------------
 424 AC_ARG_ENABLE(control_center_embedding,
 425               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 426                              [Enable support for single-window control center]),
 427                              , enable_control_center_embedding=auto)
 428
 429 if test "x$enable_control_center_embedding" != "xno"; then
 430    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 431    [
 432       libgnome-control-center-extension
 433    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 434
 435    if test "x$have_control_center_embedding" = "xyes"; then
 436       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 437    fi
 438 else
 439    have_control_center_embedding="no"
 440 fi
 441
 442 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 443    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 444 fi
 445
 446 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 447 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 448 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 449
 450 # -----------------------------------------------------------
 451 # Coding style checks
 452 # -----------------------------------------------------------
 453 AC_ARG_ENABLE(coding-style-checks,
 454   AC_HELP_STRING([--disable-coding-style-checks],
 455                  [don't check coding style using grep]),
 456     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 457
 458 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 459 # -----------------------------------------------------------
 460
 461 AC_OUTPUT([
 462    Makefile
 463    data/Makefile
 464    data/empathy.desktop.in
 465    data/empathy-accounts.desktop.in
 466    data/icons/Makefile
 467    extensions/Makefile
 468    po/Makefile.in
 469    libempathy/Makefile
 470    libempathy-gtk/Makefile
 471    src/Makefile
 472    nautilus-sendto-plugin/Makefile
 473    help/Makefile
 474    tests/Makefile
 475    tests/interactive/Makefile
 476    tests/xml/Makefile
 477    tools/Makefile
 478 ])
 479
 480 echo "
 481 Configure summary:
 482
 483         Compiler....................:  ${CC}
 484         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 485         Prefix......................:  ${prefix}
 486         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 487
 488     Features:
 489         Spell checking (enchant)....:  ${have_enchant}
 490         Display maps (libchamplain).:  ${have_libchamplain}
 491         Location awareness (Geoclue):  ${have_geoclue}
 492         Adium themes (Webkit).......:  ${have_webkit}
 493         Meego widgets ..............:  ${have_meego}
 494         Control center embedding....:  ${have_control_center_embedding}
 495
 496     Connectivity:
 497         NetworkManager integration..:  ${have_nm}
 498         ConnMan integration.........:  ${have_connman}
 499
 500     Extras:
 501         Nautilus-sendto plugin......:  ${have_nst}
 502 "