configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [6])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.13
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GTK_REQUIRED=2.21.2
  38 KEYRING_REQUIRED=2.22
  39 LIBCANBERRA_GTK_REQUIRED=0.4
  40 LIBNOTIFY_REQUIRED=0.4.4
  41 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.11.12
  44 TELEPATHY_LOGGER=0.1.2
  45 UNIQUE_REQUIRED=1.1.2
  46
  47 # Optionnal deps
  48 CLUTTER_GTK_REQUIRED=0.10
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  53 LIBCHAMPLAIN_REQUIRED=0.4
  54 NAUTILUS_SENDTO_REQUIRED=2.28.1
  55 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  56 NETWORK_MANAGER_REQUIRED=0.7.0
  57 WEBKIT_REQUIRED=1.1.15
  58 GNOME_CONTROL_CENTER_GTK3_REQUIRED=2.31.4
  59
  60 # Use --enable-maintainer-mode to disable deprecated symbols,
  61 # disable single include and enable GSEAL. If this is not a released empathy,
  62 # maintainer mode is forced
  63 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  64 GNOME_MAINTAINER_MODE_DEFINES
  65
  66 AC_CONFIG_MACRO_DIR([m4])
  67 AC_CONFIG_HEADERS([config.h])
  68 AC_CONFIG_SRCDIR([configure.ac])
  69 AC_CONFIG_AUX_DIR(.)
  70
  71 GNOME_COMMON_INIT
  72
  73 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  74
  75 # Support silent build rules, requires at least automake-1.11. Disable
  76 # by either passing --disable-silent-rules to configure or passing V=1
  77 # to make
  78 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  79
  80 AC_ISC_POSIX
  81 AC_PROG_CC
  82 AC_HEADER_STDC
  83 AM_PROG_LIBTOOL
  84 AM_PROG_MKDIR_P
  85 AM_PATH_GLIB_2_0
  86 AC_PATH_XTRA
  87 IT_PROG_INTLTOOL([0.35.0])
  88 GNOME_DOC_INIT([0.17.3])
  89 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  90 GLIB_GSETTINGS
  91 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  92 AC_SUBST(GLIB_GENMARSHAL)
  93
  94 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  95 if test -z "$XSLTPROC"; then
  96   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  97 fi
  98 AM_PATH_PYTHON([2.3])
  99
 100 EMPATHY_ARG_VALGRIND
 101
 102
 103 # -----------------------------------------------------------
 104 # Error flags
 105 # -----------------------------------------------------------
 106 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 107 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 108
 109 AC_ARG_ENABLE(Werror,
 110   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 111     werror=$enableval, :)
 112
 113 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 114 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 115         wno_missing_field_initializers=yes,
 116         wno_missing_field_initializers=no)
 117 AS_COMPILER_FLAG(-Wno-unused-parameter,
 118         wno_unused_parameter=yes,
 119         wno_unused_parameter=no)
 120
 121 ifelse(empathy_released, 1, [],
 122     [
 123         if test x$werror = xyes; then
 124             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 125         fi
 126         if test x$wextra = xyes -a \
 127             x$wno_missing_field_initializers = xyes -a \
 128             x$wno_unused_parameter = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 130         fi
 131     ])
 132
 133 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 134 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 135 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 136 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 137 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 138 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 139
 140 AC_SUBST(ERROR_CFLAGS)
 141
 142 # -----------------------------------------------------------
 143 # Pkg-Config dependency checks
 144 # -----------------------------------------------------------
 145
 146 PKG_CHECK_MODULES(EMPATHY,
 147 [
 148    dbus-glib-1
 149    farsight2-0.10
 150    folks >= $FOLKS_REQUIRED
 151    folks-telepathy >= $FOLKS_REQUIRED
 152    gconf-2.0 >= $GCONF_REQUIRED
 153    gio-2.0 >= $GLIB_REQUIRED
 154    gio-unix-2.0 >= $GLIB_REQUIRED
 155    gnome-keyring-1 >= $KEYRING_REQUIRED
 156    gobject-2.0
 157    gstreamer-0.10
 158    gstreamer-interfaces-0.10
 159    libebook-1.2
 160    libxml-2.0
 161    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 162    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 163    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 164    x11
 165 ])
 166
 167 # -----------------------------------------------------------
 168 # GTK+
 169 # -----------------------------------------------------------
 170 AC_ARG_ENABLE(gtk3,
 171               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 172                              [build with GTK+3]), ,
 173                              enable_gtk3=auto)
 174
 175 # Try to use GTK+3 if available
 176 if test "x$enable_gtk3" != "xno"; then
 177    PKG_CHECK_MODULES(GTK,
 178    [
 179       gtk+-3.0 >= $GTK_REQUIRED
 180    ], have_gtk3="yes", have_gtk3="no")
 181 else
 182    have_gtk3="no"
 183 fi
 184
 185 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 186    AC_MSG_ERROR([Could not find gtk3 dependencies.])
 187 fi
 188
 189 if test "x$have_gtk3" == "xyes"; then
 190    # GTK3 specific deps
 191    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 192    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 193    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 194 else
 195    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 196
 197    # GTK2 specific deps
 198    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 199    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 200    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 201
 202    # Enable GSEAL checks if needed
 203    if test $USE_MAINTAINER_MODE = yes; then
 204       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 205    fi
 206 fi
 207
 208 # -----------------------------------------------------------
 209 # Enable debug
 210 # -----------------------------------------------------------
 211
 212 AC_ARG_ENABLE(debug,
 213   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 214     enable_debug=$enableval, enable_debug=yes )
 215
 216 if test x$enable_debug = xyes; then
 217   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 218 fi
 219
 220 # -----------------------------------------------------------
 221 # Language Support
 222 # -----------------------------------------------------------
 223
 224 GETTEXT_PACKAGE=empathy
 225 AC_SUBST(GETTEXT_PACKAGE)
 226 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 227
 228 AM_GLIB_GNU_GETTEXT
 229
 230 # -----------------------------------------------------------
 231 # Connectivity integration
 232 # -----------------------------------------------------------
 233 AC_ARG_WITH(connectivity,
 234               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 235                              [build with connectivity support]), ,
 236                              with_connectivity=auto)
 237
 238 if test "x$with_connectivity" = "xno"; then
 239    have_nm=no
 240    have_connman=no
 241
 242 elif test "x$with_connectivity" = "xconnman"; then
 243    have_nm=no
 244
 245    PKG_CHECK_MODULES(CONNMAN,
 246    [
 247       dbus-glib-1
 248    ], have_connman="yes", have_connman="no")
 249
 250    if test "x$have_connman" = "xyes"; then
 251       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 252    fi
 253
 254 else
 255    have_connman=no
 256
 257    PKG_CHECK_MODULES(NETWORK_MANAGER,
 258    [
 259       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 260    ], have_nm="yes", have_nm="no")
 261
 262    if test "x$have_nm" = "xyes"; then
 263       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 264    fi
 265 fi
 266
 267 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 268    AC_MSG_ERROR([Couldn't find connman dependencies.])
 269 fi
 270
 271 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 272    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 273 fi
 274
 275 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 276 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 277
 278 # -----------------------------------------------------------
 279 # Webkit
 280 # -----------------------------------------------------------
 281 AC_ARG_ENABLE(webkit,
 282               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 283                              [build with webkit support]), ,
 284                              enable_webkit=auto)
 285
 286 if test "x$enable_webkit" != "xno"; then
 287
 288    if test "x$have_gtk3" == "xno"; then
 289       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 290           have_webkit="yes", have_webkit="no")
 291    else
 292       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 293           have_webkit="yes", have_webkit="no")
 294    fi
 295
 296    if test "x$have_webkit" = "xyes"; then
 297       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 298    fi
 299 else
 300    have_webkit=no
 301 fi
 302
 303 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 304    AC_MSG_ERROR([Could not find webkit dependencies.])
 305 fi
 306 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 307
 308 # -----------------------------------------------------------
 309 # spellchecking checks: enchant and iso-codes
 310 # -----------------------------------------------------------
 311 AC_ARG_ENABLE(spell,
 312               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 313                              [Enable spell checking]), ,
 314                              enable_spell=auto)
 315
 316 if test "x$enable_spell" != "xno"; then
 317    PKG_CHECK_MODULES(ENCHANT,
 318    [
 319       enchant >= $ENCHANT_REQUIRED,
 320       iso-codes >= $ISO_CODES_REQUIRED
 321    ], have_enchant="yes", have_enchant="no")
 322
 323    if test "x$have_enchant" = "xyes"; then
 324       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 325       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 326          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 327             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 328             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 329             result=yes
 330       else
 331             result=no
 332             have_enchant="no"
 333       fi
 334       AC_MSG_RESULT([$result])
 335    fi
 336 else
 337    have_enchant=no
 338 fi
 339
 340 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 341    AC_MSG_ERROR([Could not find spell dependencies.])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 345
 346 # -----------------------------------------------------------
 347 # Map view checks: libchamplain
 348 # -----------------------------------------------------------
 349 AC_ARG_ENABLE(map,
 350               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 351                              [Enable map view]), ,
 352                              enable_map=auto)
 353
 354 if test "x$enable_map" != "xno"; then
 355
 356    if test "x$have_gtk3" == "xno"; then
 357       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 358       [
 359          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 360          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 361          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 362       ], have_libchamplain="yes", have_libchamplain="no")
 363    else
 364       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 365       have_libchamplain="no"
 366    fi
 367
 368    if test "x$have_libchamplain" = "xyes"; then
 369       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 370    fi
 371 else
 372    have_libchamplain=no
 373 fi
 374
 375 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 376    AC_MSG_ERROR([Could not find map view dependencies.])
 377 fi
 378
 379 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 380
 381 # -----------------------------------------------------------
 382 # location checks: geoclue
 383 # -----------------------------------------------------------
 384 AC_ARG_ENABLE(location,
 385               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 386                              [Enable location awareness]), ,
 387                              enable_location=auto)
 388
 389 if test "x$enable_location" != "xno"; then
 390    PKG_CHECK_MODULES(GEOCLUE,
 391    [
 392       geoclue >= $GEOCLUE_REQUIRED
 393    ], have_geoclue="yes", have_geoclue="no")
 394
 395    if test "x$have_geoclue" = "xyes"; then
 396       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 397    fi
 398 else
 399    have_geoclue="no"
 400 fi
 401
 402 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 403    AC_MSG_ERROR([Could not find location dependencies.])
 404 fi
 405
 406 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 407 AC_SUBST(GEOCLUE_CFLAGS)
 408 AC_SUBST(GEOCLUE_LIBS)
 409
 410 # -----------------------------------------------------------
 411 # meego widgets support
 412 # -----------------------------------------------------------
 413 AC_ARG_ENABLE(meego,
 414               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 415                              [Enable meego widgets]), ,
 416                              enable_meego=no)
 417
 418 if test "x$enable_meego" != "xno"; then
 419     PKG_CHECK_MODULES(MEEGO,
 420     [
 421        mx-gtk-1.0
 422     ], have_meego="yes", have_meego="no")
 423
 424     if test "x$have_meego" = "xyes"; then
 425        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 426     fi
 427 else
 428    have_meego="no"
 429 fi
 430
 431 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 432    AC_MSG_ERROR([Could not find meego dependencies.])
 433 fi
 434
 435 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 436 AC_SUBST(MEEGO_CFLAGS)
 437 AC_SUBST(MEEGO_LIBS)
 438
 439 # -----------------------------------------------------------
 440 # nautilus-sendto
 441 # -----------------------------------------------------------
 442 AC_ARG_ENABLE(nautilus-sendto,
 443               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 444                              [build nautilus-sendto plugin]), ,
 445                              enable_nautilus_sendto=auto)
 446
 447 if test "x$enable_nautilus_sendto" != "xno"; then
 448    if test "x$have_gtk3" == "xno"; then
 449       # Newer NST requires GTK+3 so we can't use it
 450       PKG_CHECK_MODULES(NST,
 451       [
 452          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 453          nautilus-sendto < 2.90.0
 454       ], have_nst="yes", have_nst="no")
 455
 456       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 457    else
 458       PKG_CHECK_MODULES(NST,
 459       [
 460          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 461       ], have_nst="yes", have_nst="no")
 462    fi
 463 else
 464    have_nst=no
 465 fi
 466
 467 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 468    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 469 fi
 470
 471 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 472
 473 # -----------------------------------------------------------
 474 # new, single-window control center
 475 # -----------------------------------------------------------
 476 AC_ARG_ENABLE(control_center_embedding,
 477               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 478                              [Enable support for single-window control center]),
 479                              , enable_control_center_embedding=auto)
 480
 481 if test "x$enable_control_center_embedding" != "xno"; then
 482
 483    if test "x$have_gtk3" == "xno"; then
 484       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center < GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 485           have_control_center_embedding="yes", have_control_center_embedding="no")
 486    else
 487       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 488           have_control_center_embedding="yes", have_control_center_embedding="no")
 489    fi
 490
 491    if test "x$have_control_center_embedding" = "xyes"; then
 492       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 493
 494       AC_MSG_CHECKING([gnome-control-center extension dir])
 495       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 496       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 497           AC_MSG_ERROR([Could not determine extensiondir])
 498       else
 499           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 500       fi
 501       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 502    fi
 503 else
 504    have_control_center_embedding="no"
 505 fi
 506
 507 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 508    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 509 fi
 510
 511 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 512 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 513 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 514
 515 # -----------------------------------------------------------
 516 # Coding style checks
 517 # -----------------------------------------------------------
 518 AC_ARG_ENABLE(coding-style-checks,
 519   AC_HELP_STRING([--disable-coding-style-checks],
 520                  [do not check coding style using grep]),
 521     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 522
 523 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 524 # -----------------------------------------------------------
 525
 526 AC_OUTPUT([
 527    Makefile
 528    data/Makefile
 529    data/empathy.desktop.in
 530    data/empathy-accounts.desktop.in
 531    data/icons/Makefile
 532    extensions/Makefile
 533    po/Makefile.in
 534    libempathy/Makefile
 535    libempathy-gtk/Makefile
 536    src/Makefile
 537    nautilus-sendto-plugin/Makefile
 538    help/Makefile
 539    tests/Makefile
 540    tests/interactive/Makefile
 541    tests/xml/Makefile
 542    tools/Makefile
 543 ])
 544
 545 echo "
 546 Configure summary:
 547
 548         Compiler....................:  ${CC}
 549         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 550         Prefix......................:  ${prefix}
 551         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 552         Use GTK+3...................:  ${have_gtk3}
 553
 554     Features:
 555         Spell checking (enchant)....:  ${have_enchant}
 556         Display maps (libchamplain).:  ${have_libchamplain}
 557         Location awareness (Geoclue):  ${have_geoclue}
 558         Adium themes (Webkit).......:  ${have_webkit}
 559         Meego widgets ..............:  ${have_meego}
 560         Control center embedding....:  ${have_control_center_embedding}
 561
 562     Connectivity:
 563         NetworkManager integration..:  ${have_nm}
 564         ConnMan integration.........:  ${have_connman}
 565
 566     Extras:
 567         Nautilus-sendto plugin......:  ${have_nst}
 568 "