configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [5])
   6 m4_define([empathy_micro_version], [2])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.32.0
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_32, [Prevent post 2.32 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53 CLUTTER_GST_REQUIRED=1.5.2
  54
  55 TELEPATHY_GLIB_REQUIRED=0.19.1
  56 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  57 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  58 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  59
  60 GSTREAMER_REQUIRED=0.10.32
  61 KEYRING_REQUIRED=2.26.0
  62 GCR_REQUIRED=2.91.4
  63 LIBCANBERRA_GTK_REQUIRED=0.25
  64 LIBNOTIFY_REQUIRED=0.7.0
  65 TELEPATHY_FARSTREAM_REQUIRED=0.2.1
  66 TELEPATHY_LOGGER=0.2.13
  67 WEBKIT_REQUIRED=1.3.13
  68 GOA_REQUIRED=3.5.1
  69
  70 # Optional deps
  71 ENCHANT_REQUIRED=1.2.0
  72 GEOCLUE_REQUIRED=0.12
  73 ISO_CODES_REQUIRED=0.35
  74 NAUTILUS_SENDTO_REQUIRED=2.90.0
  75 NETWORK_MANAGER_REQUIRED=0.7.0
  76 CHAMPLAIN_REQUIRED=0.12.1
  77 CHEESE_GTK_REQUIRED=3.4.0
  78
  79 # Use --enable-maintainer-mode to disable deprecated symbols,
  80 # disable single include and enable GSEAL. If this is not a released empathy,
  81 # maintainer mode is forced
  82 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  83 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  84 #GNOME_MAINTAINER_MODE_DEFINES
  85
  86 AC_CONFIG_MACRO_DIR([m4])
  87 AC_CONFIG_HEADERS([config.h])
  88 AC_CONFIG_SRCDIR([configure.ac])
  89 AC_CONFIG_AUX_DIR(.)
  90
  91 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  92
  93 # Support silent build rules. Disable
  94 # by either passing --disable-silent-rules to configure or passing V=1
  95 # to make
  96 AM_SILENT_RULES([yes])
  97
  98 # Check for programs
  99 AC_PROG_CC
 100 AC_HEADER_STDC
 101 AM_PROG_MKDIR_P
 102 AM_PATH_GLIB_2_0
 103 AC_PATH_XTRA
 104
 105 # Initialize libtool
 106 LT_PREREQ([2.2])
 107 LT_INIT
 108
 109 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 110 GLIB_GSETTINGS
 111 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 112 AC_SUBST(GLIB_GENMARSHAL)
 113
 114 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 115 if test -z "$XSLTPROC"; then
 116   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 117 fi
 118 AM_PATH_PYTHON([2.3])
 119
 120 EMPATHY_ARG_VALGRIND
 121
 122
 123 # -----------------------------------------------------------
 124 # Error flags
 125 # -----------------------------------------------------------
 126 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 127 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 128
 129 AC_ARG_ENABLE(Werror,
 130   AS_HELP_STRING([--disable-Werror],
 131                  [compile without -Werror (normally enabled in development builds)]),
 132     werror=$enableval, :)
 133
 134 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 135 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 136         wno_missing_field_initializers=yes,
 137         wno_missing_field_initializers=no)
 138 AS_COMPILER_FLAG(-Wno-unused-parameter,
 139         wno_unused_parameter=yes,
 140         wno_unused_parameter=no)
 141
 142 ifelse(empathy_released, 1, [],
 143     [
 144         if test x$werror = xyes; then
 145             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 146         fi
 147         if test x$wextra = xyes -a \
 148             x$wno_missing_field_initializers = xyes -a \
 149             x$wno_unused_parameter = xyes; then
 150             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 151         fi
 152     ])
 153
 154 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 155 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 156 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 157 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 158 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 159
 160 AC_SUBST(ERROR_CFLAGS)
 161
 162 AC_ARG_ENABLE(gprof,
 163             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 164             [build with support for gprof]),,
 165             [enable_gprof=no])
 166 if test "x$enable_gprof" != "xno" ; then
 167     CFLAGS="$CFLAGS -pg"
 168     LDFLAGS="$LDFLAGS -pg"
 169 fi
 170
 171 AC_SUBST(LDFLAGS)
 172
 173 # -----------------------------------------------------------
 174 # Pkg-Config dependency checks
 175 # -----------------------------------------------------------
 176
 177 AC_CHECK_LIBM
 178 AC_SUBST(LIBM)
 179
 180 PKG_CHECK_MODULES(EMPATHY,
 181 [
 182    dbus-glib-1
 183    folks >= $FOLKS_REQUIRED
 184    folks-telepathy >= $FOLKS_REQUIRED
 185    glib-2.0 >= $GLIB_REQUIRED
 186    gio-2.0 >= $GLIB_REQUIRED
 187    gio-unix-2.0 >= $GLIB_REQUIRED
 188    gnome-keyring-1 >= $KEYRING_REQUIRED
 189    gnutls >= $GNUTLS_REQUIRED
 190    gmodule-export-2.0
 191    gobject-2.0
 192    gsettings-desktop-schemas
 193    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 194    gstreamer-interfaces-0.10
 195    libxml-2.0
 196    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 197    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 198    x11
 199    gtk+-3.0 >= $GTK_REQUIRED
 200    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 201    libnotify >= $LIBNOTIFY_REQUIRED
 202    gcr-3 >= $GCR_REQUIRED
 203    libpulse
 204    libpulse-mainloop-glib
 205    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 206    libsoup-2.4
 207 ])
 208
 209 PKG_CHECK_MODULES(EMPATHY_CALL,
 210 [
 211    farstream-0.1
 212    telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 213    clutter-1.0 >= $CLUTTER_REQUIRED
 214    clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 215    clutter-gst-1.0 >= $CLUTTER_GST_REQUIRED
 216 ])
 217
 218 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 219    [Name of provider for accounts imported from GOA])
 220
 221 # -----------------------------------------------------------
 222 # evolution-data-server (about-me)
 223 # -----------------------------------------------------------
 224 AC_ARG_WITH(eds,
 225             AS_HELP_STRING([--with-eds],
 226                            [build with evolution-data-server support]),,
 227             [with_eds=yes])
 228 if test x"$with_eds" = x"yes" ; then
 229    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 230    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 231 fi
 232
 233 # -----------------------------------------------------------
 234 # Enable debug
 235 # -----------------------------------------------------------
 236
 237 AC_ARG_ENABLE(debug,
 238   AS_HELP_STRING([--disable-debug],
 239                  [compile without debug code]),
 240     enable_debug=$enableval, enable_debug=yes )
 241
 242 if test x$enable_debug = xyes; then
 243   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 244 fi
 245
 246 # -----------------------------------------------------------
 247 # Language Support
 248 # -----------------------------------------------------------
 249 IT_PROG_INTLTOOL([0.50.0])
 250
 251 GETTEXT_PACKAGE=empathy
 252 AC_SUBST(GETTEXT_PACKAGE)
 253 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 254
 255 # -----------------------------------------------------------
 256 # gudev
 257 # -----------------------------------------------------------
 258 AC_ARG_ENABLE(gudev,
 259               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 260                              [build with gudev support]), ,
 261                              enable_gudev=auto)
 262
 263 if test "x$enable_gudev" != "xno"; then
 264
 265    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 266         have_gudev="yes", have_gudev="no")
 267
 268    if test "x$have_gudev" = "xyes"; then
 269       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 270    fi
 271 else
 272    have_gudev=no
 273 fi
 274
 275 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 276    AC_MSG_ERROR([Could not find gudev dependencies:
 277
 278 $UDEV_PKG_ERRORS])
 279 fi
 280 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 281
 282 # -----------------------------------------------------------
 283 # spellchecking checks: enchant and iso-codes
 284 # -----------------------------------------------------------
 285 AC_ARG_ENABLE(spell,
 286               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 287                              [Enable spell checking]), ,
 288                              enable_spell=auto)
 289
 290 if test "x$enable_spell" != "xno"; then
 291    PKG_CHECK_MODULES(ENCHANT,
 292    [
 293       enchant >= $ENCHANT_REQUIRED,
 294       iso-codes >= $ISO_CODES_REQUIRED
 295    ], have_enchant="yes", have_enchant="no")
 296
 297    if test "x$have_enchant" = "xyes"; then
 298       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 299       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 300          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 301             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 302             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 303             result=yes
 304       else
 305             result=no
 306             have_enchant="no"
 307       fi
 308       AC_MSG_RESULT([$result])
 309    fi
 310 else
 311    have_enchant=no
 312 fi
 313
 314 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 315    AC_MSG_ERROR([Could not find spell-checking dependencies:
 316
 317 $ENCHANT_PKG_ERRORS])
 318 fi
 319
 320 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 321
 322 # -----------------------------------------------------------
 323 # Map view checks: libchamplain
 324 # -----------------------------------------------------------
 325 AC_ARG_ENABLE(map,
 326               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 327                              [Enable map view]), ,
 328                              enable_map=auto)
 329
 330 if test "x$enable_map" != "xno"; then
 331
 332    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 333     [
 334        clutter-gtk-1.0
 335        champlain-gtk-0.12
 336        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 337     ], have_libchamplain="yes", have_libchamplain="no")
 338
 339    if test "x$have_libchamplain" = "xyes"; then
 340       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 341    fi
 342 else
 343    have_libchamplain=no
 344 fi
 345
 346 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 347    AC_MSG_ERROR([Could not find map view dependencies:
 348
 349 $LIBCHAMPLAIN_PKG_ERRORS])
 350 fi
 351
 352 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 353
 354 # -----------------------------------------------------------
 355 # location checks: geoclue
 356 # -----------------------------------------------------------
 357 AC_ARG_ENABLE(location,
 358               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 359                              [Enable location awareness]), ,
 360                              enable_location=auto)
 361
 362 if test "x$enable_location" != "xno"; then
 363    PKG_CHECK_MODULES(GEOCLUE,
 364    [
 365       geoclue >= $GEOCLUE_REQUIRED
 366    ], have_geoclue="yes", have_geoclue="no")
 367
 368    if test "x$have_geoclue" = "xyes"; then
 369       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 370    fi
 371 else
 372    have_geoclue="no"
 373 fi
 374
 375 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 376    AC_MSG_ERROR([Could not find location dependencies:
 377
 378 $GEOCLUE_PKG_ERRORS])
 379 fi
 380
 381 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 382 AC_SUBST(GEOCLUE_CFLAGS)
 383 AC_SUBST(GEOCLUE_LIBS)
 384
 385 # -----------------------------------------------------------
 386 # location checks: geocode-glib
 387 # -----------------------------------------------------------
 388 AC_ARG_ENABLE(geocode,
 389               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 390                              [Enable geocode support]), ,
 391                              enable_geocode=auto)
 392
 393 if test "x$enable_geocode" != "xno"; then
 394    PKG_CHECK_MODULES(GEOCODE,
 395    [
 396       geocode-glib
 397    ], have_geocode="yes", have_geocode="no")
 398
 399    if test "x$have_geocode" = "xyes"; then
 400       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 401    fi
 402 else
 403    have_geocode="no"
 404 fi
 405
 406 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 407    AC_MSG_ERROR([Could not find geocode dependencies:
 408
 409 $GEOCODE_PKG_ERRORS])
 410 fi
 411
 412 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 413 AC_SUBST(GEOCODE_CFLAGS)
 414 AC_SUBST(GEOCODE_LIBS)
 415
 416 # -----------------------------------------------------------
 417 # nautilus-sendto
 418 # -----------------------------------------------------------
 419 AC_ARG_ENABLE(nautilus-sendto,
 420               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 421                              [build nautilus-sendto plugin]), ,
 422                              enable_nautilus_sendto=auto)
 423
 424 if test "x$enable_nautilus_sendto" != "xno"; then
 425    PKG_CHECK_MODULES(NST,
 426     [
 427        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 428     ], have_nst="yes", have_nst="no")
 429 else
 430    have_nst=no
 431 fi
 432
 433 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 434    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 435
 436 $NST_PKG_ERRORS])
 437 fi
 438
 439 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 440
 441 # -----------------------------------------------------------
 442 # goa-mc-plugin
 443 # -----------------------------------------------------------
 444 AC_ARG_ENABLE(goa,
 445               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 446                              [build GOA MC plugin]), ,
 447                              enable_goa=auto)
 448
 449 if test "x$enable_goa" != "xno"; then
 450    PKG_CHECK_MODULES(GOA,
 451     [
 452        mission-control-plugins
 453        goa-1.0 >= $GOA_REQUIRED
 454     ], have_goa="yes", have_goa="no")
 455
 456    AC_MSG_CHECKING([Mission Control plugins dir])
 457    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 458
 459    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 460    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 461 else
 462    have_goa=no
 463 fi
 464
 465 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 466    AC_MSG_ERROR([Could not find GOA dependencies.])
 467 fi
 468
 469 if test "x$have_goa" = "xyes"; then
 470    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 471 fi
 472
 473 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 474
 475 # Optional dependency for avatar selection
 476 AC_ARG_WITH([cheese],
 477             AS_HELP_STRING([--with-cheese],
 478                            [enable cheese webcam support]),,
 479             with_cheese=auto)
 480
 481 if test x"$with_cheese" != x"no" ; then
 482    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 483    if test x${have_cheese} = xyes; then
 484      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 485    fi
 486    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 487      AC_MSG_ERROR([Cheese configured but not found:
 488
 489 $CHEESE_PKG_ERRORS])
 490    fi
 491 else
 492    have_cheese=no
 493 fi
 494 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 495
 496 # Help documentation
 497 YELP_HELP_INIT
 498
 499 # -----------------------------------------------------------
 500 # Coding style checks
 501 # -----------------------------------------------------------
 502 AC_ARG_ENABLE(coding-style-checks,
 503   AS_HELP_STRING([--disable-coding-style-checks],
 504                  [do not check coding style using grep]),
 505     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 506     [ENABLE_CODING_STYLE_CHECKS=yes])
 507
 508 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 509 # -----------------------------------------------------------
 510
 511 AC_CONFIG_FILES([
 512    Makefile
 513    data/Makefile
 514    data/empathy.desktop.in
 515    data/empathy-accounts.desktop.in
 516    data/icons/Makefile
 517    extensions/Makefile
 518    po/Makefile.in
 519    libempathy/Makefile
 520    libempathy-gtk/Makefile
 521    src/Makefile
 522    nautilus-sendto-plugin/Makefile
 523    goa-mc-plugin/Makefile
 524    help/Makefile
 525    tests/Makefile
 526    tests/interactive/Makefile
 527    tests/xml/Makefile
 528    tests/certificates/Makefile
 529    tools/Makefile
 530 ])
 531 AC_OUTPUT
 532
 533 echo "
 534 Configure summary:
 535
 536         Compiler....................:  ${CC}
 537         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 538         Linker Flags................:  ${LDFLAGS}
 539         Prefix......................:  ${prefix}
 540         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 541
 542     Features:
 543         Spell checking (enchant)....:  ${have_enchant}
 544         Display maps (libchamplain).:  ${have_libchamplain}
 545         Location awareness (Geoclue):  ${have_geoclue}
 546         Geocode support (Geocode)...:  ${have_geocode}
 547         Cheese webcam support ......:  ${have_cheese}
 548         Camera monitoring...........:  ${have_gudev}
 549
 550     Extras:
 551         Nautilus-sendto plugin......:  ${have_nst}
 552         GOA MC plugin...............:  ${have_goa}
 553         Salut E-D-S support.........:  ${with_eds}
 554 "