configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GLIB_REQUIRED=2.30.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.18
  47 TELEPATHY_GLIB_REQUIRED=0.17.3
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50 GOA_REQUIRED=3.3.0
  51
  52 # Optional deps
  53 CLUTTER_REQUIRED=1.7.14
  54 CLUTTER_GTK_REQUIRED=0.90.3
  55 ENCHANT_REQUIRED=1.2.0
  56 GEOCLUE_REQUIRED=0.11
  57 ISO_CODES_REQUIRED=0.35
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60 CHAMPLAIN_REQUIRED=0.12.1
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # Disable GLib deprecation warnings for now; we don't want to bump the GLib dep
  70 # and make things harder for contributiors without good reason. We'll re-enable
  71 # those warnings later during the cycle (bgo #662662)
  72 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
  73
  74 # FIXME: bgo #669673
  75 AC_DEFINE(CLUTTER_DISABLE_DEPRECATION_WARNINGS, 1, [Build with Clutter deprecated])
  76
  77 # telepathy-yell
  78 prev_top_build_prefix=$ac_top_build_prefix
  79 prev_ac_configure_args=$ac_configure_args
  80 ac_configure_args="$ac_configure_args --disable-shared-library"
  81 AX_CONFIG_DIR([telepathy-yell])
  82 ac_top_build_prefix=$prev_top_build_prefix
  83 ac_configure_args=$prev_ac_configure_args
  84 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  85
  86 AC_CONFIG_MACRO_DIR([m4])
  87 AC_CONFIG_HEADERS([config.h])
  88 AC_CONFIG_SRCDIR([configure.ac])
  89 AC_CONFIG_AUX_DIR(.)
  90
  91 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  92
  93 # Support silent build rules. Disable
  94 # by either passing --disable-silent-rules to configure or passing V=1
  95 # to make
  96 AM_SILENT_RULES([yes])
  97
  98 # Check for programs
  99 AC_PROG_CC
 100 AC_HEADER_STDC
 101 AM_PROG_MKDIR_P
 102 AM_PATH_GLIB_2_0
 103 AC_PATH_XTRA
 104
 105 # Initialize libtool
 106 LT_PREREQ([2.2])
 107 LT_INIT
 108
 109 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 110 GLIB_GSETTINGS
 111 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 112 AC_SUBST(GLIB_GENMARSHAL)
 113
 114 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 115 if test -z "$XSLTPROC"; then
 116   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 117 fi
 118 AM_PATH_PYTHON([2.3])
 119
 120 EMPATHY_ARG_VALGRIND
 121
 122
 123 # -----------------------------------------------------------
 124 # Error flags
 125 # -----------------------------------------------------------
 126 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 127 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 128
 129 AC_ARG_ENABLE(Werror,
 130   AS_HELP_STRING([--disable-Werror],
 131                  [compile without -Werror (normally enabled in development builds)]),
 132     werror=$enableval, :)
 133
 134 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 135 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 136         wno_missing_field_initializers=yes,
 137         wno_missing_field_initializers=no)
 138 AS_COMPILER_FLAG(-Wno-unused-parameter,
 139         wno_unused_parameter=yes,
 140         wno_unused_parameter=no)
 141
 142 ifelse(empathy_released, 1, [],
 143     [
 144         if test x$werror = xyes; then
 145             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 146         fi
 147         if test x$wextra = xyes -a \
 148             x$wno_missing_field_initializers = xyes -a \
 149             x$wno_unused_parameter = xyes; then
 150             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 151         fi
 152     ])
 153
 154 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 155 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 156 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 157 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 158 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 159
 160 AC_SUBST(ERROR_CFLAGS)
 161
 162 AC_ARG_ENABLE(gprof,
 163             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 164             [build with support for gprof]),,
 165             [enable_gprof=no])
 166 if test "x$enable_gprof" != "xno" ; then
 167     CFLAGS="$CFLAGS -pg"
 168     LDFLAGS="$LDFLAGS -pg"
 169 fi
 170
 171 AC_SUBST(LDFLAGS)
 172
 173 # -----------------------------------------------------------
 174 # Pkg-Config dependency checks
 175 # -----------------------------------------------------------
 176
 177 AC_CHECK_LIBM
 178 AC_SUBST(LIBM)
 179
 180 PKG_CHECK_MODULES(EMPATHY,
 181 [
 182    dbus-glib-1
 183    folks >= $FOLKS_REQUIRED
 184    folks-telepathy >= $FOLKS_REQUIRED
 185    glib-2.0 >= $GLIB_REQUIRED
 186    gio-2.0 >= $GLIB_REQUIRED
 187    gio-unix-2.0 >= $GLIB_REQUIRED
 188    gnome-keyring-1 >= $KEYRING_REQUIRED
 189    gnutls >= $GNUTLS_REQUIRED
 190    gmodule-export-2.0
 191    gobject-2.0
 192    gsettings-desktop-schemas
 193    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 194    gstreamer-interfaces-0.10
 195    libxml-2.0
 196    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 197    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 198    x11
 199    gtk+-3.0 >= $GTK_REQUIRED
 200    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 201    libnotify >= $LIBNOTIFY_REQUIRED
 202    gcr-3 >= $GCR_REQUIRED
 203    libpulse
 204    libpulse-mainloop-glib
 205    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 206    libsoup-2.4
 207 ])
 208
 209 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 210
 211 PKG_CHECK_MODULES(EMPATHY_AV,
 212 [
 213    farsight2-0.10
 214    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 215 ])
 216
 217 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 218    [Name of provider for accounts imported from GOA])
 219
 220 # -----------------------------------------------------------
 221 # Call interface
 222 # -----------------------------------------------------------
 223 AC_ARG_ENABLE(call,
 224             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 225             [build with Call interface support]),,
 226             [enable_call=auto])
 227 if test "x$enable_call" != "xno" ; then
 228    PKG_CHECK_MODULES(EMPATHY_CALL,
 229    [
 230       farsight2-0.10
 231       telepathy-farstream >= 0.1.2
 232       clutter-1.0 >= $CLUTTER_REQUIRED
 233       clutter-gtk-1.0
 234       clutter-gst-1.0
 235    ], have_call="yes", have_call="no" )
 236
 237    if test "x$have_call" = "xyes"; then
 238       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 239    fi
 240 else
 241   have_call=no
 242 fi
 243
 244 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 245    AC_MSG_ERROR([Could not find Call handler dependencies:
 246
 247 $EMPATHY_CALL_PKG_ERRORS])
 248 fi
 249 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 250
 251
 252 # -----------------------------------------------------------
 253 # Call support in tp-logger
 254 # -----------------------------------------------------------
 255 AC_ARG_ENABLE(call-logs,
 256             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 257             [build with call logs support]),,
 258             [enable_call_logs=auto])
 259 if test "x$enable_call_logs" != "xno" ; then
 260    SAVE_CFLAGS=$CFLAGS
 261    SAVE_CPPFLAGS=$CPPFLAGS
 262    SAVE_LDFLAGS=$LDFLAGS
 263    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 264    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 265    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 266
 267    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 268       have_call_logs="yes", have_call_logs="no")
 269
 270    CFLAGS=$SAVE_CFLAGS
 271    CPPFLAGS=$SAVE_CPPFLAGS
 272    LDFLAGS=$SAVE_LDFLAGS
 273
 274    if test "x$have_call_logs" = "xyes"; then
 275       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 276    fi
 277 else
 278   have_call_logs=no
 279 fi
 280
 281 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 282    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 283                  built with --enable-call])
 284 fi
 285
 286 # -----------------------------------------------------------
 287 # evolution-data-server (about-me)
 288 # -----------------------------------------------------------
 289 AC_ARG_WITH(eds,
 290             AS_HELP_STRING([--with-eds],
 291                            [build with evolution-data-server support]),,
 292             [with_eds=yes])
 293 if test x"$with_eds" = x"yes" ; then
 294    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 295    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 296 fi
 297
 298 # -----------------------------------------------------------
 299 # Enable debug
 300 # -----------------------------------------------------------
 301
 302 AC_ARG_ENABLE(debug,
 303   AS_HELP_STRING([--disable-debug],
 304                  [compile without debug code]),
 305     enable_debug=$enableval, enable_debug=yes )
 306
 307 if test x$enable_debug = xyes; then
 308   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 309 fi
 310
 311 # -----------------------------------------------------------
 312 # Language Support
 313 # -----------------------------------------------------------
 314 IT_PROG_INTLTOOL([0.40.0])
 315
 316 AM_GNU_GETTEXT_VERSION([0.17])
 317 AM_GNU_GETTEXT([external])
 318
 319 GETTEXT_PACKAGE=empathy
 320 AC_SUBST(GETTEXT_PACKAGE)
 321 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 322
 323 # -----------------------------------------------------------
 324 # Connectivity integration
 325 # -----------------------------------------------------------
 326 AC_ARG_WITH(connectivity,
 327               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 328                              [build with connectivity support]), ,
 329                              with_connectivity=auto)
 330
 331 if test "x$with_connectivity" = "xno"; then
 332    have_nm=no
 333    have_connman=no
 334
 335 elif test "x$with_connectivity" = "xconnman"; then
 336    have_nm=no
 337
 338    PKG_CHECK_MODULES(CONNMAN,
 339    [
 340       dbus-glib-1
 341    ], have_connman="yes", have_connman="no")
 342
 343    if test "x$have_connman" = "xyes"; then
 344       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 345    fi
 346
 347 else
 348    have_connman=no
 349
 350    PKG_CHECK_MODULES(NETWORK_MANAGER,
 351    [
 352       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 353    ], have_nm="yes", have_nm="no")
 354
 355    if test "x$have_nm" = "xyes"; then
 356       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 357    fi
 358 fi
 359
 360 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 361    AC_MSG_ERROR([Couldn't find connman dependencies:
 362
 363 $CONNMAN_PKG_ERRORS])
 364 fi
 365
 366 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 367    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 368
 369 $NETWORK_MANAGER_PKG_ERRORS])
 370 fi
 371
 372 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 373 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 374
 375 # -----------------------------------------------------------
 376 # gudev
 377 # -----------------------------------------------------------
 378 AC_ARG_ENABLE(gudev,
 379               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 380                              [build with gudev support]), ,
 381                              enable_gudev=auto)
 382
 383 if test "x$enable_gudev" != "xno"; then
 384
 385    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 386         have_gudev="yes", have_gudev="no")
 387
 388    if test "x$have_gudev" = "xyes"; then
 389       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 390    fi
 391 else
 392    have_gudev=no
 393 fi
 394
 395 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 396    AC_MSG_ERROR([Could not find gudev dependencies:
 397
 398 $UDEV_PKG_ERRORS])
 399 fi
 400 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 401
 402 # -----------------------------------------------------------
 403 # spellchecking checks: enchant and iso-codes
 404 # -----------------------------------------------------------
 405 AC_ARG_ENABLE(spell,
 406               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 407                              [Enable spell checking]), ,
 408                              enable_spell=auto)
 409
 410 if test "x$enable_spell" != "xno"; then
 411    PKG_CHECK_MODULES(ENCHANT,
 412    [
 413       enchant >= $ENCHANT_REQUIRED,
 414       iso-codes >= $ISO_CODES_REQUIRED
 415    ], have_enchant="yes", have_enchant="no")
 416
 417    if test "x$have_enchant" = "xyes"; then
 418       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 419       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 420          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 421             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 422             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 423             result=yes
 424       else
 425             result=no
 426             have_enchant="no"
 427       fi
 428       AC_MSG_RESULT([$result])
 429    fi
 430 else
 431    have_enchant=no
 432 fi
 433
 434 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 435    AC_MSG_ERROR([Could not find spell-checking dependencies:
 436
 437 $ENCHANT_PKG_ERRORS])
 438 fi
 439
 440 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 441
 442 # -----------------------------------------------------------
 443 # Map view checks: libchamplain
 444 # -----------------------------------------------------------
 445 AC_ARG_ENABLE(map,
 446               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 447                              [Enable map view]), ,
 448                              enable_map=auto)
 449
 450 if test "x$enable_map" != "xno"; then
 451
 452    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 453     [
 454        clutter-gtk-1.0
 455        champlain-gtk-0.12
 456        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 457     ], have_libchamplain="yes", have_libchamplain="no")
 458
 459    if test "x$have_libchamplain" = "xyes"; then
 460       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 461    fi
 462 else
 463    have_libchamplain=no
 464 fi
 465
 466 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 467    AC_MSG_ERROR([Could not find map view dependencies:
 468
 469 $LIBCHAMPLAIN_PKG_ERRORS])
 470 fi
 471
 472 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 473
 474 # -----------------------------------------------------------
 475 # location checks: geoclue
 476 # -----------------------------------------------------------
 477 AC_ARG_ENABLE(location,
 478               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 479                              [Enable location awareness]), ,
 480                              enable_location=auto)
 481
 482 if test "x$enable_location" != "xno"; then
 483    PKG_CHECK_MODULES(GEOCLUE,
 484    [
 485       geoclue >= $GEOCLUE_REQUIRED
 486    ], have_geoclue="yes", have_geoclue="no")
 487
 488    if test "x$have_geoclue" = "xyes"; then
 489       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 490    fi
 491 else
 492    have_geoclue="no"
 493 fi
 494
 495 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 496    AC_MSG_ERROR([Could not find location dependencies:
 497
 498 $GEOCLUE_PKG_ERRORS])
 499 fi
 500
 501 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 502 AC_SUBST(GEOCLUE_CFLAGS)
 503 AC_SUBST(GEOCLUE_LIBS)
 504
 505 # -----------------------------------------------------------
 506 # location checks: geocode-glib
 507 # -----------------------------------------------------------
 508 AC_ARG_ENABLE(geocode,
 509               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 510                              [Enable geocode support]), ,
 511                              enable_geocode=auto)
 512
 513 if test "x$enable_geocode" != "xno"; then
 514    PKG_CHECK_MODULES(GEOCODE,
 515    [
 516       geocode-glib
 517    ], have_geocode="yes", have_geocode="no")
 518
 519    if test "x$have_geocode" = "xyes"; then
 520       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 521    fi
 522 else
 523    have_geocode="no"
 524 fi
 525
 526 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 527    AC_MSG_ERROR([Could not find geocode dependencies:
 528
 529 $GEOCODE_PKG_ERRORS])
 530 fi
 531
 532 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 533 AC_SUBST(GEOCODE_CFLAGS)
 534 AC_SUBST(GEOCODE_LIBS)
 535
 536 # -----------------------------------------------------------
 537 # meego widgets support
 538 # -----------------------------------------------------------
 539 AC_ARG_ENABLE(meego,
 540               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 541                              [Enable meego widgets]), ,
 542                              enable_meego=no)
 543
 544 if test "x$enable_meego" != "xno"; then
 545     PKG_CHECK_MODULES(MEEGO,
 546     [
 547        mx-gtk-1.0
 548        gio-unix-2.0
 549     ], have_meego="yes", have_meego="no")
 550
 551     if test "x$have_meego" = "xyes"; then
 552        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 553     fi
 554 else
 555    have_meego="no"
 556 fi
 557
 558 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 559    AC_MSG_ERROR([Could not find meego dependencies:
 560
 561 $MEEGO_PKG_ERRORS])
 562 fi
 563
 564 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 565 AC_SUBST(MEEGO_CFLAGS)
 566 AC_SUBST(MEEGO_LIBS)
 567
 568 # -----------------------------------------------------------
 569 # nautilus-sendto
 570 # -----------------------------------------------------------
 571 AC_ARG_ENABLE(nautilus-sendto,
 572               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 573                              [build nautilus-sendto plugin]), ,
 574                              enable_nautilus_sendto=auto)
 575
 576 if test "x$enable_nautilus_sendto" != "xno"; then
 577    PKG_CHECK_MODULES(NST,
 578     [
 579        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 580     ], have_nst="yes", have_nst="no")
 581 else
 582    have_nst=no
 583 fi
 584
 585 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 586    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 587
 588 $NST_PKG_ERRORS])
 589 fi
 590
 591 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 592
 593 # -----------------------------------------------------------
 594 # goa-mc-plugin
 595 # -----------------------------------------------------------
 596 AC_ARG_ENABLE(goa,
 597               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 598                              [build GOA MC plugin]), ,
 599                              enable_goa=auto)
 600
 601 if test "x$enable_goa" != "xno"; then
 602    PKG_CHECK_MODULES(GOA,
 603     [
 604        mission-control-plugins
 605        goa-1.0 >= $GOA_REQUIRED
 606     ], have_goa="yes", have_goa="no")
 607
 608    AC_MSG_CHECKING([Mission Control plugins dir])
 609    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 610
 611    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 612    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 613 else
 614    have_goa=no
 615 fi
 616
 617 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 618    AC_MSG_ERROR([Could not find GOA dependencies.])
 619 fi
 620
 621 if test "x$have_goa" = "xyes"; then
 622    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 623 fi
 624
 625 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 626
 627 # Optional dependency for avatar selection
 628 AC_ARG_WITH([cheese],
 629             AS_HELP_STRING([--with-cheese],
 630                            [enable cheese webcam support]),,
 631             with_cheese=auto)
 632
 633 if test x"$with_cheese" != x"no" ; then
 634    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 635    if test x${have_cheese} = xyes; then
 636      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 637    fi
 638    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 639      AC_MSG_ERROR([Cheese configured but not found:
 640
 641 $CHEESE_PKG_ERRORS])
 642    fi
 643 else
 644    have_cheese=no
 645 fi
 646 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 647
 648 # Help documentation
 649 YELP_HELP_INIT
 650
 651 # -----------------------------------------------------------
 652 # Coding style checks
 653 # -----------------------------------------------------------
 654 AC_ARG_ENABLE(coding-style-checks,
 655   AS_HELP_STRING([--disable-coding-style-checks],
 656                  [do not check coding style using grep]),
 657     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 658     [ENABLE_CODING_STYLE_CHECKS=yes])
 659
 660 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 661 # -----------------------------------------------------------
 662
 663 AC_CONFIG_FILES([
 664    Makefile
 665    data/Makefile
 666    data/empathy.desktop.in
 667    data/empathy-accounts.desktop.in
 668    data/icons/Makefile
 669    extensions/Makefile
 670    po/Makefile.in
 671    libempathy/Makefile
 672    libempathy-gtk/Makefile
 673    src/Makefile
 674    nautilus-sendto-plugin/Makefile
 675    goa-mc-plugin/Makefile
 676    help/Makefile
 677    tests/Makefile
 678    tests/interactive/Makefile
 679    tests/xml/Makefile
 680    tools/Makefile
 681 ])
 682 AC_OUTPUT
 683
 684 echo "
 685 Configure summary:
 686
 687         Compiler....................:  ${CC}
 688         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 689         Linker Flags................:  ${LDFLAGS}
 690         Prefix......................:  ${prefix}
 691         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 692
 693     Features:
 694         Spell checking (enchant)....:  ${have_enchant}
 695         Display maps (libchamplain).:  ${have_libchamplain}
 696         Location awareness (Geoclue):  ${have_geoclue}
 697         Geocode support (Geocode)...:  ${have_geocode}
 698         Meego widgets...............:  ${have_meego}
 699         Cheese webcam support ......:  ${have_cheese}
 700         Camera monitoring...........:  ${have_gudev}
 701
 702     Connectivity:
 703         NetworkManager integration..:  ${have_nm}
 704         ConnMan integration.........:  ${have_connman}
 705
 706     Extras:
 707         Nautilus-sendto plugin......:  ${have_nst}
 708         GOA MC plugin...............:  ${have_goa}
 709         Salut E-D-S support.........:  ${with_eds}
 710         Exp. Call channel handler...:  ${have_call}
 711         Exp. Call log support.......:  ${have_call_logs}
 712 "