configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [91])
   6 m4_define([empathy_micro_version], [2])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.3.2
  35 GLIB_REQUIRED=2.27.2
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=2.91.3
  38 KEYRING_REQUIRED=2.26.0
  39 LIBCANBERRA_GTK_REQUIRED=0.25
  40 LIBNOTIFY_REQUIRED=0.7.0
  41 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  42 TELEPATHY_GLIB_REQUIRED=0.13.1.1
  43 TELEPATHY_LOGGER=0.1.5
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.90.3
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  51 LIBCHAMPLAIN_REQUIRED=0.7.1
  52 NAUTILUS_SENDTO_REQUIRED=2.90.0
  53 NETWORK_MANAGER_REQUIRED=0.7.0
  54 WEBKIT_REQUIRED=1.3.2
  55 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  56
  57 # Use --enable-maintainer-mode to disable deprecated symbols,
  58 # disable single include and enable GSEAL. If this is not a released empathy,
  59 # maintainer mode is forced
  60 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  61 GNOME_MAINTAINER_MODE_DEFINES
  62
  63 AC_CONFIG_MACRO_DIR([m4])
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_SRCDIR([configure.ac])
  66 AC_CONFIG_AUX_DIR(.)
  67
  68 GNOME_COMMON_INIT
  69
  70 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  71
  72 # Support silent build rules, requires at least automake-1.11. Disable
  73 # by either passing --disable-silent-rules to configure or passing V=1
  74 # to make
  75 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  76
  77 AC_ISC_POSIX
  78 AC_PROG_CC
  79 AC_HEADER_STDC
  80 AM_PROG_LIBTOOL
  81 AM_PROG_MKDIR_P
  82 AM_PATH_GLIB_2_0
  83 AC_PATH_XTRA
  84 IT_PROG_INTLTOOL([0.35.0])
  85 GNOME_DOC_INIT([0.17.3])
  86 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  87 GLIB_GSETTINGS
  88 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90
  91 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  92 if test -z "$XSLTPROC"; then
  93   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  94 fi
  95 AM_PATH_PYTHON([2.3])
  96
  97 EMPATHY_ARG_VALGRIND
  98
  99
 100 # -----------------------------------------------------------
 101 # Error flags
 102 # -----------------------------------------------------------
 103 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 104 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 105
 106 AC_ARG_ENABLE(Werror,
 107   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 108     werror=$enableval, :)
 109
 110 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 111 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 112         wno_missing_field_initializers=yes,
 113         wno_missing_field_initializers=no)
 114 AS_COMPILER_FLAG(-Wno-unused-parameter,
 115         wno_unused_parameter=yes,
 116         wno_unused_parameter=no)
 117
 118 ifelse(empathy_released, 1, [],
 119     [
 120         if test x$werror = xyes; then
 121             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 122         fi
 123         if test x$wextra = xyes -a \
 124             x$wno_missing_field_initializers = xyes -a \
 125             x$wno_unused_parameter = xyes; then
 126             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 127         fi
 128     ])
 129
 130 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 131 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 132 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 133 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 134 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 135 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 136
 137 AC_SUBST(ERROR_CFLAGS)
 138
 139 # -----------------------------------------------------------
 140 # Pkg-Config dependency checks
 141 # -----------------------------------------------------------
 142
 143 PKG_CHECK_MODULES(EMPATHY,
 144 [
 145    dbus-glib-1
 146    farsight2-0.10
 147    folks >= $FOLKS_REQUIRED
 148    folks-telepathy >= $FOLKS_REQUIRED
 149    gio-2.0 >= $GLIB_REQUIRED
 150    gio-unix-2.0 >= $GLIB_REQUIRED
 151    gnome-keyring-1 >= $KEYRING_REQUIRED
 152    gnutls >= $GNUTLS_REQUIRED
 153    gmodule-export-2.0
 154    gobject-2.0
 155    gsettings-desktop-schemas
 156    gstreamer-0.10
 157    gstreamer-interfaces-0.10
 158    libxml-2.0
 159    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 160    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 161    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 162    x11
 163    gtk+-3.0 >= $GTK_REQUIRED
 164    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 165    libnotify >= $LIBNOTIFY_REQUIRED
 166    gcr-3 >= $KEYRING_REQUIRED
 167 ])
 168
 169 # -----------------------------------------------------------
 170 # evolution-data-server (about-me)
 171 # -----------------------------------------------------------
 172 AC_ARG_WITH(eds,
 173             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 174             [with_eds=yes])
 175 if test x"$with_eds" = x"yes" ; then
 176    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 177    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 178 fi
 179
 180 # -----------------------------------------------------------
 181 # Enable debug
 182 # -----------------------------------------------------------
 183
 184 AC_ARG_ENABLE(debug,
 185   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 186     enable_debug=$enableval, enable_debug=yes )
 187
 188 if test x$enable_debug = xyes; then
 189   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 190 fi
 191
 192 # -----------------------------------------------------------
 193 # Language Support
 194 # -----------------------------------------------------------
 195
 196 GETTEXT_PACKAGE=empathy
 197 AC_SUBST(GETTEXT_PACKAGE)
 198 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 199
 200 AM_GLIB_GNU_GETTEXT
 201
 202 # -----------------------------------------------------------
 203 # Make CA certificates path configurable
 204 # Stolen from GIO's TLS
 205 # -----------------------------------------------------------
 206 AC_MSG_CHECKING([location of system Certificate Authority list])
 207 AC_ARG_WITH(ca-file,
 208             [AC_HELP_STRING([--with-ca-file=@<:@path@:>@],
 209                             [path to system Certificate Authority list])])
 210 if test "$with_ca_file" = "no"; then
 211     AC_MSG_RESULT([disabled])
 212 else
 213     if test -z "$with_ca_file"; then
 214         for f in /etc/pki/tls/certs/ca-bundle.crt \
 215                  /etc/ssl/certs/ca-certificates.crt; do
 216             if test -f "$f"; then
 217                 with_ca_file="$f"
 218             fi
 219         done
 220         if test -z "$with_ca_file"; then
 221             AC_MSG_ERROR([could not find. Use --with-ca-file=path to set, or --without-ca-file to disable])
 222         fi
 223     fi
 224
 225     AC_MSG_RESULT($with_ca_file)
 226     if ! test -f "$with_ca_file"; then
 227         AC_MSG_ERROR([No such file '$with_ca_file'. Use --with-ca-file=path to set, or --without-ca-file to disable])
 228     fi
 229     GTLS_SYSTEM_CA_FILE="$with_ca_file"
 230
 231     AC_DEFINE_UNQUOTED([GTLS_SYSTEM_CA_FILE], ["$GTLS_SYSTEM_CA_FILE"], [path to system Certificate Authority list])
 232 fi
 233
 234 # -----------------------------------------------------------
 235 # Connectivity integration
 236 # -----------------------------------------------------------
 237 AC_ARG_WITH(connectivity,
 238               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 239                              [build with connectivity support]), ,
 240                              with_connectivity=auto)
 241
 242 if test "x$with_connectivity" = "xno"; then
 243    have_nm=no
 244    have_connman=no
 245
 246 elif test "x$with_connectivity" = "xconnman"; then
 247    have_nm=no
 248
 249    PKG_CHECK_MODULES(CONNMAN,
 250    [
 251       dbus-glib-1
 252    ], have_connman="yes", have_connman="no")
 253
 254    if test "x$have_connman" = "xyes"; then
 255       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 256    fi
 257
 258 else
 259    have_connman=no
 260
 261    PKG_CHECK_MODULES(NETWORK_MANAGER,
 262    [
 263       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 264    ], have_nm="yes", have_nm="no")
 265
 266    if test "x$have_nm" = "xyes"; then
 267       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 268    fi
 269 fi
 270
 271 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 272    AC_MSG_ERROR([Couldn't find connman dependencies.])
 273 fi
 274
 275 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 276    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 277 fi
 278
 279 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 280 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 281
 282 # -----------------------------------------------------------
 283 # Webkit
 284 # -----------------------------------------------------------
 285 AC_ARG_ENABLE(webkit,
 286               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 287                              [build with webkit support]), ,
 288                              enable_webkit=auto)
 289
 290 if test "x$enable_webkit" != "xno"; then
 291    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 292         have_webkit="yes", have_webkit="no")
 293
 294    if test "x$have_webkit" = "xyes"; then
 295       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 296    fi
 297 else
 298    have_webkit=no
 299 fi
 300
 301 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 302    AC_MSG_ERROR([Could not find webkit dependencies.])
 303 fi
 304 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 305
 306 # -----------------------------------------------------------
 307 # spellchecking checks: enchant and iso-codes
 308 # -----------------------------------------------------------
 309 AC_ARG_ENABLE(spell,
 310               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 311                              [Enable spell checking]), ,
 312                              enable_spell=auto)
 313
 314 if test "x$enable_spell" != "xno"; then
 315    PKG_CHECK_MODULES(ENCHANT,
 316    [
 317       enchant >= $ENCHANT_REQUIRED,
 318       iso-codes >= $ISO_CODES_REQUIRED
 319    ], have_enchant="yes", have_enchant="no")
 320
 321    if test "x$have_enchant" = "xyes"; then
 322       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 323       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 324          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 325             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 326             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 327             result=yes
 328       else
 329             result=no
 330             have_enchant="no"
 331       fi
 332       AC_MSG_RESULT([$result])
 333    fi
 334 else
 335    have_enchant=no
 336 fi
 337
 338 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 339    AC_MSG_ERROR([Could not find spell dependencies.])
 340 fi
 341
 342 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 343
 344 # -----------------------------------------------------------
 345 # Map view checks: libchamplain
 346 # -----------------------------------------------------------
 347 AC_ARG_ENABLE(map,
 348               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 349                              [Enable map view]), ,
 350                              enable_map=auto)
 351
 352 if test "x$enable_map" != "xno"; then
 353
 354    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 355     [
 356        champlain-0.8 >= $LIBCHAMPLAIN_REQUIRED,
 357 # champplain-gtk3 doesn't exist. Fix the name once bgo #631009
 358        champlain-gtk3-0.8 >= $LIBCHAMPLAIN_GTK_REQUIRED
 359        clutter-gtk >= $CLUTTER_GTK_REQUIRED
 360     ], have_libchamplain="yes", have_libchamplain="no")
 361
 362    if test "x$have_libchamplain" = "xyes"; then
 363       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 364    fi
 365 else
 366    have_libchamplain=no
 367 fi
 368
 369 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 370    AC_MSG_ERROR([Could not find map view dependencies.])
 371 fi
 372
 373 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 374
 375 # -----------------------------------------------------------
 376 # location checks: geoclue
 377 # -----------------------------------------------------------
 378 AC_ARG_ENABLE(location,
 379               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 380                              [Enable location awareness]), ,
 381                              enable_location=auto)
 382
 383 if test "x$enable_location" != "xno"; then
 384    PKG_CHECK_MODULES(GEOCLUE,
 385    [
 386       geoclue >= $GEOCLUE_REQUIRED
 387    ], have_geoclue="yes", have_geoclue="no")
 388
 389    if test "x$have_geoclue" = "xyes"; then
 390       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 391    fi
 392 else
 393    have_geoclue="no"
 394 fi
 395
 396 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 397    AC_MSG_ERROR([Could not find location dependencies.])
 398 fi
 399
 400 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 401 AC_SUBST(GEOCLUE_CFLAGS)
 402 AC_SUBST(GEOCLUE_LIBS)
 403
 404 # -----------------------------------------------------------
 405 # meego widgets support
 406 # -----------------------------------------------------------
 407 AC_ARG_ENABLE(meego,
 408               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 409                              [Enable meego widgets]), ,
 410                              enable_meego=no)
 411
 412 if test "x$enable_meego" != "xno"; then
 413     PKG_CHECK_MODULES(MEEGO,
 414     [
 415        mx-gtk-1.0
 416        gio-unix-2.0
 417     ], have_meego="yes", have_meego="no")
 418
 419     if test "x$have_meego" = "xyes"; then
 420        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 421     fi
 422 else
 423    have_meego="no"
 424 fi
 425
 426 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 427    AC_MSG_ERROR([Could not find meego dependencies.])
 428 fi
 429
 430 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 431 AC_SUBST(MEEGO_CFLAGS)
 432 AC_SUBST(MEEGO_LIBS)
 433
 434 # -----------------------------------------------------------
 435 # nautilus-sendto
 436 # -----------------------------------------------------------
 437 AC_ARG_ENABLE(nautilus-sendto,
 438               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 439                              [build nautilus-sendto plugin]), ,
 440                              enable_nautilus_sendto=auto)
 441
 442 if test "x$enable_nautilus_sendto" != "xno"; then
 443    PKG_CHECK_MODULES(NST,
 444     [
 445        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 446     ], have_nst="yes", have_nst="no")
 447 else
 448    have_nst=no
 449 fi
 450
 451 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 452    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 453 fi
 454
 455 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 456
 457 # -----------------------------------------------------------
 458 # new, single-window control center
 459 # -----------------------------------------------------------
 460 AC_ARG_ENABLE(control_center_embedding,
 461               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 462                              [Enable support for single-window control center]),
 463                              , enable_control_center_embedding=auto)
 464
 465 if test "x$enable_control_center_embedding" != "xno"; then
 466
 467    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 468         have_control_center_embedding="yes", have_control_center_embedding="no")
 469
 470    if test "x$have_control_center_embedding" = "xyes"; then
 471       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 472
 473       AC_MSG_CHECKING([gnome-control-center extension dir])
 474       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 475       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 476           AC_MSG_ERROR([Could not determine extensiondir])
 477       else
 478           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 479       fi
 480       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 481    fi
 482 else
 483    have_control_center_embedding="no"
 484 fi
 485
 486 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 487    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 488 fi
 489
 490 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 491 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 492 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 493
 494 # -----------------------------------------------------------
 495 # Coding style checks
 496 # -----------------------------------------------------------
 497 AC_ARG_ENABLE(coding-style-checks,
 498   AC_HELP_STRING([--disable-coding-style-checks],
 499                  [do not check coding style using grep]),
 500     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 501
 502 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 503 # -----------------------------------------------------------
 504
 505 AC_OUTPUT([
 506    Makefile
 507    data/Makefile
 508    data/empathy.desktop.in
 509    data/empathy-accounts.desktop.in
 510    data/icons/Makefile
 511    extensions/Makefile
 512    po/Makefile.in
 513    libempathy/Makefile
 514    libempathy-gtk/Makefile
 515    src/Makefile
 516    nautilus-sendto-plugin/Makefile
 517    help/Makefile
 518    tests/Makefile
 519    tests/interactive/Makefile
 520    tests/xml/Makefile
 521    tools/Makefile
 522 ])
 523
 524 echo "
 525 Configure summary:
 526
 527         Compiler....................:  ${CC}
 528         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 529         Prefix......................:  ${prefix}
 530         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 531         CA Cert Path................:  ${GTLS_SYSTEM_CA_FILE}
 532
 533     Features:
 534         Spell checking (enchant)....:  ${have_enchant}
 535         Display maps (libchamplain).:  ${have_libchamplain}
 536         Location awareness (Geoclue):  ${have_geoclue}
 537         Adium themes (Webkit).......:  ${have_webkit}
 538         Meego widgets ..............:  ${have_meego}
 539         Control center embedding....:  ${have_control_center_embedding}
 540
 541     Connectivity:
 542         NetworkManager integration..:  ${have_nm}
 543         ConnMan integration.........:  ${have_connman}
 544
 545     Extras:
 546         Nautilus-sendto plugin......:  ${have_nst}
 547         Salut E-D-S support.........:  ${with_eds}
 548 "