configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [91])
   6 m4_define([empathy_micro_version], [6])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.3.5
  35 GLIB_REQUIRED=2.27.2
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=2.99.0
  38 KEYRING_REQUIRED=2.26.0
  39 GCR_REQUIRED=2.91.4
  40 LIBCANBERRA_GTK_REQUIRED=0.25
  41 LIBNOTIFY_REQUIRED=0.7.0
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.13.12
  44 TELEPATHY_LOGGER=0.1.5
  45
  46 # Optional deps
  47 CLUTTER_GTK_REQUIRED=0.90.3
  48 ENCHANT_REQUIRED=1.2.0
  49 GEOCLUE_REQUIRED=0.11
  50 ISO_CODES_REQUIRED=0.35
  51 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  52 LIBCHAMPLAIN_REQUIRED=0.9
  53 NAUTILUS_SENDTO_REQUIRED=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.3.2
  56 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  57
  58 # Use --enable-maintainer-mode to disable deprecated symbols,
  59 # disable single include and enable GSEAL. If this is not a released empathy,
  60 # maintainer mode is forced
  61 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  62 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 #GNOME_MAINTAINER_MODE_DEFINES
  64
  65 AC_CONFIG_MACRO_DIR([m4])
  66 AC_CONFIG_HEADERS([config.h])
  67 AC_CONFIG_SRCDIR([configure.ac])
  68 AC_CONFIG_AUX_DIR(.)
  69
  70 GNOME_COMMON_INIT
  71
  72 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  73
  74 # Support silent build rules, requires at least automake-1.11. Disable
  75 # by either passing --disable-silent-rules to configure or passing V=1
  76 # to make
  77 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  78
  79 AC_ISC_POSIX
  80 AC_PROG_CC
  81 AC_HEADER_STDC
  82 AM_PROG_LIBTOOL
  83 AM_PROG_MKDIR_P
  84 AM_PATH_GLIB_2_0
  85 AC_PATH_XTRA
  86 IT_PROG_INTLTOOL([0.35.0])
  87 GNOME_DOC_INIT([0.17.3])
  88 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  89 GLIB_GSETTINGS
  90 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  91 AC_SUBST(GLIB_GENMARSHAL)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    folks >= $FOLKS_REQUIRED
 149    folks-telepathy >= $FOLKS_REQUIRED
 150    glib-2.0 >= $GLIB_REQUIRED
 151    gio-2.0 >= $GLIB_REQUIRED
 152    gio-unix-2.0 >= $GLIB_REQUIRED
 153    gnome-keyring-1 >= $KEYRING_REQUIRED
 154    gnutls >= $GNUTLS_REQUIRED
 155    gmodule-export-2.0
 156    gobject-2.0
 157    gsettings-desktop-schemas
 158    gstreamer-0.10
 159    gstreamer-interfaces-0.10
 160    libxml-2.0
 161    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 162    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 163    x11
 164    gtk+-3.0 >= $GTK_REQUIRED
 165    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 166    libnotify >= $LIBNOTIFY_REQUIRED
 167    gcr-3 >= $GCR_REQUIRED
 168 ])
 169
 170 PKG_CHECK_MODULES(EMPATHY_AV,
 171 [
 172    farsight2-0.10
 173    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 174 ])
 175
 176 # -----------------------------------------------------------
 177 # evolution-data-server (about-me)
 178 # -----------------------------------------------------------
 179 AC_ARG_WITH(eds,
 180             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 181             [with_eds=yes])
 182 if test x"$with_eds" = x"yes" ; then
 183    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 184    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 185 fi
 186
 187 # -----------------------------------------------------------
 188 # Enable debug
 189 # -----------------------------------------------------------
 190
 191 AC_ARG_ENABLE(debug,
 192   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 193     enable_debug=$enableval, enable_debug=yes )
 194
 195 if test x$enable_debug = xyes; then
 196   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 197 fi
 198
 199 # -----------------------------------------------------------
 200 # Language Support
 201 # -----------------------------------------------------------
 202
 203 GETTEXT_PACKAGE=empathy
 204 AC_SUBST(GETTEXT_PACKAGE)
 205 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 206
 207 AM_GLIB_GNU_GETTEXT
 208
 209 # -----------------------------------------------------------
 210 # Connectivity integration
 211 # -----------------------------------------------------------
 212 AC_ARG_WITH(connectivity,
 213               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 214                              [build with connectivity support]), ,
 215                              with_connectivity=auto)
 216
 217 if test "x$with_connectivity" = "xno"; then
 218    have_nm=no
 219    have_connman=no
 220
 221 elif test "x$with_connectivity" = "xconnman"; then
 222    have_nm=no
 223
 224    PKG_CHECK_MODULES(CONNMAN,
 225    [
 226       dbus-glib-1
 227    ], have_connman="yes", have_connman="no")
 228
 229    if test "x$have_connman" = "xyes"; then
 230       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 231    fi
 232
 233 else
 234    have_connman=no
 235
 236    PKG_CHECK_MODULES(NETWORK_MANAGER,
 237    [
 238       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 239    ], have_nm="yes", have_nm="no")
 240
 241    if test "x$have_nm" = "xyes"; then
 242       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 243    fi
 244 fi
 245
 246 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 247    AC_MSG_ERROR([Couldn't find connman dependencies.])
 248 fi
 249
 250 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 251    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 252 fi
 253
 254 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 255 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 256
 257 # -----------------------------------------------------------
 258 # Webkit
 259 # -----------------------------------------------------------
 260 AC_ARG_ENABLE(webkit,
 261               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 262                              [build with webkit support]), ,
 263                              enable_webkit=auto)
 264
 265 if test "x$enable_webkit" != "xno"; then
 266    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 267         have_webkit="yes", have_webkit="no")
 268
 269    if test "x$have_webkit" = "xyes"; then
 270       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 271    fi
 272 else
 273    have_webkit=no
 274 fi
 275
 276 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 277    AC_MSG_ERROR([Could not find webkit dependencies.])
 278 fi
 279 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 280
 281 # -----------------------------------------------------------
 282 # spellchecking checks: enchant and iso-codes
 283 # -----------------------------------------------------------
 284 AC_ARG_ENABLE(spell,
 285               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 286                              [Enable spell checking]), ,
 287                              enable_spell=auto)
 288
 289 if test "x$enable_spell" != "xno"; then
 290    PKG_CHECK_MODULES(ENCHANT,
 291    [
 292       enchant >= $ENCHANT_REQUIRED,
 293       iso-codes >= $ISO_CODES_REQUIRED
 294    ], have_enchant="yes", have_enchant="no")
 295
 296    if test "x$have_enchant" = "xyes"; then
 297       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 298       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 299          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 300             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 301             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 302             result=yes
 303       else
 304             result=no
 305             have_enchant="no"
 306       fi
 307       AC_MSG_RESULT([$result])
 308    fi
 309 else
 310    have_enchant=no
 311 fi
 312
 313 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 314    AC_MSG_ERROR([Could not find spell dependencies.])
 315 fi
 316
 317 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 318
 319 # -----------------------------------------------------------
 320 # Map view checks: libchamplain
 321 # -----------------------------------------------------------
 322 AC_ARG_ENABLE(map,
 323               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 324                              [Enable map view]), ,
 325                              enable_map=auto)
 326
 327 if test "x$enable_map" != "xno"; then
 328
 329    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 330     [
 331        champlain-0.10
 332        champlain-gtk-0.10
 333        clutter-gtk-1.0
 334     ], have_libchamplain="yes", have_libchamplain="no")
 335
 336    if test "x$have_libchamplain" = "xyes"; then
 337       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 338    fi
 339 else
 340    have_libchamplain=no
 341 fi
 342
 343 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 344    AC_MSG_ERROR([Could not find map view dependencies.])
 345 fi
 346
 347 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 348
 349 # -----------------------------------------------------------
 350 # location checks: geoclue
 351 # -----------------------------------------------------------
 352 AC_ARG_ENABLE(location,
 353               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 354                              [Enable location awareness]), ,
 355                              enable_location=auto)
 356
 357 if test "x$enable_location" != "xno"; then
 358    PKG_CHECK_MODULES(GEOCLUE,
 359    [
 360       geoclue >= $GEOCLUE_REQUIRED
 361    ], have_geoclue="yes", have_geoclue="no")
 362
 363    if test "x$have_geoclue" = "xyes"; then
 364       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 365    fi
 366 else
 367    have_geoclue="no"
 368 fi
 369
 370 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 371    AC_MSG_ERROR([Could not find location dependencies.])
 372 fi
 373
 374 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 375 AC_SUBST(GEOCLUE_CFLAGS)
 376 AC_SUBST(GEOCLUE_LIBS)
 377
 378 # -----------------------------------------------------------
 379 # meego widgets support
 380 # -----------------------------------------------------------
 381 AC_ARG_ENABLE(meego,
 382               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 383                              [Enable meego widgets]), ,
 384                              enable_meego=no)
 385
 386 if test "x$enable_meego" != "xno"; then
 387     PKG_CHECK_MODULES(MEEGO,
 388     [
 389        mx-gtk-1.0
 390        gio-unix-2.0
 391     ], have_meego="yes", have_meego="no")
 392
 393     if test "x$have_meego" = "xyes"; then
 394        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 395     fi
 396 else
 397    have_meego="no"
 398 fi
 399
 400 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 401    AC_MSG_ERROR([Could not find meego dependencies.])
 402 fi
 403
 404 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 405 AC_SUBST(MEEGO_CFLAGS)
 406 AC_SUBST(MEEGO_LIBS)
 407
 408 # -----------------------------------------------------------
 409 # nautilus-sendto
 410 # -----------------------------------------------------------
 411 AC_ARG_ENABLE(nautilus-sendto,
 412               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 413                              [build nautilus-sendto plugin]), ,
 414                              enable_nautilus_sendto=auto)
 415
 416 if test "x$enable_nautilus_sendto" != "xno"; then
 417    PKG_CHECK_MODULES(NST,
 418     [
 419        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 420     ], have_nst="yes", have_nst="no")
 421 else
 422    have_nst=no
 423 fi
 424
 425 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 426    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 427 fi
 428
 429 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 430
 431 # -----------------------------------------------------------
 432 # new, single-window control center
 433 # -----------------------------------------------------------
 434 AC_ARG_ENABLE(control_center_embedding,
 435               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 436                              [Enable support for single-window control center]),
 437                              , enable_control_center_embedding=auto)
 438
 439 if test "x$enable_control_center_embedding" != "xno"; then
 440
 441    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 442         have_control_center_embedding="yes", have_control_center_embedding="no")
 443
 444    if test "x$have_control_center_embedding" = "xyes"; then
 445       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 446
 447       AC_MSG_CHECKING([gnome-control-center extension dir])
 448       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 449       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 450           AC_MSG_ERROR([Could not determine extensiondir])
 451       else
 452           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 453       fi
 454       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 455    fi
 456 else
 457    have_control_center_embedding="no"
 458 fi
 459
 460 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 461    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 462 fi
 463
 464 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 465 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 466 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 467
 468 # -----------------------------------------------------------
 469 # Coding style checks
 470 # -----------------------------------------------------------
 471 AC_ARG_ENABLE(coding-style-checks,
 472   AC_HELP_STRING([--disable-coding-style-checks],
 473                  [do not check coding style using grep]),
 474     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 475
 476 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 477 # -----------------------------------------------------------
 478
 479 AC_OUTPUT([
 480    Makefile
 481    data/Makefile
 482    data/empathy.desktop.in
 483    data/empathy-accounts.desktop.in
 484    data/icons/Makefile
 485    extensions/Makefile
 486    po/Makefile.in
 487    libempathy/Makefile
 488    libempathy-gtk/Makefile
 489    src/Makefile
 490    nautilus-sendto-plugin/Makefile
 491    help/Makefile
 492    tests/Makefile
 493    tests/interactive/Makefile
 494    tests/xml/Makefile
 495    tools/Makefile
 496 ])
 497
 498 echo "
 499 Configure summary:
 500
 501         Compiler....................:  ${CC}
 502         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 503         Prefix......................:  ${prefix}
 504         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 505
 506     Features:
 507         Spell checking (enchant)....:  ${have_enchant}
 508         Display maps (libchamplain).:  ${have_libchamplain}
 509         Location awareness (Geoclue):  ${have_geoclue}
 510         Adium themes (Webkit).......:  ${have_webkit}
 511         Meego widgets ..............:  ${have_meego}
 512         Control center embedding....:  ${have_control_center_embedding}
 513
 514     Connectivity:
 515         NetworkManager integration..:  ${have_nm}
 516         ConnMan integration.........:  ${have_connman}
 517
 518     Extras:
 519         Nautilus-sendto plugin......:  ${have_nst}
 520         Salut E-D-S support.........:  ${with_eds}
 521 "