configure.ac

   1 AC_INIT(Empathy, 2.27.1, http://bugzilla.gnome.org/browse.cgi?product=empathy)
   2 AC_PREREQ(2.59)
   3 AC_COPYRIGHT([
   4   Copyright (C) 2003-2007 Imendio AB
   5   Copyright (C) 2007-2008 Collabora Ltd.
   6 ])
   7
   8 # LT Version numbers, remember to change them just *before* a release.
   9 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
  10 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
  11 #   (No interfaces changed:                   REVISION++)
  12 LIBEMPATHY_CURRENT=22
  13 LIBEMPATHY_AGE=0
  14 LIBEMPATHY_REVISION=0
  15
  16 LIBEMPATHY_GTK_CURRENT=21
  17 LIBEMPATHY_GTK_AGE=2
  18 LIBEMPATHY_GTK_REVISION=0
  19
  20 AC_SUBST(LIBEMPATHY_CURRENT)
  21 AC_SUBST(LIBEMPATHY_AGE)
  22 AC_SUBST(LIBEMPATHY_REVISION)
  23 AC_SUBST(LIBEMPATHY_GTK_CURRENT)
  24 AC_SUBST(LIBEMPATHY_GTK_AGE)
  25 AC_SUBST(LIBEMPATHY_GTK_REVISION)
  26
  27 # Minimal version required
  28 GLIB_REQUIRED=2.16.0
  29 GTK_REQUIRED=2.16.0
  30 GCONF_REQUIRED=1.2.0
  31 LIBPANELAPPLET_REQUIRED=2.10.0
  32 TELEPATHY_GLIB_REQUIRED=0.7.23
  33 MISSION_CONTROL_REQUIRED=4.61
  34 ENCHANT_REQUIRED=1.2.0
  35 ISO_CODES_REQUIRED=0.35
  36 LIBNOTIFY_REQUIRED=0.4.4
  37 LIBCANBERRA_GTK_REQUIRED=0.4
  38
  39 # Uncomment that to build with deprecated symbols disabled
  40 #AC_DEFINE(G_DISABLE_DEPRECATED, [], [Disable deprecated GLib symbols])
  41 #AC_DEFINE(GDK_PIXBUF_DISABLE_DEPRECATED, [], [Disable deprecated GDK pixbuf symbols])
  42 #AC_DEFINE(GDK_DISABLE_DEPRECATED, [], [Disable deprecated GDK symbols])
  43 #AC_DEFINE(GTK_DISABLE_DEPRECATED, [], [Disable deprecated GTK symbols])
  44
  45 # Uncomment that to build with single include disabled
  46 #AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  47 #AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  48 #AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  49
  50 AC_CONFIG_MACRO_DIR([m4])
  51 AC_CONFIG_HEADERS([config.h])
  52 AC_CONFIG_SRCDIR([configure.ac])
  53 AC_CONFIG_AUX_DIR(.)
  54
  55 GNOME_COMMON_INIT
  56
  57 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  58 AM_MAINTAINER_MODE
  59 AC_ISC_POSIX
  60 AC_PROG_CC
  61 AC_HEADER_STDC
  62 AM_PROG_LIBTOOL
  63 AM_PROG_MKDIR_P
  64 AM_PATH_GLIB_2_0
  65 AC_PATH_XTRA
  66 IT_PROG_INTLTOOL([0.35.0])
  67 GTK_DOC_CHECK([1.3])
  68 GNOME_DOC_INIT
  69 IDT_COMPILE_WARNINGS
  70 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  71 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  72 AM_GCONF_SOURCE_2
  73 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  74 AC_SUBST(GLIB_GENMARSHAL)
  75
  76 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  77 if test -z "$XSLTPROC"; then
  78   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  79 fi
  80 AM_PATH_PYTHON([2.3])
  81
  82 EMPATHY_ARG_VALGRIND
  83
  84 # -----------------------------------------------------------
  85 # Pkg-Config dependency checks
  86 # -----------------------------------------------------------
  87
  88 PKG_CHECK_MODULES(LIBEMPATHY,
  89 [
  90    glib-2.0 >= $GLIB_REQUIRED
  91    gobject-2.0
  92    gio-2.0 >= $GLIB_REQUIRED
  93    gio-unix-2.0 >= $GLIB_REQUIRED
  94    libxml-2.0
  95    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
  96    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  97    telepathy-farsight
  98 ])
  99
 100 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 101 [
 102    glib-2.0 >= $GLIB_REQUIRED
 103    gobject-2.0
 104    gio-2.0 >= $GLIB_REQUIRED
 105    gconf-2.0 >= $GCONF_REQUIRED
 106    x11
 107    gtk+-2.0 >= $GTK_REQUIRED
 108    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 109    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 110    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 111    telepathy-farsight
 112    gstreamer-0.10
 113    gstreamer-interfaces-0.10
 114 ])
 115
 116 PKG_CHECK_MODULES(EMPATHY,
 117 [
 118    glib-2.0 >= $GLIB_REQUIRED
 119    gobject-2.0
 120    gio-2.0 >= $GLIB_REQUIRED
 121    gconf-2.0 >= $GCONF_REQUIRED
 122    x11
 123    gtk+-2.0 >= $GTK_REQUIRED
 124    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 125    libebook-1.2
 126    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 127    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 128    telepathy-farsight
 129    gstreamer-0.10
 130    gstreamer-interfaces-0.10
 131 ])
 132
 133 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 134
 135 # -----------------------------------------------------------
 136 # Enable debug
 137 # -----------------------------------------------------------
 138
 139 AC_ARG_ENABLE(debug,
 140   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 141     enable_debug=$enableval, enable_debug=yes )
 142
 143 if test x$enable_debug = xyes; then
 144   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 145 fi
 146
 147 # -----------------------------------------------------------
 148 # Language Support
 149 # -----------------------------------------------------------
 150
 151 GETTEXT_PACKAGE=empathy
 152 AC_SUBST(GETTEXT_PACKAGE)
 153 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 154
 155 AM_GLIB_GNU_GETTEXT
 156
 157 # -----------------------------------------------------------
 158 # spellchecking checks: enchant and iso-codes
 159 # -----------------------------------------------------------
 160 AC_ARG_ENABLE(spell,
 161               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 162                              [Enable spell checking]), ,
 163                              enable_spell=auto)
 164
 165 if test "x$enable_spell" != "xno"; then
 166    PKG_CHECK_MODULES(ENCHANT,
 167    [
 168       enchant >= $ENCHANT_REQUIRED,
 169       iso-codes >= $ISO_CODES_REQUIRED
 170    ], have_enchant="yes", have_enchant="no")
 171
 172    if test "x$have_enchant" = "xyes"; then
 173       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 174       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 175          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 176             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 177             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 178             result=yes
 179       else
 180             result=no
 181             have_enchant="no"
 182       fi
 183       AC_MSG_RESULT([$result])
 184    fi
 185 else
 186    have_enchant=no
 187 fi
 188
 189 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 190    AC_MSG_ERROR([Couldn't find spell dependencies.])
 191 fi
 192
 193 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 194
 195 # -----------------------------------------------------------
 196 # Megaphone
 197 # -----------------------------------------------------------
 198 AC_ARG_ENABLE(megaphone,
 199               AS_HELP_STRING([--enable-megaphone=@<:@no/yes/auto@:>@],
 200                              [build megaphone applet]), ,
 201                              enable_megaphone=auto)
 202
 203 if test "x$enable_megaphone" != "xno"; then
 204    PKG_CHECK_MODULES(MEGAPHONE,
 205    [
 206       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 207       glib-2.0 >= $GLIB_REQUIRED
 208       gtk+-2.0 >= $GTK_REQUIRED
 209       gconf-2.0 >= $GCONF_REQUIRED
 210       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 211    ], have_megaphone="yes", have_megaphone="no")
 212 else
 213    have_megaphone=no
 214 fi
 215
 216 if test "x$enable_megaphone" = "xyes" -a "x$have_megaphone" != "xyes"; then
 217    AC_MSG_ERROR([Couldn't find megaphone dependencies.])
 218 fi
 219
 220 AM_CONDITIONAL(HAVE_MEGAPHONE, test "x$have_megaphone" = "xyes")
 221
 222 # -----------------------------------------------------------
 223 # Nothere
 224 # -----------------------------------------------------------
 225 AC_ARG_ENABLE(nothere,
 226               AS_HELP_STRING([--enable-nothere=@<:@no/yes/auto@:>@],
 227                              [build nothere applet]), ,
 228                              enable_nothere=auto)
 229
 230 if test "x$enable_nothere" != "xno"; then
 231    PKG_CHECK_MODULES(NOTHERE,
 232    [
 233       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 234       glib-2.0 >= $GLIB_REQUIRED
 235       gtk+-2.0 >= $GTK_REQUIRED
 236       gconf-2.0 >= $GCONF_REQUIRED
 237       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 238    ], have_nothere="yes", have_nothere="no")
 239 else
 240    have_nothere=no
 241 fi
 242
 243 if test "x$enable_nothere" = "xyes" -a "x$have_nothere" != "xyes"; then
 244    AC_MSG_ERROR([Couldn't find nothere dependencies.])
 245 fi
 246
 247 AM_CONDITIONAL(HAVE_NOTHERE, test "x$have_nothere" = "xyes")
 248
 249 # -----------------------------------------------------------
 250 # Tests
 251 # -----------------------------------------------------------
 252 AC_ARG_ENABLE(tests,
 253               AS_HELP_STRING([--enable-tests=@<:@no/yes/auto@:>@],
 254                              [build tests]), ,
 255                              enable_tests=auto)
 256
 257 if test "x$enable_tests" != "xno"; then
 258    PKG_CHECK_MODULES(CHECK,
 259    [
 260       check >= 0.9.4
 261    ], have_check="yes", have_check="no")
 262 else
 263    have_check=no
 264 fi
 265
 266 if test "x$enable_tests" = "xyes" -a "x$have_check" != "xyes"; then
 267    AC_MSG_ERROR([Couldn't find check dependencies.])
 268 fi
 269
 270 AM_CONDITIONAL(HAVE_TESTS, test "x$have_check" = "xyes")
 271
 272 # -----------------------------------------------------------
 273 # Python Bindings
 274 # -----------------------------------------------------------
 275 AC_ARG_ENABLE(python,
 276               AS_HELP_STRING([--enable-python=@<:@no/yes/auto@:>@],
 277                              [build python bindings to libempathy and libempathy-gtk]), ,
 278                              enable_python=auto)
 279
 280 if test "x$enable_python" != "xno"; then
 281    PKG_CHECK_MODULES(PYTHON_BINDING,
 282    [
 283       pygtk-2.0,
 284       glib-2.0 >= $GLIB_REQUIRED
 285       gobject-2.0
 286       gconf-2.0 >= $GCONF_REQUIRED
 287       libxml-2.0
 288       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 289       gtk+-2.0 >= $GTK_REQUIRED
 290       gstreamer-0.10
 291       gstreamer-interfaces-0.10
 292       telepathy-farsight
 293    ], have_python="yes", have_python="no")
 294    if test "x$have_python" = "xyes" ; then
 295       AM_CHECK_PYTHON_HEADERS(,have_python="no")
 296       AC_CHECK_PROGS([PYGOBJECTCODEGEN], [pygobject-codegen-2.0 pygtk-codegen-2.0])
 297    fi
 298 else
 299    have_python=no
 300 fi
 301
 302 if test "x$enable_python" = "xyes" -a "x$have_python" != "xyes"; then
 303    AC_MSG_ERROR([Couldn't find python.])
 304 fi
 305
 306 AM_CONDITIONAL(HAVE_PYTHON, test "x$have_python" = "xyes")
 307
 308 # -----------------------------------------------------------
 309
 310 AC_OUTPUT([
 311    Makefile
 312    data/Makefile
 313    data/empathy.desktop.in
 314    data/icons/Makefile
 315    extensions/Makefile
 316    po/Makefile.in
 317    libempathy/Makefile
 318    libempathy/libempathy.pc
 319    libempathy-gtk/Makefile
 320    libempathy-gtk/libempathy-gtk.pc
 321    src/Makefile
 322    megaphone/Makefile
 323    megaphone/src/Makefile
 324    megaphone/data/Makefile
 325    nothere/Makefile
 326    nothere/src/Makefile
 327    nothere/data/Makefile
 328    docs/Makefile
 329    docs/libempathy/Makefile
 330    docs/libempathy/version.xml
 331    docs/libempathy-gtk/Makefile
 332    docs/libempathy-gtk/version.xml
 333    help/Makefile
 334    python/Makefile
 335    python/pyempathy/Makefile
 336    python/pyempathygtk/Makefile
 337    tests/Makefile
 338    tests/xml/Makefile
 339    tools/Makefile
 340 ])