Merge branch 'folks-async-and-prepare'
[empathy.git] / configure.ac
1 dnl If not 1, append datestamp to the version number
2 m4_define(empathy_released, 0)
3
4 m4_define([empathy_major_version], [2])
5 m4_define([empathy_minor_version], [31])
6 m4_define([empathy_micro_version], [5])
7 m4_define([empathy_nano_version], [1])
8
9 dnl Display the nano_version only if it's not '0'
10 m4_define([empathy_base_version],
11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
12 m4_define([empathy_full_version],
13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
14               [empathy_base_version].[empathy_nano_version])])
15
16 m4_define(empathy_maybe_datestamp,
17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
18
19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
20
21
22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
23
24
25 AC_PREREQ(2.59)
26 AC_COPYRIGHT([
27   Copyright (C) 2003-2007 Imendio AB
28   Copyright (C) 2007-2010 Collabora Ltd.
29 ])
30
31 # Minimal version required
32
33 # Hardp deps
34 FOLKS_REQUIRED=0.1.11
35 GCONF_REQUIRED=1.2.0
36 GLIB_REQUIRED=2.25.9
37 GTK_REQUIRED=2.21.2
38 KEYRING_REQUIRED=2.22
39 LIBCANBERRA_GTK_REQUIRED=0.4
40 LIBNOTIFY_REQUIRED=0.4.4
41 LIBNOTIFY_REQUIRED_GTK3=0.5.1
42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
43 TELEPATHY_GLIB_REQUIRED=0.11.7
44 TELEPATHY_LOGGER=0.1.2
45 UNIQUE_REQUIRED=1.1.2
46
47 # Optionnal deps
48 CLUTTER_GTK_REQUIRED=0.10
49 ENCHANT_REQUIRED=1.2.0
50 GEOCLUE_REQUIRED=0.11
51 ISO_CODES_REQUIRED=0.35
52 LIBCHAMPLAIN_GTK_REQUIRED=0.4
53 LIBCHAMPLAIN_REQUIRED=0.4
54 NAUTILUS_SENDTO_REQUIRED=2.28.1
55 NAUTILUS_SENDTO_REQUIRED_GTK3=2.90.0
56 NETWORK_MANAGER_REQUIRED=0.7.0
57 WEBKIT_REQUIRED=1.1.15
58
59 # Use --enable-maintainer-mode to disable deprecated symbols,
60 # disable single include and enable GSEAL. If this is not a released empathy,
61 # maintainer mode is forced
62 ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
63 GNOME_MAINTAINER_MODE_DEFINES
64
65 AC_CONFIG_MACRO_DIR([m4])
66 AC_CONFIG_HEADERS([config.h])
67 AC_CONFIG_SRCDIR([configure.ac])
68 AC_CONFIG_AUX_DIR(.)
69
70 GNOME_COMMON_INIT
71
72 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
73
74 # Support silent build rules, requires at least automake-1.11. Disable
75 # by either passing --disable-silent-rules to configure or passing V=1
76 # to make
77 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
78
79 AC_ISC_POSIX
80 AC_PROG_CC
81 AC_HEADER_STDC
82 AM_PROG_LIBTOOL
83 AM_PROG_MKDIR_P
84 AM_PATH_GLIB_2_0
85 AC_PATH_XTRA
86 IT_PROG_INTLTOOL([0.35.0])
87 GNOME_DOC_INIT([0.17.3])
88 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
89 GLIB_GSETTINGS
90 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
91 AC_SUBST(GLIB_GENMARSHAL)
92
93 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
94 if test -z "$XSLTPROC"; then
95   AC_MSG_ERROR([xsltproc (from libxslt) is required])
96 fi
97 AM_PATH_PYTHON([2.3])
98
99 EMPATHY_ARG_VALGRIND
100
101
102 # -----------------------------------------------------------
103 # Error flags
104 # -----------------------------------------------------------
105 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
106 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
107
108 AC_ARG_ENABLE(Werror,
109   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
110     werror=$enableval, :)
111
112 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
113 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
114         wno_missing_field_initializers=yes,
115         wno_missing_field_initializers=no)
116 AS_COMPILER_FLAG(-Wno-unused-parameter,
117         wno_unused_parameter=yes,
118         wno_unused_parameter=no)
119
120 ifelse(empathy_released, 1, [],
121     [
122         if test x$werror = xyes; then
123             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
124         fi
125         if test x$wextra = xyes -a \
126             x$wno_missing_field_initializers = xyes -a \
127             x$wno_unused_parameter = xyes; then
128             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
129         fi
130     ])
131
132 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
133 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
134 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
135 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
136 # Disabled because some GTK+ headers (like gtkitemfactory.h) are bugged :(
137 #AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
138
139 AC_SUBST(ERROR_CFLAGS)
140
141 # -----------------------------------------------------------
142 # Pkg-Config dependency checks
143 # -----------------------------------------------------------
144
145 PKG_CHECK_MODULES(EMPATHY,
146 [
147    dbus-glib-1
148    farsight2-0.10
149    folks >= $FOLKS_REQUIRED
150    folks-telepathy >= $FOLKS_REQUIRED
151    gconf-2.0 >= $GCONF_REQUIRED
152    gio-2.0 >= $GLIB_REQUIRED
153    gio-unix-2.0 >= $GLIB_REQUIRED
154    gnome-keyring-1 >= $KEYRING_REQUIRED
155    gobject-2.0
156    gstreamer-0.10
157    gstreamer-interfaces-0.10
158    libebook-1.2
159    libxml-2.0
160    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
161    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
162    telepathy-logger-0.1 >= $TELEPATHY_LOGGER
163    x11
164 ])
165
166 # -----------------------------------------------------------
167 # GTK+
168 # -----------------------------------------------------------
169 AC_ARG_ENABLE(gtk3,
170               AS_HELP_STRING([--enable-gtk3=@<:@no/yes/auto@:>@],
171                              [build with GTK+3]), ,
172                              enable_gtk3=auto)
173
174 # Try to use GTK+3 if available
175 if test "x$enable_gtk3" != "xno"; then
176    PKG_CHECK_MODULES(GTK,
177    [
178       gtk+-3.0 >= $GTK_REQUIRED
179    ], have_gtk3="yes", have_gtk3="no")
180 else
181    have_gtk3="no"
182 fi
183
184 if test "x$enable_gtk3" = "xyes" -a "x$have_gtk3" != "xyes"; then
185    AC_MSG_ERROR([Could not find gtk3 dependencies.])
186 fi
187
188 if test "x$have_gtk3" == "xyes"; then
189    # GTK3 specific deps
190    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED)
191    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED_GTK3)
192    PKG_CHECK_MODULES(UNIQUE, unique-3.0 >= $UNIQUE_REQUIRED)
193 else
194    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED)
195
196    # GTK2 specific deps
197    PKG_CHECK_MODULES(CANBERRA, libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED)
198    PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
199    PKG_CHECK_MODULES(UNIQUE, unique-1.0 >= $UNIQUE_REQUIRED)
200
201    # Enable GSEAL checks if needed
202    if test $USE_MAINTAINER_MODE = yes; then
203       AC_DEFINE(GSEAL_ENABLE, [], [Seal public structs to force usage of accessors])
204    fi
205 fi
206
207 # -----------------------------------------------------------
208 # Enable debug
209 # -----------------------------------------------------------
210
211 AC_ARG_ENABLE(debug,
212   AC_HELP_STRING([--disable-debug],[compile without debug code]),
213     enable_debug=$enableval, enable_debug=yes )
214
215 if test x$enable_debug = xyes; then
216   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
217 fi
218
219 # -----------------------------------------------------------
220 # Language Support
221 # -----------------------------------------------------------
222
223 GETTEXT_PACKAGE=empathy
224 AC_SUBST(GETTEXT_PACKAGE)
225 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
226
227 AM_GLIB_GNU_GETTEXT
228
229 # -----------------------------------------------------------
230 # Connectivity integration
231 # -----------------------------------------------------------
232 AC_ARG_WITH(connectivity,
233               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
234                              [build with connectivity support]), ,
235                              with_connectivity=auto)
236
237 if test "x$with_connectivity" = "xno"; then
238    have_nm=no
239    have_connman=no
240
241 elif test "x$with_connectivity" = "xconnman"; then
242    have_nm=no
243
244    PKG_CHECK_MODULES(CONNMAN,
245    [
246       dbus-glib-1
247    ], have_connman="yes", have_connman="no")
248
249    if test "x$have_connman" = "xyes"; then
250       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
251    fi
252
253 else
254    have_connman=no
255
256    PKG_CHECK_MODULES(NETWORK_MANAGER,
257    [
258       libnm-glib >= $NETWORK_MANAGER_REQUIRED
259    ], have_nm="yes", have_nm="no")
260
261    if test "x$have_nm" = "xyes"; then
262       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
263    fi
264 fi
265
266 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
267    AC_MSG_ERROR([Couldn't find connman dependencies.])
268 fi
269
270 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
271    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
272 fi
273
274 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
275 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
276
277 # -----------------------------------------------------------
278 # Webkit
279 # -----------------------------------------------------------
280 AC_ARG_ENABLE(webkit,
281               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
282                              [build with webkit support]), ,
283                              enable_webkit=auto)
284
285 if test "x$enable_webkit" != "xno"; then
286
287    if test "x$have_gtk3" == "xno"; then
288       PKG_CHECK_MODULES(WEBKIT, [webkit-1.0 >= $WEBKIT_REQUIRED],
289           have_webkit="yes", have_webkit="no")
290    else
291       PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
292           have_webkit="yes", have_webkit="no")
293    fi
294
295    if test "x$have_webkit" = "xyes"; then
296       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
297    fi
298 else
299    have_webkit=no
300 fi
301
302 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
303    AC_MSG_ERROR([Could not find webkit dependencies.])
304 fi
305 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
306
307 # -----------------------------------------------------------
308 # spellchecking checks: enchant and iso-codes
309 # -----------------------------------------------------------
310 AC_ARG_ENABLE(spell,
311               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
312                              [Enable spell checking]), ,
313                              enable_spell=auto)
314
315 if test "x$enable_spell" != "xno"; then
316    PKG_CHECK_MODULES(ENCHANT,
317    [
318       enchant >= $ENCHANT_REQUIRED,
319       iso-codes >= $ISO_CODES_REQUIRED
320    ], have_enchant="yes", have_enchant="no")
321
322    if test "x$have_enchant" = "xyes"; then
323       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
324       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
325          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
326             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
327             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
328             result=yes
329       else
330             result=no
331             have_enchant="no"
332       fi
333       AC_MSG_RESULT([$result])
334    fi
335 else
336    have_enchant=no
337 fi
338
339 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
340    AC_MSG_ERROR([Could not find spell dependencies.])
341 fi
342
343 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
344
345 # -----------------------------------------------------------
346 # Map view checks: libchamplain
347 # -----------------------------------------------------------
348 AC_ARG_ENABLE(map,
349               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
350                              [Enable map view]), ,
351                              enable_map=auto)
352
353 if test "x$enable_map" != "xno"; then
354
355    if test "x$have_gtk3" == "xno"; then
356       PKG_CHECK_MODULES(LIBCHAMPLAIN,
357       [
358          champlain-0.4 >= $LIBCHAMPLAIN_REQUIRED,
359          champlain-gtk-0.4 >= $LIBCHAMPLAIN_GTK_REQUIRED
360          clutter-gtk-0.10 >= $CLUTTER_GTK_REQUIRED
361       ], have_libchamplain="yes", have_libchamplain="no")
362    else
363       # FIXME: check deps once clutter-gtk and champlain have been ported to GTK3
364       have_libchamplain="no"
365    fi
366
367    if test "x$have_libchamplain" = "xyes"; then
368       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
369    fi
370 else
371    have_libchamplain=no
372 fi
373
374 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
375    AC_MSG_ERROR([Could not find map view dependencies.])
376 fi
377
378 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
379
380 # -----------------------------------------------------------
381 # location checks: geoclue
382 # -----------------------------------------------------------
383 AC_ARG_ENABLE(location,
384               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
385                              [Enable location awareness]), ,
386                              enable_location=auto)
387
388 if test "x$enable_location" != "xno"; then
389    PKG_CHECK_MODULES(GEOCLUE,
390    [
391       geoclue >= $GEOCLUE_REQUIRED
392    ], have_geoclue="yes", have_geoclue="no")
393
394    if test "x$have_geoclue" = "xyes"; then
395       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
396    fi
397 else
398    have_geoclue="no"
399 fi
400
401 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
402    AC_MSG_ERROR([Could not find location dependencies.])
403 fi
404
405 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
406 AC_SUBST(GEOCLUE_CFLAGS)
407 AC_SUBST(GEOCLUE_LIBS)
408
409 # -----------------------------------------------------------
410 # meego widgets support
411 # -----------------------------------------------------------
412 AC_ARG_ENABLE(meego,
413               AS_HELP_STRING([--enable-meego=@<:no/yes@:>@],
414                              [Enable meego widgets]), ,
415                              enable_meego=no)
416
417 if test "x$enable_meego" != "xno"; then
418     PKG_CHECK_MODULES(MEEGO,
419     [
420        mx-gtk-1.0
421     ], have_meego="yes", have_meego="no")
422
423     if test "x$have_meego" = "xyes"; then
424        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
425     fi
426 else
427    have_meego="no"
428 fi
429
430 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
431    AC_MSG_ERROR([Could not find meego dependencies.])
432 fi
433
434 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
435 AC_SUBST(MEEGO_CFLAGS)
436 AC_SUBST(MEEGO_LIBS)
437
438 # -----------------------------------------------------------
439 # nautilus-sendto
440 # -----------------------------------------------------------
441 AC_ARG_ENABLE(nautilus-sendto,
442               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
443                              [build nautilus-sendto plugin]), ,
444                              enable_nautilus_sendto=auto)
445
446 if test "x$enable_nautilus_sendto" != "xno"; then
447    if test "x$have_gtk3" == "xno"; then
448       # Newer NST requires GTK+3 so we can't use it
449       PKG_CHECK_MODULES(NST,
450       [
451          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
452          nautilus-sendto < 2.90.0
453       ], have_nst="yes", have_nst="no")
454
455       AC_DEFINE(HAVE_OLD_NST, [], [Legacy compat mode with old nautilus-sendto] )
456    else
457       PKG_CHECK_MODULES(NST,
458       [
459          nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED_GTK3
460       ], have_nst="yes", have_nst="no")
461    fi
462 else
463    have_nst=no
464 fi
465
466 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
467    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
468 fi
469
470 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
471
472 # -----------------------------------------------------------
473 # new, single-window control center
474 # -----------------------------------------------------------
475 AC_ARG_ENABLE(control_center_embedding,
476               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
477                              [Enable support for single-window control center]),
478                              , enable_control_center_embedding=auto)
479
480 if test "x$enable_control_center_embedding" != "xno"; then
481    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING,
482    [
483       libgnome-control-center
484    ], have_control_center_embedding="yes", have_control_center_embedding="no")
485
486    if test "x$have_control_center_embedding" = "xyes"; then
487       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
488
489       AC_MSG_CHECKING([gnome-control-center extension dir])
490       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
491       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
492           AC_MSG_ERROR([Could not determine extensiondir])
493       else
494           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
495       fi
496       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
497    fi
498 else
499    have_control_center_embedding="no"
500 fi
501
502 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
503    AC_MSG_ERROR([Could not find single-window control center dependencies.])
504 fi
505
506 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
507 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
508 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
509
510 # -----------------------------------------------------------
511 # Coding style checks
512 # -----------------------------------------------------------
513 AC_ARG_ENABLE(coding-style-checks,
514   AC_HELP_STRING([--disable-coding-style-checks],
515                  [do not check coding style using grep]),
516     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
517
518 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
519 # -----------------------------------------------------------
520
521 AC_OUTPUT([
522    Makefile
523    data/Makefile
524    data/empathy.desktop.in
525    data/empathy-accounts.desktop.in
526    data/icons/Makefile
527    extensions/Makefile
528    po/Makefile.in
529    libempathy/Makefile
530    libempathy-gtk/Makefile
531    src/Makefile
532    nautilus-sendto-plugin/Makefile
533    help/Makefile
534    tests/Makefile
535    tests/interactive/Makefile
536    tests/xml/Makefile
537    tools/Makefile
538 ])
539
540 echo "
541 Configure summary:
542
543         Compiler....................:  ${CC}
544         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
545         Prefix......................:  ${prefix}
546         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
547         Use GTK+3...................:  ${have_gtk3}
548
549     Features:
550         Spell checking (enchant)....:  ${have_enchant}
551         Display maps (libchamplain).:  ${have_libchamplain}
552         Location awareness (Geoclue):  ${have_geoclue}
553         Adium themes (Webkit).......:  ${have_webkit}
554         Meego widgets ..............:  ${have_meego}
555         Control center embedding....:  ${have_control_center_embedding}
556
557     Connectivity:
558         NetworkManager integration..:  ${have_nm}
559         ConnMan integration.........:  ${have_connman}
560
561     Extras:
562         Nautilus-sendto plugin......:  ${have_nst}
563 "