configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [29])
   6 m4_define([empathy_micro_version], [3])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.22.0
  33 GTK_REQUIRED=2.18.0
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.9.0
  36 ENCHANT_REQUIRED=1.2.0
  37 ISO_CODES_REQUIRED=0.35
  38 LIBNOTIFY_REQUIRED=0.4.4
  39 LIBCANBERRA_GTK_REQUIRED=0.4
  40 LIBCHAMPLAIN_REQUIRED=0.4
  41 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  42 CLUTTER_GTK_REQUIRED=0.10
  43 GEOCLUE_REQUIRED=0.11
  44 WEBKIT_REQUIRED=1.1.15
  45 KEYRING_REQUIRED=2.22
  46 NETWORK_MANAGER_REQUIRED=0.7.0
  47 NAUTILUS_SENDTO_REQUIRED=2.28.0.1
  48
  49 # Use --enable-maintainer-mode to disabled deprecated symbols
  50 GNOME_MAINTAINER_MODE_DEFINES
  51
  52 # Uncomment that to build with single include disabled
  53 #AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  54 #AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  55 #AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  56
  57 AC_CONFIG_MACRO_DIR([m4])
  58 AC_CONFIG_HEADERS([config.h])
  59 AC_CONFIG_SRCDIR([configure.ac])
  60 AC_CONFIG_AUX_DIR(.)
  61
  62 GNOME_COMMON_INIT
  63
  64 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  65 AC_ISC_POSIX
  66 AC_PROG_CC
  67 AC_HEADER_STDC
  68 AM_PROG_LIBTOOL
  69 AM_PROG_MKDIR_P
  70 AM_PATH_GLIB_2_0
  71 AC_PATH_XTRA
  72 IT_PROG_INTLTOOL([0.35.0])
  73 GNOME_DOC_INIT([0.17.3])
  74 IDT_COMPILE_WARNINGS
  75 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  76 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  77 AM_GCONF_SOURCE_2
  78 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  79 AC_SUBST(GLIB_GENMARSHAL)
  80
  81 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  82 if test -z "$XSLTPROC"; then
  83   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  84 fi
  85 AM_PATH_PYTHON([2.3])
  86
  87 EMPATHY_ARG_VALGRIND
  88
  89
  90 # -----------------------------------------------------------
  91 # Error flags
  92 # -----------------------------------------------------------
  93 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
  94 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
  95
  96 AC_ARG_ENABLE(Werror,
  97   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
  98     werror=$enableval, :)
  99
 100 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 101 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 102         wno_missing_field_initializers=yes,
 103         wno_missing_field_initializers=no)
 104 AS_COMPILER_FLAG(-Wno-unused-parameter,
 105         wno_unused_parameter=yes,
 106         wno_unused_parameter=no)
 107
 108 ifelse(empathy_released, 1, [],
 109     [
 110         if test x$werror = xyes; then
 111             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 112         fi
 113         if test x$wextra = xyes -a \
 114             x$wno_missing_field_initializers = xyes -a \
 115             x$wno_unused_parameter = xyes; then
 116             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 117         fi
 118     ])
 119
 120 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 121 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 122 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 123 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 124 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 125 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 126
 127 AC_SUBST(ERROR_CFLAGS)
 128
 129 # -----------------------------------------------------------
 130 # Pkg-Config dependency checks
 131 # -----------------------------------------------------------
 132
 133 PKG_CHECK_MODULES(LIBEMPATHY,
 134 [
 135    glib-2.0 >= $GLIB_REQUIRED
 136    gobject-2.0
 137    gio-2.0 >= $GLIB_REQUIRED
 138    gio-unix-2.0 >= $GLIB_REQUIRED
 139    libxml-2.0
 140    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 141    telepathy-farsight
 142    farsight2-0.10
 143    gstreamer-0.10
 144 ])
 145
 146 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 147 [
 148    glib-2.0 >= $GLIB_REQUIRED
 149    gobject-2.0
 150    gio-2.0 >= $GLIB_REQUIRED
 151    gconf-2.0 >= $GCONF_REQUIRED
 152    x11
 153    gtk+-2.0 >= $GTK_REQUIRED
 154    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 155    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 156    farsight2-0.10
 157    gstreamer-0.10
 158    gstreamer-interfaces-0.10
 159 ])
 160
 161 PKG_CHECK_MODULES(EMPATHY,
 162 [
 163    glib-2.0 >= $GLIB_REQUIRED
 164    gobject-2.0
 165    gio-2.0 >= $GLIB_REQUIRED
 166    gdk-x11-2.0
 167    gtk+-2.0 >= $GTK_REQUIRED
 168    libebook-1.2
 169    dbus-glib-1
 170    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 171    telepathy-farsight
 172    farsight2-0.10
 173    gstreamer-0.10
 174    unique-1.0
 175    gnome-keyring-1 >= $KEYRING_REQUIRED
 176 ])
 177
 178 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 179
 180 # -----------------------------------------------------------
 181 # Enable debug
 182 # -----------------------------------------------------------
 183
 184 AC_ARG_ENABLE(debug,
 185   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 186     enable_debug=$enableval, enable_debug=yes )
 187
 188 if test x$enable_debug = xyes; then
 189   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 190 fi
 191
 192 # -----------------------------------------------------------
 193 # Language Support
 194 # -----------------------------------------------------------
 195
 196 GETTEXT_PACKAGE=empathy
 197 AC_SUBST(GETTEXT_PACKAGE)
 198 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 199
 200 AM_GLIB_GNU_GETTEXT
 201
 202 # -----------------------------------------------------------
 203 # Connectivity integration
 204 # -----------------------------------------------------------
 205 AC_ARG_WITH(connectivity,
 206               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 207                              [build with connectivity support]), ,
 208                              with_connectivity=auto)
 209
 210 if test "x$with_connectivity" = "xno"; then
 211    have_nm=no
 212    have_connman=no
 213
 214 elif test "x$with_connectivity" = "xconnman"; then
 215
 216    PKG_CHECK_MODULES(CONNMAN,
 217    [
 218       dbus-glib-1
 219    ], have_connman="yes", have_connman="no")
 220
 221    if test "x$have_connman" = "xyes"; then
 222       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 223       have_nm=no
 224    fi
 225
 226 else
 227
 228    PKG_CHECK_MODULES(NETWORK_MANAGER,
 229    [
 230       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 231    ], have_nm="yes", have_nm="no")
 232
 233    if test "x$have_nm" = "xyes"; then
 234       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 235       have_connman=no
 236    fi
 237 fi
 238
 239 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 240    AC_MSG_ERROR([Couldn't find connman dependencies.])
 241 fi
 242
 243 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 244    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 245 fi
 246
 247 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 248 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 249
 250 # -----------------------------------------------------------
 251 # Webkit
 252 # -----------------------------------------------------------
 253 AC_ARG_ENABLE(webkit,
 254               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 255                              [build with webkit support]), ,
 256                              enable_webkit=auto)
 257
 258 if test "x$enable_webkit" != "xno"; then
 259    PKG_CHECK_MODULES(WEBKIT,
 260    [
 261       webkit-1.0 >= $WEBKIT_REQUIRED
 262    ], have_webkit="yes", have_webkit="no")
 263
 264    if test "x$have_webkit" = "xyes"; then
 265       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 266    fi
 267 else
 268    have_webkit=no
 269 fi
 270
 271 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 272    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 273 fi
 274 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 275
 276 # -----------------------------------------------------------
 277 # spellchecking checks: enchant and iso-codes
 278 # -----------------------------------------------------------
 279 AC_ARG_ENABLE(spell,
 280               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 281                              [Enable spell checking]), ,
 282                              enable_spell=auto)
 283
 284 if test "x$enable_spell" != "xno"; then
 285    PKG_CHECK_MODULES(ENCHANT,
 286    [
 287       enchant >= $ENCHANT_REQUIRED,
 288       iso-codes >= $ISO_CODES_REQUIRED
 289    ], have_enchant="yes", have_enchant="no")
 290
 291    if test "x$have_enchant" = "xyes"; then
 292       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 293       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 294          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 295             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 296             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 297             result=yes
 298       else
 299             result=no
 300             have_enchant="no"
 301       fi
 302       AC_MSG_RESULT([$result])
 303    fi
 304 else
 305    have_enchant=no
 306 fi
 307
 308 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 309    AC_MSG_ERROR([Couldn't find spell dependencies.])
 310 fi
 311
 312 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 313
 314 # -----------------------------------------------------------
 315 # Map view checks: libchamplain
 316 # -----------------------------------------------------------
 317 AC_ARG_ENABLE(map,
 318               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 319                              [Enable map view]), ,
 320                              enable_map=auto)
 321
 322 if test "x$enable_map" != "xno"; then
 323    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 324    [
 325       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 326       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 327       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 328    ], have_libchamplain="yes", have_libchamplain="no")
 329
 330    if test "x$have_libchamplain" = "xyes"; then
 331       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 332    fi
 333 else
 334    have_libchamplain=no
 335 fi
 336
 337 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 338    AC_MSG_ERROR([Couldn't find map view dependencies.])
 339 fi
 340
 341 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 342
 343 # -----------------------------------------------------------
 344 # location checks: geoclue
 345 # -----------------------------------------------------------
 346 AC_ARG_ENABLE(location,
 347               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 348                              [Enable location awareness]), ,
 349                              enable_location=auto)
 350
 351 if test "x$enable_location" != "xno"; then
 352    PKG_CHECK_MODULES(GEOCLUE,
 353    [
 354       geoclue >= $GEOCLUE_REQUIRED
 355    ], have_geoclue="yes", have_geoclue="no")
 356
 357    if test "x$have_geoclue" = "xyes"; then
 358       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 359    fi
 360 else
 361    have_geoclue="no"
 362 fi
 363
 364 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 365    AC_MSG_ERROR([Couldn't find location dependencies.])
 366 fi
 367
 368 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 369 AC_SUBST(GEOCLUE_CFLAGS)
 370 AC_SUBST(GEOCLUE_LIBS)
 371
 372 # -----------------------------------------------------------
 373 # moblin widgets support
 374 # -----------------------------------------------------------
 375 AC_ARG_ENABLE(moblin,
 376               AS_HELP_STRING([--enable-moblin=@<:no/yes@:>@],
 377                              [Enable moblin widgets]), ,
 378                              enable_moblin=no)
 379
 380 if test "x$enable_moblin" != "xno"; then
 381     PKG_CHECK_MODULES(MOBLIN,
 382     [
 383        nbtk-gtk-1.2
 384     ], have_moblin="yes", have_moblin="no")
 385
 386     if test "x$have_moblin" = "xyes"; then
 387        AC_DEFINE(HAVE_MOBLIN, 1, [Define if you have moblin])
 388     fi
 389 else
 390    have_moblin="no"
 391 fi
 392
 393 if test "x$enable_moblin" = "xyes" -a "x$have_moblin" != "xyes"; then
 394    AC_MSG_ERROR([Couldn't find moblin dependencies.])
 395 fi
 396
 397 AM_CONDITIONAL(HAVE_MOBLIN, test "x$have_moblin" = "xyes")
 398 AC_SUBST(MOBLIN_CFLAGS)
 399 AC_SUBST(MOBLIN_LIBS)
 400
 401 # -----------------------------------------------------------
 402 # nautilus-sendto
 403 # -----------------------------------------------------------
 404 AC_ARG_ENABLE(nautilus-sendto,
 405               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 406                              [build nautilus-sendto plugin]), ,
 407                              enable_nautilus_sendto=auto)
 408
 409 if test "x$enable_nautilus_sendto" != "xno"; then
 410    PKG_CHECK_MODULES(NST,
 411    [
 412       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 413    ], have_nst="yes", have_nst="no")
 414 else
 415    have_nst=no
 416 fi
 417
 418 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 419    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 420 fi
 421
 422 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 423
 424 # -----------------------------------------------------------
 425 # Coding style checks
 426 # -----------------------------------------------------------
 427 AC_ARG_ENABLE(coding-style-checks,
 428   AC_HELP_STRING([--disable-coding-style-checks],
 429                  [don't check coding style using grep]),
 430     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 431
 432 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 433 # -----------------------------------------------------------
 434
 435 SHAVE_INIT(.)
 436
 437 AC_OUTPUT([
 438    Makefile
 439    data/Makefile
 440    data/empathy.desktop.in
 441    data/icons/Makefile
 442    extensions/Makefile
 443    po/Makefile.in
 444    libempathy/Makefile
 445    libempathy-gtk/Makefile
 446    src/Makefile
 447    nautilus-sendto-plugin/Makefile
 448    help/Makefile
 449    tests/Makefile
 450    tests/interactive/Makefile
 451    tests/xml/Makefile
 452    tools/Makefile
 453    shave
 454    shave-libtool
 455 ])
 456
 457 echo "
 458 Configure summary:
 459
 460         Compiler....................:  ${CC}
 461         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 462         Prefix......................:  ${prefix}
 463         Shaved build................:  ${enable_shave}
 464         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 465
 466     Features:
 467         Spell checking (enchant)....:  ${have_enchant}
 468         Display maps (libchamplain).:  ${have_libchamplain}
 469         Location awareness (Geoclue):  ${have_geoclue}
 470         Adium themes (Webkit).......:  ${have_webkit}
 471         Moblin widgets .............:  ${have_moblin}
 472
 473     Connectivity:
 474         NetworkManager integration..:  ${have_nm}
 475         ConnMan integration.........:  ${have_connman}
 476
 477     Extras:
 478         Nautilus-sendto plugin......:  ${have_nst}
 479 "