configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [2])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.5.1
  35 GLIB_REQUIRED=2.28.0
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=3.0.2
  38 GSTREAMER_REQUIRED=0.10.32
  39 KEYRING_REQUIRED=2.26.0
  40 GCR_REQUIRED=2.91.4
  41 LIBCANBERRA_GTK_REQUIRED=0.25
  42 LIBNOTIFY_REQUIRED=0.7.0
  43 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  44 TELEPATHY_GLIB_REQUIRED=0.15.2
  45 TELEPATHY_LOGGER=0.2.10
  46
  47 # Optional deps
  48 CLUTTER_GTK_REQUIRED=0.90.3
  49 ENCHANT_REQUIRED=1.2.0
  50 GEOCLUE_REQUIRED=0.11
  51 ISO_CODES_REQUIRED=0.35
  52 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  53 LIBCHAMPLAIN_REQUIRED=0.9
  54 NAUTILUS_SENDTO_REQUIRED=2.90.0
  55 NETWORK_MANAGER_REQUIRED=0.7.0
  56 WEBKIT_REQUIRED=1.3.13
  57 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  58
  59 # Use --enable-maintainer-mode to disable deprecated symbols,
  60 # disable single include and enable GSEAL. If this is not a released empathy,
  61 # maintainer mode is forced
  62 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  63 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  64 #GNOME_MAINTAINER_MODE_DEFINES
  65
  66 # telepathy-yell
  67 prev_top_build_prefix=$ac_top_build_prefix
  68 prev_ac_configure_args=$ac_configure_args
  69 ac_configure_args="$ac_configure_args --disable-shared-library"
  70 AX_CONFIG_DIR([telepathy-yell])
  71 ac_top_build_prefix=$prev_top_build_prefix
  72 ac_configure_args=$prev_ac_configure_args
  73 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  74
  75 AC_CONFIG_MACRO_DIR([m4])
  76 AC_CONFIG_HEADERS([config.h])
  77 AC_CONFIG_SRCDIR([configure.ac])
  78 AC_CONFIG_AUX_DIR(.)
  79
  80 GNOME_COMMON_INIT
  81
  82 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  83
  84 # Support silent build rules, requires at least automake-1.11. Disable
  85 # by either passing --disable-silent-rules to configure or passing V=1
  86 # to make
  87 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  88
  89 AC_ISC_POSIX
  90 AC_PROG_CC
  91 AC_HEADER_STDC
  92 AM_PROG_LIBTOOL
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96 IT_PROG_INTLTOOL([0.35.0])
  97 GNOME_DOC_INIT([0.17.3])
  98 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  99 GLIB_GSETTINGS
 100 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 101 AC_SUBST(GLIB_GENMARSHAL)
 102
 103 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 104 if test -z "$XSLTPROC"; then
 105   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 106 fi
 107 AM_PATH_PYTHON([2.3])
 108
 109 EMPATHY_ARG_VALGRIND
 110
 111
 112 # -----------------------------------------------------------
 113 # Error flags
 114 # -----------------------------------------------------------
 115 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 116 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 117
 118 AC_ARG_ENABLE(Werror,
 119   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 120     werror=$enableval, :)
 121
 122 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 123 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 124         wno_missing_field_initializers=yes,
 125         wno_missing_field_initializers=no)
 126 AS_COMPILER_FLAG(-Wno-unused-parameter,
 127         wno_unused_parameter=yes,
 128         wno_unused_parameter=no)
 129
 130 ifelse(empathy_released, 1, [],
 131     [
 132         if test x$werror = xyes; then
 133             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 134         fi
 135         if test x$wextra = xyes -a \
 136             x$wno_missing_field_initializers = xyes -a \
 137             x$wno_unused_parameter = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 139         fi
 140     ])
 141
 142 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 143 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 144 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 145 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 146 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 147
 148 AC_SUBST(ERROR_CFLAGS)
 149
 150 # -----------------------------------------------------------
 151 # Pkg-Config dependency checks
 152 # -----------------------------------------------------------
 153
 154 PKG_CHECK_MODULES(EMPATHY,
 155 [
 156    dbus-glib-1
 157    folks >= $FOLKS_REQUIRED
 158    folks-telepathy >= $FOLKS_REQUIRED
 159    glib-2.0 >= $GLIB_REQUIRED
 160    gio-2.0 >= $GLIB_REQUIRED
 161    gio-unix-2.0 >= $GLIB_REQUIRED
 162    gnome-keyring-1 >= $KEYRING_REQUIRED
 163    gnutls >= $GNUTLS_REQUIRED
 164    gmodule-export-2.0
 165    gobject-2.0
 166    gsettings-desktop-schemas
 167    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 168    gstreamer-interfaces-0.10
 169    libxml-2.0
 170    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 171    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 172    x11
 173    gtk+-3.0 >= $GTK_REQUIRED
 174    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 175    libnotify >= $LIBNOTIFY_REQUIRED
 176    gcr-3 >= $GCR_REQUIRED
 177 ])
 178
 179 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 180
 181 PKG_CHECK_MODULES(EMPATHY_AV,
 182 [
 183    farsight2-0.10
 184    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 185 ])
 186
 187 # -----------------------------------------------------------
 188 # Call interface
 189 # -----------------------------------------------------------
 190 AC_ARG_WITH(call,
 191             AC_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 192             [build with Call interface support]),,
 193             [with_call=auto])
 194 if test "x$with_call" != "xno" ; then
 195    PKG_CHECK_MODULES(EMPATHY_CALL,
 196    [
 197       farsight2-0.10
 198       telepathy-farstream
 199    ], have_farstream="yes", have_farstream="no" )
 200
 201    if test "x$have_farstream" = "xyes"; then
 202       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 203    fi
 204 else
 205   have_farstream=no
 206 fi
 207
 208 if test "x$with_call" = "xyes" -a "x$have_farstream" != "xyes"; then
 209    AC_MSG_ERROR([Could not find Call handler dependencies.])
 210 fi
 211 AM_CONDITIONAL(HAVE_CALL, test "x$have_farstream" = "xyes")
 212
 213
 214 # -----------------------------------------------------------
 215 # Call support in tp-logger
 216 # -----------------------------------------------------------
 217 AC_ARG_WITH(call-logs,
 218             AC_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 219             [build with call logs support]),,
 220             [with_call_logs=auto])
 221 if test "x$with_call_logs" != "xno" ; then
 222    SAVE_CFLAGS=$CFLAGS
 223    SAVE_CPPFLAGS=$CPPFLAGS
 224    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 225    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 226
 227    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 228       have_call_logs="yes", have_call_logs="no")
 229
 230    CFLAGS=$SAVE_CFLAGS
 231    CPPFLAGS=$SAVE_CPPFLAGS
 232
 233    if test "x$have_call_logs" = "xyes"; then
 234       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 235    fi
 236 else
 237   have_call_logs=no
 238 fi
 239
 240 if test "x$with_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 241    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 242                  built with --enable-call])
 243 fi
 244
 245 # -----------------------------------------------------------
 246 # evolution-data-server (about-me)
 247 # -----------------------------------------------------------
 248 AC_ARG_WITH(eds,
 249             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 250             [with_eds=yes])
 251 if test x"$with_eds" = x"yes" ; then
 252    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 253    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 254 fi
 255
 256 # -----------------------------------------------------------
 257 # Enable debug
 258 # -----------------------------------------------------------
 259
 260 AC_ARG_ENABLE(debug,
 261   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 262     enable_debug=$enableval, enable_debug=yes )
 263
 264 if test x$enable_debug = xyes; then
 265   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 266 fi
 267
 268 # -----------------------------------------------------------
 269 # Language Support
 270 # -----------------------------------------------------------
 271
 272 GETTEXT_PACKAGE=empathy
 273 AC_SUBST(GETTEXT_PACKAGE)
 274 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 275
 276 AM_GLIB_GNU_GETTEXT
 277
 278 # -----------------------------------------------------------
 279 # Connectivity integration
 280 # -----------------------------------------------------------
 281 AC_ARG_WITH(connectivity,
 282               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 283                              [build with connectivity support]), ,
 284                              with_connectivity=auto)
 285
 286 if test "x$with_connectivity" = "xno"; then
 287    have_nm=no
 288    have_connman=no
 289
 290 elif test "x$with_connectivity" = "xconnman"; then
 291    have_nm=no
 292
 293    PKG_CHECK_MODULES(CONNMAN,
 294    [
 295       dbus-glib-1
 296    ], have_connman="yes", have_connman="no")
 297
 298    if test "x$have_connman" = "xyes"; then
 299       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 300    fi
 301
 302 else
 303    have_connman=no
 304
 305    PKG_CHECK_MODULES(NETWORK_MANAGER,
 306    [
 307       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 308    ], have_nm="yes", have_nm="no")
 309
 310    if test "x$have_nm" = "xyes"; then
 311       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 312    fi
 313 fi
 314
 315 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 316    AC_MSG_ERROR([Couldn't find connman dependencies.])
 317 fi
 318
 319 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 320    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 321 fi
 322
 323 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 324 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 325
 326 # -----------------------------------------------------------
 327 # Webkit
 328 # -----------------------------------------------------------
 329 AC_ARG_ENABLE(webkit,
 330               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 331                              [build with webkit support]), ,
 332                              enable_webkit=auto)
 333
 334 if test "x$enable_webkit" != "xno"; then
 335    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 336         have_webkit="yes", have_webkit="no")
 337
 338    if test "x$have_webkit" = "xyes"; then
 339       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 340    fi
 341 else
 342    have_webkit=no
 343 fi
 344
 345 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 346    AC_MSG_ERROR([Could not find webkit dependencies.])
 347 fi
 348 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 349
 350 # -----------------------------------------------------------
 351 # spellchecking checks: enchant and iso-codes
 352 # -----------------------------------------------------------
 353 AC_ARG_ENABLE(spell,
 354               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 355                              [Enable spell checking]), ,
 356                              enable_spell=auto)
 357
 358 if test "x$enable_spell" != "xno"; then
 359    PKG_CHECK_MODULES(ENCHANT,
 360    [
 361       enchant >= $ENCHANT_REQUIRED,
 362       iso-codes >= $ISO_CODES_REQUIRED
 363    ], have_enchant="yes", have_enchant="no")
 364
 365    if test "x$have_enchant" = "xyes"; then
 366       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 367       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 368          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 369             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 370             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 371             result=yes
 372       else
 373             result=no
 374             have_enchant="no"
 375       fi
 376       AC_MSG_RESULT([$result])
 377    fi
 378 else
 379    have_enchant=no
 380 fi
 381
 382 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 383    AC_MSG_ERROR([Could not find spell dependencies.])
 384 fi
 385
 386 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 387
 388 # -----------------------------------------------------------
 389 # Map view checks: libchamplain
 390 # -----------------------------------------------------------
 391 AC_ARG_ENABLE(map,
 392               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 393                              [Enable map view]), ,
 394                              enable_map=auto)
 395
 396 if test "x$enable_map" != "xno"; then
 397
 398    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 399     [
 400        clutter-gtk-1.0
 401        champlain-gtk-0.10
 402        champlain-0.10
 403     ], have_libchamplain="yes", have_libchamplain="no")
 404
 405    if test "x$have_libchamplain" = "xyes"; then
 406       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 407    fi
 408 else
 409    have_libchamplain=no
 410 fi
 411
 412 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 413    AC_MSG_ERROR([Could not find map view dependencies.])
 414 fi
 415
 416 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 417
 418 # -----------------------------------------------------------
 419 # location checks: geoclue
 420 # -----------------------------------------------------------
 421 AC_ARG_ENABLE(location,
 422               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 423                              [Enable location awareness]), ,
 424                              enable_location=auto)
 425
 426 if test "x$enable_location" != "xno"; then
 427    PKG_CHECK_MODULES(GEOCLUE,
 428    [
 429       geoclue >= $GEOCLUE_REQUIRED
 430    ], have_geoclue="yes", have_geoclue="no")
 431
 432    if test "x$have_geoclue" = "xyes"; then
 433       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 434    fi
 435 else
 436    have_geoclue="no"
 437 fi
 438
 439 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 440    AC_MSG_ERROR([Could not find location dependencies.])
 441 fi
 442
 443 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 444 AC_SUBST(GEOCLUE_CFLAGS)
 445 AC_SUBST(GEOCLUE_LIBS)
 446
 447 # -----------------------------------------------------------
 448 # location checks: geocode-glib
 449 # -----------------------------------------------------------
 450 AC_ARG_ENABLE(geocode,
 451               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 452                              [Enable geocode support]), ,
 453                              enable_geocode=auto)
 454
 455 if test "x$enable_geocode" != "xno"; then
 456    PKG_CHECK_MODULES(GEOCODE,
 457    [
 458       geocode-glib
 459    ], have_geocode="yes", have_geocode="no")
 460
 461    if test "x$have_geocode" = "xyes"; then
 462       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 463    fi
 464 else
 465    have_geocode="no"
 466 fi
 467
 468 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 469    AC_MSG_ERROR([Could not find geocode dependencies.])
 470 fi
 471
 472 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 473 AC_SUBST(GEOCODE_CFLAGS)
 474 AC_SUBST(GEOCODE_LIBS)
 475
 476 # -----------------------------------------------------------
 477 # meego widgets support
 478 # -----------------------------------------------------------
 479 AC_ARG_ENABLE(meego,
 480               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 481                              [Enable meego widgets]), ,
 482                              enable_meego=no)
 483
 484 if test "x$enable_meego" != "xno"; then
 485     PKG_CHECK_MODULES(MEEGO,
 486     [
 487        mx-gtk-1.0
 488        gio-unix-2.0
 489     ], have_meego="yes", have_meego="no")
 490
 491     if test "x$have_meego" = "xyes"; then
 492        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 493     fi
 494 else
 495    have_meego="no"
 496 fi
 497
 498 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 499    AC_MSG_ERROR([Could not find meego dependencies.])
 500 fi
 501
 502 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 503 AC_SUBST(MEEGO_CFLAGS)
 504 AC_SUBST(MEEGO_LIBS)
 505
 506 # -----------------------------------------------------------
 507 # nautilus-sendto
 508 # -----------------------------------------------------------
 509 AC_ARG_ENABLE(nautilus-sendto,
 510               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 511                              [build nautilus-sendto plugin]), ,
 512                              enable_nautilus_sendto=auto)
 513
 514 if test "x$enable_nautilus_sendto" != "xno"; then
 515    PKG_CHECK_MODULES(NST,
 516     [
 517        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 518     ], have_nst="yes", have_nst="no")
 519 else
 520    have_nst=no
 521 fi
 522
 523 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 524    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 525 fi
 526
 527 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 528
 529 # -----------------------------------------------------------
 530 # new, single-window control center
 531 # -----------------------------------------------------------
 532 AC_ARG_ENABLE(control_center_embedding,
 533               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 534                              [Enable support for single-window control center]),
 535                              , enable_control_center_embedding=auto)
 536
 537 if test "x$enable_control_center_embedding" != "xno"; then
 538
 539    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 540         have_control_center_embedding="yes", have_control_center_embedding="no")
 541
 542    if test "x$have_control_center_embedding" = "xyes"; then
 543       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 544
 545       AC_MSG_CHECKING([gnome-control-center extension dir])
 546       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 547       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 548           AC_MSG_ERROR([Could not determine extensiondir])
 549       else
 550           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 551       fi
 552       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 553    fi
 554 else
 555    have_control_center_embedding="no"
 556 fi
 557
 558 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 559    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 560 fi
 561
 562 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 563 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 564 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 565
 566 # Optional dependency for avatar selection
 567 AC_ARG_WITH([cheese],
 568             AS_HELP_STRING([--with-cheese], [enable cheese webcam support]),,
 569             with_cheese=auto)
 570
 571 if test x"$with_cheese" != x"no" ; then
 572    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 573    if test x${have_cheese} = xyes; then
 574      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 575    fi
 576    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 577      AC_MSG_ERROR([Cheese configured but not found])
 578    fi
 579 else
 580    have_cheese=no
 581 fi
 582 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 583
 584
 585 # -----------------------------------------------------------
 586 # Coding style checks
 587 # -----------------------------------------------------------
 588 AC_ARG_ENABLE(coding-style-checks,
 589   AC_HELP_STRING([--disable-coding-style-checks],
 590                  [do not check coding style using grep]),
 591     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 592
 593 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 594 # -----------------------------------------------------------
 595
 596 AC_OUTPUT([
 597    Makefile
 598    data/Makefile
 599    data/empathy.desktop.in
 600    data/empathy-accounts.desktop.in
 601    data/icons/Makefile
 602    extensions/Makefile
 603    po/Makefile.in
 604    libempathy/Makefile
 605    libempathy-gtk/Makefile
 606    src/Makefile
 607    nautilus-sendto-plugin/Makefile
 608    help/Makefile
 609    tests/Makefile
 610    tests/interactive/Makefile
 611    tests/xml/Makefile
 612    tools/Makefile
 613 ])
 614
 615 echo "
 616 Configure summary:
 617
 618         Compiler....................:  ${CC}
 619         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 620         Prefix......................:  ${prefix}
 621         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 622
 623     Features:
 624         Spell checking (enchant)....:  ${have_enchant}
 625         Display maps (libchamplain).:  ${have_libchamplain}
 626         Location awareness (Geoclue):  ${have_geoclue}
 627         Geocode support (Geoclue)...:  ${have_geocode}
 628         Adium themes (Webkit).......:  ${have_webkit}
 629         Meego widgets...............:  ${have_meego}
 630         Control center embedding....:  ${have_control_center_embedding}
 631         Cheese webcam support ......:  ${have_cheese}
 632
 633     Connectivity:
 634         NetworkManager integration..:  ${have_nm}
 635         ConnMan integration.........:  ${have_connman}
 636
 637     Extras:
 638         Nautilus-sendto plugin......:  ${have_nst}
 639         Salut E-D-S support.........:  ${with_eds}
 640         Exp. Call channel handler...:  ${have_farstream}
 641         Exp. Call log support.......:  ${have_call_logs}
 642 "