configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [6])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.13
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GTK_REQUIRED=2.21.2
  38 KEYRING_REQUIRED=2.26.0
  39 LIBCANBERRA_GTK_REQUIRED=0.4
  40 LIBNOTIFY_REQUIRED=0.4.4
  41 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.11.12
  44 TELEPATHY_LOGGER=0.1.5
  45 UNIQUE_REQUIRED=1.1.2
  46
  47 # Optionnal deps
  48 CLUTTER_GTK_REQUIRED=0.10
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  53 LIBCHAMPLAIN_REQUIRED=0.4
  54 NAUTILUS_SENDTO_REQUIRED=2.28.1
  55 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  56 NETWORK_MANAGER_REQUIRED=0.7.0
  57 WEBKIT_REQUIRED=1.1.15
  58 GNOME_CONTROL_CENTER_GTK3_REQUIRED=2.31.4
  59
  60 # Use --enable-maintainer-mode to disable deprecated symbols,
  61 # disable single include and enable GSEAL. If this is not a released empathy,
  62 # maintainer mode is forced
  63 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  64 GNOME_MAINTAINER_MODE_DEFINES
  65
  66 AC_CONFIG_MACRO_DIR([m4])
  67 AC_CONFIG_HEADERS([config.h])
  68 AC_CONFIG_SRCDIR([configure.ac])
  69 AC_CONFIG_AUX_DIR(.)
  70
  71 GNOME_COMMON_INIT
  72
  73 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  74
  75 # Support silent build rules, requires at least automake-1.11. Disable
  76 # by either passing --disable-silent-rules to configure or passing V=1
  77 # to make
  78 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  79
  80 AC_ISC_POSIX
  81 AC_PROG_CC
  82 AC_HEADER_STDC
  83 AM_PROG_LIBTOOL
  84 AM_PROG_MKDIR_P
  85 AM_PATH_GLIB_2_0
  86 AC_PATH_XTRA
  87 IT_PROG_INTLTOOL([0.35.0])
  88 GNOME_DOC_INIT([0.17.3])
  89 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  90 GLIB_GSETTINGS
  91 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  92 AC_SUBST(GLIB_GENMARSHAL)
  93
  94 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  95 if test -z "$XSLTPROC"; then
  96   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  97 fi
  98 AM_PATH_PYTHON([2.3])
  99
 100 EMPATHY_ARG_VALGRIND
 101
 102
 103 # -----------------------------------------------------------
 104 # Error flags
 105 # -----------------------------------------------------------
 106 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 107 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 108
 109 AC_ARG_ENABLE(Werror,
 110   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 111     werror=$enableval, :)
 112
 113 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 114 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 115         wno_missing_field_initializers=yes,
 116         wno_missing_field_initializers=no)
 117 AS_COMPILER_FLAG(-Wno-unused-parameter,
 118         wno_unused_parameter=yes,
 119         wno_unused_parameter=no)
 120
 121 ifelse(empathy_released, 1, [],
 122     [
 123         if test x$werror = xyes; then
 124             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 125         fi
 126         if test x$wextra = xyes -a \
 127             x$wno_missing_field_initializers = xyes -a \
 128             x$wno_unused_parameter = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 130         fi
 131     ])
 132
 133 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 134 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 135 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 136 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 137 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 138 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 139
 140 AC_SUBST(ERROR_CFLAGS)
 141
 142 # -----------------------------------------------------------
 143 # Pkg-Config dependency checks
 144 # -----------------------------------------------------------
 145
 146 PKG_CHECK_MODULES(EMPATHY,
 147 [
 148    dbus-glib-1
 149    farsight2-0.10
 150    folks >= $FOLKS_REQUIRED
 151    folks-telepathy >= $FOLKS_REQUIRED
 152    gconf-2.0 >= $GCONF_REQUIRED
 153    gcr-0 >= $KEYRING_REQUIRED
 154    gio-2.0 >= $GLIB_REQUIRED
 155    gio-unix-2.0 >= $GLIB_REQUIRED
 156    gnome-keyring-1 >= $KEYRING_REQUIRED
 157    gnutls
 158    gobject-2.0
 159    gstreamer-0.10
 160    gstreamer-interfaces-0.10
 161    libebook-1.2
 162    libxml-2.0
 163    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 164    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 165    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 166    x11
 167 ])
 168
 169 # -----------------------------------------------------------
 170 # GTK+
 171 # -----------------------------------------------------------
 172 AC_ARG_ENABLE(gtk3,
 173               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 174                              [build with GTK+3]), ,
 175                              enable_gtk3=auto)
 176
 177 # Try to use GTK+3 if available
 178 if test "x$enable_gtk3" != "xno"; then
 179    PKG_CHECK_MODULES(GTK,
 180    [
 181       gtk+-3.0 >= $GTK_REQUIRED
 182    ], have_gtk3="yes", have_gtk3="no")
 183 else
 184    have_gtk3="no"
 185 fi
 186
 187 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 188    AC_MSG_ERROR([Could not find gtk3 dependencies.])
 189 fi
 190
 191 if test "x$have_gtk3" == "xyes"; then
 192    # GTK3 specific deps
 193    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 194    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 195    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 196 else
 197    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 198
 199    # GTK2 specific deps
 200    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 201    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 202    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 203
 204    # Enable GSEAL checks if needed
 205    if test $USE_MAINTAINER_MODE = yes; then
 206       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 207    fi
 208 fi
 209
 210 # -----------------------------------------------------------
 211 # Enable debug
 212 # -----------------------------------------------------------
 213
 214 AC_ARG_ENABLE(debug,
 215   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 216     enable_debug=$enableval, enable_debug=yes )
 217
 218 if test x$enable_debug = xyes; then
 219   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 220 fi
 221
 222 # -----------------------------------------------------------
 223 # Language Support
 224 # -----------------------------------------------------------
 225
 226 GETTEXT_PACKAGE=empathy
 227 AC_SUBST(GETTEXT_PACKAGE)
 228 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 229
 230 AM_GLIB_GNU_GETTEXT
 231
 232 # -----------------------------------------------------------
 233 # Connectivity integration
 234 # -----------------------------------------------------------
 235 AC_ARG_WITH(connectivity,
 236               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 237                              [build with connectivity support]), ,
 238                              with_connectivity=auto)
 239
 240 if test "x$with_connectivity" = "xno"; then
 241    have_nm=no
 242    have_connman=no
 243
 244 elif test "x$with_connectivity" = "xconnman"; then
 245    have_nm=no
 246
 247    PKG_CHECK_MODULES(CONNMAN,
 248    [
 249       dbus-glib-1
 250    ], have_connman="yes", have_connman="no")
 251
 252    if test "x$have_connman" = "xyes"; then
 253       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 254    fi
 255
 256 else
 257    have_connman=no
 258
 259    PKG_CHECK_MODULES(NETWORK_MANAGER,
 260    [
 261       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 262    ], have_nm="yes", have_nm="no")
 263
 264    if test "x$have_nm" = "xyes"; then
 265       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 266    fi
 267 fi
 268
 269 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 270    AC_MSG_ERROR([Couldn't find connman dependencies.])
 271 fi
 272
 273 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 274    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 275 fi
 276
 277 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 278 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 279
 280 # -----------------------------------------------------------
 281 # Webkit
 282 # -----------------------------------------------------------
 283 AC_ARG_ENABLE(webkit,
 284               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 285                              [build with webkit support]), ,
 286                              enable_webkit=auto)
 287
 288 if test "x$enable_webkit" != "xno"; then
 289
 290    if test "x$have_gtk3" == "xno"; then
 291       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 292           have_webkit="yes", have_webkit="no")
 293    else
 294       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 295           have_webkit="yes", have_webkit="no")
 296    fi
 297
 298    if test "x$have_webkit" = "xyes"; then
 299       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 300    fi
 301 else
 302    have_webkit=no
 303 fi
 304
 305 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 306    AC_MSG_ERROR([Could not find webkit dependencies.])
 307 fi
 308 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 309
 310 # -----------------------------------------------------------
 311 # spellchecking checks: enchant and iso-codes
 312 # -----------------------------------------------------------
 313 AC_ARG_ENABLE(spell,
 314               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 315                              [Enable spell checking]), ,
 316                              enable_spell=auto)
 317
 318 if test "x$enable_spell" != "xno"; then
 319    PKG_CHECK_MODULES(ENCHANT,
 320    [
 321       enchant >= $ENCHANT_REQUIRED,
 322       iso-codes >= $ISO_CODES_REQUIRED
 323    ], have_enchant="yes", have_enchant="no")
 324
 325    if test "x$have_enchant" = "xyes"; then
 326       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 327       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 328          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 329             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 330             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 331             result=yes
 332       else
 333             result=no
 334             have_enchant="no"
 335       fi
 336       AC_MSG_RESULT([$result])
 337    fi
 338 else
 339    have_enchant=no
 340 fi
 341
 342 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 343    AC_MSG_ERROR([Could not find spell dependencies.])
 344 fi
 345
 346 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 347
 348 # -----------------------------------------------------------
 349 # Map view checks: libchamplain
 350 # -----------------------------------------------------------
 351 AC_ARG_ENABLE(map,
 352               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 353                              [Enable map view]), ,
 354                              enable_map=auto)
 355
 356 if test "x$enable_map" != "xno"; then
 357
 358    if test "x$have_gtk3" == "xno"; then
 359       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 360       [
 361          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 362          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 363          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 364       ], have_libchamplain="yes", have_libchamplain="no")
 365    else
 366       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 367       have_libchamplain="no"
 368    fi
 369
 370    if test "x$have_libchamplain" = "xyes"; then
 371       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 372    fi
 373 else
 374    have_libchamplain=no
 375 fi
 376
 377 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 378    AC_MSG_ERROR([Could not find map view dependencies.])
 379 fi
 380
 381 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 382
 383 # -----------------------------------------------------------
 384 # location checks: geoclue
 385 # -----------------------------------------------------------
 386 AC_ARG_ENABLE(location,
 387               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 388                              [Enable location awareness]), ,
 389                              enable_location=auto)
 390
 391 if test "x$enable_location" != "xno"; then
 392    PKG_CHECK_MODULES(GEOCLUE,
 393    [
 394       geoclue >= $GEOCLUE_REQUIRED
 395    ], have_geoclue="yes", have_geoclue="no")
 396
 397    if test "x$have_geoclue" = "xyes"; then
 398       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 399    fi
 400 else
 401    have_geoclue="no"
 402 fi
 403
 404 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 405    AC_MSG_ERROR([Could not find location dependencies.])
 406 fi
 407
 408 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 409 AC_SUBST(GEOCLUE_CFLAGS)
 410 AC_SUBST(GEOCLUE_LIBS)
 411
 412 # -----------------------------------------------------------
 413 # meego widgets support
 414 # -----------------------------------------------------------
 415 AC_ARG_ENABLE(meego,
 416               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 417                              [Enable meego widgets]), ,
 418                              enable_meego=no)
 419
 420 if test "x$enable_meego" != "xno"; then
 421     PKG_CHECK_MODULES(MEEGO,
 422     [
 423        mx-gtk-1.0
 424     ], have_meego="yes", have_meego="no")
 425
 426     if test "x$have_meego" = "xyes"; then
 427        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 428     fi
 429 else
 430    have_meego="no"
 431 fi
 432
 433 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 434    AC_MSG_ERROR([Could not find meego dependencies.])
 435 fi
 436
 437 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 438 AC_SUBST(MEEGO_CFLAGS)
 439 AC_SUBST(MEEGO_LIBS)
 440
 441 # -----------------------------------------------------------
 442 # nautilus-sendto
 443 # -----------------------------------------------------------
 444 AC_ARG_ENABLE(nautilus-sendto,
 445               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 446                              [build nautilus-sendto plugin]), ,
 447                              enable_nautilus_sendto=auto)
 448
 449 if test "x$enable_nautilus_sendto" != "xno"; then
 450    if test "x$have_gtk3" == "xno"; then
 451       # Newer NST requires GTK+3 so we can't use it
 452       PKG_CHECK_MODULES(NST,
 453       [
 454          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 455          nautilus-sendto < 2.90.0
 456       ], have_nst="yes", have_nst="no")
 457
 458       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 459    else
 460       PKG_CHECK_MODULES(NST,
 461       [
 462          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 463       ], have_nst="yes", have_nst="no")
 464    fi
 465 else
 466    have_nst=no
 467 fi
 468
 469 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 470    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 471 fi
 472
 473 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 474
 475 # -----------------------------------------------------------
 476 # new, single-window control center
 477 # -----------------------------------------------------------
 478 AC_ARG_ENABLE(control_center_embedding,
 479               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 480                              [Enable support for single-window control center]),
 481                              , enable_control_center_embedding=auto)
 482
 483 if test "x$enable_control_center_embedding" != "xno"; then
 484
 485    if test "x$have_gtk3" == "xno"; then
 486       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center < GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 487           have_control_center_embedding="yes", have_control_center_embedding="no")
 488    else
 489       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 490           have_control_center_embedding="yes", have_control_center_embedding="no")
 491    fi
 492
 493    if test "x$have_control_center_embedding" = "xyes"; then
 494       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 495
 496       AC_MSG_CHECKING([gnome-control-center extension dir])
 497       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 498       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 499           AC_MSG_ERROR([Could not determine extensiondir])
 500       else
 501           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 502       fi
 503       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 504    fi
 505 else
 506    have_control_center_embedding="no"
 507 fi
 508
 509 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 510    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 511 fi
 512
 513 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 514 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 515 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 516
 517 # -----------------------------------------------------------
 518 # Coding style checks
 519 # -----------------------------------------------------------
 520 AC_ARG_ENABLE(coding-style-checks,
 521   AC_HELP_STRING([--disable-coding-style-checks],
 522                  [do not check coding style using grep]),
 523     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 524
 525 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 526 # -----------------------------------------------------------
 527
 528 AC_OUTPUT([
 529    Makefile
 530    data/Makefile
 531    data/empathy.desktop.in
 532    data/empathy-accounts.desktop.in
 533    data/icons/Makefile
 534    extensions/Makefile
 535    po/Makefile.in
 536    libempathy/Makefile
 537    libempathy-gtk/Makefile
 538    src/Makefile
 539    nautilus-sendto-plugin/Makefile
 540    help/Makefile
 541    tests/Makefile
 542    tests/interactive/Makefile
 543    tests/xml/Makefile
 544    tools/Makefile
 545 ])
 546
 547 echo "
 548 Configure summary:
 549
 550         Compiler....................:  ${CC}
 551         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 552         Prefix......................:  ${prefix}
 553         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 554         Use GTK+3...................:  ${have_gtk3}
 555
 556     Features:
 557         Spell checking (enchant)....:  ${have_enchant}
 558         Display maps (libchamplain).:  ${have_libchamplain}
 559         Location awareness (Geoclue):  ${have_geoclue}
 560         Adium themes (Webkit).......:  ${have_webkit}
 561         Meego widgets ..............:  ${have_meego}
 562         Control center embedding....:  ${have_control_center_embedding}
 563
 564     Connectivity:
 565         NetworkManager integration..:  ${have_nm}
 566         ConnMan integration.........:  ${have_connman}
 567
 568     Extras:
 569         Nautilus-sendto plugin......:  ${have_nst}
 570 "