configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.15
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GNUTLS_REQUIRED=2.8.5
  38 GTK_REQUIRED=2.21.2
  39 KEYRING_REQUIRED=2.26.0
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBNOTIFY_REQUIRED=0.4.4
  42 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  43 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  44 TELEPATHY_GLIB_REQUIRED=0.11.13
  45 TELEPATHY_LOGGER=0.1.5
  46 UNIQUE_REQUIRED=1.1.2
  47
  48 # Optionnal deps
  49 CLUTTER_GTK_REQUIRED=0.10
  50 ENCHANT_REQUIRED=1.2.0
  51 GEOCLUE_REQUIRED=0.11
  52 ISO_CODES_REQUIRED=0.35
  53 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  54 LIBCHAMPLAIN_REQUIRED=0.7.1
  55 NAUTILUS_SENDTO_REQUIRED=2.31.7
  56 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  57 NETWORK_MANAGER_REQUIRED=0.7.0
  58 WEBKIT_REQUIRED=1.1.15
  59 GNOME_CONTROL_CENTER_GTK3_REQUIRED=2.31.4
  60
  61 # Use --enable-maintainer-mode to disable deprecated symbols,
  62 # disable single include and enable GSEAL. If this is not a released empathy,
  63 # maintainer mode is forced
  64 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  65 GNOME_MAINTAINER_MODE_DEFINES
  66
  67 AC_CONFIG_MACRO_DIR([m4])
  68 AC_CONFIG_HEADERS([config.h])
  69 AC_CONFIG_SRCDIR([configure.ac])
  70 AC_CONFIG_AUX_DIR(.)
  71
  72 GNOME_COMMON_INIT
  73
  74 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  75
  76 # Support silent build rules, requires at least automake-1.11. Disable
  77 # by either passing --disable-silent-rules to configure or passing V=1
  78 # to make
  79 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  80
  81 AC_ISC_POSIX
  82 AC_PROG_CC
  83 AC_HEADER_STDC
  84 AM_PROG_LIBTOOL
  85 AM_PROG_MKDIR_P
  86 AM_PATH_GLIB_2_0
  87 AC_PATH_XTRA
  88 IT_PROG_INTLTOOL([0.35.0])
  89 GNOME_DOC_INIT([0.17.3])
  90 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  91 GLIB_GSETTINGS
  92 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  93 AC_SUBST(GLIB_GENMARSHAL)
  94
  95 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  96 if test -z "$XSLTPROC"; then
  97   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  98 fi
  99 AM_PATH_PYTHON([2.3])
 100
 101 EMPATHY_ARG_VALGRIND
 102
 103
 104 # -----------------------------------------------------------
 105 # Error flags
 106 # -----------------------------------------------------------
 107 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 108 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 109
 110 AC_ARG_ENABLE(Werror,
 111   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 112     werror=$enableval, :)
 113
 114 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 115 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 116         wno_missing_field_initializers=yes,
 117         wno_missing_field_initializers=no)
 118 AS_COMPILER_FLAG(-Wno-unused-parameter,
 119         wno_unused_parameter=yes,
 120         wno_unused_parameter=no)
 121
 122 ifelse(empathy_released, 1, [],
 123     [
 124         if test x$werror = xyes; then
 125             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 126         fi
 127         if test x$wextra = xyes -a \
 128             x$wno_missing_field_initializers = xyes -a \
 129             x$wno_unused_parameter = xyes; then
 130             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 131         fi
 132     ])
 133
 134 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 135 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 136 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 137 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 138 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 139 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 140
 141 AC_SUBST(ERROR_CFLAGS)
 142
 143 # -----------------------------------------------------------
 144 # Pkg-Config dependency checks
 145 # -----------------------------------------------------------
 146
 147 PKG_CHECK_MODULES(EMPATHY,
 148 [
 149    dbus-glib-1
 150    farsight2-0.10
 151    folks >= $FOLKS_REQUIRED
 152    folks-telepathy >= $FOLKS_REQUIRED
 153    gconf-2.0 >= $GCONF_REQUIRED
 154    gio-2.0 >= $GLIB_REQUIRED
 155    gio-unix-2.0 >= $GLIB_REQUIRED
 156    gnome-keyring-1 >= $KEYRING_REQUIRED
 157    gnutls >= $GNUTLS_REQUIRED
 158    gmodule-export-2.0
 159    gobject-2.0
 160    gstreamer-0.10
 161    gstreamer-interfaces-0.10
 162    libxml-2.0
 163    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 164    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 165    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 166    x11
 167 ])
 168
 169 # -----------------------------------------------------------
 170 # evolution-data-server (about-me)
 171 # -----------------------------------------------------------
 172 AC_ARG_WITH(eds,
 173             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 174             [with_eds=yes])
 175 if test x"$with_eds" = x"yes" ; then
 176    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 177    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 178 fi
 179
 180 # -----------------------------------------------------------
 181 # GTK+
 182 # -----------------------------------------------------------
 183 AC_ARG_ENABLE(gtk3,
 184               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 185                              [build with GTK+3]), ,
 186                              enable_gtk3=auto)
 187
 188 # Try to use GTK+3 if available
 189 if test "x$enable_gtk3" != "xno"; then
 190    PKG_CHECK_MODULES(GTK,
 191    [
 192       gtk+-3.0 >= $GTK_REQUIRED
 193    ], have_gtk3="yes", have_gtk3="no")
 194 else
 195    have_gtk3="no"
 196 fi
 197
 198 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 199    AC_MSG_ERROR([Could not find gtk3 dependencies.])
 200 fi
 201
 202 if test "x$have_gtk3" == "xyes"; then
 203    # GTK3 specific deps
 204    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 205    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 206    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 207    # gcr-1 doesn't exist at the moment, and could even be named differently
 208    # once it exists, but checking for it makes sure configure abort, instead
 209    # of allowing to build an empathy binary linked to both GTK+ 2 and 3.
 210    PKG_CHECK_MODULES(GCR, gcr-1 >= $KEYRING_REQUIRED)
 211 else
 212    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 213
 214    # GTK2 specific deps
 215    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 216    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 217    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 218    PKG_CHECK_MODULES(GCR, gcr-0 >= $KEYRING_REQUIRED)
 219
 220    # Enable GSEAL checks if needed
 221    if test $USE_MAINTAINER_MODE = yes; then
 222       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 223    fi
 224 fi
 225
 226 # -----------------------------------------------------------
 227 # Enable debug
 228 # -----------------------------------------------------------
 229
 230 AC_ARG_ENABLE(debug,
 231   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 232     enable_debug=$enableval, enable_debug=yes )
 233
 234 if test x$enable_debug = xyes; then
 235   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 236 fi
 237
 238 # -----------------------------------------------------------
 239 # Language Support
 240 # -----------------------------------------------------------
 241
 242 GETTEXT_PACKAGE=empathy
 243 AC_SUBST(GETTEXT_PACKAGE)
 244 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 245
 246 AM_GLIB_GNU_GETTEXT
 247
 248 # -----------------------------------------------------------
 249 # Connectivity integration
 250 # -----------------------------------------------------------
 251 AC_ARG_WITH(connectivity,
 252               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 253                              [build with connectivity support]), ,
 254                              with_connectivity=auto)
 255
 256 if test "x$with_connectivity" = "xno"; then
 257    have_nm=no
 258    have_connman=no
 259
 260 elif test "x$with_connectivity" = "xconnman"; then
 261    have_nm=no
 262
 263    PKG_CHECK_MODULES(CONNMAN,
 264    [
 265       dbus-glib-1
 266    ], have_connman="yes", have_connman="no")
 267
 268    if test "x$have_connman" = "xyes"; then
 269       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 270    fi
 271
 272 else
 273    have_connman=no
 274
 275    PKG_CHECK_MODULES(NETWORK_MANAGER,
 276    [
 277       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 278    ], have_nm="yes", have_nm="no")
 279
 280    if test "x$have_nm" = "xyes"; then
 281       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 282    fi
 283 fi
 284
 285 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 286    AC_MSG_ERROR([Couldn't find connman dependencies.])
 287 fi
 288
 289 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 290    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 291 fi
 292
 293 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 294 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 295
 296 # -----------------------------------------------------------
 297 # Webkit
 298 # -----------------------------------------------------------
 299 AC_ARG_ENABLE(webkit,
 300               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 301                              [build with webkit support]), ,
 302                              enable_webkit=auto)
 303
 304 if test "x$enable_webkit" != "xno"; then
 305
 306    if test "x$have_gtk3" == "xno"; then
 307       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 308           have_webkit="yes", have_webkit="no")
 309    else
 310       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 311           have_webkit="yes", have_webkit="no")
 312    fi
 313
 314    if test "x$have_webkit" = "xyes"; then
 315       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 316    fi
 317 else
 318    have_webkit=no
 319 fi
 320
 321 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 322    AC_MSG_ERROR([Could not find webkit dependencies.])
 323 fi
 324 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 325
 326 # -----------------------------------------------------------
 327 # spellchecking checks: enchant and iso-codes
 328 # -----------------------------------------------------------
 329 AC_ARG_ENABLE(spell,
 330               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 331                              [Enable spell checking]), ,
 332                              enable_spell=auto)
 333
 334 if test "x$enable_spell" != "xno"; then
 335    PKG_CHECK_MODULES(ENCHANT,
 336    [
 337       enchant >= $ENCHANT_REQUIRED,
 338       iso-codes >= $ISO_CODES_REQUIRED
 339    ], have_enchant="yes", have_enchant="no")
 340
 341    if test "x$have_enchant" = "xyes"; then
 342       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 343       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 344          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 345             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 346             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 347             result=yes
 348       else
 349             result=no
 350             have_enchant="no"
 351       fi
 352       AC_MSG_RESULT([$result])
 353    fi
 354 else
 355    have_enchant=no
 356 fi
 357
 358 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 359    AC_MSG_ERROR([Could not find spell dependencies.])
 360 fi
 361
 362 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 363
 364 # -----------------------------------------------------------
 365 # Map view checks: libchamplain
 366 # -----------------------------------------------------------
 367 AC_ARG_ENABLE(map,
 368               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 369                              [Enable map view]), ,
 370                              enable_map=auto)
 371
 372 if test "x$enable_map" != "xno"; then
 373
 374    if test "x$have_gtk3" == "xno"; then
 375       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 376       [
 377          champlain-0.8 >= $LIBCHAMPLAIN_REQUIRED,
 378          champlain-gtk-0.8 >= $LIBCHAMPLAIN_GTK_REQUIRED
 379          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 380       ], have_libchamplain="yes", have_libchamplain="no")
 381    else
 382       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 383       have_libchamplain="no"
 384    fi
 385
 386    if test "x$have_libchamplain" = "xyes"; then
 387       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 388    fi
 389 else
 390    have_libchamplain=no
 391 fi
 392
 393 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 394    AC_MSG_ERROR([Could not find map view dependencies.])
 395 fi
 396
 397 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 398
 399 # -----------------------------------------------------------
 400 # location checks: geoclue
 401 # -----------------------------------------------------------
 402 AC_ARG_ENABLE(location,
 403               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 404                              [Enable location awareness]), ,
 405                              enable_location=auto)
 406
 407 if test "x$enable_location" != "xno"; then
 408    PKG_CHECK_MODULES(GEOCLUE,
 409    [
 410       geoclue >= $GEOCLUE_REQUIRED
 411    ], have_geoclue="yes", have_geoclue="no")
 412
 413    if test "x$have_geoclue" = "xyes"; then
 414       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 415    fi
 416 else
 417    have_geoclue="no"
 418 fi
 419
 420 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 421    AC_MSG_ERROR([Could not find location dependencies.])
 422 fi
 423
 424 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 425 AC_SUBST(GEOCLUE_CFLAGS)
 426 AC_SUBST(GEOCLUE_LIBS)
 427
 428 # -----------------------------------------------------------
 429 # meego widgets support
 430 # -----------------------------------------------------------
 431 AC_ARG_ENABLE(meego,
 432               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 433                              [Enable meego widgets]), ,
 434                              enable_meego=no)
 435
 436 if test "x$enable_meego" != "xno"; then
 437     PKG_CHECK_MODULES(MEEGO,
 438     [
 439        mx-gtk-1.0
 440     ], have_meego="yes", have_meego="no")
 441
 442     if test "x$have_meego" = "xyes"; then
 443        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 444     fi
 445 else
 446    have_meego="no"
 447 fi
 448
 449 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 450    AC_MSG_ERROR([Could not find meego dependencies.])
 451 fi
 452
 453 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 454 AC_SUBST(MEEGO_CFLAGS)
 455 AC_SUBST(MEEGO_LIBS)
 456
 457 # -----------------------------------------------------------
 458 # nautilus-sendto
 459 # -----------------------------------------------------------
 460 AC_ARG_ENABLE(nautilus-sendto,
 461               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 462                              [build nautilus-sendto plugin]), ,
 463                              enable_nautilus_sendto=auto)
 464
 465 if test "x$enable_nautilus_sendto" != "xno"; then
 466    if test "x$have_gtk3" == "xno"; then
 467       # Newer NST requires GTK+3 so we can't use it
 468       PKG_CHECK_MODULES(NST,
 469       [
 470          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 471          nautilus-sendto < 2.90.0
 472       ], have_nst="yes", have_nst="no")
 473    else
 474       PKG_CHECK_MODULES(NST,
 475       [
 476          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 477       ], have_nst="yes", have_nst="no")
 478    fi
 479 else
 480    have_nst=no
 481 fi
 482
 483 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 484    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 485 fi
 486
 487 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 488
 489 # -----------------------------------------------------------
 490 # new, single-window control center
 491 # -----------------------------------------------------------
 492 AC_ARG_ENABLE(control_center_embedding,
 493               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 494                              [Enable support for single-window control center]),
 495                              , enable_control_center_embedding=auto)
 496
 497 if test "x$enable_control_center_embedding" != "xno"; then
 498
 499    if test "x$have_gtk3" == "xno"; then
 500       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center < GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 501           have_control_center_embedding="yes", have_control_center_embedding="no")
 502    else
 503       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 504           have_control_center_embedding="yes", have_control_center_embedding="no")
 505    fi
 506
 507    if test "x$have_control_center_embedding" = "xyes"; then
 508       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 509
 510       AC_MSG_CHECKING([gnome-control-center extension dir])
 511       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 512       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 513           AC_MSG_ERROR([Could not determine extensiondir])
 514       else
 515           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 516       fi
 517       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 518    fi
 519 else
 520    have_control_center_embedding="no"
 521 fi
 522
 523 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 524    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 525 fi
 526
 527 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 528 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 529 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 530
 531 # -----------------------------------------------------------
 532 # Coding style checks
 533 # -----------------------------------------------------------
 534 AC_ARG_ENABLE(coding-style-checks,
 535   AC_HELP_STRING([--disable-coding-style-checks],
 536                  [do not check coding style using grep]),
 537     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 538
 539 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 540 # -----------------------------------------------------------
 541
 542 AC_OUTPUT([
 543    Makefile
 544    data/Makefile
 545    data/empathy.desktop.in
 546    data/empathy-accounts.desktop.in
 547    data/icons/Makefile
 548    extensions/Makefile
 549    po/Makefile.in
 550    libempathy/Makefile
 551    libempathy-gtk/Makefile
 552    src/Makefile
 553    nautilus-sendto-plugin/Makefile
 554    help/Makefile
 555    tests/Makefile
 556    tests/interactive/Makefile
 557    tests/xml/Makefile
 558    tools/Makefile
 559 ])
 560
 561 echo "
 562 Configure summary:
 563
 564         Compiler....................:  ${CC}
 565         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 566         Prefix......................:  ${prefix}
 567         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 568         Use GTK+3...................:  ${have_gtk3}
 569
 570     Features:
 571         Spell checking (enchant)....:  ${have_enchant}
 572         Display maps (libchamplain).:  ${have_libchamplain}
 573         Location awareness (Geoclue):  ${have_geoclue}
 574         Adium themes (Webkit).......:  ${have_webkit}
 575         Meego widgets ..............:  ${have_meego}
 576         Control center embedding....:  ${have_control_center_embedding}
 577
 578     Connectivity:
 579         NetworkManager integration..:  ${have_nm}
 580         ConnMan integration.........:  ${have_connman}
 581
 582     Extras:
 583         Nautilus-sendto plugin......:  ${have_nst}
 584         Salut E-D-S support.........:  ${with_eds}
 585 "