configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [1])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GLIB_REQUIRED=2.30.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.18
  47 TELEPATHY_FARSTREAM_REQUIRED=0.2.1
  48 TELEPATHY_GLIB_REQUIRED=0.17.5
  49 TELEPATHY_LOGGER=0.2.10
  50 WEBKIT_REQUIRED=1.3.13
  51 GOA_REQUIRED=3.3.0
  52
  53 # Optional deps
  54 CLUTTER_REQUIRED=1.7.14
  55 CLUTTER_GTK_REQUIRED=0.90.3
  56 ENCHANT_REQUIRED=1.2.0
  57 GEOCLUE_REQUIRED=0.11
  58 ISO_CODES_REQUIRED=0.35
  59 NAUTILUS_SENDTO_REQUIRED=2.90.0
  60 NETWORK_MANAGER_REQUIRED=0.7.0
  61 CHAMPLAIN_REQUIRED=0.12.1
  62
  63 # Use --enable-maintainer-mode to disable deprecated symbols,
  64 # disable single include and enable GSEAL. If this is not a released empathy,
  65 # maintainer mode is forced
  66 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  67 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  68 #GNOME_MAINTAINER_MODE_DEFINES
  69
  70 # Disable GLib deprecation warnings for now; we don't want to bump the GLib dep
  71 # and make things harder for contributiors without good reason. We'll re-enable
  72 # those warnings later during the cycle (bgo #662662)
  73 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
  74
  75 # FIXME: bgo #669673
  76 AC_DEFINE(CLUTTER_DISABLE_DEPRECATION_WARNINGS, 1, [Build with Clutter deprecated])
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 102 GLIB_GSETTINGS
 103 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 104 AC_SUBST(GLIB_GENMARSHAL)
 105
 106 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 107 if test -z "$XSLTPROC"; then
 108   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 109 fi
 110 AM_PATH_PYTHON([2.3])
 111
 112 EMPATHY_ARG_VALGRIND
 113
 114
 115 # -----------------------------------------------------------
 116 # Error flags
 117 # -----------------------------------------------------------
 118 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 119 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 120
 121 AC_ARG_ENABLE(Werror,
 122   AS_HELP_STRING([--disable-Werror],
 123                  [compile without -Werror (normally enabled in development builds)]),
 124     werror=$enableval, :)
 125
 126 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 127 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 128         wno_missing_field_initializers=yes,
 129         wno_missing_field_initializers=no)
 130 AS_COMPILER_FLAG(-Wno-unused-parameter,
 131         wno_unused_parameter=yes,
 132         wno_unused_parameter=no)
 133
 134 ifelse(empathy_released, 1, [],
 135     [
 136         if test x$werror = xyes; then
 137             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 138         fi
 139         if test x$wextra = xyes -a \
 140             x$wno_missing_field_initializers = xyes -a \
 141             x$wno_unused_parameter = xyes; then
 142             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 143         fi
 144     ])
 145
 146 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 147 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 148 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 149 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 150 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 151
 152 AC_SUBST(ERROR_CFLAGS)
 153
 154 AC_ARG_ENABLE(gprof,
 155             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 156             [build with support for gprof]),,
 157             [enable_gprof=no])
 158 if test "x$enable_gprof" != "xno" ; then
 159     CFLAGS="$CFLAGS -pg"
 160     LDFLAGS="$LDFLAGS -pg"
 161 fi
 162
 163 AC_SUBST(LDFLAGS)
 164
 165 # -----------------------------------------------------------
 166 # Pkg-Config dependency checks
 167 # -----------------------------------------------------------
 168
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 PKG_CHECK_MODULES(EMPATHY,
 173 [
 174    dbus-glib-1
 175    folks >= $FOLKS_REQUIRED
 176    folks-telepathy >= $FOLKS_REQUIRED
 177    glib-2.0 >= $GLIB_REQUIRED
 178    gio-2.0 >= $GLIB_REQUIRED
 179    gio-unix-2.0 >= $GLIB_REQUIRED
 180    gnome-keyring-1 >= $KEYRING_REQUIRED
 181    gnutls >= $GNUTLS_REQUIRED
 182    gmodule-export-2.0
 183    gobject-2.0
 184    gsettings-desktop-schemas
 185    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 186    gstreamer-interfaces-0.10
 187    libxml-2.0
 188    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 189    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 190    x11
 191    gtk+-3.0 >= $GTK_REQUIRED
 192    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 193    libnotify >= $LIBNOTIFY_REQUIRED
 194    gcr-3 >= $GCR_REQUIRED
 195    libpulse
 196    libpulse-mainloop-glib
 197    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 198    libsoup-2.4
 199 ])
 200
 201 PKG_CHECK_MODULES(EMPATHY_CALL,
 202 [
 203    farstream-0.1
 204    telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 205    clutter-1.0 >= $CLUTTER_REQUIRED
 206    clutter-gtk-1.0
 207    clutter-gst-1.0
 208 ])
 209
 210 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 211    [Name of provider for accounts imported from GOA])
 212
 213 # -----------------------------------------------------------
 214 # Call support in tp-logger
 215 # -----------------------------------------------------------
 216 AC_ARG_ENABLE(call-logs,
 217             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 218             [build with call logs support]),,
 219             [enable_call_logs=auto])
 220 if test "x$enable_call_logs" != "xno" ; then
 221    SAVE_CFLAGS=$CFLAGS
 222    SAVE_CPPFLAGS=$CPPFLAGS
 223    SAVE_LDFLAGS=$LDFLAGS
 224    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 225    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 226    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 227
 228    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 229       have_call_logs="yes", have_call_logs="no")
 230
 231    CFLAGS=$SAVE_CFLAGS
 232    CPPFLAGS=$SAVE_CPPFLAGS
 233    LDFLAGS=$SAVE_LDFLAGS
 234
 235    if test "x$have_call_logs" = "xyes"; then
 236       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 237    fi
 238 else
 239   have_call_logs=no
 240 fi
 241
 242 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 243    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 244                  built with --enable-call])
 245 fi
 246
 247 # -----------------------------------------------------------
 248 # evolution-data-server (about-me)
 249 # -----------------------------------------------------------
 250 AC_ARG_WITH(eds,
 251             AS_HELP_STRING([--with-eds],
 252                            [build with evolution-data-server support]),,
 253             [with_eds=yes])
 254 if test x"$with_eds" = x"yes" ; then
 255    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 256    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 257 fi
 258
 259 # -----------------------------------------------------------
 260 # Enable debug
 261 # -----------------------------------------------------------
 262
 263 AC_ARG_ENABLE(debug,
 264   AS_HELP_STRING([--disable-debug],
 265                  [compile without debug code]),
 266     enable_debug=$enableval, enable_debug=yes )
 267
 268 if test x$enable_debug = xyes; then
 269   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 270 fi
 271
 272 # -----------------------------------------------------------
 273 # Language Support
 274 # -----------------------------------------------------------
 275 IT_PROG_INTLTOOL([0.40.0])
 276
 277 AM_GNU_GETTEXT_VERSION([0.17])
 278 AM_GNU_GETTEXT([external])
 279
 280 GETTEXT_PACKAGE=empathy
 281 AC_SUBST(GETTEXT_PACKAGE)
 282 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 283
 284 # -----------------------------------------------------------
 285 # Connectivity integration
 286 # -----------------------------------------------------------
 287 AC_ARG_WITH(connectivity,
 288               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 289                              [build with connectivity support]), ,
 290                              with_connectivity=auto)
 291
 292 if test "x$with_connectivity" = "xno"; then
 293    have_nm=no
 294    have_connman=no
 295
 296 elif test "x$with_connectivity" = "xconnman"; then
 297    have_nm=no
 298
 299    PKG_CHECK_MODULES(CONNMAN,
 300    [
 301       dbus-glib-1
 302    ], have_connman="yes", have_connman="no")
 303
 304    if test "x$have_connman" = "xyes"; then
 305       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 306    fi
 307
 308 else
 309    have_connman=no
 310
 311    PKG_CHECK_MODULES(NETWORK_MANAGER,
 312    [
 313       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 314    ], have_nm="yes", have_nm="no")
 315
 316    if test "x$have_nm" = "xyes"; then
 317       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 318    fi
 319 fi
 320
 321 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 322    AC_MSG_ERROR([Couldn't find connman dependencies:
 323
 324 $CONNMAN_PKG_ERRORS])
 325 fi
 326
 327 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 328    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 329
 330 $NETWORK_MANAGER_PKG_ERRORS])
 331 fi
 332
 333 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 334 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 335
 336 # -----------------------------------------------------------
 337 # gudev
 338 # -----------------------------------------------------------
 339 AC_ARG_ENABLE(gudev,
 340               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 341                              [build with gudev support]), ,
 342                              enable_gudev=auto)
 343
 344 if test "x$enable_gudev" != "xno"; then
 345
 346    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 347         have_gudev="yes", have_gudev="no")
 348
 349    if test "x$have_gudev" = "xyes"; then
 350       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 351    fi
 352 else
 353    have_gudev=no
 354 fi
 355
 356 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 357    AC_MSG_ERROR([Could not find gudev dependencies:
 358
 359 $UDEV_PKG_ERRORS])
 360 fi
 361 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 362
 363 # -----------------------------------------------------------
 364 # spellchecking checks: enchant and iso-codes
 365 # -----------------------------------------------------------
 366 AC_ARG_ENABLE(spell,
 367               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 368                              [Enable spell checking]), ,
 369                              enable_spell=auto)
 370
 371 if test "x$enable_spell" != "xno"; then
 372    PKG_CHECK_MODULES(ENCHANT,
 373    [
 374       enchant >= $ENCHANT_REQUIRED,
 375       iso-codes >= $ISO_CODES_REQUIRED
 376    ], have_enchant="yes", have_enchant="no")
 377
 378    if test "x$have_enchant" = "xyes"; then
 379       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 380       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 381          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 382             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 383             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 384             result=yes
 385       else
 386             result=no
 387             have_enchant="no"
 388       fi
 389       AC_MSG_RESULT([$result])
 390    fi
 391 else
 392    have_enchant=no
 393 fi
 394
 395 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 396    AC_MSG_ERROR([Could not find spell-checking dependencies:
 397
 398 $ENCHANT_PKG_ERRORS])
 399 fi
 400
 401 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 402
 403 # -----------------------------------------------------------
 404 # Map view checks: libchamplain
 405 # -----------------------------------------------------------
 406 AC_ARG_ENABLE(map,
 407               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 408                              [Enable map view]), ,
 409                              enable_map=auto)
 410
 411 if test "x$enable_map" != "xno"; then
 412
 413    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 414     [
 415        clutter-gtk-1.0
 416        champlain-gtk-0.14
 417        champlain-0.14 >= $CHAMPLAIN_REQUIRED
 418     ], have_libchamplain="yes", have_libchamplain="no")
 419
 420    if test "x$have_libchamplain" = "xyes"; then
 421       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 422    fi
 423 else
 424    have_libchamplain=no
 425 fi
 426
 427 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 428    AC_MSG_ERROR([Could not find map view dependencies:
 429
 430 $LIBCHAMPLAIN_PKG_ERRORS])
 431 fi
 432
 433 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 434
 435 # -----------------------------------------------------------
 436 # location checks: geoclue
 437 # -----------------------------------------------------------
 438 AC_ARG_ENABLE(location,
 439               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 440                              [Enable location awareness]), ,
 441                              enable_location=auto)
 442
 443 if test "x$enable_location" != "xno"; then
 444    PKG_CHECK_MODULES(GEOCLUE,
 445    [
 446       geoclue >= $GEOCLUE_REQUIRED
 447    ], have_geoclue="yes", have_geoclue="no")
 448
 449    if test "x$have_geoclue" = "xyes"; then
 450       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 451    fi
 452 else
 453    have_geoclue="no"
 454 fi
 455
 456 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 457    AC_MSG_ERROR([Could not find location dependencies:
 458
 459 $GEOCLUE_PKG_ERRORS])
 460 fi
 461
 462 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 463 AC_SUBST(GEOCLUE_CFLAGS)
 464 AC_SUBST(GEOCLUE_LIBS)
 465
 466 # -----------------------------------------------------------
 467 # location checks: geocode-glib
 468 # -----------------------------------------------------------
 469 AC_ARG_ENABLE(geocode,
 470               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 471                              [Enable geocode support]), ,
 472                              enable_geocode=auto)
 473
 474 if test "x$enable_geocode" != "xno"; then
 475    PKG_CHECK_MODULES(GEOCODE,
 476    [
 477       geocode-glib
 478    ], have_geocode="yes", have_geocode="no")
 479
 480    if test "x$have_geocode" = "xyes"; then
 481       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 482    fi
 483 else
 484    have_geocode="no"
 485 fi
 486
 487 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 488    AC_MSG_ERROR([Could not find geocode dependencies:
 489
 490 $GEOCODE_PKG_ERRORS])
 491 fi
 492
 493 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 494 AC_SUBST(GEOCODE_CFLAGS)
 495 AC_SUBST(GEOCODE_LIBS)
 496
 497 # -----------------------------------------------------------
 498 # meego widgets support
 499 # -----------------------------------------------------------
 500 AC_ARG_ENABLE(meego,
 501               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 502                              [Enable meego widgets]), ,
 503                              enable_meego=no)
 504
 505 if test "x$enable_meego" != "xno"; then
 506     PKG_CHECK_MODULES(MEEGO,
 507     [
 508        mx-gtk-1.0
 509        gio-unix-2.0
 510     ], have_meego="yes", have_meego="no")
 511
 512     if test "x$have_meego" = "xyes"; then
 513        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 514     fi
 515 else
 516    have_meego="no"
 517 fi
 518
 519 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 520    AC_MSG_ERROR([Could not find meego dependencies:
 521
 522 $MEEGO_PKG_ERRORS])
 523 fi
 524
 525 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 526 AC_SUBST(MEEGO_CFLAGS)
 527 AC_SUBST(MEEGO_LIBS)
 528
 529 # -----------------------------------------------------------
 530 # nautilus-sendto
 531 # -----------------------------------------------------------
 532 AC_ARG_ENABLE(nautilus-sendto,
 533               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 534                              [build nautilus-sendto plugin]), ,
 535                              enable_nautilus_sendto=auto)
 536
 537 if test "x$enable_nautilus_sendto" != "xno"; then
 538    PKG_CHECK_MODULES(NST,
 539     [
 540        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 541     ], have_nst="yes", have_nst="no")
 542 else
 543    have_nst=no
 544 fi
 545
 546 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 547    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 548
 549 $NST_PKG_ERRORS])
 550 fi
 551
 552 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 553
 554 # -----------------------------------------------------------
 555 # goa-mc-plugin
 556 # -----------------------------------------------------------
 557 AC_ARG_ENABLE(goa,
 558               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 559                              [build GOA MC plugin]), ,
 560                              enable_goa=auto)
 561
 562 if test "x$enable_goa" != "xno"; then
 563    PKG_CHECK_MODULES(GOA,
 564     [
 565        mission-control-plugins
 566        goa-1.0 >= $GOA_REQUIRED
 567     ], have_goa="yes", have_goa="no")
 568
 569    AC_MSG_CHECKING([Mission Control plugins dir])
 570    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 571
 572    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 573    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 574 else
 575    have_goa=no
 576 fi
 577
 578 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 579    AC_MSG_ERROR([Could not find GOA dependencies.])
 580 fi
 581
 582 if test "x$have_goa" = "xyes"; then
 583    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 584 fi
 585
 586 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 587
 588 # Optional dependency for avatar selection
 589 AC_ARG_WITH([cheese],
 590             AS_HELP_STRING([--with-cheese],
 591                            [enable cheese webcam support]),,
 592             with_cheese=auto)
 593
 594 if test x"$with_cheese" != x"no" ; then
 595    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 596    if test x${have_cheese} = xyes; then
 597      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 598    fi
 599    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 600      AC_MSG_ERROR([Cheese configured but not found:
 601
 602 $CHEESE_PKG_ERRORS])
 603    fi
 604 else
 605    have_cheese=no
 606 fi
 607 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 608
 609 # Help documentation
 610 YELP_HELP_INIT
 611
 612 # -----------------------------------------------------------
 613 # Coding style checks
 614 # -----------------------------------------------------------
 615 AC_ARG_ENABLE(coding-style-checks,
 616   AS_HELP_STRING([--disable-coding-style-checks],
 617                  [do not check coding style using grep]),
 618     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 619     [ENABLE_CODING_STYLE_CHECKS=yes])
 620
 621 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 622 # -----------------------------------------------------------
 623
 624 AC_CONFIG_FILES([
 625    Makefile
 626    data/Makefile
 627    data/empathy.desktop.in
 628    data/empathy-accounts.desktop.in
 629    data/icons/Makefile
 630    extensions/Makefile
 631    po/Makefile.in
 632    libempathy/Makefile
 633    libempathy-gtk/Makefile
 634    src/Makefile
 635    nautilus-sendto-plugin/Makefile
 636    goa-mc-plugin/Makefile
 637    help/Makefile
 638    tests/Makefile
 639    tests/interactive/Makefile
 640    tests/xml/Makefile
 641    tools/Makefile
 642 ])
 643 AC_OUTPUT
 644
 645 echo "
 646 Configure summary:
 647
 648         Compiler....................:  ${CC}
 649         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 650         Linker Flags................:  ${LDFLAGS}
 651         Prefix......................:  ${prefix}
 652         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 653
 654     Features:
 655         Spell checking (enchant)....:  ${have_enchant}
 656         Display maps (libchamplain).:  ${have_libchamplain}
 657         Location awareness (Geoclue):  ${have_geoclue}
 658         Geocode support (Geocode)...:  ${have_geocode}
 659         Meego widgets...............:  ${have_meego}
 660         Cheese webcam support ......:  ${have_cheese}
 661         Camera monitoring...........:  ${have_gudev}
 662
 663     Connectivity:
 664         NetworkManager integration..:  ${have_nm}
 665         ConnMan integration.........:  ${have_connman}
 666
 667     Extras:
 668         Nautilus-sendto plugin......:  ${have_nst}
 669         GOA MC plugin...............:  ${have_goa}
 670         Salut E-D-S support.........:  ${with_eds}
 671         Exp. Call log support.......:  ${have_call_logs}
 672 "