configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GLIB_REQUIRED=2.30.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.18
  47 TELEPATHY_GLIB_REQUIRED=0.17.3
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50 GOA_REQUIRED=3.3.0
  51
  52 # Optional deps
  53 CLUTTER_REQUIRED=1.7.14
  54 CLUTTER_GTK_REQUIRED=0.90.3
  55 ENCHANT_REQUIRED=1.2.0
  56 GEOCLUE_REQUIRED=0.11
  57 ISO_CODES_REQUIRED=0.35
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60 CHAMPLAIN_REQUIRED=0.12.1
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # Disable GLib deprecation warnings for now; we don't want to bump the GLib dep
  70 # and make things harder for contributiors without good reason. We'll re-enable
  71 # those warnings later during the cycle (bgo #662662)
  72 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
  73
  74 AC_CONFIG_MACRO_DIR([m4])
  75 AC_CONFIG_HEADERS([config.h])
  76 AC_CONFIG_SRCDIR([configure.ac])
  77 AC_CONFIG_AUX_DIR(.)
  78
  79 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  80
  81 # Support silent build rules. Disable
  82 # by either passing --disable-silent-rules to configure or passing V=1
  83 # to make
  84 AM_SILENT_RULES([yes])
  85
  86 # Check for programs
  87 AC_PROG_CC
  88 AC_HEADER_STDC
  89 AM_PROG_MKDIR_P
  90 AM_PATH_GLIB_2_0
  91 AC_PATH_XTRA
  92
  93 # Initialize libtool
  94 LT_PREREQ([2.2])
  95 LT_INIT
  96
  97 GNOME_DOC_INIT([0.17.3])
  98 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  99 GLIB_GSETTINGS
 100 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 101 AC_SUBST(GLIB_GENMARSHAL)
 102
 103 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 104 if test -z "$XSLTPROC"; then
 105   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 106 fi
 107 AM_PATH_PYTHON([2.3])
 108
 109 EMPATHY_ARG_VALGRIND
 110
 111
 112 # -----------------------------------------------------------
 113 # Error flags
 114 # -----------------------------------------------------------
 115 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 116 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 117
 118 AC_ARG_ENABLE(Werror,
 119   AS_HELP_STRING([--disable-Werror],
 120                  [compile without -Werror (normally enabled in development builds)]),
 121     werror=$enableval, :)
 122
 123 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 124 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 125         wno_missing_field_initializers=yes,
 126         wno_missing_field_initializers=no)
 127 AS_COMPILER_FLAG(-Wno-unused-parameter,
 128         wno_unused_parameter=yes,
 129         wno_unused_parameter=no)
 130
 131 ifelse(empathy_released, 1, [],
 132     [
 133         if test x$werror = xyes; then
 134             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 135         fi
 136         if test x$wextra = xyes -a \
 137             x$wno_missing_field_initializers = xyes -a \
 138             x$wno_unused_parameter = xyes; then
 139             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 140         fi
 141     ])
 142
 143 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 144 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 145 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 146 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 147 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 148
 149 AC_SUBST(ERROR_CFLAGS)
 150
 151 AC_ARG_ENABLE(gprof,
 152             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 153             [build with support for gprof]),,
 154             [enable_gprof=no])
 155 if test "x$enable_gprof" != "xno" ; then
 156     CFLAGS="$CFLAGS -pg"
 157     LDFLAGS="$LDFLAGS -pg"
 158 fi
 159
 160 AC_SUBST(LDFLAGS)
 161
 162 # -----------------------------------------------------------
 163 # Pkg-Config dependency checks
 164 # -----------------------------------------------------------
 165
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 PKG_CHECK_MODULES(EMPATHY,
 170 [
 171    dbus-glib-1
 172    folks >= $FOLKS_REQUIRED
 173    folks-telepathy >= $FOLKS_REQUIRED
 174    glib-2.0 >= $GLIB_REQUIRED
 175    gio-2.0 >= $GLIB_REQUIRED
 176    gio-unix-2.0 >= $GLIB_REQUIRED
 177    gnome-keyring-1 >= $KEYRING_REQUIRED
 178    gnutls >= $GNUTLS_REQUIRED
 179    gmodule-export-2.0
 180    gobject-2.0
 181    gsettings-desktop-schemas
 182    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 183    gstreamer-interfaces-0.10
 184    libxml-2.0
 185    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 186    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 187    x11
 188    gtk+-3.0 >= $GTK_REQUIRED
 189    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 190    libnotify >= $LIBNOTIFY_REQUIRED
 191    gcr-3 >= $GCR_REQUIRED
 192    libpulse
 193    libpulse-mainloop-glib
 194    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 195    libsoup-2.4
 196 ])
 197
 198 PKG_CHECK_MODULES(EMPATHY_AV,
 199 [
 200    farsight2-0.10
 201    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 202 ])
 203
 204 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 205    [Name of provider for accounts imported from GOA])
 206
 207 # -----------------------------------------------------------
 208 # Call interface
 209 # -----------------------------------------------------------
 210 AC_ARG_ENABLE(call,
 211             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 212             [build with Call interface support]),,
 213             [enable_call=auto])
 214 if test "x$enable_call" != "xno" ; then
 215    PKG_CHECK_MODULES(EMPATHY_CALL,
 216    [
 217       farstream-0.1
 218       telepathy-farstream >= 0.2.0
 219       clutter-1.0 >= $CLUTTER_REQUIRED
 220       clutter-gtk-1.0
 221       clutter-gst-1.0
 222    ], have_call="yes", have_call="no" )
 223
 224    if test "x$have_call" = "xyes"; then
 225       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 226    fi
 227 else
 228   have_call=no
 229 fi
 230
 231 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 232    AC_MSG_ERROR([Could not find Call handler dependencies:
 233
 234 $EMPATHY_CALL_PKG_ERRORS])
 235 fi
 236 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 237
 238
 239 # -----------------------------------------------------------
 240 # Call support in tp-logger
 241 # -----------------------------------------------------------
 242 AC_ARG_ENABLE(call-logs,
 243             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 244             [build with call logs support]),,
 245             [enable_call_logs=auto])
 246 if test "x$enable_call_logs" != "xno" ; then
 247    SAVE_CFLAGS=$CFLAGS
 248    SAVE_CPPFLAGS=$CPPFLAGS
 249    SAVE_LDFLAGS=$LDFLAGS
 250    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 251    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 252    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 253
 254    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 255       have_call_logs="yes", have_call_logs="no")
 256
 257    CFLAGS=$SAVE_CFLAGS
 258    CPPFLAGS=$SAVE_CPPFLAGS
 259    LDFLAGS=$SAVE_LDFLAGS
 260
 261    if test "x$have_call_logs" = "xyes"; then
 262       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 263    fi
 264 else
 265   have_call_logs=no
 266 fi
 267
 268 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 269    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 270                  built with --enable-call])
 271 fi
 272
 273 # -----------------------------------------------------------
 274 # evolution-data-server (about-me)
 275 # -----------------------------------------------------------
 276 AC_ARG_WITH(eds,
 277             AS_HELP_STRING([--with-eds],
 278                            [build with evolution-data-server support]),,
 279             [with_eds=yes])
 280 if test x"$with_eds" = x"yes" ; then
 281    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 282    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 283 fi
 284
 285 # -----------------------------------------------------------
 286 # Enable debug
 287 # -----------------------------------------------------------
 288
 289 AC_ARG_ENABLE(debug,
 290   AS_HELP_STRING([--disable-debug],
 291                  [compile without debug code]),
 292     enable_debug=$enableval, enable_debug=yes )
 293
 294 if test x$enable_debug = xyes; then
 295   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 296 fi
 297
 298 # -----------------------------------------------------------
 299 # Language Support
 300 # -----------------------------------------------------------
 301 IT_PROG_INTLTOOL([0.40.0])
 302
 303 AM_GNU_GETTEXT_VERSION([0.17])
 304 AM_GNU_GETTEXT([external])
 305
 306 GETTEXT_PACKAGE=empathy
 307 AC_SUBST(GETTEXT_PACKAGE)
 308 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 309
 310 # -----------------------------------------------------------
 311 # Connectivity integration
 312 # -----------------------------------------------------------
 313 AC_ARG_WITH(connectivity,
 314               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 315                              [build with connectivity support]), ,
 316                              with_connectivity=auto)
 317
 318 if test "x$with_connectivity" = "xno"; then
 319    have_nm=no
 320    have_connman=no
 321
 322 elif test "x$with_connectivity" = "xconnman"; then
 323    have_nm=no
 324
 325    PKG_CHECK_MODULES(CONNMAN,
 326    [
 327       dbus-glib-1
 328    ], have_connman="yes", have_connman="no")
 329
 330    if test "x$have_connman" = "xyes"; then
 331       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 332    fi
 333
 334 else
 335    have_connman=no
 336
 337    PKG_CHECK_MODULES(NETWORK_MANAGER,
 338    [
 339       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 340    ], have_nm="yes", have_nm="no")
 341
 342    if test "x$have_nm" = "xyes"; then
 343       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 344    fi
 345 fi
 346
 347 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 348    AC_MSG_ERROR([Couldn't find connman dependencies:
 349
 350 $CONNMAN_PKG_ERRORS])
 351 fi
 352
 353 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 354    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 355
 356 $NETWORK_MANAGER_PKG_ERRORS])
 357 fi
 358
 359 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 360 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 361
 362 # -----------------------------------------------------------
 363 # gudev
 364 # -----------------------------------------------------------
 365 AC_ARG_ENABLE(gudev,
 366               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 367                              [build with gudev support]), ,
 368                              enable_gudev=auto)
 369
 370 if test "x$enable_gudev" != "xno"; then
 371
 372    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 373         have_gudev="yes", have_gudev="no")
 374
 375    if test "x$have_gudev" = "xyes"; then
 376       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 377    fi
 378 else
 379    have_gudev=no
 380 fi
 381
 382 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 383    AC_MSG_ERROR([Could not find gudev dependencies:
 384
 385 $UDEV_PKG_ERRORS])
 386 fi
 387 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 388
 389 # -----------------------------------------------------------
 390 # spellchecking checks: enchant and iso-codes
 391 # -----------------------------------------------------------
 392 AC_ARG_ENABLE(spell,
 393               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 394                              [Enable spell checking]), ,
 395                              enable_spell=auto)
 396
 397 if test "x$enable_spell" != "xno"; then
 398    PKG_CHECK_MODULES(ENCHANT,
 399    [
 400       enchant >= $ENCHANT_REQUIRED,
 401       iso-codes >= $ISO_CODES_REQUIRED
 402    ], have_enchant="yes", have_enchant="no")
 403
 404    if test "x$have_enchant" = "xyes"; then
 405       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 406       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 407          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 408             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 409             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 410             result=yes
 411       else
 412             result=no
 413             have_enchant="no"
 414       fi
 415       AC_MSG_RESULT([$result])
 416    fi
 417 else
 418    have_enchant=no
 419 fi
 420
 421 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 422    AC_MSG_ERROR([Could not find spell-checking dependencies:
 423
 424 $ENCHANT_PKG_ERRORS])
 425 fi
 426
 427 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 428
 429 # -----------------------------------------------------------
 430 # Map view checks: libchamplain
 431 # -----------------------------------------------------------
 432 AC_ARG_ENABLE(map,
 433               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 434                              [Enable map view]), ,
 435                              enable_map=auto)
 436
 437 if test "x$enable_map" != "xno"; then
 438
 439    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 440     [
 441        clutter-gtk-1.0
 442        champlain-gtk-0.12
 443        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 444     ], have_libchamplain="yes", have_libchamplain="no")
 445
 446    if test "x$have_libchamplain" = "xyes"; then
 447       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 448    fi
 449 else
 450    have_libchamplain=no
 451 fi
 452
 453 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 454    AC_MSG_ERROR([Could not find map view dependencies:
 455
 456 $LIBCHAMPLAIN_PKG_ERRORS])
 457 fi
 458
 459 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 460
 461 # -----------------------------------------------------------
 462 # location checks: geoclue
 463 # -----------------------------------------------------------
 464 AC_ARG_ENABLE(location,
 465               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 466                              [Enable location awareness]), ,
 467                              enable_location=auto)
 468
 469 if test "x$enable_location" != "xno"; then
 470    PKG_CHECK_MODULES(GEOCLUE,
 471    [
 472       geoclue >= $GEOCLUE_REQUIRED
 473    ], have_geoclue="yes", have_geoclue="no")
 474
 475    if test "x$have_geoclue" = "xyes"; then
 476       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 477    fi
 478 else
 479    have_geoclue="no"
 480 fi
 481
 482 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 483    AC_MSG_ERROR([Could not find location dependencies:
 484
 485 $GEOCLUE_PKG_ERRORS])
 486 fi
 487
 488 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 489 AC_SUBST(GEOCLUE_CFLAGS)
 490 AC_SUBST(GEOCLUE_LIBS)
 491
 492 # -----------------------------------------------------------
 493 # location checks: geocode-glib
 494 # -----------------------------------------------------------
 495 AC_ARG_ENABLE(geocode,
 496               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 497                              [Enable geocode support]), ,
 498                              enable_geocode=auto)
 499
 500 if test "x$enable_geocode" != "xno"; then
 501    PKG_CHECK_MODULES(GEOCODE,
 502    [
 503       geocode-glib
 504    ], have_geocode="yes", have_geocode="no")
 505
 506    if test "x$have_geocode" = "xyes"; then
 507       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 508    fi
 509 else
 510    have_geocode="no"
 511 fi
 512
 513 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 514    AC_MSG_ERROR([Could not find geocode dependencies:
 515
 516 $GEOCODE_PKG_ERRORS])
 517 fi
 518
 519 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 520 AC_SUBST(GEOCODE_CFLAGS)
 521 AC_SUBST(GEOCODE_LIBS)
 522
 523 # -----------------------------------------------------------
 524 # meego widgets support
 525 # -----------------------------------------------------------
 526 AC_ARG_ENABLE(meego,
 527               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 528                              [Enable meego widgets]), ,
 529                              enable_meego=no)
 530
 531 if test "x$enable_meego" != "xno"; then
 532     PKG_CHECK_MODULES(MEEGO,
 533     [
 534        mx-gtk-1.0
 535        gio-unix-2.0
 536     ], have_meego="yes", have_meego="no")
 537
 538     if test "x$have_meego" = "xyes"; then
 539        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 540     fi
 541 else
 542    have_meego="no"
 543 fi
 544
 545 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 546    AC_MSG_ERROR([Could not find meego dependencies:
 547
 548 $MEEGO_PKG_ERRORS])
 549 fi
 550
 551 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 552 AC_SUBST(MEEGO_CFLAGS)
 553 AC_SUBST(MEEGO_LIBS)
 554
 555 # -----------------------------------------------------------
 556 # nautilus-sendto
 557 # -----------------------------------------------------------
 558 AC_ARG_ENABLE(nautilus-sendto,
 559               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 560                              [build nautilus-sendto plugin]), ,
 561                              enable_nautilus_sendto=auto)
 562
 563 if test "x$enable_nautilus_sendto" != "xno"; then
 564    PKG_CHECK_MODULES(NST,
 565     [
 566        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 567     ], have_nst="yes", have_nst="no")
 568 else
 569    have_nst=no
 570 fi
 571
 572 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 573    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 574
 575 $NST_PKG_ERRORS])
 576 fi
 577
 578 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 579
 580 # -----------------------------------------------------------
 581 # goa-mc-plugin
 582 # -----------------------------------------------------------
 583 AC_ARG_ENABLE(goa,
 584               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 585                              [build GOA MC plugin]), ,
 586                              enable_goa=auto)
 587
 588 if test "x$enable_goa" != "xno"; then
 589    PKG_CHECK_MODULES(GOA,
 590     [
 591        mission-control-plugins
 592        goa-1.0 >= $GOA_REQUIRED
 593     ], have_goa="yes", have_goa="no")
 594
 595    AC_MSG_CHECKING([Mission Control plugins dir])
 596    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 597
 598    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 599    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 600 else
 601    have_goa=no
 602 fi
 603
 604 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 605    AC_MSG_ERROR([Could not find GOA dependencies.])
 606 fi
 607
 608 if test "x$have_goa" = "xyes"; then
 609    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 610 fi
 611
 612 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 613
 614 # Optional dependency for avatar selection
 615 AC_ARG_WITH([cheese],
 616             AS_HELP_STRING([--with-cheese],
 617                            [enable cheese webcam support]),,
 618             with_cheese=auto)
 619
 620 if test x"$with_cheese" != x"no" ; then
 621    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 622    if test x${have_cheese} = xyes; then
 623      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 624    fi
 625    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 626      AC_MSG_ERROR([Cheese configured but not found:
 627
 628 $CHEESE_PKG_ERRORS])
 629    fi
 630 else
 631    have_cheese=no
 632 fi
 633 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 634
 635
 636 # -----------------------------------------------------------
 637 # Coding style checks
 638 # -----------------------------------------------------------
 639 AC_ARG_ENABLE(coding-style-checks,
 640   AS_HELP_STRING([--disable-coding-style-checks],
 641                  [do not check coding style using grep]),
 642     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 643     [ENABLE_CODING_STYLE_CHECKS=yes])
 644
 645 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 646 # -----------------------------------------------------------
 647
 648 AC_CONFIG_FILES([
 649    Makefile
 650    data/Makefile
 651    data/empathy.desktop.in
 652    data/empathy-accounts.desktop.in
 653    data/icons/Makefile
 654    extensions/Makefile
 655    po/Makefile.in
 656    libempathy/Makefile
 657    libempathy-gtk/Makefile
 658    src/Makefile
 659    nautilus-sendto-plugin/Makefile
 660    goa-mc-plugin/Makefile
 661    help/Makefile
 662    tests/Makefile
 663    tests/interactive/Makefile
 664    tests/xml/Makefile
 665    tools/Makefile
 666 ])
 667 AC_OUTPUT
 668
 669 echo "
 670 Configure summary:
 671
 672         Compiler....................:  ${CC}
 673         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 674         Linker Flags................:  ${LDFLAGS}
 675         Prefix......................:  ${prefix}
 676         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 677
 678     Features:
 679         Spell checking (enchant)....:  ${have_enchant}
 680         Display maps (libchamplain).:  ${have_libchamplain}
 681         Location awareness (Geoclue):  ${have_geoclue}
 682         Geocode support (Geocode)...:  ${have_geocode}
 683         Meego widgets...............:  ${have_meego}
 684         Cheese webcam support ......:  ${have_cheese}
 685         Camera monitoring...........:  ${have_gudev}
 686
 687     Connectivity:
 688         NetworkManager integration..:  ${have_nm}
 689         ConnMan integration.........:  ${have_connman}
 690
 691     Extras:
 692         Nautilus-sendto plugin......:  ${have_nst}
 693         GOA MC plugin...............:  ${have_goa}
 694         Salut E-D-S support.........:  ${with_eds}
 695         Exp. Call channel handler...:  ${have_call}
 696         Exp. Call log support.......:  ${have_call_logs}
 697 "