configure.ac

   1 AC_INIT(Empathy, 2.25.90, http://bugzilla.gnome.org/browse.cgi?product=empathy)
   2 AC_PREREQ(2.59)
   3 AC_COPYRIGHT([
   4   Copyright (C) 2003-2007 Imendio AB
   5   Copyright (C) 2007-2008 Collabora Ltd.
   6 ])
   7
   8 # LT Version numbers, remember to change them just *before* a release.
   9 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
  10 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
  11 #   (No interfaces changed:                   REVISION++)
  12 LIBEMPATHY_CURRENT=20
  13 LIBEMPATHY_AGE=0
  14 LIBEMPATHY_REVISION=0
  15
  16 LIBEMPATHY_GTK_CURRENT=19
  17 LIBEMPATHY_GTK_AGE=0
  18 LIBEMPATHY_GTK_REVISION=0
  19
  20 AC_SUBST(LIBEMPATHY_CURRENT)
  21 AC_SUBST(LIBEMPATHY_AGE)
  22 AC_SUBST(LIBEMPATHY_REVISION)
  23 AC_SUBST(LIBEMPATHY_GTK_CURRENT)
  24 AC_SUBST(LIBEMPATHY_GTK_AGE)
  25 AC_SUBST(LIBEMPATHY_GTK_REVISION)
  26
  27 # Minimal version required
  28 GLIB_REQUIRED=2.16.0
  29 GTK_REQUIRED=2.14.0
  30 GCONF_REQUIRED=1.2.0
  31 LIBGLADE_REQUIRED=2.0.0
  32 LIBPANELAPPLET_REQUIRED=2.10.0
  33 TELEPATHY_GLIB_REQUIRED=0.7.19
  34 MISSION_CONTROL_REQUIRED=4.61
  35 ENCHANT_REQUIRED=1.2.0
  36 ISO_CODES_REQUIRED=0.35
  37 LIBNOTIFY_REQUIRED=0.4.4
  38
  39 # Uncomment that to build with deprecated symbols disabled
  40 #AC_DEFINE(G_DISABLE_DEPRECATED, [], [Disable deprecated GLib symbols])
  41 #AC_DEFINE(GDK_PIXBUF_DISABLE_DEPRECATED, [], [Disable deprecated GDK pixbuf symbols])
  42 #AC_DEFINE(GDK_DISABLE_DEPRECATED, [], [Disable deprecated GDK symbols])
  43 #AC_DEFINE(GTK_DISABLE_DEPRECATED, [], [Disable deprecated GTK symbols])
  44
  45 # Uncomment that to build with single include disabled
  46 #AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  47 #AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  48 #AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  49
  50 AC_CONFIG_MACRO_DIR([m4])
  51 AC_CONFIG_HEADERS([config.h])
  52 AC_CONFIG_SRCDIR([configure.ac])
  53 AC_CONFIG_AUX_DIR(.)
  54
  55 GNOME_COMMON_INIT
  56
  57 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  58 AM_MAINTAINER_MODE
  59 AC_ISC_POSIX
  60 AC_PROG_CC
  61 AC_HEADER_STDC
  62 AM_PROG_LIBTOOL
  63 AM_PROG_MKDIR_P
  64 AM_PATH_GLIB_2_0
  65 AC_PATH_XTRA
  66 IT_PROG_INTLTOOL([0.35.0])
  67 GTK_DOC_CHECK([1.3])
  68 GNOME_DOC_INIT
  69 IDT_COMPILE_WARNINGS
  70 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  71 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  72 AM_GCONF_SOURCE_2
  73 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  74 AC_SUBST(GLIB_GENMARSHAL)
  75
  76 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  77 if test -z "$XSLTPROC"; then
  78   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  79 fi
  80 AM_PATH_PYTHON([2.3])
  81
  82 EMPATHY_ARG_VALGRIND
  83
  84 # -----------------------------------------------------------
  85 # Pkg-Config dependency checks
  86 # -----------------------------------------------------------
  87
  88 PKG_CHECK_MODULES(LIBEMPATHY,
  89 [
  90    glib-2.0 >= $GLIB_REQUIRED
  91    gobject-2.0
  92    libxml-2.0
  93    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
  94    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  95    gio-2.0 >= $GLIB_REQUIRED
  96    gio-unix-2.0 >= $GLIB_REQUIRED
  97 ])
  98
  99 PKG_CHECK_MODULES(EMPATHY,
 100 [
 101    glib-2.0 >= $GLIB_REQUIRED
 102    gobject-2.0
 103    gio-2.0 >= $GLIB_REQUIRED
 104    gconf-2.0 >= $GCONF_REQUIRED
 105    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 106    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 107    gtk+-2.0 >= $GTK_REQUIRED
 108    x11
 109    libglade-2.0 >= $LIBGLADE_REQUIRED
 110    libebook-1.2
 111    libcanberra-gtk >= 0.4
 112 ])
 113
 114 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 115
 116 # -----------------------------------------------------------
 117 # Enable debug
 118 # -----------------------------------------------------------
 119
 120 AC_ARG_ENABLE(debug,
 121   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 122     enable_debug=$enableval, enable_debug=yes )
 123
 124 if test x$enable_debug = xyes; then
 125   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 126 fi
 127
 128 # -----------------------------------------------------------
 129 # Language Support
 130 # -----------------------------------------------------------
 131
 132 GETTEXT_PACKAGE=empathy
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 135
 136 AM_GLIB_GNU_GETTEXT
 137
 138 # -----------------------------------------------------------
 139 # spellchecking checks: enchant and iso-codes
 140 # -----------------------------------------------------------
 141 AC_ARG_ENABLE(spell,
 142               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 143                              [Enable spell checking]), ,
 144                              enable_spell=auto)
 145
 146 if test "x$enable_spell" != "xno"; then
 147    PKG_CHECK_MODULES(ENCHANT,
 148    [
 149       enchant >= $ENCHANT_REQUIRED,
 150       iso-codes >= $ISO_CODES_REQUIRED
 151    ], have_enchant="yes", have_enchant="no")
 152
 153    if test "x$have_enchant" = "xyes"; then
 154       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 155       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 156          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 157             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 158             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 159             result=yes
 160       else
 161             result=no
 162             have_enchant="no"
 163       fi
 164       AC_MSG_RESULT([$result])
 165    fi
 166 else
 167    have_enchant=no
 168 fi
 169
 170 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 171    AC_MSG_ERROR([Couldn't find spell dependencies.])
 172 fi
 173
 174 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 175
 176 # -----------------------------------------------------------
 177 # Megaphone
 178 # -----------------------------------------------------------
 179 AC_ARG_ENABLE(megaphone,
 180               AS_HELP_STRING([--enable-megaphone=@<:@no/yes/auto@:>@],
 181                              [build megaphone applet]), ,
 182                              enable_megaphone=auto)
 183
 184 if test "x$enable_megaphone" != "xno"; then
 185    PKG_CHECK_MODULES(MEGAPHONE,
 186    [
 187       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 188       glib-2.0 >= $GLIB_REQUIRED
 189       gtk+-2.0 >= $GTK_REQUIRED
 190       gconf-2.0 >= $GCONF_REQUIRED
 191       libglade-2.0 >= $LIBGLADE_REQUIRED
 192       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 193    ], have_megaphone="yes", have_megaphone="no")
 194 else
 195    have_megaphone=no
 196 fi
 197
 198 if test "x$enable_megaphone" = "xyes" -a "x$have_megaphone" != "xyes"; then
 199    AC_MSG_ERROR([Couldn't find megaphone dependencies.])
 200 fi
 201
 202 AM_CONDITIONAL(HAVE_MEGAPHONE, test "x$have_megaphone" = "xyes")
 203
 204 # -----------------------------------------------------------
 205 # Nothere
 206 # -----------------------------------------------------------
 207 AC_ARG_ENABLE(nothere,
 208               AS_HELP_STRING([--enable-nothere=@<:@no/yes/auto@:>@],
 209                              [build nothere applet]), ,
 210                              enable_nothere=auto)
 211
 212 if test "x$enable_nothere" != "xno"; then
 213    PKG_CHECK_MODULES(NOTHERE,
 214    [
 215       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 216       glib-2.0 >= $GLIB_REQUIRED
 217       gtk+-2.0 >= $GTK_REQUIRED
 218       gconf-2.0 >= $GCONF_REQUIRED
 219       libglade-2.0 >= $LIBGLADE_REQUIRED
 220       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 221    ], have_nothere="yes", have_nothere="no")
 222 else
 223    have_nothere=no
 224 fi
 225
 226 if test "x$enable_nothere" = "xyes" -a "x$have_nothere" != "xyes"; then
 227    AC_MSG_ERROR([Couldn't find nothere dependencies.])
 228 fi
 229
 230 AM_CONDITIONAL(HAVE_NOTHERE, test "x$have_nothere" = "xyes")
 231
 232 # -----------------------------------------------------------
 233 # Tests
 234 # -----------------------------------------------------------
 235 AC_ARG_ENABLE(tests,
 236               AS_HELP_STRING([--enable-tests=@<:@no/yes/auto@:>@],
 237                              [build tests]), ,
 238                              enable_tests=auto)
 239
 240 if test "x$enable_tests" != "xno"; then
 241    PKG_CHECK_MODULES(CHECK,
 242    [
 243       check >= 0.9.4
 244    ], have_check="yes", have_check="no")
 245 else
 246    have_check=no
 247 fi
 248
 249 if test "x$enable_tests" = "xyes" -a "x$have_check" != "xyes"; then
 250    AC_MSG_ERROR([Couldn't find check dependencies.])
 251 fi
 252
 253 AM_CONDITIONAL(HAVE_TESTS, test "x$have_check" = "xyes")
 254
 255 # -----------------------------------------------------------
 256 # Python Bindings
 257 # -----------------------------------------------------------
 258 AC_ARG_ENABLE(python,
 259               AS_HELP_STRING([--enable-python=@<:@no/yes/auto@:>@],
 260                              [build python bindings to libempathy and libempathy-gtk]), ,
 261                              enable_python=auto)
 262
 263 if test "x$enable_python" != "xno"; then
 264    PKG_CHECK_MODULES(PYTHON_BINDING,
 265    [
 266       pygtk-2.0,
 267       glib-2.0 >= $GLIB_REQUIRED
 268       gobject-2.0
 269       gconf-2.0 >= $GCONF_REQUIRED
 270       libxml-2.0
 271       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 272       gtk+-2.0 >= $GTK_REQUIRED
 273       libglade-2.0 >= $LIBGLADE_REQUIRED
 274    ], have_python="yes", have_python="no")
 275    if test "x$have_python" = "xyes" ; then
 276       AM_CHECK_PYTHON_HEADERS(,have_python="no")
 277       AC_CHECK_PROGS([PYGOBJECTCODEGEN], [pygobject-codegen-2.0 pygtk-codegen-2.0])
 278    fi
 279 else
 280    have_python=no
 281 fi
 282
 283 if test "x$enable_python" = "xyes" -a "x$have_python" != "xyes"; then
 284    AC_MSG_ERROR([Couldn't find python.])
 285 fi
 286
 287 AM_CONDITIONAL(HAVE_PYTHON, test "x$have_python" = "xyes")
 288
 289 # -----------------------------------------------------------
 290
 291 AC_OUTPUT([
 292    Makefile
 293    data/Makefile
 294    data/empathy.desktop.in
 295    data/icons/Makefile
 296    extensions/Makefile
 297    po/Makefile.in
 298    libempathy/Makefile
 299    libempathy/libempathy.pc
 300    libempathy-gtk/Makefile
 301    libempathy-gtk/libempathy-gtk.pc
 302    src/Makefile
 303    megaphone/Makefile
 304    megaphone/src/Makefile
 305    megaphone/data/Makefile
 306    nothere/Makefile
 307    nothere/src/Makefile
 308    nothere/data/Makefile
 309    docs/Makefile
 310    docs/libempathy/Makefile
 311    docs/libempathy/version.xml
 312    docs/libempathy-gtk/Makefile
 313    docs/libempathy-gtk/version.xml
 314    help/Makefile
 315    python/Makefile
 316    python/pyempathy/Makefile
 317    python/pyempathygtk/Makefile
 318    tests/Makefile
 319    tests/xml/Makefile
 320    tools/Makefile
 321 ])