configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2008 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 GCONF_REQUIRED=1.2.0
  35 GLIB_REQUIRED=2.25.9
  36 GTK_REQUIRED=2.21.2
  37 KEYRING_REQUIRED=2.22
  38 LIBCANBERRA_GTK_REQUIRED=0.4
  39 LIBNOTIFY_REQUIRED=0.4.4
  40 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  41 TELEPATHY_GLIB_REQUIRED=0.11.7
  42 TELEPATHY_LOGGER=0.1.2
  43 UNIQUE_REQUIRED=1.1.2
  44
  45 # Optionnal deps
  46 CLUTTER_GTK_REQUIRED=0.10
  47 ENCHANT_REQUIRED=1.2.0
  48 GEOCLUE_REQUIRED=0.11
  49 ISO_CODES_REQUIRED=0.35
  50 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  51 LIBCHAMPLAIN_REQUIRED=0.4
  52 NAUTILUS_SENDTO_REQUIRED=2.28.1
  53 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.1.15
  56
  57 # Use --enable-maintainer-mode to disable deprecated symbols,
  58 # disable single include and enable GSEAL. If this is not a released empathy,
  59 # maintainer mode is forced
  60 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  61 GNOME_MAINTAINER_MODE_DEFINES
  62
  63 AC_CONFIG_MACRO_DIR([m4])
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_SRCDIR([configure.ac])
  66 AC_CONFIG_AUX_DIR(.)
  67
  68 GNOME_COMMON_INIT
  69
  70 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  71
  72 # Support silent build rules, requires at least automake-1.11. Disable
  73 # by either passing --disable-silent-rules to configure or passing V=1
  74 # to make
  75 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  76
  77 AC_ISC_POSIX
  78 AC_PROG_CC
  79 AC_HEADER_STDC
  80 AM_PROG_LIBTOOL
  81 AM_PROG_MKDIR_P
  82 AM_PATH_GLIB_2_0
  83 AC_PATH_XTRA
  84 IT_PROG_INTLTOOL([0.35.0])
  85 GNOME_DOC_INIT([0.17.3])
  86 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  87 GLIB_GSETTINGS
  88 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90 CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center-extension`
  91 AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
  92
  93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  94 if test -z "$XSLTPROC"; then
  95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  96 fi
  97 AM_PATH_PYTHON([2.3])
  98
  99 EMPATHY_ARG_VALGRIND
 100
 101
 102 # -----------------------------------------------------------
 103 # Error flags
 104 # -----------------------------------------------------------
 105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 107
 108 AC_ARG_ENABLE(Werror,
 109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 110     werror=$enableval, :)
 111
 112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 114         wno_missing_field_initializers=yes,
 115         wno_missing_field_initializers=no)
 116 AS_COMPILER_FLAG(-Wno-unused-parameter,
 117         wno_unused_parameter=yes,
 118         wno_unused_parameter=no)
 119
 120 ifelse(empathy_released, 1, [],
 121     [
 122         if test x$werror = xyes; then
 123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 124         fi
 125         if test x$wextra = xyes -a \
 126             x$wno_missing_field_initializers = xyes -a \
 127             x$wno_unused_parameter = xyes; then
 128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 129         fi
 130     ])
 131
 132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 138
 139 AC_SUBST(ERROR_CFLAGS)
 140
 141 # -----------------------------------------------------------
 142 # Pkg-Config dependency checks
 143 # -----------------------------------------------------------
 144
 145 PKG_CHECK_MODULES(EMPATHY,
 146 [
 147    dbus-glib-1
 148    farsight2-0.10
 149    gconf-2.0 >= $GCONF_REQUIRED
 150    gio-2.0 >= $GLIB_REQUIRED
 151    gio-unix-2.0 >= $GLIB_REQUIRED
 152    gnome-keyring-1 >= $KEYRING_REQUIRED
 153    gobject-2.0
 154    gstreamer-0.10
 155    gstreamer-interfaces-0.10
 156    libebook-1.2
 157    libxml-2.0
 158    telepathy-farsight
 159    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 160    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 161    x11
 162 ])
 163
 164 # -----------------------------------------------------------
 165 # GTK+
 166 # -----------------------------------------------------------
 167 AC_ARG_ENABLE(gtk3,
 168               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 169                              [build with GTK+3]), ,
 170                              enable_gtk3=auto)
 171
 172 # Try to use GTK+3 if available
 173 if test "x$enable_gtk3" != "xno"; then
 174   PKG_CHECK_MODULES(GTK, [gtk+-3.0 >= $GTK_REQUIRED],
 175       enable_gtk3="yes", enable_gtk3="no")
 176
 177   # GTK3 specific deps
 178   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 179   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 180   PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 181 fi
 182
 183 # ...if not use GTK+2
 184 if test "x$enable_gtk3" == "xno"; then
 185   enable_gtk3=no
 186   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 187
 188   # GTK2 specific deps
 189   PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 190   PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 191   PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 192
 193   # Enable GSEAL checks if needed
 194   if test $USE_MAINTAINER_MODE = yes; then
 195     AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 196   fi
 197 fi
 198
 199 # -----------------------------------------------------------
 200 # Enable debug
 201 # -----------------------------------------------------------
 202
 203 AC_ARG_ENABLE(debug,
 204   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 205     enable_debug=$enableval, enable_debug=yes )
 206
 207 if test x$enable_debug = xyes; then
 208   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 209 fi
 210
 211 # -----------------------------------------------------------
 212 # Language Support
 213 # -----------------------------------------------------------
 214
 215 GETTEXT_PACKAGE=empathy
 216 AC_SUBST(GETTEXT_PACKAGE)
 217 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 218
 219 AM_GLIB_GNU_GETTEXT
 220
 221 # -----------------------------------------------------------
 222 # Connectivity integration
 223 # -----------------------------------------------------------
 224 AC_ARG_WITH(connectivity,
 225               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 226                              [build with connectivity support]), ,
 227                              with_connectivity=auto)
 228
 229 if test "x$with_connectivity" = "xno"; then
 230    have_nm=no
 231    have_connman=no
 232
 233 elif test "x$with_connectivity" = "xconnman"; then
 234
 235    PKG_CHECK_MODULES(CONNMAN,
 236    [
 237       dbus-glib-1
 238    ], have_connman="yes", have_connman="no")
 239
 240    if test "x$have_connman" = "xyes"; then
 241       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 242       have_nm=no
 243    fi
 244
 245 else
 246
 247    PKG_CHECK_MODULES(NETWORK_MANAGER,
 248    [
 249       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 250    ], have_nm="yes", have_nm="no")
 251
 252    if test "x$have_nm" = "xyes"; then
 253       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 254       have_connman=no
 255    else
 256       PKG_CHECK_MODULES(NETWORK_MANAGER,
 257       [
 258           libnm-glib >= $NETWORK_MANAGER_REQUIRED
 259       ], have_nm="yes", have_nm="no")
 260
 261       if test "x$have_nm" = "xyes"; then
 262       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 263       have_connman=no
 264       fi
 265    fi
 266 fi
 267
 268 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 269    AC_MSG_ERROR([Couldn't find connman dependencies.])
 270 fi
 271
 272 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 273    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 274 fi
 275
 276 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 277 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 278
 279 # -----------------------------------------------------------
 280 # Webkit
 281 # -----------------------------------------------------------
 282 AC_ARG_ENABLE(webkit,
 283               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 284                              [build with webkit support]), ,
 285                              enable_webkit=auto)
 286
 287 if test "x$enable_webkit" != "xno"; then
 288
 289    if test "x$enable_gtk3" == "xno"; then
 290       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 291           have_webkit="yes", have_webkit="no")
 292    else
 293       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 294           have_webkit="yes", have_webkit="no")
 295    fi
 296
 297    if test "x$have_webkit" = "xyes"; then
 298       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 299    fi
 300 else
 301    have_webkit=no
 302 fi
 303
 304 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 305    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 306 fi
 307 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 308
 309 # -----------------------------------------------------------
 310 # spellchecking checks: enchant and iso-codes
 311 # -----------------------------------------------------------
 312 AC_ARG_ENABLE(spell,
 313               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 314                              [Enable spell checking]), ,
 315                              enable_spell=auto)
 316
 317 if test "x$enable_spell" != "xno"; then
 318    PKG_CHECK_MODULES(ENCHANT,
 319    [
 320       enchant >= $ENCHANT_REQUIRED,
 321       iso-codes >= $ISO_CODES_REQUIRED
 322    ], have_enchant="yes", have_enchant="no")
 323
 324    if test "x$have_enchant" = "xyes"; then
 325       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 326       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 327          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 328             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 329             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 330             result=yes
 331       else
 332             result=no
 333             have_enchant="no"
 334       fi
 335       AC_MSG_RESULT([$result])
 336    fi
 337 else
 338    have_enchant=no
 339 fi
 340
 341 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 342    AC_MSG_ERROR([Couldn't find spell dependencies.])
 343 fi
 344
 345 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 346
 347 # -----------------------------------------------------------
 348 # Map view checks: libchamplain
 349 # -----------------------------------------------------------
 350 AC_ARG_ENABLE(map,
 351               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 352                              [Enable map view]), ,
 353                              enable_map=auto)
 354
 355 if test "x$enable_map" != "xno"; then
 356
 357    if test "x$enable_gtk3" == "xno"; then
 358       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 359       [
 360          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 361          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 362          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 363       ], have_libchamplain="yes", have_libchamplain="no")
 364    else
 365       have_libchamplain="no"
 366    fi
 367
 368    if test "x$have_libchamplain" = "xyes"; then
 369       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 370    fi
 371 else
 372    # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 373    have_libchamplain=no
 374 fi
 375
 376 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 377    AC_MSG_ERROR([Couldn't find map view dependencies.])
 378 fi
 379
 380 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 381
 382 # -----------------------------------------------------------
 383 # location checks: geoclue
 384 # -----------------------------------------------------------
 385 AC_ARG_ENABLE(location,
 386               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 387                              [Enable location awareness]), ,
 388                              enable_location=auto)
 389
 390 if test "x$enable_location" != "xno"; then
 391    PKG_CHECK_MODULES(GEOCLUE,
 392    [
 393       geoclue >= $GEOCLUE_REQUIRED
 394    ], have_geoclue="yes", have_geoclue="no")
 395
 396    if test "x$have_geoclue" = "xyes"; then
 397       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 398    fi
 399 else
 400    have_geoclue="no"
 401 fi
 402
 403 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 404    AC_MSG_ERROR([Couldn't find location dependencies.])
 405 fi
 406
 407 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 408 AC_SUBST(GEOCLUE_CFLAGS)
 409 AC_SUBST(GEOCLUE_LIBS)
 410
 411 # -----------------------------------------------------------
 412 # meego widgets support
 413 # -----------------------------------------------------------
 414 AC_ARG_ENABLE(meego,
 415               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 416                              [Enable meego widgets]), ,
 417                              enable_meego=no)
 418
 419 if test "x$enable_meego" != "xno"; then
 420     PKG_CHECK_MODULES(MEEGO,
 421     [
 422        mx-gtk-1.0
 423     ], have_meego="yes", have_meego="no")
 424
 425     if test "x$have_meego" = "xyes"; then
 426        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 427     fi
 428 else
 429    have_meego="no"
 430 fi
 431
 432 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 433    AC_MSG_ERROR([Couldn't find meego dependencies.])
 434 fi
 435
 436 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 437 AC_SUBST(MEEGO_CFLAGS)
 438 AC_SUBST(MEEGO_LIBS)
 439
 440 # -----------------------------------------------------------
 441 # nautilus-sendto
 442 # -----------------------------------------------------------
 443 AC_ARG_ENABLE(nautilus-sendto,
 444               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 445                              [build nautilus-sendto plugin]), ,
 446                              enable_nautilus_sendto=auto)
 447
 448 if test "x$enable_nautilus_sendto" != "xno"; then
 449    if test "x$enable_gtk3" == "xno"; then
 450       # Newer NST requires GTK+3 so we can't use it
 451       PKG_CHECK_MODULES(NST,[nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 452           nautilus-sendto < 2.90.0],
 453           have_nst="yes", have_nst="no")
 454
 455       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 456    else
 457       PKG_CHECK_MODULES(NST,[nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3],
 458           have_nst="yes", have_nst="no")
 459    fi
 460 else
 461    have_nst=no
 462 fi
 463
 464 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 465    AC_MSG_ERROR([Couldn't find nautilus-sendto dependencies.])
 466 fi
 467
 468 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 469
 470 # -----------------------------------------------------------
 471 # new, single-window control center
 472 # -----------------------------------------------------------
 473 AC_ARG_ENABLE(control_center_embedding,
 474               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 475                              [Enable support for single-window control center]),
 476                              , enable_control_center_embedding=auto)
 477
 478 if test "x$enable_control_center_embedding" != "xno"; then
 479    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
 480    [
 481       libgnome-control-center-extension
 482    ], have_control_center_embedding="yes", have_control_center_embedding="no")
 483
 484    if test "x$have_control_center_embedding" = "xyes"; then
 485       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 486    fi
 487 else
 488    have_control_center_embedding="no"
 489 fi
 490
 491 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 492    AC_MSG_ERROR([Couldn't find single-window control center dependencies.])
 493 fi
 494
 495 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 496 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 497 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 498
 499 # -----------------------------------------------------------
 500 # Coding style checks
 501 # -----------------------------------------------------------
 502 AC_ARG_ENABLE(coding-style-checks,
 503   AC_HELP_STRING([--disable-coding-style-checks],
 504                  [don't check coding style using grep]),
 505     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 506
 507 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 508 # -----------------------------------------------------------
 509
 510 AC_OUTPUT([
 511    Makefile
 512    data/Makefile
 513    data/empathy.desktop.in
 514    data/empathy-accounts.desktop.in
 515    data/icons/Makefile
 516    extensions/Makefile
 517    po/Makefile.in
 518    libempathy/Makefile
 519    libempathy-gtk/Makefile
 520    src/Makefile
 521    nautilus-sendto-plugin/Makefile
 522    help/Makefile
 523    tests/Makefile
 524    tests/interactive/Makefile
 525    tests/xml/Makefile
 526    tools/Makefile
 527 ])
 528
 529 echo "
 530 Configure summary:
 531
 532         Compiler....................:  ${CC}
 533         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 534         Prefix......................:  ${prefix}
 535         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 536         Use GTK+3...................:  ${enable_gtk3}
 537
 538     Features:
 539         Spell checking (enchant)....:  ${have_enchant}
 540         Display maps (libchamplain).:  ${have_libchamplain}
 541         Location awareness (Geoclue):  ${have_geoclue}
 542         Adium themes (Webkit).......:  ${have_webkit}
 543         Meego widgets ..............:  ${have_meego}
 544         Control center embedding....:  ${have_control_center_embedding}
 545
 546     Connectivity:
 547         NetworkManager integration..:  ${have_nm}
 548         ConnMan integration.........:  ${have_connman}
 549
 550     Extras:
 551         Nautilus-sendto plugin......:  ${have_nst}
 552 "