configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [5])
   6 m4_define([empathy_micro_version], [91])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.7.1
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.19.6
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58
  59 GSTREAMER_REQUIRED=0.10.32
  60 LIBSECRET_REQUIRED=0.5
  61 GCR_REQUIRED=2.91.4
  62 LIBCANBERRA_GTK_REQUIRED=0.25
  63 LIBNOTIFY_REQUIRED=0.7.0
  64 TELEPATHY_LOGGER=0.2.13
  65 WEBKIT_REQUIRED=1.3.13
  66 GOA_REQUIRED=3.5.1
  67
  68 # Optional deps
  69 ENCHANT_REQUIRED=1.2.0
  70 GEOCLUE_REQUIRED=0.12
  71 ISO_CODES_REQUIRED=0.35
  72 NAUTILUS_SENDTO_REQUIRED=2.90.0
  73 NETWORK_MANAGER_REQUIRED=0.7.0
  74 CHAMPLAIN_REQUIRED=0.12.1
  75 CHEESE_GTK_REQUIRED=3.4.0
  76 LIBACCOUNTS_REQUIRED=1.1
  77 LIBSIGNON_REQUIRED=1.1
  78 MC_PLUGINS_REQUIRED=5.13.0
  79
  80 # Use --enable-maintainer-mode to disable deprecated symbols,
  81 # disable single include and enable GSEAL. If this is not a released empathy,
  82 # maintainer mode is forced
  83 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  84 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  85 #GNOME_MAINTAINER_MODE_DEFINES
  86
  87 # egg-list-box
  88 prev_top_build_prefix=$ac_top_build_prefix
  89 prev_ac_configure_args=$ac_configure_args
  90 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
  91 ac_top_build_prefix=$prev_top_build_prefix
  92 ac_configure_args=$prev_ac_configure_args
  93
  94 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
  95 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
  96
  97 AC_CONFIG_MACRO_DIR([m4])
  98 AC_CONFIG_HEADERS([config.h])
  99 AC_CONFIG_SRCDIR([configure.ac])
 100 AC_CONFIG_AUX_DIR(.)
 101
 102 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 103
 104 # Support silent build rules. Disable
 105 # by either passing --disable-silent-rules to configure or passing V=1
 106 # to make
 107 AM_SILENT_RULES([yes])
 108
 109 # Check for programs
 110 AC_PROG_CC
 111 AC_HEADER_STDC
 112 AM_PROG_MKDIR_P
 113 AM_PATH_GLIB_2_0
 114 AC_PATH_XTRA
 115
 116 # Initialize libtool
 117 LT_PREREQ([2.2])
 118 LT_INIT
 119
 120 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 121 GLIB_GSETTINGS
 122 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 123 AC_SUBST(GLIB_GENMARSHAL)
 124
 125 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 126 if test -z "$XSLTPROC"; then
 127   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 128 fi
 129 AM_PATH_PYTHON([2.3])
 130
 131 EMPATHY_ARG_VALGRIND
 132
 133
 134 # -----------------------------------------------------------
 135 # Error flags
 136 # -----------------------------------------------------------
 137 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 138 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 139
 140 AC_ARG_ENABLE(Werror,
 141   AS_HELP_STRING([--disable-Werror],
 142                  [compile without -Werror (normally enabled in development builds)]),
 143     werror=$enableval, :)
 144
 145 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 146 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 147         wno_missing_field_initializers=yes,
 148         wno_missing_field_initializers=no)
 149 AS_COMPILER_FLAG(-Wno-unused-parameter,
 150         wno_unused_parameter=yes,
 151         wno_unused_parameter=no)
 152
 153 ifelse(empathy_released, 1, [],
 154     [
 155         if test x$werror = xyes; then
 156             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 157         fi
 158         if test x$wextra = xyes -a \
 159             x$wno_missing_field_initializers = xyes -a \
 160             x$wno_unused_parameter = xyes; then
 161             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 162         fi
 163     ])
 164
 165 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 166 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 167 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 168 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 169 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 170
 171 AC_SUBST(ERROR_CFLAGS)
 172
 173 AC_ARG_ENABLE(gprof,
 174             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 175             [build with support for gprof]),,
 176             [enable_gprof=no])
 177 if test "x$enable_gprof" != "xno" ; then
 178     CFLAGS="$CFLAGS -pg"
 179     LDFLAGS="$LDFLAGS -pg"
 180 fi
 181
 182 AC_SUBST(LDFLAGS)
 183
 184 # -----------------------------------------------------------
 185 # Pkg-Config dependency checks
 186 # -----------------------------------------------------------
 187
 188 AC_CHECK_LIBM
 189 AC_SUBST(LIBM)
 190
 191 PKG_CHECK_MODULES(EMPATHY,
 192 [
 193    dbus-glib-1
 194    folks >= $FOLKS_REQUIRED
 195    folks-telepathy >= $FOLKS_REQUIRED
 196    glib-2.0 >= $GLIB_REQUIRED
 197    gio-2.0 >= $GLIB_REQUIRED
 198    gio-unix-2.0 >= $GLIB_REQUIRED
 199    libsecret-1 >= $LIBSECRET_REQUIRED
 200    gnutls >= $GNUTLS_REQUIRED
 201    gmodule-export-2.0
 202    gobject-2.0
 203    gsettings-desktop-schemas
 204    libxml-2.0
 205    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 206    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 207    x11
 208    gtk+-3.0 >= $GTK_REQUIRED
 209    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 210    libnotify >= $LIBNOTIFY_REQUIRED
 211    gcr-3 >= $GCR_REQUIRED
 212    libpulse
 213    libpulse-mainloop-glib
 214    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 215    libsoup-2.4
 216    gee-1.0
 217 ])
 218
 219 # -----------------------------------------------------------
 220 # GStreamer
 221 # -----------------------------------------------------------
 222 AC_ARG_ENABLE(gst-1.0,
 223               AS_HELP_STRING([--enable-gst-1.0=@<:@no/yes/auto@:>@],
 224                              [build with GStreamer 1.0]),
 225                              enable_gst1=$enableval,
 226                              enable_gst1=auto)
 227
 228 # Try to use GStreamer 1.à if available
 229 have_gst1="no"
 230 if test "x$enable_gst1" != "xno"; then
 231   PKG_CHECK_MODULES(EMPATHY_CALL,
 232   [
 233      farstream-0.2
 234      telepathy-farstream >= 0.4.999
 235      clutter-1.0 >= $CLUTTER_REQUIRED
 236      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 237      clutter-gst-2.0
 238   ], have_gst1="yes", have_gst1="no")
 239
 240   if test "x$have_gst1" = "xyes"; then
 241     AC_DEFINE(HAVE_GST1, 1, [Build with GStreamer 1.0])
 242   fi
 243 fi
 244
 245 if test "x$enable_gst1" = "xyes" -a "x$have_gst1" != "xyes"; then
 246    AC_MSG_ERROR([Could not find GStreamer 1.0 dependencies:
 247
 248 $EMPATHY_CALL_PKG_ERRORS])
 249 fi
 250
 251 if test "x$have_gst1" != "xyes"; then
 252   PKG_CHECK_MODULES(EMPATHY_CALL,
 253   [
 254      farstream-0.1
 255      telepathy-farstream >= 0.2.1
 256      clutter-1.0 >= $CLUTTER_REQUIRED
 257      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 258      clutter-gst-1.0 >= 1.5.2
 259      gstreamer-0.10 >= $GSTREAMER_REQUIRED
 260      gstreamer-interfaces-0.10
 261   ])
 262 fi
 263
 264 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 265    [Name of provider for accounts imported from GOA])
 266
 267 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 268     "im.telepathy.Account.Storage.UOA",
 269    [Name of provider for accounts imported from libaccounts])
 270
 271 # -----------------------------------------------------------
 272 # Enable debug
 273 # -----------------------------------------------------------
 274
 275 AC_ARG_ENABLE(debug,
 276   AS_HELP_STRING([--disable-debug],
 277                  [compile without debug code]),
 278     enable_debug=$enableval, enable_debug=yes )
 279
 280 if test x$enable_debug = xyes; then
 281   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 282 fi
 283
 284 # -----------------------------------------------------------
 285 # Language Support
 286 # -----------------------------------------------------------
 287 IT_PROG_INTLTOOL([0.50.0])
 288
 289 GETTEXT_PACKAGE=empathy
 290 AC_SUBST(GETTEXT_PACKAGE)
 291 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 292
 293 # -----------------------------------------------------------
 294 # gudev
 295 # -----------------------------------------------------------
 296 AC_ARG_ENABLE(gudev,
 297               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 298                              [build with gudev support]), ,
 299                              enable_gudev=auto)
 300
 301 if test "x$enable_gudev" != "xno"; then
 302
 303    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 304         have_gudev="yes", have_gudev="no")
 305
 306    if test "x$have_gudev" = "xyes"; then
 307       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 308    fi
 309 else
 310    have_gudev=no
 311 fi
 312
 313 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 314    AC_MSG_ERROR([Could not find gudev dependencies:
 315
 316 $UDEV_PKG_ERRORS])
 317 fi
 318 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 319
 320 # -----------------------------------------------------------
 321 # spellchecking checks: enchant and iso-codes
 322 # -----------------------------------------------------------
 323 AC_ARG_ENABLE(spell,
 324               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 325                              [Enable spell checking]), ,
 326                              enable_spell=auto)
 327
 328 if test "x$enable_spell" != "xno"; then
 329    PKG_CHECK_MODULES(ENCHANT,
 330    [
 331       enchant >= $ENCHANT_REQUIRED,
 332       iso-codes >= $ISO_CODES_REQUIRED
 333    ], have_enchant="yes", have_enchant="no")
 334
 335    if test "x$have_enchant" = "xyes"; then
 336       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 337       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 338          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 339             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 340             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 341             result=yes
 342       else
 343             result=no
 344             have_enchant="no"
 345       fi
 346       AC_MSG_RESULT([$result])
 347    fi
 348 else
 349    have_enchant=no
 350 fi
 351
 352 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 353    AC_MSG_ERROR([Could not find spell-checking dependencies:
 354
 355 $ENCHANT_PKG_ERRORS])
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 359
 360 # -----------------------------------------------------------
 361 # Map view checks: libchamplain
 362 # -----------------------------------------------------------
 363 AC_ARG_ENABLE(map,
 364               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 365                              [Enable map view]), ,
 366                              enable_map=auto)
 367
 368 if test "x$enable_map" != "xno"; then
 369
 370    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 371     [
 372        clutter-gtk-1.0
 373        champlain-gtk-0.12
 374        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 375     ], have_libchamplain="yes", have_libchamplain="no")
 376
 377    if test "x$have_libchamplain" = "xyes"; then
 378       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 379    fi
 380 else
 381    have_libchamplain=no
 382 fi
 383
 384 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 385    AC_MSG_ERROR([Could not find map view dependencies:
 386
 387 $LIBCHAMPLAIN_PKG_ERRORS])
 388 fi
 389
 390 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 391
 392 # -----------------------------------------------------------
 393 # location checks: geoclue
 394 # -----------------------------------------------------------
 395 AC_ARG_ENABLE(location,
 396               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 397                              [Enable location awareness]), ,
 398                              enable_location=auto)
 399
 400 if test "x$enable_location" != "xno"; then
 401    PKG_CHECK_MODULES(GEOCLUE,
 402    [
 403       geoclue >= $GEOCLUE_REQUIRED
 404    ], have_geoclue="yes", have_geoclue="no")
 405
 406    if test "x$have_geoclue" = "xyes"; then
 407       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 408    fi
 409 else
 410    have_geoclue="no"
 411 fi
 412
 413 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 414    AC_MSG_ERROR([Could not find location dependencies:
 415
 416 $GEOCLUE_PKG_ERRORS])
 417 fi
 418
 419 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 420 AC_SUBST(GEOCLUE_CFLAGS)
 421 AC_SUBST(GEOCLUE_LIBS)
 422
 423 # -----------------------------------------------------------
 424 # location checks: geocode-glib
 425 # -----------------------------------------------------------
 426 AC_ARG_ENABLE(geocode,
 427               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 428                              [Enable geocode support]), ,
 429                              enable_geocode=auto)
 430
 431 if test "x$enable_geocode" != "xno"; then
 432    PKG_CHECK_MODULES(GEOCODE,
 433    [
 434       geocode-glib
 435    ], have_geocode="yes", have_geocode="no")
 436
 437    if test "x$have_geocode" = "xyes"; then
 438       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 439    fi
 440 else
 441    have_geocode="no"
 442 fi
 443
 444 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 445    AC_MSG_ERROR([Could not find geocode dependencies:
 446
 447 $GEOCODE_PKG_ERRORS])
 448 fi
 449
 450 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 451 AC_SUBST(GEOCODE_CFLAGS)
 452 AC_SUBST(GEOCODE_LIBS)
 453
 454 # -----------------------------------------------------------
 455 # nautilus-sendto
 456 # -----------------------------------------------------------
 457 AC_ARG_ENABLE(nautilus-sendto,
 458               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 459                              [build nautilus-sendto plugin]), ,
 460                              enable_nautilus_sendto=auto)
 461
 462 if test "x$enable_nautilus_sendto" != "xno"; then
 463    PKG_CHECK_MODULES(NST,
 464     [
 465        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 466     ], have_nst="yes", have_nst="no")
 467 else
 468    have_nst=no
 469 fi
 470
 471 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 472    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 473
 474 $NST_PKG_ERRORS])
 475 fi
 476
 477 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 478
 479 # -----------------------------------------------------------
 480 # goa-mc-plugin
 481 # -----------------------------------------------------------
 482 AC_ARG_ENABLE(goa,
 483               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 484                              [build GOA MC plugin]), ,
 485                              enable_goa=auto)
 486
 487 if test "x$enable_goa" != "xno"; then
 488    PKG_CHECK_MODULES(GOA,
 489     [
 490        mission-control-plugins
 491        goa-1.0 >= $GOA_REQUIRED
 492     ], have_goa="yes", have_goa="no")
 493 else
 494    have_goa=no
 495 fi
 496
 497 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 498    AC_MSG_ERROR([Could not find GOA dependencies:
 499
 500 $GOA_PKG_ERRORS])
 501 fi
 502
 503 if test "x$have_goa" = "xyes"; then
 504    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 505 fi
 506
 507 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 508
 509 # Optional dependency for avatar selection
 510 AC_ARG_WITH([cheese],
 511             AS_HELP_STRING([--with-cheese],
 512                            [enable cheese webcam support]),,
 513             with_cheese=auto)
 514
 515 if test x"$with_cheese" != x"no" ; then
 516    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 517    if test x${have_cheese} = xyes; then
 518      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 519    fi
 520    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 521      AC_MSG_ERROR([Cheese configured but not found:
 522
 523 $CHEESE_PKG_ERRORS])
 524    fi
 525 else
 526    have_cheese=no
 527 fi
 528 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 529
 530 # -----------------------------------------------------------
 531 # ubuntu-online-accounts support
 532 # -----------------------------------------------------------
 533 AC_ARG_ENABLE(ubuntu-online-accounts,
 534               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 535                              [build Ubuntu Online Accounts plugins]), ,
 536                              enable_ubuntu_online_accounts=auto)
 537
 538 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 539    PKG_CHECK_MODULES(UOA,
 540     [
 541        account-plugin
 542        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 543        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 544        libsignon-glib >= $LIBSIGNON_REQUIRED
 545     ], have_uoa="yes", have_uoa="no")
 546
 547    # provider plugin dir
 548    AC_MSG_CHECKING([Accounts provider plugin dir])
 549    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 550
 551    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 552    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 553
 554    # app plugin dir
 555    AC_MSG_CHECKING([Accounts provider app plugin dir])
 556    ACCOUNTS_APP_PLUGIN_DIR=`pkg-config --variable=application_plugindir account-plugin`
 557
 558    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 559    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 560
 561    # provider files dir
 562    AC_MSG_CHECKING([Accounts provider files dir])
 563    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 564
 565    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 566    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 567
 568    # service files dir
 569    AC_MSG_CHECKING([Accounts service files dir])
 570    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 571
 572    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 573    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 574
 575    # application files dir
 576    AC_MSG_CHECKING([Accounts applications files dir])
 577    ACCOUNTS_APPLICATION_FILES_DIR=`pkg-config --variable=applicationfilesdir libaccounts-glib`
 578
 579    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 580    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 581
 582 else
 583    have_uoa=no
 584 fi
 585
 586 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 587    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 588
 589 $UOA_PKG_ERRORS])
 590 fi
 591
 592 if test "x$have_uoa" = "xyes"; then
 593    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 594 fi
 595
 596 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 597
 598 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 599    AC_MSG_CHECKING([Mission Control plugins dir])
 600    MISSION_CONTROL_PLUGINS_DIR=${libdir}/mission-control-plugins.`pkg-config --variable=MCP_ABI_VERSION mission-control-plugins`
 601
 602    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 603    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 604 fi
 605
 606
 607 # Help documentation
 608 YELP_HELP_INIT
 609
 610 # -----------------------------------------------------------
 611 # Coding style checks
 612 # -----------------------------------------------------------
 613 AC_ARG_ENABLE(coding-style-checks,
 614   AS_HELP_STRING([--disable-coding-style-checks],
 615                  [do not check coding style using grep]),
 616     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 617     [ENABLE_CODING_STYLE_CHECKS=yes])
 618
 619 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 620 # -----------------------------------------------------------
 621
 622 AC_CONFIG_FILES([
 623    Makefile
 624    data/Makefile
 625    data/empathy.desktop.in
 626    data/icons/Makefile
 627    data/themes/Makefile
 628    extensions/Makefile
 629    po/Makefile.in
 630    libempathy/Makefile
 631    libempathy-gtk/Makefile
 632    src/Makefile
 633    nautilus-sendto-plugin/Makefile
 634    goa-mc-plugin/Makefile
 635    ubuntu-online-accounts/Makefile
 636    ubuntu-online-accounts/mc-plugin/Makefile
 637    ubuntu-online-accounts/cc-plugins/Makefile
 638    ubuntu-online-accounts/cc-plugins/providers/Makefile
 639    ubuntu-online-accounts/cc-plugins/services/Makefile
 640    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 641    help/Makefile
 642    tests/Makefile
 643    tests/interactive/Makefile
 644    tests/xml/Makefile
 645    tests/certificates/Makefile
 646    tools/Makefile
 647 ])
 648 AC_OUTPUT
 649
 650 echo "
 651 Configure summary:
 652
 653         Compiler....................:  ${CC}
 654         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 655         Linker Flags................:  ${LDFLAGS}
 656         Prefix......................:  ${prefix}
 657         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 658         Use GStreamer 1.0...........:  ${have_gst1}
 659
 660     Features:
 661         Spell checking (enchant)....:  ${have_enchant}
 662         Display maps (libchamplain).:  ${have_libchamplain}
 663         Location awareness (Geoclue):  ${have_geoclue}
 664         Geocode support (Geocode)...:  ${have_geocode}
 665         Cheese webcam support ......:  ${have_cheese}
 666         Camera monitoring...........:  ${have_gudev}
 667
 668     Extras:
 669         Nautilus-sendto plugin......:  ${have_nst}
 670         GOA MC plugin...............:  ${have_goa}
 671         Ubuntu Online plugins.......:  ${have_uoa}
 672 "