configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [1])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT(Empathy, empathy_version, http://bugzilla.gnome.org/browse.cgi?product=empathy)
  23
  24
  25 AC_PREREQ(2.59)
  26 AC_COPYRIGHT([
  27   Copyright (C) 2003-2007 Imendio AB
  28   Copyright (C) 2007-2010 Collabora Ltd.
  29 ])
  30
  31 # Minimal version required
  32
  33 # Hardp deps
  34 FOLKS_REQUIRED=0.5.1
  35 GLIB_REQUIRED=2.28.0
  36 GNUTLS_REQUIRED=2.8.5
  37 GTK_REQUIRED=3.0.2
  38 KEYRING_REQUIRED=2.26.0
  39 GCR_REQUIRED=2.91.4
  40 LIBCANBERRA_GTK_REQUIRED=0.25
  41 LIBNOTIFY_REQUIRED=0.7.0
  42 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  43 TELEPATHY_GLIB_REQUIRED=0.15.1
  44 TELEPATHY_LOGGER=0.2.0
  45
  46 # Optional deps
  47 CLUTTER_GTK_REQUIRED=0.90.3
  48 ENCHANT_REQUIRED=1.2.0
  49 GEOCLUE_REQUIRED=0.11
  50 ISO_CODES_REQUIRED=0.35
  51 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  52 LIBCHAMPLAIN_REQUIRED=0.9
  53 NAUTILUS_SENDTO_REQUIRED=2.90.0
  54 NETWORK_MANAGER_REQUIRED=0.7.0
  55 WEBKIT_REQUIRED=1.3.2
  56 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  57
  58 # Use --enable-maintainer-mode to disable deprecated symbols,
  59 # disable single include and enable GSEAL. If this is not a released empathy,
  60 # maintainer mode is forced
  61 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  62 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  63 #GNOME_MAINTAINER_MODE_DEFINES
  64
  65 # telepathy-yell
  66 prev_top_build_prefix=$ac_top_build_prefix
  67 AX_CONFIG_DIR([telepathy-yell])
  68 ac_top_build_prefix=$prev_top_build_prefix
  69 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  70
  71 AC_CONFIG_MACRO_DIR([m4])
  72 AC_CONFIG_HEADERS([config.h])
  73 AC_CONFIG_SRCDIR([configure.ac])
  74 AC_CONFIG_AUX_DIR(.)
  75
  76 GNOME_COMMON_INIT
  77
  78 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  79
  80 # Support silent build rules, requires at least automake-1.11. Disable
  81 # by either passing --disable-silent-rules to configure or passing V=1
  82 # to make
  83 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  84
  85 AC_ISC_POSIX
  86 AC_PROG_CC
  87 AC_HEADER_STDC
  88 AM_PROG_LIBTOOL
  89 AM_PROG_MKDIR_P
  90 AM_PATH_GLIB_2_0
  91 AC_PATH_XTRA
  92 IT_PROG_INTLTOOL([0.35.0])
  93 GNOME_DOC_INIT([0.17.3])
  94 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  95 GLIB_GSETTINGS
  96 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  97 AC_SUBST(GLIB_GENMARSHAL)
  98
  99 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 100 if test -z "$XSLTPROC"; then
 101   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 102 fi
 103 AM_PATH_PYTHON([2.3])
 104
 105 EMPATHY_ARG_VALGRIND
 106
 107
 108 # -----------------------------------------------------------
 109 # Error flags
 110 # -----------------------------------------------------------
 111 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 112 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 113
 114 AC_ARG_ENABLE(Werror,
 115   AC_HELP_STRING([--disable-Werror],[compile without -Werror (normally enabled in development builds)]),
 116     werror=$enableval, :)
 117
 118 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 119 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 120         wno_missing_field_initializers=yes,
 121         wno_missing_field_initializers=no)
 122 AS_COMPILER_FLAG(-Wno-unused-parameter,
 123         wno_unused_parameter=yes,
 124         wno_unused_parameter=no)
 125
 126 ifelse(empathy_released, 1, [],
 127     [
 128         if test x$werror = xyes; then
 129             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 130         fi
 131         if test x$wextra = xyes -a \
 132             x$wno_missing_field_initializers = xyes -a \
 133             x$wno_unused_parameter = xyes; then
 134             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 135         fi
 136     ])
 137
 138 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 139 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 140 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 141 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 142 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 143
 144 AC_SUBST(ERROR_CFLAGS)
 145
 146 # -----------------------------------------------------------
 147 # Pkg-Config dependency checks
 148 # -----------------------------------------------------------
 149
 150 PKG_CHECK_MODULES(EMPATHY,
 151 [
 152    dbus-glib-1
 153    folks >= $FOLKS_REQUIRED
 154    folks-telepathy >= $FOLKS_REQUIRED
 155    glib-2.0 >= $GLIB_REQUIRED
 156    gio-2.0 >= $GLIB_REQUIRED
 157    gio-unix-2.0 >= $GLIB_REQUIRED
 158    gnome-keyring-1 >= $KEYRING_REQUIRED
 159    gnutls >= $GNUTLS_REQUIRED
 160    gmodule-export-2.0
 161    gobject-2.0
 162    gsettings-desktop-schemas
 163    gstreamer-0.10
 164    gstreamer-interfaces-0.10
 165    libxml-2.0
 166    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 167    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 168    x11
 169    gtk+-3.0 >= $GTK_REQUIRED
 170    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 171    libnotify >= $LIBNOTIFY_REQUIRED
 172    gcr-3 >= $GCR_REQUIRED
 173 ])
 174
 175 PKG_CHECK_MODULES(EMPATHY_AV,
 176 [
 177    farsight2-0.10
 178    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 179 ])
 180
 181 # -----------------------------------------------------------
 182 # Call interface
 183 # -----------------------------------------------------------
 184 AC_ARG_WITH(call,
 185             AC_HELP_STRING([--with-call], [build with Call interface support]),,
 186             [with_call=yes])
 187 if test "x$with_call" = "xyes" ; then
 188    PKG_CHECK_MODULES(YELL, [telepathy-yell])
 189    AC_DEFINE(HAVE_CALL, 1, [Define if we have Call interface support])
 190 fi
 191
 192 # -----------------------------------------------------------
 193 # evolution-data-server (about-me)
 194 # -----------------------------------------------------------
 195 AC_ARG_WITH(eds,
 196             AC_HELP_STRING([--with-eds], [build with evolution-data-server support]),,
 197             [with_eds=yes])
 198 if test x"$with_eds" = x"yes" ; then
 199    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 200    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 201 fi
 202
 203 # -----------------------------------------------------------
 204 # Enable debug
 205 # -----------------------------------------------------------
 206
 207 AC_ARG_ENABLE(debug,
 208   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 209     enable_debug=$enableval, enable_debug=yes )
 210
 211 if test x$enable_debug = xyes; then
 212   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 213 fi
 214
 215 # -----------------------------------------------------------
 216 # Language Support
 217 # -----------------------------------------------------------
 218
 219 GETTEXT_PACKAGE=empathy
 220 AC_SUBST(GETTEXT_PACKAGE)
 221 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 222
 223 AM_GLIB_GNU_GETTEXT
 224
 225 # -----------------------------------------------------------
 226 # Connectivity integration
 227 # -----------------------------------------------------------
 228 AC_ARG_WITH(connectivity,
 229               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 230                              [build with connectivity support]), ,
 231                              with_connectivity=auto)
 232
 233 if test "x$with_connectivity" = "xno"; then
 234    have_nm=no
 235    have_connman=no
 236
 237 elif test "x$with_connectivity" = "xconnman"; then
 238    have_nm=no
 239
 240    PKG_CHECK_MODULES(CONNMAN,
 241    [
 242       dbus-glib-1
 243    ], have_connman="yes", have_connman="no")
 244
 245    if test "x$have_connman" = "xyes"; then
 246       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 247    fi
 248
 249 else
 250    have_connman=no
 251
 252    PKG_CHECK_MODULES(NETWORK_MANAGER,
 253    [
 254       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 255    ], have_nm="yes", have_nm="no")
 256
 257    if test "x$have_nm" = "xyes"; then
 258       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 259    fi
 260 fi
 261
 262 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 263    AC_MSG_ERROR([Couldn't find connman dependencies.])
 264 fi
 265
 266 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 267    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 268 fi
 269
 270 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 271 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 272
 273 # -----------------------------------------------------------
 274 # Webkit
 275 # -----------------------------------------------------------
 276 AC_ARG_ENABLE(webkit,
 277               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 278                              [build with webkit support]), ,
 279                              enable_webkit=auto)
 280
 281 if test "x$enable_webkit" != "xno"; then
 282    PKG_CHECK_MODULES(WEBKIT, [webkitgtk-3.0 >= $WEBKIT_REQUIRED],
 283         have_webkit="yes", have_webkit="no")
 284
 285    if test "x$have_webkit" = "xyes"; then
 286       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 287    fi
 288 else
 289    have_webkit=no
 290 fi
 291
 292 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 293    AC_MSG_ERROR([Could not find webkit dependencies.])
 294 fi
 295 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 296
 297 # -----------------------------------------------------------
 298 # spellchecking checks: enchant and iso-codes
 299 # -----------------------------------------------------------
 300 AC_ARG_ENABLE(spell,
 301               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 302                              [Enable spell checking]), ,
 303                              enable_spell=auto)
 304
 305 if test "x$enable_spell" != "xno"; then
 306    PKG_CHECK_MODULES(ENCHANT,
 307    [
 308       enchant >= $ENCHANT_REQUIRED,
 309       iso-codes >= $ISO_CODES_REQUIRED
 310    ], have_enchant="yes", have_enchant="no")
 311
 312    if test "x$have_enchant" = "xyes"; then
 313       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 314       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 315          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 316             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 317             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 318             result=yes
 319       else
 320             result=no
 321             have_enchant="no"
 322       fi
 323       AC_MSG_RESULT([$result])
 324    fi
 325 else
 326    have_enchant=no
 327 fi
 328
 329 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 330    AC_MSG_ERROR([Could not find spell dependencies.])
 331 fi
 332
 333 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 334
 335 # -----------------------------------------------------------
 336 # Map view checks: libchamplain
 337 # -----------------------------------------------------------
 338 AC_ARG_ENABLE(map,
 339               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 340                              [Enable map view]), ,
 341                              enable_map=auto)
 342
 343 if test "x$enable_map" != "xno"; then
 344
 345    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 346     [
 347        clutter-gtk-1.0
 348        champlain-gtk-0.10
 349        champlain-0.10
 350     ], have_libchamplain="yes", have_libchamplain="no")
 351
 352    if test "x$have_libchamplain" = "xyes"; then
 353       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 354    fi
 355 else
 356    have_libchamplain=no
 357 fi
 358
 359 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 360    AC_MSG_ERROR([Could not find map view dependencies.])
 361 fi
 362
 363 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 364
 365 # -----------------------------------------------------------
 366 # location checks: geoclue
 367 # -----------------------------------------------------------
 368 AC_ARG_ENABLE(location,
 369               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 370                              [Enable location awareness]), ,
 371                              enable_location=auto)
 372
 373 if test "x$enable_location" != "xno"; then
 374    PKG_CHECK_MODULES(GEOCLUE,
 375    [
 376       geoclue >= $GEOCLUE_REQUIRED
 377    ], have_geoclue="yes", have_geoclue="no")
 378
 379    if test "x$have_geoclue" = "xyes"; then
 380       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 381    fi
 382 else
 383    have_geoclue="no"
 384 fi
 385
 386 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 387    AC_MSG_ERROR([Could not find location dependencies.])
 388 fi
 389
 390 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 391 AC_SUBST(GEOCLUE_CFLAGS)
 392 AC_SUBST(GEOCLUE_LIBS)
 393
 394 # -----------------------------------------------------------
 395 # meego widgets support
 396 # -----------------------------------------------------------
 397 AC_ARG_ENABLE(meego,
 398               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 399                              [Enable meego widgets]), ,
 400                              enable_meego=no)
 401
 402 if test "x$enable_meego" != "xno"; then
 403     PKG_CHECK_MODULES(MEEGO,
 404     [
 405        mx-gtk-1.0
 406        gio-unix-2.0
 407     ], have_meego="yes", have_meego="no")
 408
 409     if test "x$have_meego" = "xyes"; then
 410        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 411     fi
 412 else
 413    have_meego="no"
 414 fi
 415
 416 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 417    AC_MSG_ERROR([Could not find meego dependencies.])
 418 fi
 419
 420 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 421 AC_SUBST(MEEGO_CFLAGS)
 422 AC_SUBST(MEEGO_LIBS)
 423
 424 # -----------------------------------------------------------
 425 # nautilus-sendto
 426 # -----------------------------------------------------------
 427 AC_ARG_ENABLE(nautilus-sendto,
 428               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 429                              [build nautilus-sendto plugin]), ,
 430                              enable_nautilus_sendto=auto)
 431
 432 if test "x$enable_nautilus_sendto" != "xno"; then
 433    PKG_CHECK_MODULES(NST,
 434     [
 435        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 436     ], have_nst="yes", have_nst="no")
 437 else
 438    have_nst=no
 439 fi
 440
 441 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 442    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 443 fi
 444
 445 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 446
 447 # -----------------------------------------------------------
 448 # new, single-window control center
 449 # -----------------------------------------------------------
 450 AC_ARG_ENABLE(control_center_embedding,
 451               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 452                              [Enable support for single-window control center]),
 453                              , enable_control_center_embedding=auto)
 454
 455 if test "x$enable_control_center_embedding" != "xno"; then
 456
 457    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 458         have_control_center_embedding="yes", have_control_center_embedding="no")
 459
 460    if test "x$have_control_center_embedding" = "xyes"; then
 461       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 462
 463       AC_MSG_CHECKING([gnome-control-center extension dir])
 464       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 465       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 466           AC_MSG_ERROR([Could not determine extensiondir])
 467       else
 468           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 469       fi
 470       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 471    fi
 472 else
 473    have_control_center_embedding="no"
 474 fi
 475
 476 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 477    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 478 fi
 479
 480 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 481 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 482 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 483
 484 # Optional dependency for avatar selection
 485 AC_ARG_WITH([cheese],
 486             AS_HELP_STRING([--with-cheese], [enable cheese webcam support]),,
 487             with_cheese=auto)
 488
 489 if test x"$with_cheese" != x"no" ; then
 490    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 491    if test x${have_cheese} = xyes; then
 492      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 493    fi
 494    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 495      AC_MSG_ERROR([Cheese configured but not found])
 496    fi
 497 else
 498    have_cheese=no
 499 fi
 500 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 501
 502
 503 # -----------------------------------------------------------
 504 # Coding style checks
 505 # -----------------------------------------------------------
 506 AC_ARG_ENABLE(coding-style-checks,
 507   AC_HELP_STRING([--disable-coding-style-checks],
 508                  [do not check coding style using grep]),
 509     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 510
 511 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 512 # -----------------------------------------------------------
 513
 514 AC_OUTPUT([
 515    Makefile
 516    data/Makefile
 517    data/empathy.desktop.in
 518    data/empathy-accounts.desktop.in
 519    data/icons/Makefile
 520    extensions/Makefile
 521    po/Makefile.in
 522    libempathy/Makefile
 523    libempathy-gtk/Makefile
 524    src/Makefile
 525    nautilus-sendto-plugin/Makefile
 526    help/Makefile
 527    tests/Makefile
 528    tests/interactive/Makefile
 529    tests/xml/Makefile
 530    tools/Makefile
 531 ])
 532
 533 echo "
 534 Configure summary:
 535
 536         Compiler....................:  ${CC}
 537         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 538         Prefix......................:  ${prefix}
 539         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 540
 541     Features:
 542         Spell checking (enchant)....:  ${have_enchant}
 543         Display maps (libchamplain).:  ${have_libchamplain}
 544         Location awareness (Geoclue):  ${have_geoclue}
 545         Adium themes (Webkit).......:  ${have_webkit}
 546         Meego widgets ..............:  ${have_meego}
 547         Control center embedding....:  ${have_control_center_embedding}
 548         Cheese webcam support ......:  ${have_cheese}
 549
 550     Connectivity:
 551         NetworkManager integration..:  ${have_nm}
 552         ConnMan integration.........:  ${have_connman}
 553
 554     Extras:
 555         Nautilus-sendto plugin......:  ${have_nst}
 556         Salut E-D-S support.........:  ${with_eds}
 557 "