configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_GLIB_REQUIRED=0.11.7
  42 TELEPATHY_LOGGER=0.1.2
  43 UNIQUE_REQUIRED=1.1.2
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.10
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  51 LIBCHAMPLAIN_REQUIRED=0.4
  52 NAUTILUS_SENDTO_REQUIRED=2.28.1
  53 NETWORK_MANAGER_REQUIRED=0.7.0
  54 WEBKIT_REQUIRED=1.1.15
  55
  56 # Use --enable-maintainer-mode to disable deprecated symbols,
  57 # disable single include and enable GSEAL. If this is not a released empathy,
  58 # maintainer mode is forced
  59 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  60 GNOME_MAINTAINER_MODE_DEFINES
  61
  62 AC_CONFIG_MACRO_DIR([m4])
  63 AC_CONFIG_HEADERS([config.h])
  64 AC_CONFIG_SRCDIR([configure.ac])
  65 AC_CONFIG_AUX_DIR(.)
  66
  67 GNOME_COMMON_INIT
  68
  69 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  70
  71 # Support silent build rules, requires at least automake-1.11. Disable
  72 # by either passing --disable-silent-rules to configure or passing V=1
  73 # to make
  74 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  75
  76 AC_ISC_POSIX
  77 AC_PROG_CC
  78 AC_HEADER_STDC
  79 AM_PROG_LIBTOOL
  80 AM_PROG_MKDIR_P
  81 AM_PATH_GLIB_2_0
  82 AC_PATH_XTRA
  83 IT_PROG_INTLTOOL([0.35.0])
  84 GNOME_DOC_INIT([0.17.3])
  85 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  86 GLIB_GSETTINGS
  87 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  88 AC_SUBST(GLIB_GENMARSHAL)
  89 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  90 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  91
  92 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  93 if test -z "$XSLTPROC"; then
  94   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  95 fi
  96 AM_PATH_PYTHON([2.3])
  97
  98 EMPATHY_ARG_VALGRIND
  99
 100
 101 # -----------------------------------------------------------
 102 # Error flags
 103 # -----------------------------------------------------------
 104 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 105 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 106
 107 AC_ARG_ENABLE(Werror,
 108   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 109     werror=$enableval, :)
 110
 111 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 112 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 113         wno_missing_field_initializers=yes,
 114         wno_missing_field_initializers=no)
 115 AS_COMPILER_FLAG(-Wno-unused-parameter,
 116         wno_unused_parameter=yes,
 117         wno_unused_parameter=no)
 118
 119 ifelse(empathy_released, 1, [],
 120     [
 121         if test x$werror = xyes; then
 122             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 123         fi
 124         if test x$wextra = xyes -a \
 125             x$wno_missing_field_initializers = xyes -a \
 126             x$wno_unused_parameter = xyes; then
 127             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 128         fi
 129     ])
 130
 131 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 132 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 133 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 134 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 135 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 136 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 137
 138 AC_SUBST(ERROR_CFLAGS)
 139
 140 # -----------------------------------------------------------
 141 # Pkg-Config dependency checks
 142 # -----------------------------------------------------------
 143
 144 PKG_CHECK_MODULES(EMPATHY,
 145 [
 146    dbus-glib-1
 147    farsight2-0.10
 148    gconf-2.0 >= $GCONF_REQUIRED
 149    gio-2.0 >= $GLIB_REQUIRED
 150    gio-unix-2.0 >= $GLIB_REQUIRED
 151    gnome-keyring-1 >= $KEYRING_REQUIRED
 152    gobject-2.0
 153    gstreamer-0.10
 154    gstreamer-interfaces-0.10
 155    libebook-1.2
 156    libxml-2.0
 157    telepathy-farsight
 158    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 159    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 160    x11
 161 ])
 162
 163 # -----------------------------------------------------------
 164 # GTK+
 165 # -----------------------------------------------------------
 166 AC_ARG_ENABLE(gtk3,
 167               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 168                              [build with GTK+3]), ,
 169                              enable_gtk3=auto)
 170
 171 # Try to use GTK+3 if available
 172 if test "x$enable_gtk3" != "xno"; then
 173   PKG_CHECK_MODULES(GTK, [gtk+-3.0 >= $GTK_REQUIRED],
 174       enable_gtk3="yes", enable_gtk3="no")
 175
 176   # GTK3 specific deps
 177   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 178   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 179   PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 180 fi
 181
 182 # ...if not use GTK+2
 183 if test "x$enable_gtk3" == "xno"; then
 184   enable_gtk3=no
 185   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 186
 187   # GTK2 specific deps
 188   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 189   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 190   PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 191
 192   # Enable GSEAL checks if needed
 193   if test $USE_MAINTAINER_MODE = yes; then
 194     AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 195   fi
 196 fi
 197
 198 # -----------------------------------------------------------
 199 # Enable debug
 200 # -----------------------------------------------------------
 201
 202 AC_ARG_ENABLE(debug,
 203   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 204     enable_debug=$enableval, enable_debug=yes )
 205
 206 if test x$enable_debug = xyes; then
 207   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 208 fi
 209
 210 # -----------------------------------------------------------
 211 # Language Support
 212 # -----------------------------------------------------------
 213
 214 GETTEXT_PACKAGE=empathy
 215 AC_SUBST(GETTEXT_PACKAGE)
 216 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 217
 218 AM_GLIB_GNU_GETTEXT
 219
 220 # -----------------------------------------------------------
 221 # Connectivity integration
 222 # -----------------------------------------------------------
 223 AC_ARG_WITH(connectivity,
 224               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 225                              [build with connectivity support]), ,
 226                              with_connectivity=auto)
 227
 228 if test "x$with_connectivity" = "xno"; then
 229    have_nm=no
 230    have_connman=no
 231
 232 elif test "x$with_connectivity" = "xconnman"; then
 233
 234    PKG_CHECK_MODULES(CONNMAN,
 235    [
 236       dbus-glib-1
 237    ], have_connman="yes", have_connman="no")
 238
 239    if test "x$have_connman" = "xyes"; then
 240       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 241       have_nm=no
 242    fi
 243
 244 else
 245
 246    PKG_CHECK_MODULES(NETWORK_MANAGER,
 247    [
 248       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 249    ], have_nm="yes", have_nm="no")
 250
 251    if test "x$have_nm" = "xyes"; then
 252       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 253       have_connman=no
 254    else
 255       PKG_CHECK_MODULES(NETWORK_MANAGER,
 256       [
 257           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 258       ], have_nm="yes", have_nm="no")
 259
 260       if test "x$have_nm" = "xyes"; then
 261       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 262       have_connman=no
 263       fi
 264    fi
 265 fi
 266
 267 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 268    AC_MSG_ERROR([Couldn't find connman dependencies.])
 269 fi
 270
 271 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 272    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 273 fi
 274
 275 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 276 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 277
 278 # -----------------------------------------------------------
 279 # Webkit
 280 # -----------------------------------------------------------
 281 AC_ARG_ENABLE(webkit,
 282               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 283                              [build with webkit support]), ,
 284                              enable_webkit=auto)
 285
 286 if test "x$enable_webkit" != "xno"; then
 287
 288    if test "x$enable_gtk3" == "xno"; then
 289       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 290           have_webkit="yes", have_webkit="no")
 291    else
 292       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 293           have_webkit="yes", have_webkit="no")
 294    fi
 295
 296    if test "x$have_webkit" = "xyes"; then
 297       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 298    fi
 299 else
 300    have_webkit=no
 301 fi
 302
 303 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 304    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 305 fi
 306 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 307
 308 # -----------------------------------------------------------
 309 # spellchecking checks: enchant and iso-codes
 310 # -----------------------------------------------------------
 311 AC_ARG_ENABLE(spell,
 312               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 313                              [Enable spell checking]), ,
 314                              enable_spell=auto)
 315
 316 if test "x$enable_spell" != "xno"; then
 317    PKG_CHECK_MODULES(ENCHANT,
 318    [
 319       enchant >= $ENCHANT_REQUIRED,
 320       iso-codes >= $ISO_CODES_REQUIRED
 321    ], have_enchant="yes", have_enchant="no")
 322
 323    if test "x$have_enchant" = "xyes"; then
 324       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 325       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 326          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 327             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 328             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 329             result=yes
 330       else
 331             result=no
 332             have_enchant="no"
 333       fi
 334       AC_MSG_RESULT([$result])
 335    fi
 336 else
 337    have_enchant=no
 338 fi
 339
 340 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 341    AC_MSG_ERROR([Couldn't find spell dependencies.])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 345
 346 # -----------------------------------------------------------
 347 # Map view checks: libchamplain
 348 # -----------------------------------------------------------
 349 AC_ARG_ENABLE(map,
 350               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 351                              [Enable map view]), ,
 352                              enable_map=auto)
 353
 354 if test "x$enable_map" != "xno"; then
 355
 356    if test "x$enable_gtk3" == "xno"; then
 357       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 358       [
 359          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 360          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 361          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 362       ], have_libchamplain="yes", have_libchamplain="no")
 363    else
 364       have_libchamplain="no"
 365    fi
 366
 367    if test "x$have_libchamplain" = "xyes"; then
 368       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 369    fi
 370 else
 371    # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 372    have_libchamplain=no
 373 fi
 374
 375 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 376    AC_MSG_ERROR([Couldn't find map view dependencies.])
 377 fi
 378
 379 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 380
 381 # -----------------------------------------------------------
 382 # location checks: geoclue
 383 # -----------------------------------------------------------
 384 AC_ARG_ENABLE(location,
 385               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 386                              [Enable location awareness]), ,
 387                              enable_location=auto)
 388
 389 if test "x$enable_location" != "xno"; then
 390    PKG_CHECK_MODULES(GEOCLUE,
 391    [
 392       geoclue >= $GEOCLUE_REQUIRED
 393    ], have_geoclue="yes", have_geoclue="no")
 394
 395    if test "x$have_geoclue" = "xyes"; then
 396       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 397    fi
 398 else
 399    have_geoclue="no"
 400 fi
 401
 402 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 403    AC_MSG_ERROR([Couldn't find location dependencies.])
 404 fi
 405
 406 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 407 AC_SUBST(GEOCLUE_CFLAGS)
 408 AC_SUBST(GEOCLUE_LIBS)
 409
 410 # -----------------------------------------------------------
 411 # meego widgets support
 412 # -----------------------------------------------------------
 413 AC_ARG_ENABLE(meego,
 414               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 415                              [Enable meego widgets]), ,
 416                              enable_meego=no)
 417
 418 if test "x$enable_meego" != "xno"; then
 419     PKG_CHECK_MODULES(MEEGO,
 420     [
 421        mx-gtk-1.0
 422     ], have_meego="yes", have_meego="no")
 423
 424     if test "x$have_meego" = "xyes"; then
 425        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 426     fi
 427 else
 428    have_meego="no"
 429 fi
 430
 431 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 432    AC_MSG_ERROR([Couldn't find meego dependencies.])
 433 fi
 434
 435 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 436 AC_SUBST(MEEGO_CFLAGS)
 437 AC_SUBST(MEEGO_LIBS)
 438
 439 # -----------------------------------------------------------
 440 # nautilus-sendto
 441 # -----------------------------------------------------------
 442 AC_ARG_ENABLE(nautilus-sendto,
 443               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 444                              [build nautilus-sendto plugin]), ,
 445                              enable_nautilus_sendto=auto)
 446
 447 if test "x$enable_nautilus_sendto" != "xno"; then
 448    PKG_CHECK_MODULES(NST,
 449    [
 450       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 451    ], have_nst="yes", have_nst="no")
 452 else
 453    have_nst=no
 454 fi
 455
 456 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 457    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 458 fi
 459
 460 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 461
 462 # -----------------------------------------------------------
 463 # new, single-window control center
 464 # -----------------------------------------------------------
 465 AC_ARG_ENABLE(control_center_embedding,
 466               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 467                              [Enable support for single-window control center]),
 468                              , enable_control_center_embedding=auto)
 469
 470 if test "x$enable_control_center_embedding" != "xno"; then
 471    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 472    [
 473       libgnome-control-center-extension
 474    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 475
 476    if test "x$have_control_center_embedding" = "xyes"; then
 477       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 478    fi
 479 else
 480    have_control_center_embedding="no"
 481 fi
 482
 483 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 484    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 485 fi
 486
 487 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 488 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 489 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 490
 491 # -----------------------------------------------------------
 492 # Coding style checks
 493 # -----------------------------------------------------------
 494 AC_ARG_ENABLE(coding-style-checks,
 495   AC_HELP_STRING([--disable-coding-style-checks],
 496                  [don't check coding style using grep]),
 497     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 498
 499 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 500 # -----------------------------------------------------------
 501
 502 AC_OUTPUT([
 503    Makefile
 504    data/Makefile
 505    data/empathy.desktop.in
 506    data/empathy-accounts.desktop.in
 507    data/icons/Makefile
 508    extensions/Makefile
 509    po/Makefile.in
 510    libempathy/Makefile
 511    libempathy-gtk/Makefile
 512    src/Makefile
 513    nautilus-sendto-plugin/Makefile
 514    help/Makefile
 515    tests/Makefile
 516    tests/interactive/Makefile
 517    tests/xml/Makefile
 518    tools/Makefile
 519 ])
 520
 521 echo "
 522 Configure summary:
 523
 524         Compiler....................:  ${CC}
 525         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 526         Prefix......................:  ${prefix}
 527         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 528         Use GTK+3...................:  ${enable_gtk3}
 529
 530     Features:
 531         Spell checking (enchant)....:  ${have_enchant}
 532         Display maps (libchamplain).:  ${have_libchamplain}
 533         Location awareness (Geoclue):  ${have_geoclue}
 534         Adium themes (Webkit).......:  ${have_webkit}
 535         Meego widgets ..............:  ${have_meego}
 536         Control center embedding....:  ${have_control_center_embedding}
 537
 538     Connectivity:
 539         NetworkManager integration..:  ${have_nm}
 540         ConnMan integration.........:  ${have_connman}
 541
 542     Extras:
 543         Nautilus-sendto plugin......:  ${have_nst}
 544 "