configure.ac

   1 AC_INIT(Empathy, 2.25.3, http://bugzilla.gnome.org/browse.cgi?product=empathy)
   2 AC_PREREQ(2.59)
   3 AC_COPYRIGHT([
   4   Copyright (C) 2003-2007 Imendio AB
   5   Copyright (C) 2007-2008 Collabora Ltd.
   6 ])
   7
   8 # LT Version numbers, remember to change them just *before* a release.
   9 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
  10 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
  11 #   (No interfaces changed:                   REVISION++)
  12 LIBEMPATHY_CURRENT=17
  13 LIBEMPATHY_AGE=0
  14 LIBEMPATHY_REVISION=0
  15
  16 LIBEMPATHY_GTK_CURRENT=16
  17 LIBEMPATHY_GTK_AGE=1
  18 LIBEMPATHY_GTK_REVISION=0
  19
  20 AC_SUBST(LIBEMPATHY_CURRENT)
  21 AC_SUBST(LIBEMPATHY_AGE)
  22 AC_SUBST(LIBEMPATHY_REVISION)
  23 AC_SUBST(LIBEMPATHY_GTK_CURRENT)
  24 AC_SUBST(LIBEMPATHY_GTK_AGE)
  25 AC_SUBST(LIBEMPATHY_GTK_REVISION)
  26
  27 # Minimal version required
  28 GLIB_REQUIRED=2.16.0
  29 GTK_REQUIRED=2.14.0
  30 GCONF_REQUIRED=1.2.0
  31 LIBGLADE_REQUIRED=2.0.0
  32 LIBPANELAPPLET_REQUIRED=2.10.0
  33 TELEPATHY_GLIB_REQUIRED=0.7.15
  34 MISSION_CONTROL_REQUIRED=4.61
  35 ENCHANT_REQUIRED=1.2.0
  36 ISO_CODES_REQUIRED=0.35
  37
  38 # Uncomment that to build with deprecated symbols disabled
  39 #AC_DEFINE(G_DISABLE_DEPRECATED, [], [Disable deprecated GLib symbols])
  40 #AC_DEFINE(GDK_PIXBUF_DISABLE_DEPRECATED, [], [Disable deprecated GDK pixbuf symbols])
  41 #AC_DEFINE(GDK_DISABLE_DEPRECATED, [], [Disable deprecated GDK symbols])
  42 #AC_DEFINE(GTK_DISABLE_DEPRECATED, [], [Disable deprecated GTK symbols])
  43
  44 # Uncomment that to build with single include disabled
  45 #AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  46 #AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  47 #AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  48
  49 AC_CONFIG_MACRO_DIR([m4])
  50 AC_CONFIG_HEADERS([config.h])
  51 AC_CONFIG_SRCDIR([configure.ac])
  52 AC_CONFIG_AUX_DIR(.)
  53
  54 GNOME_COMMON_INIT
  55
  56 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  57 AM_MAINTAINER_MODE
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AC_HEADER_STDC
  61 AM_PROG_LIBTOOL
  62 AM_PROG_MKDIR_P
  63 AM_PATH_GLIB_2_0
  64 AC_PATH_XTRA
  65 IT_PROG_INTLTOOL([0.35.0])
  66 GTK_DOC_CHECK([1.3])
  67 GNOME_DOC_INIT
  68 IDT_COMPILE_WARNINGS
  69 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  70 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  71 AM_GCONF_SOURCE_2
  72 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  73 AC_SUBST(GLIB_GENMARSHAL)
  74
  75 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  76 if test -z "$XSLTPROC"; then
  77   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  78 fi
  79 AM_PATH_PYTHON([2.3])
  80
  81 EMPATHY_ARG_VALGRIND
  82
  83 # -----------------------------------------------------------
  84 # Pkg-Config dependency checks
  85 # -----------------------------------------------------------
  86
  87 PKG_CHECK_MODULES(LIBEMPATHY,
  88 [
  89    glib-2.0 >= $GLIB_REQUIRED
  90    gobject-2.0
  91    libxml-2.0
  92    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
  93    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  94    gio-2.0 >= $GLIB_REQUIRED
  95    gio-unix-2.0 >= $GLIB_REQUIRED
  96 ])
  97
  98 PKG_CHECK_MODULES(EMPATHY,
  99 [
 100    glib-2.0 >= $GLIB_REQUIRED
 101    gobject-2.0
 102    gio-2.0 >= $GLIB_REQUIRED
 103    gconf-2.0 >= $GCONF_REQUIRED
 104    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 105    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 106    gtk+-2.0 >= $GTK_REQUIRED
 107    x11
 108    libglade-2.0 >= $LIBGLADE_REQUIRED
 109    libebook-1.2
 110 ])
 111
 112 # -----------------------------------------------------------
 113 # Enable debug
 114 # -----------------------------------------------------------
 115
 116 AC_ARG_ENABLE(debug,
 117   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 118     enable_debug=$enableval, enable_debug=yes )
 119
 120 if test x$enable_debug = xyes; then
 121   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 122 fi
 123
 124 # -----------------------------------------------------------
 125 # Language Support
 126 # -----------------------------------------------------------
 127
 128 GETTEXT_PACKAGE=empathy
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 131
 132 AM_GLIB_GNU_GETTEXT
 133
 134 # -----------------------------------------------------------
 135 # spellchecking checks: enchant and iso-codes
 136 # -----------------------------------------------------------
 137 AC_ARG_ENABLE(spell,
 138               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 139                              [Enable spell checking]), ,
 140                              enable_spell=auto)
 141
 142 if test "x$enable_spell" != "xno"; then
 143    PKG_CHECK_MODULES(ENCHANT,
 144    [
 145       enchant >= $ENCHANT_REQUIRED,
 146       iso-codes >= $ISO_CODES_REQUIRED
 147    ], have_enchant="yes", have_enchant="no")
 148
 149    if test "x$have_enchant" = "xyes"; then
 150       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 151       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 152          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 153             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 154             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 155             result=yes
 156       else
 157             result=no
 158             have_enchant="no"
 159       fi
 160       AC_MSG_RESULT([$result])
 161    fi
 162 else
 163    have_enchant=no
 164 fi
 165
 166 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 167    AC_MSG_ERROR([Couldn't find spell dependencies.])
 168 fi
 169
 170 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 171
 172 # -----------------------------------------------------------
 173 # Megaphone
 174 # -----------------------------------------------------------
 175 AC_ARG_ENABLE(megaphone,
 176               AS_HELP_STRING([--enable-megaphone=@<:@no/yes/auto@:>@],
 177                              [build megaphone applet]), ,
 178                              enable_megaphone=auto)
 179
 180 if test "x$enable_megaphone" != "xno"; then
 181    PKG_CHECK_MODULES(MEGAPHONE,
 182    [
 183       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 184       glib-2.0 >= $GLIB_REQUIRED
 185       gtk+-2.0 >= $GTK_REQUIRED
 186       gconf-2.0 >= $GCONF_REQUIRED
 187       libglade-2.0 >= $LIBGLADE_REQUIRED
 188       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 189    ], have_megaphone="yes", have_megaphone="no")
 190 else
 191    have_megaphone=no
 192 fi
 193
 194 if test "x$enable_megaphone" = "xyes" -a "x$have_megaphone" != "xyes"; then
 195    AC_MSG_ERROR([Couldn't find megaphone dependencies.])
 196 fi
 197
 198 AM_CONDITIONAL(HAVE_MEGAPHONE, test "x$have_megaphone" = "xyes")
 199
 200 # -----------------------------------------------------------
 201 # Nothere
 202 # -----------------------------------------------------------
 203 AC_ARG_ENABLE(nothere,
 204               AS_HELP_STRING([--enable-nothere=@<:@no/yes/auto@:>@],
 205                              [build nothere applet]), ,
 206                              enable_nothere=auto)
 207
 208 if test "x$enable_nothere" != "xno"; then
 209    PKG_CHECK_MODULES(NOTHERE,
 210    [
 211       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 212       glib-2.0 >= $GLIB_REQUIRED
 213       gtk+-2.0 >= $GTK_REQUIRED
 214       gconf-2.0 >= $GCONF_REQUIRED
 215       libglade-2.0 >= $LIBGLADE_REQUIRED
 216       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 217    ], have_nothere="yes", have_nothere="no")
 218 else
 219    have_nothere=no
 220 fi
 221
 222 if test "x$enable_nothere" = "xyes" -a "x$have_nothere" != "xyes"; then
 223    AC_MSG_ERROR([Couldn't find nothere dependencies.])
 224 fi
 225
 226 AM_CONDITIONAL(HAVE_NOTHERE, test "x$have_nothere" = "xyes")
 227
 228 # -----------------------------------------------------------
 229 # Tests
 230 # -----------------------------------------------------------
 231 AC_ARG_ENABLE(tests,
 232               AS_HELP_STRING([--enable-tests=@<:@no/yes/auto@:>@],
 233                              [build tests]), ,
 234                              enable_tests=auto)
 235
 236 if test "x$enable_tests" != "xno"; then
 237    PKG_CHECK_MODULES(CHECK,
 238    [
 239       check >= 0.9.4
 240    ], have_check="yes", have_check="no")
 241 else
 242    have_check=no
 243 fi
 244
 245 if test "x$enable_tests" = "xyes" -a "x$have_check" != "xyes"; then
 246    AC_MSG_ERROR([Couldn't find check dependencies.])
 247 fi
 248
 249 AM_CONDITIONAL(HAVE_TESTS, test "x$have_check" = "xyes")
 250
 251 # -----------------------------------------------------------
 252 # Python Bindings
 253 # -----------------------------------------------------------
 254 AC_ARG_ENABLE(python,
 255               AS_HELP_STRING([--enable-python=@<:@no/yes/auto@:>@],
 256                              [build python bindings to libempathy and libempathy-gtk]), ,
 257                              enable_python=auto)
 258
 259 if test "x$enable_python" != "xno"; then
 260    PKG_CHECK_MODULES(PYTHON_BINDING,
 261    [
 262       pygtk-2.0,
 263       glib-2.0 >= $GLIB_REQUIRED
 264       gobject-2.0
 265       gconf-2.0 >= $GCONF_REQUIRED
 266       libxml-2.0
 267       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 268       gtk+-2.0 >= $GTK_REQUIRED
 269       libglade-2.0 >= $LIBGLADE_REQUIRED
 270    ], have_python="yes", have_python="no")
 271    if test "x$have_python" = "xyes" ; then
 272       AM_CHECK_PYTHON_HEADERS(,have_python="no")
 273       AC_CHECK_PROGS([PYGOBJECTCODEGEN], [pygobject-codegen-2.0 pygtk-codegen-2.0])
 274    fi
 275 else
 276    have_python=no
 277 fi
 278
 279 if test "x$enable_python" = "xyes" -a "x$have_python" != "xyes"; then
 280    AC_MSG_ERROR([Couldn't find python.])
 281 fi
 282
 283 AM_CONDITIONAL(HAVE_PYTHON, test "x$have_python" = "xyes")
 284
 285 # -----------------------------------------------------------
 286
 287 AC_OUTPUT([
 288    Makefile
 289    data/Makefile
 290    data/empathy.desktop.in
 291    data/icons/Makefile
 292    extensions/Makefile
 293    po/Makefile.in
 294    libempathy/Makefile
 295    libempathy/libempathy.pc
 296    libempathy-gtk/Makefile
 297    libempathy-gtk/libempathy-gtk.pc
 298    src/Makefile
 299    megaphone/Makefile
 300    megaphone/src/Makefile
 301    megaphone/data/Makefile
 302    nothere/Makefile
 303    nothere/src/Makefile
 304    nothere/data/Makefile
 305    docs/Makefile
 306    docs/libempathy/Makefile
 307    docs/libempathy/version.xml
 308    docs/libempathy-gtk/Makefile
 309    docs/libempathy-gtk/version.xml
 310    help/Makefile
 311    python/Makefile
 312    python/pyempathy/Makefile
 313    python/pyempathygtk/Makefile
 314    tests/Makefile
 315    tests/xml/Makefile
 316    tools/Makefile
 317 ])