configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 1)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [2])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.22.0
  33 GTK_REQUIRED=2.20.0
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.11.3
  36 TELEPATHY_LOGGER=0.1.1
  37 ENCHANT_REQUIRED=1.2.0
  38 ISO_CODES_REQUIRED=0.35
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBCHAMPLAIN_REQUIRED=0.4
  42 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  43 CLUTTER_GTK_REQUIRED=0.10
  44 GEOCLUE_REQUIRED=0.11
  45 WEBKIT_REQUIRED=1.1.15
  46 KEYRING_REQUIRED=2.22
  47 NETWORK_MANAGER_REQUIRED=0.7.0
  48 NAUTILUS_SENDTO_REQUIRED=2.28.1
  49
  50 # Use --enable-maintainer-mode to disable deprecated symbols,
  51 # disable single include and enable GSEAL. If this is not a released empathy,
  52 # maintainer mode is forced
  53 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  54 GNOME_MAINTAINER_MODE_DEFINES
  55 #if test $USE_MAINTAINER_MODE = yes; then
  56 #  AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
  57 #fi
  58
  59 AC_CONFIG_MACRO_DIR([m4])
  60 AC_CONFIG_HEADERS([config.h])
  61 AC_CONFIG_SRCDIR([configure.ac])
  62 AC_CONFIG_AUX_DIR(.)
  63
  64 GNOME_COMMON_INIT
  65
  66 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  67
  68 # Support silent build rules, requires at least automake-1.11. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  72
  73 AC_ISC_POSIX
  74 AC_PROG_CC
  75 AC_HEADER_STDC
  76 AM_PROG_LIBTOOL
  77 AM_PROG_MKDIR_P
  78 AM_PATH_GLIB_2_0
  79 AC_PATH_XTRA
  80 IT_PROG_INTLTOOL([0.35.0])
  81 GNOME_DOC_INIT([0.17.3])
  82 IDT_COMPILE_WARNINGS
  83 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  84 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  85 AM_GCONF_SOURCE_2
  86 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  87 AC_SUBST(GLIB_GENMARSHAL)
  88 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  89 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  90
  91 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  92 if test -z "$XSLTPROC"; then
  93   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  94 fi
  95 AM_PATH_PYTHON([2.3])
  96
  97 EMPATHY_ARG_VALGRIND
  98
  99
 100 # -----------------------------------------------------------
 101 # Error flags
 102 # -----------------------------------------------------------
 103 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 104 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 105
 106 AC_ARG_ENABLE(Werror,
 107   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 108     werror=$enableval, :)
 109
 110 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 111 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 112         wno_missing_field_initializers=yes,
 113         wno_missing_field_initializers=no)
 114 AS_COMPILER_FLAG(-Wno-unused-parameter,
 115         wno_unused_parameter=yes,
 116         wno_unused_parameter=no)
 117
 118 ifelse(empathy_released, 1, [],
 119     [
 120         if test x$werror = xyes; then
 121             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 122         fi
 123         if test x$wextra = xyes -a \
 124             x$wno_missing_field_initializers = xyes -a \
 125             x$wno_unused_parameter = xyes; then
 126             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 127         fi
 128     ])
 129
 130 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 131 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 132 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 133 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 134 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 135 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 136
 137 AC_SUBST(ERROR_CFLAGS)
 138
 139 # -----------------------------------------------------------
 140 # Enable TPL
 141 # -----------------------------------------------------------
 142
 143 # It needs to be defined before PKG_CHECK_MODULES calls
 144 AC_ARG_ENABLE(tpl,
 145   AC_HELP_STRING([--enable-tpl],[enable telepathy-logger code and disable the
 146     empathy logger]), enable_tpl=$enableval, enable_tpl=no )
 147 AM_CONDITIONAL(ENABLE_TPL, test "x$enable_tpl" = "xyes")
 148
 149 if test x${enable_tpl} = xyes; then
 150   AC_DEFINE(ENABLE_TPL, [], [Enable TPL code])
 151 fi
 152
 153 if test "x$enable_tpl" = "xyes"; then
 154   PKG_CHECK_MODULES(TPL,
 155   [
 156      telepathy-logger = $TELEPATHY_LOGGER
 157   ])
 158   AC_SUBST(TPL_CFLAGS)
 159   AC_SUBST(TPL_LIBS)
 160 fi
 161
 162
 163 # -----------------------------------------------------------
 164 # Pkg-Config dependency checks
 165 # -----------------------------------------------------------
 166
 167 PKG_CHECK_MODULES(LIBEMPATHY,
 168 [
 169    glib-2.0 >= $GLIB_REQUIRED
 170    gobject-2.0
 171    gio-2.0 >= $GLIB_REQUIRED
 172    gio-unix-2.0 >= $GLIB_REQUIRED
 173    libxml-2.0
 174    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 175    telepathy-farsight
 176    farsight2-0.10
 177    gstreamer-0.10
 178 ])
 179
 180 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 181 [
 182    glib-2.0 >= $GLIB_REQUIRED
 183    gobject-2.0
 184    gio-2.0 >= $GLIB_REQUIRED
 185    gconf-2.0 >= $GCONF_REQUIRED
 186    x11
 187    gtk+-2.0 >= $GTK_REQUIRED
 188    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 189    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 190    farsight2-0.10
 191    gstreamer-0.10
 192    gstreamer-interfaces-0.10
 193 ])
 194
 195 PKG_CHECK_MODULES(EMPATHY,
 196 [
 197    glib-2.0 >= $GLIB_REQUIRED
 198    gobject-2.0
 199    gio-2.0 >= $GLIB_REQUIRED
 200    gdk-x11-2.0
 201    gtk+-2.0 >= $GTK_REQUIRED
 202    libebook-1.2
 203    dbus-glib-1
 204    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 205    telepathy-farsight
 206    farsight2-0.10
 207    gstreamer-0.10
 208    unique-1.0
 209    gnome-keyring-1 >= $KEYRING_REQUIRED
 210 ])
 211
 212 PKG_CHECK_MODULES(LIBEMPATHY_ACCOUNTS_PANEL,
 213 [
 214    glib-2.0 >= $GLIB_REQUIRED
 215    gobject-2.0
 216    gio-2.0 >= $GLIB_REQUIRED
 217    gdk-x11-2.0
 218    gtk+-2.0 >= $GTK_REQUIRED
 219    libebook-1.2
 220    dbus-glib-1
 221    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 222    unique-1.0
 223    gnome-keyring-1 >= $KEYRING_REQUIRED
 224 ])
 225
 226 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 227
 228 # -----------------------------------------------------------
 229 # Enable debug
 230 # -----------------------------------------------------------
 231
 232 AC_ARG_ENABLE(debug,
 233   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 234     enable_debug=$enableval, enable_debug=yes )
 235
 236 if test x$enable_debug = xyes; then
 237   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 238 fi
 239
 240 # -----------------------------------------------------------
 241 # Language Support
 242 # -----------------------------------------------------------
 243
 244 GETTEXT_PACKAGE=empathy
 245 AC_SUBST(GETTEXT_PACKAGE)
 246 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 247
 248 AM_GLIB_GNU_GETTEXT
 249
 250 # -----------------------------------------------------------
 251 # Connectivity integration
 252 # -----------------------------------------------------------
 253 AC_ARG_WITH(connectivity,
 254               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 255                              [build with connectivity support]), ,
 256                              with_connectivity=auto)
 257
 258 if test "x$with_connectivity" = "xno"; then
 259    have_nm=no
 260    have_connman=no
 261
 262 elif test "x$with_connectivity" = "xconnman"; then
 263
 264    PKG_CHECK_MODULES(CONNMAN,
 265    [
 266       dbus-glib-1
 267    ], have_connman="yes", have_connman="no")
 268
 269    if test "x$have_connman" = "xyes"; then
 270       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 271       have_nm=no
 272    fi
 273
 274 else
 275
 276    PKG_CHECK_MODULES(NETWORK_MANAGER,
 277    [
 278       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 279    ], have_nm="yes", have_nm="no")
 280
 281    if test "x$have_nm" = "xyes"; then
 282       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 283       have_connman=no
 284    else
 285       PKG_CHECK_MODULES(NETWORK_MANAGER,
 286       [
 287           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 288       ], have_nm="yes", have_nm="no")
 289
 290       if test "x$have_nm" = "xyes"; then
 291       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 292       have_connman=no
 293       fi
 294    fi
 295 fi
 296
 297 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 298    AC_MSG_ERROR([Couldn't find connman dependencies.])
 299 fi
 300
 301 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 302    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 303 fi
 304
 305 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 306 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 307
 308 # -----------------------------------------------------------
 309 # Webkit
 310 # -----------------------------------------------------------
 311 AC_ARG_ENABLE(webkit,
 312               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 313                              [build with webkit support]), ,
 314                              enable_webkit=auto)
 315
 316 if test "x$enable_webkit" != "xno"; then
 317    PKG_CHECK_MODULES(WEBKIT,
 318    [
 319       webkit-1.0 >= $WEBKIT_REQUIRED
 320    ], have_webkit="yes", have_webkit="no")
 321
 322    if test "x$have_webkit" = "xyes"; then
 323       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 324    fi
 325 else
 326    have_webkit=no
 327 fi
 328
 329 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 330    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 331 fi
 332 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 333
 334 # -----------------------------------------------------------
 335 # spellchecking checks: enchant and iso-codes
 336 # -----------------------------------------------------------
 337 AC_ARG_ENABLE(spell,
 338               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 339                              [Enable spell checking]), ,
 340                              enable_spell=auto)
 341
 342 if test "x$enable_spell" != "xno"; then
 343    PKG_CHECK_MODULES(ENCHANT,
 344    [
 345       enchant >= $ENCHANT_REQUIRED,
 346       iso-codes >= $ISO_CODES_REQUIRED
 347    ], have_enchant="yes", have_enchant="no")
 348
 349    if test "x$have_enchant" = "xyes"; then
 350       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 351       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 352          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 353             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 354             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 355             result=yes
 356       else
 357             result=no
 358             have_enchant="no"
 359       fi
 360       AC_MSG_RESULT([$result])
 361    fi
 362 else
 363    have_enchant=no
 364 fi
 365
 366 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 367    AC_MSG_ERROR([Couldn't find spell dependencies.])
 368 fi
 369
 370 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 371
 372 # -----------------------------------------------------------
 373 # Map view checks: libchamplain
 374 # -----------------------------------------------------------
 375 AC_ARG_ENABLE(map,
 376               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 377                              [Enable map view]), ,
 378                              enable_map=auto)
 379
 380 if test "x$enable_map" != "xno"; then
 381    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 382    [
 383       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 384       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 385       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 386    ], have_libchamplain="yes", have_libchamplain="no")
 387
 388    if test "x$have_libchamplain" = "xyes"; then
 389       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 390    fi
 391 else
 392    have_libchamplain=no
 393 fi
 394
 395 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 396    AC_MSG_ERROR([Couldn't find map view dependencies.])
 397 fi
 398
 399 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 400
 401 # -----------------------------------------------------------
 402 # location checks: geoclue
 403 # -----------------------------------------------------------
 404 AC_ARG_ENABLE(location,
 405               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 406                              [Enable location awareness]), ,
 407                              enable_location=auto)
 408
 409 if test "x$enable_location" != "xno"; then
 410    PKG_CHECK_MODULES(GEOCLUE,
 411    [
 412       geoclue >= $GEOCLUE_REQUIRED
 413    ], have_geoclue="yes", have_geoclue="no")
 414
 415    if test "x$have_geoclue" = "xyes"; then
 416       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 417    fi
 418 else
 419    have_geoclue="no"
 420 fi
 421
 422 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 423    AC_MSG_ERROR([Couldn't find location dependencies.])
 424 fi
 425
 426 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 427 AC_SUBST(GEOCLUE_CFLAGS)
 428 AC_SUBST(GEOCLUE_LIBS)
 429
 430 # -----------------------------------------------------------
 431 # meego widgets support
 432 # -----------------------------------------------------------
 433 AC_ARG_ENABLE(meego,
 434               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 435                              [Enable meego widgets]), ,
 436                              enable_meego=no)
 437
 438 if test "x$enable_meego" != "xno"; then
 439     PKG_CHECK_MODULES(MEEGO,
 440     [
 441        mx-gtk-1.0
 442     ], have_meego="yes", have_meego="no")
 443
 444     if test "x$have_meego" = "xyes"; then
 445        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 446        chain_enable_favourite_contacts="yes"
 447     fi
 448 else
 449    have_meego="no"
 450 fi
 451
 452 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 453    AC_MSG_ERROR([Couldn't find meego dependencies.])
 454 fi
 455
 456 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 457 AC_SUBST(MEEGO_CFLAGS)
 458 AC_SUBST(MEEGO_LIBS)
 459
 460 # -----------------------------------------------------------
 461 # favourite contacts support
 462 # -----------------------------------------------------------
 463 AC_ARG_ENABLE(favourite_contacts,
 464               AS_HELP_STRING([--enable-favourite-contacts=@<:no/yes@:>@],
 465                              [Enable favourite contacts]), ,
 466                              enable_favourite_contacts=no)
 467
 468 if test "x$enable_favourite_contacts" != "xno" -o "x$chain_enable_favourite_contacts" == "xyes"; then
 469     PKG_CHECK_MODULES(TELEPATHY_LOGGER,
 470     [
 471        telepathy-logger
 472     ], have_telepathy_logger="yes", have_telepathy_logger="no")
 473
 474     if test "x$have_telepathy_logger" = "xyes"; then
 475        have_favourite_contacts="yes"
 476        AC_DEFINE(HAVE_FAVOURITE_CONTACTS, 1, [Define if you want favourite contacts support])
 477     fi
 478 else
 479    have_favourite_contacts="no"
 480 fi
 481
 482 if test "x$enable_favourite_contacts" = "xyes" -a "x$have_favourite_contacts" != "xyes"; then
 483    AC_MSG_ERROR([Couldn't find favourite contacts dependencies.])
 484 fi
 485
 486 AM_CONDITIONAL(HAVE_FAVOURITE_CONTACTS, test "x$have_telepathy_logger" = "xyes")
 487
 488 # -----------------------------------------------------------
 489 # nautilus-sendto
 490 # -----------------------------------------------------------
 491 AC_ARG_ENABLE(nautilus-sendto,
 492               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 493                              [build nautilus-sendto plugin]), ,
 494                              enable_nautilus_sendto=auto)
 495
 496 if test "x$enable_nautilus_sendto" != "xno"; then
 497    PKG_CHECK_MODULES(NST,
 498    [
 499       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 500    ], have_nst="yes", have_nst="no")
 501 else
 502    have_nst=no
 503 fi
 504
 505 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 506    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 507 fi
 508
 509 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 510
 511 # -----------------------------------------------------------
 512 # new, single-window control center
 513 # -----------------------------------------------------------
 514 AC_ARG_ENABLE(control_center_embedding,
 515               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 516                              [Enable support for single-window control center]),
 517                              , enable_control_center_embedding=auto)
 518
 519 if test "x$enable_control_center_embedding" != "xno"; then
 520    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 521    [
 522       libgnome-control-center-extension
 523    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 524
 525    if test "x$have_control_center_embedding" = "xyes"; then
 526       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 527    fi
 528 else
 529    have_control_center_embedding="no"
 530 fi
 531
 532 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 533    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 534 fi
 535
 536 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 537 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 538 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 539
 540 # -----------------------------------------------------------
 541 # Coding style checks
 542 # -----------------------------------------------------------
 543 AC_ARG_ENABLE(coding-style-checks,
 544   AC_HELP_STRING([--disable-coding-style-checks],
 545                  [don't check coding style using grep]),
 546     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 547
 548 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 549 # -----------------------------------------------------------
 550
 551 AC_OUTPUT([
 552    Makefile
 553    data/Makefile
 554    data/empathy.desktop.in
 555    data/empathy-accounts.desktop.in
 556    data/icons/Makefile
 557    extensions/Makefile
 558    po/Makefile.in
 559    libempathy/Makefile
 560    libempathy-gtk/Makefile
 561    src/Makefile
 562    nautilus-sendto-plugin/Makefile
 563    help/Makefile
 564    tests/Makefile
 565    tests/interactive/Makefile
 566    tests/xml/Makefile
 567    tools/Makefile
 568 ])
 569
 570 echo "
 571 Configure summary:
 572
 573         Compiler....................:  ${CC}
 574         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 575         Prefix......................:  ${prefix}
 576         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 577
 578     Features:
 579         Spell checking (enchant)....:  ${have_enchant}
 580         Display maps (libchamplain).:  ${have_libchamplain}
 581         Location awareness (Geoclue):  ${have_geoclue}
 582         Adium themes (Webkit).......:  ${have_webkit}
 583         Meego widgets ..............:  ${have_meego}
 584         Favourite contacts .........:  ${have_favourite_contacts}
 585         Control center embedding....:  ${have_control_center_embedding}
 586
 587     Logging:
 588         Telepathy Logger............:  ${enable_tpl}
 589
 590     Connectivity:
 591         NetworkManager integration..:  ${have_nm}
 592         ConnMan integration.........:  ${have_connman}
 593
 594     Extras:
 595         Nautilus-sendto plugin......:  ${have_nst}
 596 "