configure.ac

   1 AC_INIT(Empathy, 0.13, http://bugzilla.gnome.org/browse.cgi?product=empathy)
   2 AC_PREREQ(2.59)
   3 AC_COPYRIGHT([
   4   Copyright (C) 2003-2007 Imendio AB
   5   Copyright (C) 2007 Collabora Ltd.
   6 ])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define)
  10
  11 AM_MAINTAINER_MODE
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16
  17 # LT Version numbers, remember to change them just *before* a release.
  18 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
  19 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
  20 #   (No interfaces changed:                   REVISION++)
  21 LIBEMPATHY_CURRENT=2
  22 LIBEMPATHY_AGE=0
  23 LIBEMPATHY_REVISION=1
  24
  25 LIBEMPATHY_GTK_CURRENT=3
  26 LIBEMPATHY_GTK_AGE=2
  27 LIBEMPATHY_GTK_REVISION=0
  28
  29 AC_SUBST(LIBEMPATHY_CURRENT)
  30 AC_SUBST(LIBEMPATHY_AGE)
  31 AC_SUBST(LIBEMPATHY_REVISION)
  32 AC_SUBST(LIBEMPATHY_GTK_CURRENT)
  33 AC_SUBST(LIBEMPATHY_GTK_AGE)
  34 AC_SUBST(LIBEMPATHY_GTK_REVISION)
  35
  36 AM_PROG_LIBTOOL
  37 AM_PATH_GLIB_2_0
  38 AC_PATH_XTRA
  39
  40 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  41 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  42 AM_GCONF_SOURCE_2
  43
  44 IT_PROG_INTLTOOL([0.35.0])
  45
  46 GTK_DOC_CHECK([1.3])
  47
  48 GLIB_REQUIRED=2.12.0
  49 GTK_REQUIRED=2.10.0
  50 GCONF_REQUIRED=1.2.0
  51 LIBGLADE_REQUIRED=2.0.0
  52 TELEPATHY_REQUIRED=0.0.51
  53 MISSION_CONTROL_REQUIRED=4.33
  54
  55 IDT_COMPILE_WARNINGS
  56
  57 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  58 AC_SUBST(GLIB_GENMARSHAL)
  59
  60 pluginlibdir=`$PKG_CONFIG mission-control --variable=pluginlibdir`
  61 AC_SUBST(pluginlibdir)
  62
  63 dnl -----------------------------------------------------------
  64 dnl Language Support
  65 dnl -----------------------------------------------------------
  66
  67 GETTEXT_PACKAGE=empathy
  68 AC_SUBST(GETTEXT_PACKAGE)
  69 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
  70
  71 AM_GLIB_GNU_GETTEXT
  72
  73 dnl -----------------------------------------------------------
  74 dnl Pkg-Config dependency checks
  75 dnl -----------------------------------------------------------
  76
  77 PKG_CHECK_MODULES(LIBEMPATHY,
  78 [
  79    glib-2.0 >= $GLIB_REQUIRED
  80    gobject-2.0
  81    gconf-2.0 >= $GCONF_REQUIRED
  82    libxml-2.0
  83    libtelepathy >= $TELEPATHY_REQUIRED
  84    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  85 ])
  86
  87 PKG_CHECK_MODULES(EMPATHY,
  88 [
  89    glib-2.0 >= $GLIB_REQUIRED
  90    gobject-2.0
  91    gconf-2.0 >= $GCONF_REQUIRED
  92    libxml-2.0
  93    gnome-vfs-2.0
  94    libtelepathy >= $TELEPATHY_REQUIRED
  95    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  96    gtk+-2.0 >= $GTK_REQUIRED
  97    libglade-2.0 >= $LIBGLADE_REQUIRED
  98    libgnomeui-2.0
  99    libebook-1.2
 100 ])
 101
 102 dnl -----------------------------------------------------------
 103 dnl ISO codes, used for aspell support
 104 dnl -----------------------------------------------------------
 105 AC_MSG_CHECKING([whether iso-codes exists and has iso-639 domain])
 106 if $PKG_CONFIG --variable=domains iso-codes | grep -q 639 ; then
 107    AC_MSG_RESULT([yes])
 108    iso_codes_prefix=`$PKG_CONFIG --variable=prefix iso-codes`
 109    iso_codes_pkgconfig=iso-codes
 110    have_iso_codes=yes
 111 else
 112    AC_MSG_RESULT([no])
 113    iso_codes_prefix=
 114    iso_codes_pkgconfig=
 115    have_iso_codes=no
 116 fi
 117
 118 AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX],["$iso_codes_prefix"],[ISO codes prefix])
 119
 120 dnl -----------------------------------------------------------
 121 dnl ASpell
 122 dnl -----------------------------------------------------------
 123 AC_ARG_ENABLE(aspell,
 124               AS_HELP_STRING([--enable-aspell=@<:@no/yes/auto@:>@],
 125                              [compile with aspell support]), ,
 126                              enable_aspell=auto)
 127
 128 if test "x$enable_aspell" = "xyes" -a "x$have_iso_codes" != "xyes"; then
 129    AC_MSG_ERROR([You must have iso-codes with the iso-639 domain to use aspell.])
 130 fi
 131
 132 if test "x$enable_aspell" != "xno" -a "x$have_iso_codes" = "xyes"; then
 133    AC_CHECK_LIB(aspell, aspell_speller_check,have_aspell=yes,have_aspell=no,)
 134
 135    if test "x$have_aspell" = "xyes"; then
 136       AC_DEFINE(HAVE_ASPELL, 1, [Define if we have aspell])
 137       EMPATHY_LIBS="$EMPATHY_LIBS -laspell"
 138    else
 139       have_aspell=no
 140    fi
 141 else
 142    have_aspell=no
 143 fi
 144
 145 if test "x$enable_aspell" = "xyes" -a "x$have_aspell" != "xyes"; then
 146    AC_MSG_ERROR([Couldn't find aspell.])
 147 fi
 148
 149
 150 dnl -----------------------------------------------------------
 151 dnl Python Bindings
 152 dnl -----------------------------------------------------------
 153 AC_ARG_ENABLE(python,
 154               AS_HELP_STRING([--enable-python=@<:@no/yes/auto@:>@],
 155                              [build python bindings to libempathy and libempathy-gtk]), ,
 156                              enable_python=auto)
 157
 158 if test "x$enable_python" != "xno"; then
 159    AM_PATH_PYTHON
 160    if test -z "$PYTHON" ; then
 161       have_python="no"
 162    else
 163       PKG_CHECK_MODULES(PYTHON_BINDING,
 164       [
 165          pygtk-2.0,
 166          glib-2.0 >= $GLIB_REQUIRED
 167          gobject-2.0
 168          gconf-2.0 >= $GCONF_REQUIRED
 169          libxml-2.0
 170          gnome-vfs-2.0
 171          libtelepathy >= $TELEPATHY_REQUIRED
 172          libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 173          gtk+-2.0 >= $GTK_REQUIRED
 174          libglade-2.0 >= $LIBGLADE_REQUIRED
 175          libgnomeui-2.0
 176       ], have_python="yes", have_python="no")
 177    fi
 178 else
 179    have_python=no
 180 fi
 181
 182 if test "x$enable_python" = "xyes" -a "x$have_python" != "xyes"; then
 183    AC_MSG_ERROR([Couldn't find python.])
 184 fi
 185
 186 AM_CONDITIONAL(HAVE_PYTHON, test "x$have_python" = "xyes")
 187
 188 dnl -----------------------------------------------------------
 189
 190 AC_OUTPUT([
 191    Makefile
 192    data/Makefile
 193    data/empathy.desktop.in
 194    data/16x16/Makefile
 195    data/22x22/Makefile
 196    data/24x24/Makefile
 197    data/32x32/Makefile
 198    data/48x48/Makefile
 199    data/scalable/Makefile
 200    po/Makefile.in
 201    libempathy/Makefile
 202    libempathy/libempathy.pc
 203    libempathy-gtk/Makefile
 204    libempathy-gtk/libempathy-gtk.pc
 205    src/Makefile
 206    doc/Makefile
 207    doc/libempathy/Makefile
 208    doc/libempathy-gtk/Makefile
 209    python/Makefile
 210    python/pyempathy/Makefile
 211    python/pyempathygtk/Makefile
 212 ])