configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_GLIB_REQUIRED=0.11.7
  42 TELEPATHY_LOGGER=0.1.2
  43 UNIQUE_REQUIRED=1.1.2
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.10
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  51 LIBCHAMPLAIN_REQUIRED=0.4
  52 NAUTILUS_SENDTO_REQUIRED=2.28.1
  53 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.1.15
  56
  57 # Use --enable-maintainer-mode to disable deprecated symbols,
  58 # disable single include and enable GSEAL. If this is not a released empathy,
  59 # maintainer mode is forced
  60 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  61 GNOME_MAINTAINER_MODE_DEFINES
  62
  63 AC_CONFIG_MACRO_DIR([m4])
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_SRCDIR([configure.ac])
  66 AC_CONFIG_AUX_DIR(.)
  67
  68 GNOME_COMMON_INIT
  69
  70 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  71
  72 # Support silent build rules, requires at least automake-1.11. Disable
  73 # by either passing --disable-silent-rules to configure or passing V=1
  74 # to make
  75 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  76
  77 AC_ISC_POSIX
  78 AC_PROG_CC
  79 AC_HEADER_STDC
  80 AM_PROG_LIBTOOL
  81 AM_PROG_MKDIR_P
  82 AM_PATH_GLIB_2_0
  83 AC_PATH_XTRA
  84 IT_PROG_INTLTOOL([0.35.0])
  85 GNOME_DOC_INIT([0.17.3])
  86 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  87 GLIB_GSETTINGS
  88 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  91 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    farsight2-0.10
 149    gconf-2.0 >= $GCONF_REQUIRED
 150    gio-2.0 >= $GLIB_REQUIRED
 151    gio-unix-2.0 >= $GLIB_REQUIRED
 152    gnome-keyring-1 >= $KEYRING_REQUIRED
 153    gobject-2.0
 154    gstreamer-0.10
 155    gstreamer-interfaces-0.10
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    x11
 162 ])
 163
 164 # -----------------------------------------------------------
 165 # GTK+
 166 # -----------------------------------------------------------
 167 AC_ARG_ENABLE(gtk3,
 168               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 169                              [build with GTK+3]), ,
 170                              enable_gtk3=auto)
 171
 172 # Try to use GTK+3 if available
 173 if test "x$enable_gtk3" != "xno"; then
 174   PKG_CHECK_MODULES(GTK, [gtk+-3.0 >= $GTK_REQUIRED],
 175       have_gtk3="yes", have_gtk3="no")
 176 else
 177   have_gtk3="no"
 178 fi
 179
 180 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 181    AC_MSG_ERROR([Couldn't find gtk3 dependencies.])
 182 fi
 183
 184 if test "x$have_gtk3" == "xyes"; then
 185   # GTK3 specific deps
 186   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 187   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 188   PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 189 else
 190   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 191
 192   # GTK2 specific deps
 193   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 194   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 195   PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 196
 197   # Enable GSEAL checks if needed
 198   if test $USE_MAINTAINER_MODE = yes; then
 199     AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 200   fi
 201 fi
 202
 203 # -----------------------------------------------------------
 204 # Enable debug
 205 # -----------------------------------------------------------
 206
 207 AC_ARG_ENABLE(debug,
 208   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 209     enable_debug=$enableval, enable_debug=yes )
 210
 211 if test x$enable_debug = xyes; then
 212   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 213 fi
 214
 215 # -----------------------------------------------------------
 216 # Language Support
 217 # -----------------------------------------------------------
 218
 219 GETTEXT_PACKAGE=empathy
 220 AC_SUBST(GETTEXT_PACKAGE)
 221 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 222
 223 AM_GLIB_GNU_GETTEXT
 224
 225 # -----------------------------------------------------------
 226 # Connectivity integration
 227 # -----------------------------------------------------------
 228 AC_ARG_WITH(connectivity,
 229               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 230                              [build with connectivity support]), ,
 231                              with_connectivity=auto)
 232
 233 if test "x$with_connectivity" = "xno"; then
 234    have_nm=no
 235    have_connman=no
 236
 237 elif test "x$with_connectivity" = "xconnman"; then
 238    have_nm=no
 239
 240    PKG_CHECK_MODULES(CONNMAN,
 241    [
 242       dbus-glib-1
 243    ], have_connman="yes", have_connman="no")
 244
 245    if test "x$have_connman" = "xyes"; then
 246       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 247    fi
 248
 249 else
 250    have_connman=no
 251
 252    PKG_CHECK_MODULES(NETWORK_MANAGER,
 253    [
 254       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 255    ], have_nm="yes", have_nm="no")
 256
 257    if test "x$have_nm" = "xyes"; then
 258       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 259    fi
 260 fi
 261
 262 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 263    AC_MSG_ERROR([Couldn't find connman dependencies.])
 264 fi
 265
 266 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 267    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 268 fi
 269
 270 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 271 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 272
 273 # -----------------------------------------------------------
 274 # Webkit
 275 # -----------------------------------------------------------
 276 AC_ARG_ENABLE(webkit,
 277               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 278                              [build with webkit support]), ,
 279                              enable_webkit=auto)
 280
 281 if test "x$enable_webkit" != "xno"; then
 282
 283    if test "x$have_gtk3" == "xno"; then
 284       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 285           have_webkit="yes", have_webkit="no")
 286    else
 287       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 288           have_webkit="yes", have_webkit="no")
 289    fi
 290
 291    if test "x$have_webkit" = "xyes"; then
 292       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 293    fi
 294 else
 295    have_webkit=no
 296 fi
 297
 298 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 299    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 300 fi
 301 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 302
 303 # -----------------------------------------------------------
 304 # spellchecking checks: enchant and iso-codes
 305 # -----------------------------------------------------------
 306 AC_ARG_ENABLE(spell,
 307               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 308                              [Enable spell checking]), ,
 309                              enable_spell=auto)
 310
 311 if test "x$enable_spell" != "xno"; then
 312    PKG_CHECK_MODULES(ENCHANT,
 313    [
 314       enchant >= $ENCHANT_REQUIRED,
 315       iso-codes >= $ISO_CODES_REQUIRED
 316    ], have_enchant="yes", have_enchant="no")
 317
 318    if test "x$have_enchant" = "xyes"; then
 319       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 320       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 321          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 322             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 323             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 324             result=yes
 325       else
 326             result=no
 327             have_enchant="no"
 328       fi
 329       AC_MSG_RESULT([$result])
 330    fi
 331 else
 332    have_enchant=no
 333 fi
 334
 335 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 336    AC_MSG_ERROR([Couldn't find spell dependencies.])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 340
 341 # -----------------------------------------------------------
 342 # Map view checks: libchamplain
 343 # -----------------------------------------------------------
 344 AC_ARG_ENABLE(map,
 345               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 346                              [Enable map view]), ,
 347                              enable_map=auto)
 348
 349 if test "x$enable_map" != "xno"; then
 350
 351    if test "x$have_gtk3" == "xno"; then
 352       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 353       [
 354          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 355          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 356          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 357       ], have_libchamplain="yes", have_libchamplain="no")
 358    else
 359       have_libchamplain="no"
 360    fi
 361
 362    if test "x$have_libchamplain" = "xyes"; then
 363       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 364    fi
 365 else
 366    # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 367    have_libchamplain=no
 368 fi
 369
 370 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 371    AC_MSG_ERROR([Couldn't find map view dependencies.])
 372 fi
 373
 374 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 375
 376 # -----------------------------------------------------------
 377 # location checks: geoclue
 378 # -----------------------------------------------------------
 379 AC_ARG_ENABLE(location,
 380               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 381                              [Enable location awareness]), ,
 382                              enable_location=auto)
 383
 384 if test "x$enable_location" != "xno"; then
 385    PKG_CHECK_MODULES(GEOCLUE,
 386    [
 387       geoclue >= $GEOCLUE_REQUIRED
 388    ], have_geoclue="yes", have_geoclue="no")
 389
 390    if test "x$have_geoclue" = "xyes"; then
 391       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 392    fi
 393 else
 394    have_geoclue="no"
 395 fi
 396
 397 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 398    AC_MSG_ERROR([Couldn't find location dependencies.])
 399 fi
 400
 401 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 402 AC_SUBST(GEOCLUE_CFLAGS)
 403 AC_SUBST(GEOCLUE_LIBS)
 404
 405 # -----------------------------------------------------------
 406 # meego widgets support
 407 # -----------------------------------------------------------
 408 AC_ARG_ENABLE(meego,
 409               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 410                              [Enable meego widgets]), ,
 411                              enable_meego=no)
 412
 413 if test "x$enable_meego" != "xno"; then
 414     PKG_CHECK_MODULES(MEEGO,
 415     [
 416        mx-gtk-1.0
 417     ], have_meego="yes", have_meego="no")
 418
 419     if test "x$have_meego" = "xyes"; then
 420        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 421     fi
 422 else
 423    have_meego="no"
 424 fi
 425
 426 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 427    AC_MSG_ERROR([Couldn't find meego dependencies.])
 428 fi
 429
 430 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 431 AC_SUBST(MEEGO_CFLAGS)
 432 AC_SUBST(MEEGO_LIBS)
 433
 434 # -----------------------------------------------------------
 435 # nautilus-sendto
 436 # -----------------------------------------------------------
 437 AC_ARG_ENABLE(nautilus-sendto,
 438               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 439                              [build nautilus-sendto plugin]), ,
 440                              enable_nautilus_sendto=auto)
 441
 442 if test "x$enable_nautilus_sendto" != "xno"; then
 443    if test "x$have_gtk3" == "xno"; then
 444       # Newer NST requires GTK+3 so we can't use it
 445       PKG_CHECK_MODULES(NST,[nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 446           nautilus-sendto < 2.90.0],
 447           have_nst="yes", have_nst="no")
 448
 449       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 450    else
 451       PKG_CHECK_MODULES(NST,[nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3],
 452           have_nst="yes", have_nst="no")
 453    fi
 454 else
 455    have_nst=no
 456 fi
 457
 458 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 459    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 460 fi
 461
 462 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 463
 464 # -----------------------------------------------------------
 465 # new, single-window control center
 466 # -----------------------------------------------------------
 467 AC_ARG_ENABLE(control_center_embedding,
 468               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 469                              [Enable support for single-window control center]),
 470                              , enable_control_center_embedding=auto)
 471
 472 if test "x$enable_control_center_embedding" != "xno"; then
 473    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 474    [
 475       libgnome-control-center-extension
 476    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 477
 478    if test "x$have_control_center_embedding" = "xyes"; then
 479       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 480    fi
 481 else
 482    have_control_center_embedding="no"
 483 fi
 484
 485 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 486    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 487 fi
 488
 489 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 490 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 491 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 492
 493 # -----------------------------------------------------------
 494 # Coding style checks
 495 # -----------------------------------------------------------
 496 AC_ARG_ENABLE(coding-style-checks,
 497   AC_HELP_STRING([--disable-coding-style-checks],
 498                  [don't check coding style using grep]),
 499     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 500
 501 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 502 # -----------------------------------------------------------
 503
 504 AC_OUTPUT([
 505    Makefile
 506    data/Makefile
 507    data/empathy.desktop.in
 508    data/empathy-accounts.desktop.in
 509    data/icons/Makefile
 510    extensions/Makefile
 511    po/Makefile.in
 512    libempathy/Makefile
 513    libempathy-gtk/Makefile
 514    src/Makefile
 515    nautilus-sendto-plugin/Makefile
 516    help/Makefile
 517    tests/Makefile
 518    tests/interactive/Makefile
 519    tests/xml/Makefile
 520    tools/Makefile
 521 ])
 522
 523 echo "
 524 Configure summary:
 525
 526         Compiler....................:  ${CC}
 527         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 528         Prefix......................:  ${prefix}
 529         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 530         Use GTK+3...................:  ${have_gtk3}
 531
 532     Features:
 533         Spell checking (enchant)....:  ${have_enchant}
 534         Display maps (libchamplain).:  ${have_libchamplain}
 535         Location awareness (Geoclue):  ${have_geoclue}
 536         Adium themes (Webkit).......:  ${have_webkit}
 537         Meego widgets ..............:  ${have_meego}
 538         Control center embedding....:  ${have_control_center_embedding}
 539
 540     Connectivity:
 541         NetworkManager integration..:  ${have_nm}
 542         ConnMan integration.........:  ${have_connman}
 543
 544     Extras:
 545         Nautilus-sendto plugin......:  ${have_nst}
 546 "