configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 1)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [29])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32 GLIB_REQUIRED=2.22.0
  33 GTK_REQUIRED=2.18.0
  34 GCONF_REQUIRED=1.2.0
  35 TELEPATHY_GLIB_REQUIRED=0.9.2
  36 ENCHANT_REQUIRED=1.2.0
  37 ISO_CODES_REQUIRED=0.35
  38 LIBNOTIFY_REQUIRED=0.4.4
  39 LIBCANBERRA_GTK_REQUIRED=0.4
  40 LIBCHAMPLAIN_REQUIRED=0.4
  41 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  42 CLUTTER_GTK_REQUIRED=0.10
  43 GEOCLUE_REQUIRED=0.11
  44 WEBKIT_REQUIRED=1.1.15
  45 KEYRING_REQUIRED=2.22
  46 NETWORK_MANAGER_REQUIRED=0.7.0
  47 NAUTILUS_SENDTO_REQUIRED=2.28.1
  48
  49 # Use --enable-maintainer-mode to disabled deprecated symbols
  50 GNOME_MAINTAINER_MODE_DEFINES
  51
  52 # Warning if GLib/GDK/GTK headers are included
  53 AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  54 AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  55 AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  56
  57 AC_CONFIG_MACRO_DIR([m4])
  58 AC_CONFIG_HEADERS([config.h])
  59 AC_CONFIG_SRCDIR([configure.ac])
  60 AC_CONFIG_AUX_DIR(.)
  61
  62 GNOME_COMMON_INIT
  63
  64 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  65
  66 # Support silent build rules, requires at least automake-1.11. Disable
  67 # by either passing --disable-silent-rules to configure or passing V=1
  68 # to make
  69 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  70
  71 AC_ISC_POSIX
  72 AC_PROG_CC
  73 AC_HEADER_STDC
  74 AM_PROG_LIBTOOL
  75 AM_PROG_MKDIR_P
  76 AM_PATH_GLIB_2_0
  77 AC_PATH_XTRA
  78 IT_PROG_INTLTOOL([0.35.0])
  79 GNOME_DOC_INIT([0.17.3])
  80 IDT_COMPILE_WARNINGS
  81 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  82 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  83 AM_GCONF_SOURCE_2
  84 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  85 AC_SUBST(GLIB_GENMARSHAL)
  86
  87 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  88 if test -z "$XSLTPROC"; then
  89   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  90 fi
  91 AM_PATH_PYTHON([2.3])
  92
  93 EMPATHY_ARG_VALGRIND
  94
  95
  96 # -----------------------------------------------------------
  97 # Error flags
  98 # -----------------------------------------------------------
  99 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 100 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 101
 102 AC_ARG_ENABLE(Werror,
 103   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 104     werror=$enableval, :)
 105
 106 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 107 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 108         wno_missing_field_initializers=yes,
 109         wno_missing_field_initializers=no)
 110 AS_COMPILER_FLAG(-Wno-unused-parameter,
 111         wno_unused_parameter=yes,
 112         wno_unused_parameter=no)
 113
 114 ifelse(empathy_released, 1, [],
 115     [
 116         if test x$werror = xyes; then
 117             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 118         fi
 119         if test x$wextra = xyes -a \
 120             x$wno_missing_field_initializers = xyes -a \
 121             x$wno_unused_parameter = xyes; then
 122             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 123         fi
 124     ])
 125
 126 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 127 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 128 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 129 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 130 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 131 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 132
 133 AC_SUBST(ERROR_CFLAGS)
 134
 135 # -----------------------------------------------------------
 136 # Pkg-Config dependency checks
 137 # -----------------------------------------------------------
 138
 139 PKG_CHECK_MODULES(LIBEMPATHY,
 140 [
 141    glib-2.0 >= $GLIB_REQUIRED
 142    gobject-2.0
 143    gio-2.0 >= $GLIB_REQUIRED
 144    gio-unix-2.0 >= $GLIB_REQUIRED
 145    libxml-2.0
 146    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 147    telepathy-farsight
 148    farsight2-0.10
 149    gstreamer-0.10
 150 ])
 151
 152 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 153 [
 154    glib-2.0 >= $GLIB_REQUIRED
 155    gobject-2.0
 156    gio-2.0 >= $GLIB_REQUIRED
 157    gconf-2.0 >= $GCONF_REQUIRED
 158    x11
 159    gtk+-2.0 >= $GTK_REQUIRED
 160    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 161    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 162    farsight2-0.10
 163    gstreamer-0.10
 164    gstreamer-interfaces-0.10
 165 ])
 166
 167 PKG_CHECK_MODULES(EMPATHY,
 168 [
 169    glib-2.0 >= $GLIB_REQUIRED
 170    gobject-2.0
 171    gio-2.0 >= $GLIB_REQUIRED
 172    gdk-x11-2.0
 173    gtk+-2.0 >= $GTK_REQUIRED
 174    libebook-1.2
 175    dbus-glib-1
 176    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 177    telepathy-farsight
 178    farsight2-0.10
 179    gstreamer-0.10
 180    unique-1.0
 181    gnome-keyring-1 >= $KEYRING_REQUIRED
 182 ])
 183
 184 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 185
 186 # -----------------------------------------------------------
 187 # Enable debug
 188 # -----------------------------------------------------------
 189
 190 AC_ARG_ENABLE(debug,
 191   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 192     enable_debug=$enableval, enable_debug=yes )
 193
 194 if test x$enable_debug = xyes; then
 195   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 196 fi
 197
 198 # -----------------------------------------------------------
 199 # Language Support
 200 # -----------------------------------------------------------
 201
 202 GETTEXT_PACKAGE=empathy
 203 AC_SUBST(GETTEXT_PACKAGE)
 204 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 205
 206 AM_GLIB_GNU_GETTEXT
 207
 208 # -----------------------------------------------------------
 209 # Connectivity integration
 210 # -----------------------------------------------------------
 211 AC_ARG_WITH(connectivity,
 212               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 213                              [build with connectivity support]), ,
 214                              with_connectivity=auto)
 215
 216 if test "x$with_connectivity" = "xno"; then
 217    have_nm=no
 218    have_connman=no
 219
 220 elif test "x$with_connectivity" = "xconnman"; then
 221
 222    PKG_CHECK_MODULES(CONNMAN,
 223    [
 224       dbus-glib-1
 225    ], have_connman="yes", have_connman="no")
 226
 227    if test "x$have_connman" = "xyes"; then
 228       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 229       have_nm=no
 230    fi
 231
 232 else
 233
 234    PKG_CHECK_MODULES(NETWORK_MANAGER,
 235    [
 236       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 237    ], have_nm="yes", have_nm="no")
 238
 239    if test "x$have_nm" = "xyes"; then
 240       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 241       have_connman=no
 242    else
 243       PKG_CHECK_MODULES(NETWORK_MANAGER,
 244       [
 245           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 246       ], have_nm="yes", have_nm="no")
 247
 248       if test "x$have_nm" = "xyes"; then
 249       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 250       have_connman=no
 251       fi
 252    fi
 253 fi
 254
 255 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 256    AC_MSG_ERROR([Couldn't find connman dependencies.])
 257 fi
 258
 259 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 260    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 261 fi
 262
 263 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 264 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 265
 266 # -----------------------------------------------------------
 267 # Webkit
 268 # -----------------------------------------------------------
 269 AC_ARG_ENABLE(webkit,
 270               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 271                              [build with webkit support]), ,
 272                              enable_webkit=auto)
 273
 274 if test "x$enable_webkit" != "xno"; then
 275    PKG_CHECK_MODULES(WEBKIT,
 276    [
 277       webkit-1.0 >= $WEBKIT_REQUIRED
 278    ], have_webkit="yes", have_webkit="no")
 279
 280    if test "x$have_webkit" = "xyes"; then
 281       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 282    fi
 283 else
 284    have_webkit=no
 285 fi
 286
 287 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 288    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 289 fi
 290 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 291
 292 # -----------------------------------------------------------
 293 # spellchecking checks: enchant and iso-codes
 294 # -----------------------------------------------------------
 295 AC_ARG_ENABLE(spell,
 296               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 297                              [Enable spell checking]), ,
 298                              enable_spell=auto)
 299
 300 if test "x$enable_spell" != "xno"; then
 301    PKG_CHECK_MODULES(ENCHANT,
 302    [
 303       enchant >= $ENCHANT_REQUIRED,
 304       iso-codes >= $ISO_CODES_REQUIRED
 305    ], have_enchant="yes", have_enchant="no")
 306
 307    if test "x$have_enchant" = "xyes"; then
 308       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 309       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 310          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 311             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 312             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 313             result=yes
 314       else
 315             result=no
 316             have_enchant="no"
 317       fi
 318       AC_MSG_RESULT([$result])
 319    fi
 320 else
 321    have_enchant=no
 322 fi
 323
 324 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 325    AC_MSG_ERROR([Couldn't find spell dependencies.])
 326 fi
 327
 328 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 329
 330 # -----------------------------------------------------------
 331 # Map view checks: libchamplain
 332 # -----------------------------------------------------------
 333 AC_ARG_ENABLE(map,
 334               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 335                              [Enable map view]), ,
 336                              enable_map=auto)
 337
 338 if test "x$enable_map" != "xno"; then
 339    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 340    [
 341       champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 342       champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 343       clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 344    ], have_libchamplain="yes", have_libchamplain="no")
 345
 346    if test "x$have_libchamplain" = "xyes"; then
 347       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 348    fi
 349 else
 350    have_libchamplain=no
 351 fi
 352
 353 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 354    AC_MSG_ERROR([Couldn't find map view dependencies.])
 355 fi
 356
 357 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 358
 359 # -----------------------------------------------------------
 360 # location checks: geoclue
 361 # -----------------------------------------------------------
 362 AC_ARG_ENABLE(location,
 363               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 364                              [Enable location awareness]), ,
 365                              enable_location=auto)
 366
 367 if test "x$enable_location" != "xno"; then
 368    PKG_CHECK_MODULES(GEOCLUE,
 369    [
 370       geoclue >= $GEOCLUE_REQUIRED
 371    ], have_geoclue="yes", have_geoclue="no")
 372
 373    if test "x$have_geoclue" = "xyes"; then
 374       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 375    fi
 376 else
 377    have_geoclue="no"
 378 fi
 379
 380 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 381    AC_MSG_ERROR([Couldn't find location dependencies.])
 382 fi
 383
 384 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 385 AC_SUBST(GEOCLUE_CFLAGS)
 386 AC_SUBST(GEOCLUE_LIBS)
 387
 388 # -----------------------------------------------------------
 389 # moblin widgets support
 390 # -----------------------------------------------------------
 391 AC_ARG_ENABLE(moblin,
 392               AS_HELP_STRING([--enable-moblin=@<:no/yes@:>@],
 393                              [Enable moblin widgets]), ,
 394                              enable_moblin=no)
 395
 396 if test "x$enable_moblin" != "xno"; then
 397     PKG_CHECK_MODULES(MOBLIN,
 398     [
 399        nbtk-gtk-1.2
 400     ], have_moblin="yes", have_moblin="no")
 401
 402     if test "x$have_moblin" = "xyes"; then
 403        AC_DEFINE(HAVE_MOBLIN, 1, [Define if you have moblin])
 404     fi
 405 else
 406    have_moblin="no"
 407 fi
 408
 409 if test "x$enable_moblin" = "xyes" -a "x$have_moblin" != "xyes"; then
 410    AC_MSG_ERROR([Couldn't find moblin dependencies.])
 411 fi
 412
 413 AM_CONDITIONAL(HAVE_MOBLIN, test "x$have_moblin" = "xyes")
 414 AC_SUBST(MOBLIN_CFLAGS)
 415 AC_SUBST(MOBLIN_LIBS)
 416
 417 # -----------------------------------------------------------
 418 # nautilus-sendto
 419 # -----------------------------------------------------------
 420 AC_ARG_ENABLE(nautilus-sendto,
 421               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 422                              [build nautilus-sendto plugin]), ,
 423                              enable_nautilus_sendto=auto)
 424
 425 if test "x$enable_nautilus_sendto" != "xno"; then
 426    PKG_CHECK_MODULES(NST,
 427    [
 428       nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 429    ], have_nst="yes", have_nst="no")
 430 else
 431    have_nst=no
 432 fi
 433
 434 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 435    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 436 fi
 437
 438 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 439
 440 # -----------------------------------------------------------
 441 # Coding style checks
 442 # -----------------------------------------------------------
 443 AC_ARG_ENABLE(coding-style-checks,
 444   AC_HELP_STRING([--disable-coding-style-checks],
 445                  [don't check coding style using grep]),
 446     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 447
 448 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 449 # -----------------------------------------------------------
 450
 451 AC_OUTPUT([
 452    Makefile
 453    data/Makefile
 454    data/empathy.desktop.in
 455    data/icons/Makefile
 456    extensions/Makefile
 457    po/Makefile.in
 458    libempathy/Makefile
 459    libempathy-gtk/Makefile
 460    src/Makefile
 461    nautilus-sendto-plugin/Makefile
 462    help/Makefile
 463    tests/Makefile
 464    tests/interactive/Makefile
 465    tests/xml/Makefile
 466    tools/Makefile
 467 ])
 468
 469 echo "
 470 Configure summary:
 471
 472         Compiler....................:  ${CC}
 473         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 474         Prefix......................:  ${prefix}
 475         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 476
 477     Features:
 478         Spell checking (enchant)....:  ${have_enchant}
 479         Display maps (libchamplain).:  ${have_libchamplain}
 480         Location awareness (Geoclue):  ${have_geoclue}
 481         Adium themes (Webkit).......:  ${have_webkit}
 482         Moblin widgets .............:  ${have_moblin}
 483
 484     Connectivity:
 485         NetworkManager integration..:  ${have_nm}
 486         ConnMan integration.........:  ${have_connman}
 487
 488     Extras:
 489         Nautilus-sendto plugin......:  ${have_nst}
 490 "