configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [2])
   5 m4_define([empathy_minor_version], [31])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.1.13
  35 GCONF_REQUIRED=1.2.0
  36 GLIB_REQUIRED=2.25.9
  37 GNUTLS_REQUIRED=2.8.5
  38 GTK_REQUIRED=2.21.2
  39 KEYRING_REQUIRED=2.26.0
  40 LIBCANBERRA_GTK_REQUIRED=0.4
  41 LIBNOTIFY_REQUIRED=0.4.4
  42 LIBNOTIFY_REQUIRED_GTK3=0.5.1
  43 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  44 TELEPATHY_GLIB_REQUIRED=0.11.13
  45 TELEPATHY_LOGGER=0.1.5
  46 UNIQUE_REQUIRED=1.1.2
  47
  48 # Optionnal deps
  49 CLUTTER_GTK_REQUIRED=0.10
  50 ENCHANT_REQUIRED=1.2.0
  51 GEOCLUE_REQUIRED=0.11
  52 ISO_CODES_REQUIRED=0.35
  53 LIBCHAMPLAIN_GTK_REQUIRED=0.4
  54 LIBCHAMPLAIN_REQUIRED=0.4
  55 NAUTILUS_SENDTO_REQUIRED=2.28.1
  56 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
  57 NETWORK_MANAGER_REQUIRED=0.7.0
  58 WEBKIT_REQUIRED=1.1.15
  59 GNOME_CONTROL_CENTER_GTK3_REQUIRED=2.31.4
  60
  61 # Use --enable-maintainer-mode to disable deprecated symbols,
  62 # disable single include and enable GSEAL. If this is not a released empathy,
  63 # maintainer mode is forced
  64 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  65 GNOME_MAINTAINER_MODE_DEFINES
  66
  67 AC_CONFIG_MACRO_DIR([m4])
  68 AC_CONFIG_HEADERS([config.h])
  69 AC_CONFIG_SRCDIR([configure.ac])
  70 AC_CONFIG_AUX_DIR(.)
  71
  72 GNOME_COMMON_INIT
  73
  74 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  75
  76 # Support silent build rules, requires at least automake-1.11. Disable
  77 # by either passing --disable-silent-rules to configure or passing V=1
  78 # to make
  79 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  80
  81 AC_ISC_POSIX
  82 AC_PROG_CC
  83 AC_HEADER_STDC
  84 AM_PROG_LIBTOOL
  85 AM_PROG_MKDIR_P
  86 AM_PATH_GLIB_2_0
  87 AC_PATH_XTRA
  88 IT_PROG_INTLTOOL([0.35.0])
  89 GNOME_DOC_INIT([0.17.3])
  90 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  91 GLIB_GSETTINGS
  92 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  93 AC_SUBST(GLIB_GENMARSHAL)
  94
  95 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  96 if test -z "$XSLTPROC"; then
  97   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  98 fi
  99 AM_PATH_PYTHON([2.3])
 100
 101 EMPATHY_ARG_VALGRIND
 102
 103
 104 # -----------------------------------------------------------
 105 # Error flags
 106 # -----------------------------------------------------------
 107 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 108 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 109
 110 AC_ARG_ENABLE(Werror,
 111   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 112     werror=$enableval, :)
 113
 114 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 115 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 116         wno_missing_field_initializers=yes,
 117         wno_missing_field_initializers=no)
 118 AS_COMPILER_FLAG(-Wno-unused-parameter,
 119         wno_unused_parameter=yes,
 120         wno_unused_parameter=no)
 121
 122 ifelse(empathy_released, 1, [],
 123     [
 124         if test x$werror = xyes; then
 125             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 126         fi
 127         if test x$wextra = xyes -a \
 128             x$wno_missing_field_initializers = xyes -a \
 129             x$wno_unused_parameter = xyes; then
 130             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 131         fi
 132     ])
 133
 134 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 135 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 136 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 137 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 138 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
 139 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 140
 141 AC_SUBST(ERROR_CFLAGS)
 142
 143 # -----------------------------------------------------------
 144 # Pkg-Config dependency checks
 145 # -----------------------------------------------------------
 146
 147 PKG_CHECK_MODULES(EMPATHY,
 148 [
 149    dbus-glib-1
 150    farsight2-0.10
 151    folks >= $FOLKS_REQUIRED
 152    folks-telepathy >= $FOLKS_REQUIRED
 153    gconf-2.0 >= $GCONF_REQUIRED
 154    gcr-0 >= $KEYRING_REQUIRED
 155    gio-2.0 >= $GLIB_REQUIRED
 156    gio-unix-2.0 >= $GLIB_REQUIRED
 157    gnome-keyring-1 >= $KEYRING_REQUIRED
 158    gnutls >= $GNUTLS_REQUIRED
 159    gobject-2.0
 160    gstreamer-0.10
 161    gstreamer-interfaces-0.10
 162    libxml-2.0
 163    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 164    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 165    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
 166    x11
 167 ])
 168
 169 # -----------------------------------------------------------
 170 # evolution-data-server (about-me)
 171 # -----------------------------------------------------------
 172 AC_ARG_WITH(eds,
 173             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 174             [with_eds=yes])
 175 if test x"$with_eds" = x"yes" ; then
 176    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 177    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 178 fi
 179
 180 # -----------------------------------------------------------
 181 # GTK+
 182 # -----------------------------------------------------------
 183 AC_ARG_ENABLE(gtk3,
 184               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
 185                              [build with GTK+3]), ,
 186                              enable_gtk3=auto)
 187
 188 # Try to use GTK+3 if available
 189 if test "x$enable_gtk3" != "xno"; then
 190    PKG_CHECK_MODULES(GTK,
 191    [
 192       gtk+-3.0 >= $GTK_REQUIRED
 193    ], have_gtk3="yes", have_gtk3="no")
 194 else
 195    have_gtk3="no"
 196 fi
 197
 198 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
 199    AC_MSG_ERROR([Could not find gtk3 dependencies.])
 200 fi
 201
 202 if test "x$have_gtk3" == "xyes"; then
 203    # GTK3 specific deps
 204    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
 205    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
 206    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
 207 else
 208    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
 209
 210    # GTK2 specific deps
 211    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
 212    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 213    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
 214
 215    # Enable GSEAL checks if needed
 216    if test $USE_MAINTAINER_MODE = yes; then
 217       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
 218    fi
 219 fi
 220
 221 # -----------------------------------------------------------
 222 # Enable debug
 223 # -----------------------------------------------------------
 224
 225 AC_ARG_ENABLE(debug,
 226   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 227     enable_debug=$enableval, enable_debug=yes )
 228
 229 if test x$enable_debug = xyes; then
 230   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 231 fi
 232
 233 # -----------------------------------------------------------
 234 # Language Support
 235 # -----------------------------------------------------------
 236
 237 GETTEXT_PACKAGE=empathy
 238 AC_SUBST(GETTEXT_PACKAGE)
 239 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 240
 241 AM_GLIB_GNU_GETTEXT
 242
 243 # -----------------------------------------------------------
 244 # Connectivity integration
 245 # -----------------------------------------------------------
 246 AC_ARG_WITH(connectivity,
 247               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 248                              [build with connectivity support]), ,
 249                              with_connectivity=auto)
 250
 251 if test "x$with_connectivity" = "xno"; then
 252    have_nm=no
 253    have_connman=no
 254
 255 elif test "x$with_connectivity" = "xconnman"; then
 256    have_nm=no
 257
 258    PKG_CHECK_MODULES(CONNMAN,
 259    [
 260       dbus-glib-1
 261    ], have_connman="yes", have_connman="no")
 262
 263    if test "x$have_connman" = "xyes"; then
 264       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 265    fi
 266
 267 else
 268    have_connman=no
 269
 270    PKG_CHECK_MODULES(NETWORK_MANAGER,
 271    [
 272       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 273    ], have_nm="yes", have_nm="no")
 274
 275    if test "x$have_nm" = "xyes"; then
 276       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 277    fi
 278 fi
 279
 280 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 281    AC_MSG_ERROR([Couldn't find connman dependencies.])
 282 fi
 283
 284 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 285    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 286 fi
 287
 288 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 289 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 290
 291 # -----------------------------------------------------------
 292 # Webkit
 293 # -----------------------------------------------------------
 294 AC_ARG_ENABLE(webkit,
 295               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 296                              [build with webkit support]), ,
 297                              enable_webkit=auto)
 298
 299 if test "x$enable_webkit" != "xno"; then
 300
 301    if test "x$have_gtk3" == "xno"; then
 302       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
 303           have_webkit="yes", have_webkit="no")
 304    else
 305       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 306           have_webkit="yes", have_webkit="no")
 307    fi
 308
 309    if test "x$have_webkit" = "xyes"; then
 310       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 311    fi
 312 else
 313    have_webkit=no
 314 fi
 315
 316 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 317    AC_MSG_ERROR([Could not find webkit dependencies.])
 318 fi
 319 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 320
 321 # -----------------------------------------------------------
 322 # spellchecking checks: enchant and iso-codes
 323 # -----------------------------------------------------------
 324 AC_ARG_ENABLE(spell,
 325               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 326                              [Enable spell checking]), ,
 327                              enable_spell=auto)
 328
 329 if test "x$enable_spell" != "xno"; then
 330    PKG_CHECK_MODULES(ENCHANT,
 331    [
 332       enchant >= $ENCHANT_REQUIRED,
 333       iso-codes >= $ISO_CODES_REQUIRED
 334    ], have_enchant="yes", have_enchant="no")
 335
 336    if test "x$have_enchant" = "xyes"; then
 337       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 338       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 339          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 340             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 341             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 342             result=yes
 343       else
 344             result=no
 345             have_enchant="no"
 346       fi
 347       AC_MSG_RESULT([$result])
 348    fi
 349 else
 350    have_enchant=no
 351 fi
 352
 353 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 354    AC_MSG_ERROR([Could not find spell dependencies.])
 355 fi
 356
 357 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 358
 359 # -----------------------------------------------------------
 360 # Map view checks: libchamplain
 361 # -----------------------------------------------------------
 362 AC_ARG_ENABLE(map,
 363               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 364                              [Enable map view]), ,
 365                              enable_map=auto)
 366
 367 if test "x$enable_map" != "xno"; then
 368
 369    if test "x$have_gtk3" == "xno"; then
 370       PKG_CHECK_MODULES(LIBCHAMPLAIN,
 371       [
 372          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
 373          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
 374          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
 375       ], have_libchamplain="yes", have_libchamplain="no")
 376    else
 377       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
 378       have_libchamplain="no"
 379    fi
 380
 381    if test "x$have_libchamplain" = "xyes"; then
 382       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 383    fi
 384 else
 385    have_libchamplain=no
 386 fi
 387
 388 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 389    AC_MSG_ERROR([Could not find map view dependencies.])
 390 fi
 391
 392 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 393
 394 # -----------------------------------------------------------
 395 # location checks: geoclue
 396 # -----------------------------------------------------------
 397 AC_ARG_ENABLE(location,
 398               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 399                              [Enable location awareness]), ,
 400                              enable_location=auto)
 401
 402 if test "x$enable_location" != "xno"; then
 403    PKG_CHECK_MODULES(GEOCLUE,
 404    [
 405       geoclue >= $GEOCLUE_REQUIRED
 406    ], have_geoclue="yes", have_geoclue="no")
 407
 408    if test "x$have_geoclue" = "xyes"; then
 409       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 410    fi
 411 else
 412    have_geoclue="no"
 413 fi
 414
 415 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 416    AC_MSG_ERROR([Could not find location dependencies.])
 417 fi
 418
 419 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 420 AC_SUBST(GEOCLUE_CFLAGS)
 421 AC_SUBST(GEOCLUE_LIBS)
 422
 423 # -----------------------------------------------------------
 424 # meego widgets support
 425 # -----------------------------------------------------------
 426 AC_ARG_ENABLE(meego,
 427               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
 428                              [Enable meego widgets]), ,
 429                              enable_meego=no)
 430
 431 if test "x$enable_meego" != "xno"; then
 432     PKG_CHECK_MODULES(MEEGO,
 433     [
 434        mx-gtk-1.0
 435     ], have_meego="yes", have_meego="no")
 436
 437     if test "x$have_meego" = "xyes"; then
 438        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 439     fi
 440 else
 441    have_meego="no"
 442 fi
 443
 444 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 445    AC_MSG_ERROR([Could not find meego dependencies.])
 446 fi
 447
 448 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 449 AC_SUBST(MEEGO_CFLAGS)
 450 AC_SUBST(MEEGO_LIBS)
 451
 452 # -----------------------------------------------------------
 453 # nautilus-sendto
 454 # -----------------------------------------------------------
 455 AC_ARG_ENABLE(nautilus-sendto,
 456               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 457                              [build nautilus-sendto plugin]), ,
 458                              enable_nautilus_sendto=auto)
 459
 460 if test "x$enable_nautilus_sendto" != "xno"; then
 461    if test "x$have_gtk3" == "xno"; then
 462       # Newer NST requires GTK+3 so we can't use it
 463       PKG_CHECK_MODULES(NST,
 464       [
 465          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 466          nautilus-sendto < 2.90.0
 467       ], have_nst="yes", have_nst="no")
 468
 469       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
 470    else
 471       PKG_CHECK_MODULES(NST,
 472       [
 473          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
 474       ], have_nst="yes", have_nst="no")
 475    fi
 476 else
 477    have_nst=no
 478 fi
 479
 480 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 481    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 482 fi
 483
 484 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 485
 486 # -----------------------------------------------------------
 487 # new, single-window control center
 488 # -----------------------------------------------------------
 489 AC_ARG_ENABLE(control_center_embedding,
 490               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 491                              [Enable support for single-window control center]),
 492                              , enable_control_center_embedding=auto)
 493
 494 if test "x$enable_control_center_embedding" != "xno"; then
 495
 496    if test "x$have_gtk3" == "xno"; then
 497       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center < GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 498           have_control_center_embedding="yes", have_control_center_embedding="no")
 499    else
 500       PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_GTK3_REQUIRED],
 501           have_control_center_embedding="yes", have_control_center_embedding="no")
 502    fi
 503
 504    if test "x$have_control_center_embedding" = "xyes"; then
 505       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 506
 507       AC_MSG_CHECKING([gnome-control-center extension dir])
 508       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 509       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 510           AC_MSG_ERROR([Could not determine extensiondir])
 511       else
 512           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 513       fi
 514       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 515    fi
 516 else
 517    have_control_center_embedding="no"
 518 fi
 519
 520 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 521    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 522 fi
 523
 524 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 525 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 526 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 527
 528 # -----------------------------------------------------------
 529 # Coding style checks
 530 # -----------------------------------------------------------
 531 AC_ARG_ENABLE(coding-style-checks,
 532   AC_HELP_STRING([--disable-coding-style-checks],
 533                  [do not check coding style using grep]),
 534     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 535
 536 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 537 # -----------------------------------------------------------
 538
 539 AC_OUTPUT([
 540    Makefile
 541    data/Makefile
 542    data/empathy.desktop.in
 543    data/empathy-accounts.desktop.in
 544    data/icons/Makefile
 545    extensions/Makefile
 546    po/Makefile.in
 547    libempathy/Makefile
 548    libempathy-gtk/Makefile
 549    src/Makefile
 550    nautilus-sendto-plugin/Makefile
 551    help/Makefile
 552    tests/Makefile
 553    tests/interactive/Makefile
 554    tests/xml/Makefile
 555    tools/Makefile
 556 ])
 557
 558 echo "
 559 Configure summary:
 560
 561         Compiler....................:  ${CC}
 562         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 563         Prefix......................:  ${prefix}
 564         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 565         Use GTK+3...................:  ${have_gtk3}
 566
 567     Features:
 568         Spell checking (enchant)....:  ${have_enchant}
 569         Display maps (libchamplain).:  ${have_libchamplain}
 570         Location awareness (Geoclue):  ${have_geoclue}
 571         Adium themes (Webkit).......:  ${have_webkit}
 572         Meego widgets ..............:  ${have_meego}
 573         Control center embedding....:  ${have_control_center_embedding}
 574
 575     Connectivity:
 576         NetworkManager integration..:  ${have_nm}
 577         ConnMan integration.........:  ${have_connman}
 578
 579     Extras:
 580         Nautilus-sendto plugin......:  ${have_nst}
 581         Salut E-D-S support.........:  ${with_eds}
 582 "