configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [9])
   6 m4_define([empathy_micro_version], [4])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.9.0
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.19.9
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58 AC_DEFINE(TP_DISABLE_SINGLE_INCLUDE, 1, [Disable single include header])
  59
  60 GSTREAMER_REQUIRED=0.10.32
  61 TP_FS_REQUIRED=0.6.0
  62 LIBSECRET_REQUIRED=0.5
  63 GCR_REQUIRED=2.91.4
  64 LIBCANBERRA_GTK_REQUIRED=0.25
  65 LIBNOTIFY_REQUIRED=0.7.0
  66 TELEPATHY_LOGGER=0.8.0
  67 WEBKIT_REQUIRED=1.9.1
  68 GOA_REQUIRED=3.5.1
  69
  70 # Optional deps
  71 ENCHANT_REQUIRED=1.2.0
  72 GEOCLUE_REQUIRED=0.12
  73 GEOCODE_GLIB_REQUIRED=0.99.1
  74 ISO_CODES_REQUIRED=0.35
  75 NAUTILUS_SENDTO_REQUIRED=2.90.0
  76 NETWORK_MANAGER_REQUIRED=0.7.0
  77 CHAMPLAIN_REQUIRED=0.12.1
  78 CHEESE_GTK_REQUIRED=3.4.0
  79 LIBACCOUNTS_REQUIRED=1.4
  80 LIBSIGNON_REQUIRED=1.1
  81 MC_PLUGINS_REQUIRED=5.13.1
  82
  83 # Use --enable-maintainer-mode to disable deprecated symbols,
  84 # disable single include and enable GSEAL. If this is not a released empathy,
  85 # maintainer mode is forced
  86 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  87 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  88 #GNOME_MAINTAINER_MODE_DEFINES
  89
  90 # tp-account-widgets
  91 prev_top_build_prefix=$ac_top_build_prefix
  92 prev_ac_configure_args=$ac_configure_args
  93 AX_CONFIG_DIR([telepathy-account-widgets])
  94 ac_top_build_prefix=$prev_top_build_prefix
  95 ac_configure_args=$prev_ac_configure_args
  96
  97 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-account-widgets/
  98 PKG_CHECK_MODULES(TPAW, telepathy-account-widgets)
  99
 100 # egg-list-box
 101 prev_top_build_prefix=$ac_top_build_prefix
 102 prev_ac_configure_args=$ac_configure_args
 103 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
 104 ac_top_build_prefix=$prev_top_build_prefix
 105 ac_configure_args=$prev_ac_configure_args
 106
 107 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
 108 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
 109
 110 AC_CONFIG_MACRO_DIR([m4])
 111 AC_CONFIG_HEADERS([config.h])
 112 AC_CONFIG_SRCDIR([configure.ac])
 113 AC_CONFIG_AUX_DIR(.)
 114
 115 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 116
 117 # Support silent build rules. Disable
 118 # by either passing --disable-silent-rules to configure or passing V=1
 119 # to make
 120 AM_SILENT_RULES([yes])
 121
 122 # Check for programs
 123 AC_PROG_CC
 124 AC_HEADER_STDC
 125 AM_PROG_MKDIR_P
 126 AM_PATH_GLIB_2_0
 127 AC_PATH_XTRA
 128
 129 # Initialize libtool
 130 LT_PREREQ([2.2])
 131 LT_INIT
 132
 133 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 134 GLIB_GSETTINGS
 135
 136 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG gio-2.0 --variable=glib_compile_resources`
 137 AC_SUBST(GLIB_COMPILE_RESOURCES)
 138 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 139 AC_SUBST(GLIB_GENMARSHAL)
 140
 141 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 142 if test -z "$XSLTPROC"; then
 143   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 144 fi
 145 AM_PATH_PYTHON([2.3])
 146
 147 EMPATHY_ARG_VALGRIND
 148
 149
 150 # -----------------------------------------------------------
 151 # Error flags
 152 # -----------------------------------------------------------
 153 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 154 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 155
 156 AC_ARG_ENABLE(Werror,
 157   AS_HELP_STRING([--disable-Werror],
 158                  [compile without -Werror (normally enabled in development builds)]),
 159     werror=$enableval, :)
 160
 161 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 162 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 163         wno_missing_field_initializers=yes,
 164         wno_missing_field_initializers=no)
 165 AS_COMPILER_FLAG(-Wno-unused-parameter,
 166         wno_unused_parameter=yes,
 167         wno_unused_parameter=no)
 168
 169 ifelse(empathy_released, 1, [],
 170     [
 171         if test x$werror = xyes; then
 172             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 173         fi
 174         if test x$wextra = xyes -a \
 175             x$wno_missing_field_initializers = xyes -a \
 176             x$wno_unused_parameter = xyes; then
 177             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 178         fi
 179     ])
 180
 181 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 182 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 183 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 184 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 185 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 186
 187 AC_SUBST(ERROR_CFLAGS)
 188
 189 AC_ARG_ENABLE(gprof,
 190             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 191             [build with support for gprof]),,
 192             [enable_gprof=no])
 193 if test "x$enable_gprof" != "xno" ; then
 194     CFLAGS="$CFLAGS -pg"
 195     LDFLAGS="$LDFLAGS -pg"
 196 fi
 197
 198 AC_SUBST(LDFLAGS)
 199
 200 # -----------------------------------------------------------
 201 # Pkg-Config dependency checks
 202 # -----------------------------------------------------------
 203
 204 AC_CHECK_LIBM
 205 AC_SUBST(LIBM)
 206
 207 PKG_CHECK_MODULES(EMPATHY,
 208 [
 209    dbus-glib-1
 210    folks >= $FOLKS_REQUIRED
 211    folks-telepathy >= $FOLKS_REQUIRED
 212    glib-2.0 >= $GLIB_REQUIRED
 213    gio-2.0 >= $GLIB_REQUIRED
 214    gio-unix-2.0 >= $GLIB_REQUIRED
 215    libsecret-1 >= $LIBSECRET_REQUIRED
 216    gnutls >= $GNUTLS_REQUIRED
 217    gmodule-export-2.0
 218    gobject-2.0
 219    gsettings-desktop-schemas
 220    libxml-2.0
 221    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 222    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 223    x11
 224    gtk+-3.0 >= $GTK_REQUIRED
 225    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 226    libnotify >= $LIBNOTIFY_REQUIRED
 227    gcr-3 >= $GCR_REQUIRED
 228    libpulse
 229    libpulse-mainloop-glib
 230    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 231    libsoup-2.4
 232    gee-0.8
 233 ])
 234
 235 # -----------------------------------------------------------
 236 # GStreamer
 237 # -----------------------------------------------------------
 238 AC_ARG_ENABLE(gst-1.0,
 239               AS_HELP_STRING([--enable-gst-1.0=@<:@no/yes/auto@:>@],
 240                              [build with GStreamer 1.0]),
 241                              enable_gst1=$enableval,
 242                              enable_gst1=auto)
 243
 244 # Try to use GStreamer 1.0 if available
 245 have_gst1="no"
 246 if test "x$enable_gst1" != "xno"; then
 247   PKG_CHECK_MODULES(EMPATHY_CALL,
 248   [
 249      farstream-0.2
 250      telepathy-farstream >= $TP_FS_REQUIRED
 251      clutter-1.0 >= $CLUTTER_REQUIRED
 252      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 253      clutter-gst-2.0
 254      gstreamer-1.0
 255      gstreamer-audio-1.0
 256      gstreamer-video-1.0
 257      cogl-1.0
 258   ], have_gst1="yes", have_gst1="no")
 259
 260   if test "x$have_gst1" = "xyes"; then
 261     AC_DEFINE(HAVE_GST1, 1, [Build with GStreamer 1.0])
 262   fi
 263 fi
 264
 265 if test "x$enable_gst1" = "xyes" -a "x$have_gst1" != "xyes"; then
 266    AC_MSG_ERROR([Could not find GStreamer 1.0 dependencies:
 267
 268 $EMPATHY_CALL_PKG_ERRORS])
 269 fi
 270
 271 if test "x$have_gst1" != "xyes"; then
 272   PKG_CHECK_MODULES(EMPATHY_CALL,
 273   [
 274      farstream-0.1
 275      telepathy-farstream >= $TP_FS_REQUIRED
 276      clutter-1.0 >= $CLUTTER_REQUIRED
 277      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 278      clutter-gst-1.0 >= 1.5.2
 279      gstreamer-0.10 >= $GSTREAMER_REQUIRED
 280      gstreamer-interfaces-0.10
 281   ])
 282 fi
 283
 284 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 285    [Name of provider for accounts imported from GOA])
 286
 287 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 288     "im.telepathy.Account.Storage.UOA",
 289    [Name of provider for accounts imported from libaccounts])
 290
 291 # -----------------------------------------------------------
 292 # Enable debug
 293 # -----------------------------------------------------------
 294
 295 AC_ARG_ENABLE(debug,
 296   AS_HELP_STRING([--disable-debug],
 297                  [compile without debug code]),
 298     enable_debug=$enableval, enable_debug=yes )
 299
 300 if test x$enable_debug = xyes; then
 301   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 302 fi
 303
 304 # -----------------------------------------------------------
 305 # Language Support
 306 # -----------------------------------------------------------
 307 IT_PROG_INTLTOOL([0.50.0])
 308
 309 GETTEXT_PACKAGE=empathy
 310 AC_SUBST(GETTEXT_PACKAGE)
 311 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 312
 313 # -----------------------------------------------------------
 314 # gudev
 315 # -----------------------------------------------------------
 316 AC_ARG_ENABLE(gudev,
 317               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 318                              [build with gudev support]), ,
 319                              enable_gudev=auto)
 320
 321 if test "x$enable_gudev" != "xno"; then
 322
 323    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 324         have_gudev="yes", have_gudev="no")
 325
 326    if test "x$have_gudev" = "xyes"; then
 327       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 328    fi
 329 else
 330    have_gudev=no
 331 fi
 332
 333 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 334    AC_MSG_ERROR([Could not find gudev dependencies:
 335
 336 $UDEV_PKG_ERRORS])
 337 fi
 338 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 339
 340 # -----------------------------------------------------------
 341 # spellchecking checks: enchant and iso-codes
 342 # -----------------------------------------------------------
 343 AC_ARG_ENABLE(spell,
 344               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 345                              [Enable spell checking]), ,
 346                              enable_spell=auto)
 347
 348 if test "x$enable_spell" != "xno"; then
 349    PKG_CHECK_MODULES(ENCHANT,
 350    [
 351       enchant >= $ENCHANT_REQUIRED,
 352       iso-codes >= $ISO_CODES_REQUIRED
 353    ], have_enchant="yes", have_enchant="no")
 354
 355    if test "x$have_enchant" = "xyes"; then
 356       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 357       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 358          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 359             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 360             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 361             result=yes
 362       else
 363             result=no
 364             have_enchant="no"
 365       fi
 366       AC_MSG_RESULT([$result])
 367    fi
 368 else
 369    have_enchant=no
 370 fi
 371
 372 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 373    AC_MSG_ERROR([Could not find spell-checking dependencies:
 374
 375 $ENCHANT_PKG_ERRORS])
 376 fi
 377
 378 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 379
 380 # -----------------------------------------------------------
 381 # Map view checks: libchamplain
 382 # -----------------------------------------------------------
 383 AC_ARG_ENABLE(map,
 384               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 385                              [Enable map view]), ,
 386                              enable_map=auto)
 387
 388 if test "x$enable_map" != "xno"; then
 389
 390    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 391     [
 392        clutter-gtk-1.0
 393        champlain-gtk-0.12
 394        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 395     ], have_libchamplain="yes", have_libchamplain="no")
 396
 397    if test "x$have_libchamplain" = "xyes"; then
 398       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 399    fi
 400 else
 401    have_libchamplain=no
 402 fi
 403
 404 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 405    AC_MSG_ERROR([Could not find map view dependencies:
 406
 407 $LIBCHAMPLAIN_PKG_ERRORS])
 408 fi
 409
 410 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 411
 412 # -----------------------------------------------------------
 413 # location checks: geoclue
 414 # -----------------------------------------------------------
 415 AC_ARG_ENABLE(location,
 416               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 417                              [Enable location awareness]), ,
 418                              enable_location=auto)
 419
 420 if test "x$enable_location" != "xno"; then
 421    PKG_CHECK_MODULES(GEOCLUE,
 422    [
 423       geoclue >= $GEOCLUE_REQUIRED
 424    ], have_geoclue="yes", have_geoclue="no")
 425
 426    if test "x$have_geoclue" = "xyes"; then
 427       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 428    fi
 429 else
 430    have_geoclue="no"
 431 fi
 432
 433 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 434    AC_MSG_ERROR([Could not find location dependencies:
 435
 436 $GEOCLUE_PKG_ERRORS])
 437 fi
 438
 439 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 440 AC_SUBST(GEOCLUE_CFLAGS)
 441 AC_SUBST(GEOCLUE_LIBS)
 442
 443 # -----------------------------------------------------------
 444 # location checks: geocode-glib
 445 # -----------------------------------------------------------
 446 AC_ARG_ENABLE(geocode,
 447               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 448                              [Enable geocode support]), ,
 449                              enable_geocode=auto)
 450
 451 if test "x$enable_geocode" != "xno"; then
 452    PKG_CHECK_MODULES(GEOCODE,
 453    [
 454       geocode-glib-1.0 >= $GEOCODE_GLIB_REQUIRED
 455    ], have_geocode="yes", have_geocode="no")
 456
 457    if test "x$have_geocode" = "xyes"; then
 458       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 459    fi
 460 else
 461    have_geocode="no"
 462 fi
 463
 464 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 465    AC_MSG_ERROR([Could not find geocode dependencies:
 466
 467 $GEOCODE_PKG_ERRORS])
 468 fi
 469
 470 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 471 AC_SUBST(GEOCODE_CFLAGS)
 472 AC_SUBST(GEOCODE_LIBS)
 473
 474 # -----------------------------------------------------------
 475 # nautilus-sendto
 476 # -----------------------------------------------------------
 477 AC_ARG_ENABLE(nautilus-sendto,
 478               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 479                              [build nautilus-sendto plugin]), ,
 480                              enable_nautilus_sendto=auto)
 481
 482 if test "x$enable_nautilus_sendto" != "xno"; then
 483    PKG_CHECK_MODULES(NST,
 484     [
 485        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 486     ], have_nst="yes", have_nst="no")
 487 else
 488    have_nst=no
 489 fi
 490
 491 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 492    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 493
 494 $NST_PKG_ERRORS])
 495 fi
 496
 497 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 498
 499 # -----------------------------------------------------------
 500 # goa-mc-plugin
 501 # -----------------------------------------------------------
 502 AC_ARG_ENABLE(goa,
 503               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 504                              [build GOA MC plugin]), ,
 505                              enable_goa=auto)
 506
 507 if test "x$enable_goa" != "xno"; then
 508    PKG_CHECK_MODULES(GOA,
 509     [
 510        mission-control-plugins
 511        goa-1.0 >= $GOA_REQUIRED
 512     ], have_goa="yes", have_goa="no")
 513 else
 514    have_goa=no
 515 fi
 516
 517 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 518    AC_MSG_ERROR([Could not find GOA dependencies:
 519
 520 $GOA_PKG_ERRORS])
 521 fi
 522
 523 if test "x$have_goa" = "xyes"; then
 524    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 525 fi
 526
 527 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 528
 529 # Optional dependency for avatar selection
 530 AC_ARG_WITH([cheese],
 531             AS_HELP_STRING([--with-cheese],
 532                            [enable cheese webcam support]),,
 533             with_cheese=auto)
 534
 535 if test x"$with_cheese" != x"no" ; then
 536    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 537    if test x${have_cheese} = xyes; then
 538      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 539    fi
 540    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 541      AC_MSG_ERROR([Cheese configured but not found:
 542
 543 $CHEESE_PKG_ERRORS])
 544    fi
 545 else
 546    have_cheese=no
 547 fi
 548 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 549
 550 # -----------------------------------------------------------
 551 # ubuntu-online-accounts support
 552 # -----------------------------------------------------------
 553 AC_ARG_ENABLE(ubuntu-online-accounts,
 554               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 555                              [build Ubuntu Online Accounts plugins]), ,
 556                              enable_ubuntu_online_accounts=auto)
 557
 558 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 559    PKG_CHECK_MODULES(UOA,
 560     [
 561        account-plugin
 562        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 563        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 564        libsignon-glib >= $LIBSIGNON_REQUIRED
 565     ], have_uoa="yes", have_uoa="no")
 566
 567    # provider plugin dir
 568    AC_MSG_CHECKING([Accounts provider plugin dir])
 569    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 570
 571    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 572    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 573
 574    # app plugin dir
 575    AC_MSG_CHECKING([Accounts provider app plugin dir])
 576    ACCOUNTS_APP_PLUGIN_DIR=`pkg-config --variable=application_plugindir account-plugin`
 577
 578    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 579    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 580
 581    # provider files dir
 582    AC_MSG_CHECKING([Accounts provider files dir])
 583    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 584
 585    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 586    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 587
 588    # service files dir
 589    AC_MSG_CHECKING([Accounts service files dir])
 590    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 591
 592    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 593    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 594
 595    # application files dir
 596    AC_MSG_CHECKING([Accounts applications files dir])
 597    ACCOUNTS_APPLICATION_FILES_DIR=`pkg-config --variable=applicationfilesdir libaccounts-glib`
 598
 599    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 600    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 601
 602 else
 603    have_uoa=no
 604 fi
 605
 606 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 607    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 608
 609 $UOA_PKG_ERRORS])
 610 fi
 611
 612 if test "x$have_uoa" = "xyes"; then
 613    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 614 fi
 615
 616 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 617
 618 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 619    AC_MSG_CHECKING([Mission Control plugins dir])
 620    MISSION_CONTROL_PLUGINS_DIR=${libdir}/mission-control-plugins.`pkg-config --variable=MCP_ABI_VERSION mission-control-plugins`
 621
 622    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 623    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 624 fi
 625
 626
 627 # Help documentation
 628 YELP_HELP_INIT
 629
 630 # -----------------------------------------------------------
 631 # Coding style checks
 632 # -----------------------------------------------------------
 633 AC_ARG_ENABLE(coding-style-checks,
 634   AS_HELP_STRING([--disable-coding-style-checks],
 635                  [do not check coding style using grep]),
 636     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 637     [ENABLE_CODING_STYLE_CHECKS=yes])
 638
 639 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 640 # -----------------------------------------------------------
 641
 642 AC_CONFIG_FILES([
 643    Makefile
 644    data/Makefile
 645    data/empathy.desktop.in
 646    data/icons/Makefile
 647    data/themes/Makefile
 648    extensions/Makefile
 649    po/Makefile.in
 650    libempathy/Makefile
 651    libempathy-gtk/Makefile
 652    src/Makefile
 653    nautilus-sendto-plugin/Makefile
 654    goa-mc-plugin/Makefile
 655    ubuntu-online-accounts/Makefile
 656    ubuntu-online-accounts/mc-plugin/Makefile
 657    ubuntu-online-accounts/cc-plugins/Makefile
 658    ubuntu-online-accounts/cc-plugins/account-plugins/Makefile
 659    ubuntu-online-accounts/cc-plugins/providers/Makefile
 660    ubuntu-online-accounts/cc-plugins/services/Makefile
 661    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 662    help/Makefile
 663    tests/Makefile
 664    tests/interactive/Makefile
 665    tests/xml/Makefile
 666    tests/certificates/Makefile
 667    tools/Makefile
 668 ])
 669 AC_OUTPUT
 670
 671 echo "
 672 Configure summary:
 673
 674         Compiler....................:  ${CC}
 675         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 676         Linker Flags................:  ${LDFLAGS}
 677         Prefix......................:  ${prefix}
 678         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 679         Use GStreamer 1.0...........:  ${have_gst1}
 680
 681     Features:
 682         Spell checking (enchant)....:  ${have_enchant}
 683         Display maps (libchamplain).:  ${have_libchamplain}
 684         Location awareness (Geoclue):  ${have_geoclue}
 685         Geocode support (Geocode)...:  ${have_geocode}
 686         Cheese webcam support ......:  ${have_cheese}
 687         Camera monitoring...........:  ${have_gudev}
 688
 689     Extras:
 690         Nautilus-sendto plugin......:  ${have_nst}
 691         GOA MC plugin...............:  ${have_goa}
 692         Ubuntu Online plugins.......:  ${have_uoa}
 693 "