configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 TELEPATHY_GLIB_REQUIRED=0.11.7
  41 TELEPATHY_LOGGER=0.1.2
  42 UNIQUE_REQUIRED=1.1.2
  43
  44 # Optionnal deps
  45 CLUTTER_GTK_REQUIRED=0.10
  46 ENCHANT_REQUIRED=1.2.0
  47 GEOCLUE_REQUIRED=0.11
  48 ISO_CODES_REQUIRED=0.35
  49 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  50 LIBCHAMPLAIN_REQUIRED=0.4
  51 NAUTILUS_SENDTO_REQUIRED=2.28.1
  52 NETWORK_MANAGER_REQUIRED=0.7.0
  53 WEBKIT_REQUIRED=1.1.15
  54
  55 # Use --enable-maintainer-mode to disable deprecated symbols,
  56 # disable single include and enable GSEAL. If this is not a released empathy,
  57 # maintainer mode is forced
  58 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  59 GNOME_MAINTAINER_MODE_DEFINES
  60 if test $USE_MAINTAINER_MODE = yes; then
  61   AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
  62 fi
  63
  64 AC_CONFIG_MACRO_DIR([m4])
  65 AC_CONFIG_HEADERS([config.h])
  66 AC_CONFIG_SRCDIR([configure.ac])
  67 AC_CONFIG_AUX_DIR(.)
  68
  69 GNOME_COMMON_INIT
  70
  71 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  72
  73 # Support silent build rules, requires at least automake-1.11. Disable
  74 # by either passing --disable-silent-rules to configure or passing V=1
  75 # to make
  76 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  77
  78 AC_ISC_POSIX
  79 AC_PROG_CC
  80 AC_HEADER_STDC
  81 AM_PROG_LIBTOOL
  82 AM_PROG_MKDIR_P
  83 AM_PATH_GLIB_2_0
  84 AC_PATH_XTRA
  85 IT_PROG_INTLTOOL([0.35.0])
  86 GNOME_DOC_INIT([0.17.3])
  87 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  88 GLIB_GSETTINGS
  89 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  90 AC_SUBST(GLIB_GENMARSHAL)
  91 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  92 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  93
  94 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  95 if test -z "$XSLTPROC"; then
  96   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  97 fi
  98 AM_PATH_PYTHON([2.3])
  99
 100 EMPATHY_ARG_VALGRIND
 101
 102
 103 # -----------------------------------------------------------
 104 # Error flags
 105 # -----------------------------------------------------------
 106 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 107 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 108
 109 AC_ARG_ENABLE(Werror,
 110   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 111     werror=$enableval, :)
 112
 113 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 114 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 115         wno_missing_field_initializers=yes,
 116         wno_missing_field_initializers=no)
 117 AS_COMPILER_FLAG(-Wno-unused-parameter,
 118         wno_unused_parameter=yes,
 119         wno_unused_parameter=no)
 120
 121 ifelse(empathy_released, 1, [],
 122     [
 123         if test x$werror = xyes; then
 124             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 125         fi
 126         if test x$wextra = xyes -a \
 127             x$wno_missing_field_initializers = xyes -a \
 128             x$wno_unused_parameter = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 130         fi
 131     ])
 132
 133 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 134 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 135 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 136 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 137 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 138 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 139
 140 AC_SUBST(ERROR_CFLAGS)
 141
 142 # -----------------------------------------------------------
 143 # Pkg-Config dependency checks
 144 # -----------------------------------------------------------
 145
 146 PKG_CHECK_MODULES(EMPATHY,
 147 [
 148    dbus-glib-1
 149    farsight2-0.10
 150    gconf-2.0 >= $GCONF_REQUIRED
 151    gdk-x11-2.0
 152    gio-2.0 >= $GLIB_REQUIRED
 153    gio-unix-2.0 >= $GLIB_REQUIRED
 154    gnome-keyring-1 >= $KEYRING_REQUIRED
 155    gobject-2.0
 156    gstreamer-0.10
 157    gstreamer-interfaces-0.10
 158    gtk+-2.0 >= $GTK_REQUIRED
 159    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 160    libebook-1.2
 161    libxml-2.0
 162    telepathy-farsight
 163    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 164    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 165    unique-1.0 >= $UNIQUE_REQUIRED
 166    x11
 167 ])
 168
 169 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 170
 171 # -----------------------------------------------------------
 172 # Enable debug
 173 # -----------------------------------------------------------
 174
 175 AC_ARG_ENABLE(debug,
 176   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 177     enable_debug=$enableval, enable_debug=yes )
 178
 179 if test x$enable_debug = xyes; then
 180   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 181 fi
 182
 183 # -----------------------------------------------------------
 184 # Language Support
 185 # -----------------------------------------------------------
 186
 187 GETTEXT_PACKAGE=empathy
 188 AC_SUBST(GETTEXT_PACKAGE)
 189 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 190
 191 AM_GLIB_GNU_GETTEXT
 192
 193 # -----------------------------------------------------------
 194 # Connectivity integration
 195 # -----------------------------------------------------------
 196 AC_ARG_WITH(connectivity,
 197               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 198                              [build with connectivity support]), ,
 199                              with_connectivity=auto)
 200
 201 if test "x$with_connectivity" = "xno"; then
 202    have_nm=no
 203    have_connman=no
 204
 205 elif test "x$with_connectivity" = "xconnman"; then
 206
 207    PKG_CHECK_MODULES(CONNMAN,
 208    [
 209       dbus-glib-1
 210    ], have_connman="yes", have_connman="no")
 211
 212    if test "x$have_connman" = "xyes"; then
 213       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 214       have_nm=no
 215    fi
 216
 217 else
 218
 219    PKG_CHECK_MODULES(NETWORK_MANAGER,
 220    [
 221       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 222    ], have_nm="yes", have_nm="no")
 223
 224    if test "x$have_nm" = "xyes"; then
 225       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 226       have_connman=no
 227    else
 228       PKG_CHECK_MODULES(NETWORK_MANAGER,
 229       [
 230           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 231       ], have_nm="yes", have_nm="no")
 232
 233       if test "x$have_nm" = "xyes"; then
 234       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 235       have_connman=no
 236       fi
 237    fi
 238 fi
 239
 240 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 241    AC_MSG_ERROR([Couldn't find connman dependencies.])
 242 fi
 243
 244 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 245    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 246 fi
 247
 248 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 249 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 250
 251 # -----------------------------------------------------------
 252 # Webkit
 253 # -----------------------------------------------------------
 254 AC_ARG_ENABLE(webkit,
 255               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 256                              [build with webkit support]), ,
 257                              enable_webkit=auto)
 258
 259 if test "x$enable_webkit" != "xno"; then
 260    PKG_CHECK_MODULES(WEBKIT,
 261    [
 262       webkit-1.0 >= $WEBKIT_REQUIRED
 263    ], have_webkit="yes", have_webkit="no")
 264
 265    if test "x$have_webkit" = "xyes"; then
 266       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 267    fi
 268 else
 269    have_webkit=no
 270 fi
 271
 272 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 273    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 274 fi
 275 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 276
 277 # -----------------------------------------------------------
 278 # spellchecking checks: enchant and iso-codes
 279 # -----------------------------------------------------------
 280 AC_ARG_ENABLE(spell,
 281               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 282                              [Enable spell checking]), ,
 283                              enable_spell=auto)
 284
 285 if test "x$enable_spell" != "xno"; then
 286    PKG_CHECK_MODULES(ENCHANT,
 287    [
 288       enchant >= $ENCHANT_REQUIRED,
 289       iso-codes >= $ISO_CODES_REQUIRED
 290    ], have_enchant="yes", have_enchant="no")
 291
 292    if test "x$have_enchant" = "xyes"; then
 293       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 294       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 295          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 296             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 297             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 298             result=yes
 299       else
 300             result=no
 301             have_enchant="no"
 302       fi
 303       AC_MSG_RESULT([$result])
 304    fi
 305 else
 306    have_enchant=no
 307 fi
 308
 309 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 310    AC_MSG_ERROR([Couldn't find spell dependencies.])
 311 fi
 312
 313 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 314
 315 # -----------------------------------------------------------
 316 # Map view checks: libchamplain
 317 # -----------------------------------------------------------
 318 AC_ARG_ENABLE(map,
 319               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 320                              [Enable map view]), ,
 321                              enable_map=auto)
 322
 323 if test "x$enable_map" != "xno"; then
 324    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 325    [
 326       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 327       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 328       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 329    ], have_libchamplain="yes", have_libchamplain="no")
 330
 331    if test "x$have_libchamplain" = "xyes"; then
 332       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 333    fi
 334 else
 335    have_libchamplain=no
 336 fi
 337
 338 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 339    AC_MSG_ERROR([Couldn't find map view dependencies.])
 340 fi
 341
 342 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 343
 344 # -----------------------------------------------------------
 345 # location checks: geoclue
 346 # -----------------------------------------------------------
 347 AC_ARG_ENABLE(location,
 348               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 349                              [Enable location awareness]), ,
 350                              enable_location=auto)
 351
 352 if test "x$enable_location" != "xno"; then
 353    PKG_CHECK_MODULES(GEOCLUE,
 354    [
 355       geoclue >= $GEOCLUE_REQUIRED
 356    ], have_geoclue="yes", have_geoclue="no")
 357
 358    if test "x$have_geoclue" = "xyes"; then
 359       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 360    fi
 361 else
 362    have_geoclue="no"
 363 fi
 364
 365 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 366    AC_MSG_ERROR([Couldn't find location dependencies.])
 367 fi
 368
 369 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 370 AC_SUBST(GEOCLUE_CFLAGS)
 371 AC_SUBST(GEOCLUE_LIBS)
 372
 373 # -----------------------------------------------------------
 374 # meego widgets support
 375 # -----------------------------------------------------------
 376 AC_ARG_ENABLE(meego,
 377               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 378                              [Enable meego widgets]), ,
 379                              enable_meego=no)
 380
 381 if test "x$enable_meego" != "xno"; then
 382     PKG_CHECK_MODULES(MEEGO,
 383     [
 384        mx-gtk-1.0
 385     ], have_meego="yes", have_meego="no")
 386
 387     if test "x$have_meego" = "xyes"; then
 388        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 389     fi
 390 else
 391    have_meego="no"
 392 fi
 393
 394 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 395    AC_MSG_ERROR([Couldn't find meego dependencies.])
 396 fi
 397
 398 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 399 AC_SUBST(MEEGO_CFLAGS)
 400 AC_SUBST(MEEGO_LIBS)
 401
 402 # -----------------------------------------------------------
 403 # nautilus-sendto
 404 # -----------------------------------------------------------
 405 AC_ARG_ENABLE(nautilus-sendto,
 406               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 407                              [build nautilus-sendto plugin]), ,
 408                              enable_nautilus_sendto=auto)
 409
 410 if test "x$enable_nautilus_sendto" != "xno"; then
 411    PKG_CHECK_MODULES(NST,
 412    [
 413       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 414    ], have_nst="yes", have_nst="no")
 415 else
 416    have_nst=no
 417 fi
 418
 419 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 420    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 421 fi
 422
 423 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 424
 425 # -----------------------------------------------------------
 426 # new, single-window control center
 427 # -----------------------------------------------------------
 428 AC_ARG_ENABLE(control_center_embedding,
 429               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 430                              [Enable support for single-window control center]),
 431                              , enable_control_center_embedding=auto)
 432
 433 if test "x$enable_control_center_embedding" != "xno"; then
 434    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 435    [
 436       libgnome-control-center-extension
 437    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 438
 439    if test "x$have_control_center_embedding" = "xyes"; then
 440       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 441    fi
 442 else
 443    have_control_center_embedding="no"
 444 fi
 445
 446 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 447    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 448 fi
 449
 450 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 451 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 452 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 453
 454 # -----------------------------------------------------------
 455 # Coding style checks
 456 # -----------------------------------------------------------
 457 AC_ARG_ENABLE(coding-style-checks,
 458   AC_HELP_STRING([--disable-coding-style-checks],
 459                  [don't check coding style using grep]),
 460     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 461
 462 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 463 # -----------------------------------------------------------
 464
 465 AC_OUTPUT([
 466    Makefile
 467    data/Makefile
 468    data/empathy.desktop.in
 469    data/empathy-accounts.desktop.in
 470    data/icons/Makefile
 471    extensions/Makefile
 472    po/Makefile.in
 473    libempathy/Makefile
 474    libempathy-gtk/Makefile
 475    src/Makefile
 476    nautilus-sendto-plugin/Makefile
 477    help/Makefile
 478    tests/Makefile
 479    tests/interactive/Makefile
 480    tests/xml/Makefile
 481    tools/Makefile
 482 ])
 483
 484 echo "
 485 Configure summary:
 486
 487         Compiler....................:  ${CC}
 488         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 489         Prefix......................:  ${prefix}
 490         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 491
 492     Features:
 493         Spell checking (enchant)....:  ${have_enchant}
 494         Display maps (libchamplain).:  ${have_libchamplain}
 495         Location awareness (Geoclue):  ${have_geoclue}
 496         Adium themes (Webkit).......:  ${have_webkit}
 497         Meego widgets ..............:  ${have_meego}
 498         Control center embedding....:  ${have_control_center_embedding}
 499
 500     Connectivity:
 501         NetworkManager integration..:  ${have_nm}
 502         ConnMan integration.........:  ${have_connman}
 503
 504     Extras:
 505         Nautilus-sendto plugin......:  ${have_nst}
 506 "