configure.ac

   1 AC_INIT(Empathy, 2.27.5, http://bugzilla.gnome.org/browse.cgi?product=empathy)
   2 AC_PREREQ(2.59)
   3 AC_COPYRIGHT([
   4   Copyright (C) 2003-2007 Imendio AB
   5   Copyright (C) 2007-2008 Collabora Ltd.
   6 ])
   7
   8 # LT Version numbers, remember to change them just *before* a release.
   9 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
  10 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
  11 #   (No interfaces changed:                   REVISION++)
  12 LIBEMPATHY_CURRENT=27
  13 LIBEMPATHY_AGE=0
  14 LIBEMPATHY_REVISION=0
  15
  16 LIBEMPATHY_GTK_CURRENT=25
  17 LIBEMPATHY_GTK_AGE=0
  18 LIBEMPATHY_GTK_REVISION=0
  19
  20 AC_SUBST(LIBEMPATHY_CURRENT)
  21 AC_SUBST(LIBEMPATHY_AGE)
  22 AC_SUBST(LIBEMPATHY_REVISION)
  23 AC_SUBST(LIBEMPATHY_GTK_CURRENT)
  24 AC_SUBST(LIBEMPATHY_GTK_AGE)
  25 AC_SUBST(LIBEMPATHY_GTK_REVISION)
  26
  27 # Minimal version required
  28 GLIB_REQUIRED=2.16.0
  29 GTK_REQUIRED=2.16.0
  30 GCONF_REQUIRED=1.2.0
  31 LIBPANELAPPLET_REQUIRED=2.10.0
  32 TELEPATHY_GLIB_REQUIRED=0.7.31
  33 MISSION_CONTROL_REQUIRED=4.61
  34 ENCHANT_REQUIRED=1.2.0
  35 ISO_CODES_REQUIRED=0.35
  36 LIBNOTIFY_REQUIRED=0.4.4
  37 LIBCANBERRA_GTK_REQUIRED=0.4
  38 LIBCHAMPLAIN_REQUIRED=0.3.3
  39 LIBCHAMPLAIN_GTK_REQUIRED=0.3.3
  40 CLUTTER_GTK_REQUIRED=0.8.2
  41 GEOCLUE_REQUIRED=0.11
  42 WEBKIT_REQUIRED=1.1.7
  43 NETWORK_MANAGER_REQUIRED=0.7.0
  44
  45 # Use --enable-maintainer-mode to disabled deprecated symbols
  46 GNOME_MAINTAINER_MODE_DEFINES
  47
  48 # Uncomment that to build with single include disabled
  49 #AC_DEFINE(G_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GLib])
  50 #AC_DEFINE(GDK_PIXBUF_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GDK pixbuf])
  51 #AC_DEFINE(GTK_DISABLE_SINGLE_INCLUDES, [], [Disable single includes for GTK])
  52
  53 AC_CONFIG_MACRO_DIR([m4])
  54 AC_CONFIG_HEADERS([config.h])
  55 AC_CONFIG_SRCDIR([configure.ac])
  56 AC_CONFIG_AUX_DIR(.)
  57
  58 GNOME_COMMON_INIT
  59
  60 AM_INIT_AUTOMAKE(1.9 dist-bzip2 no-define -Wno-portability)
  61 AC_ISC_POSIX
  62 AC_PROG_CC
  63 AC_HEADER_STDC
  64 AM_PROG_LIBTOOL
  65 AM_PROG_MKDIR_P
  66 AM_PATH_GLIB_2_0
  67 AC_PATH_XTRA
  68 IT_PROG_INTLTOOL([0.35.0])
  69 GTK_DOC_CHECK([1.3])
  70 GNOME_DOC_INIT
  71 IDT_COMPILE_WARNINGS
  72 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
  73 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  74 AM_GCONF_SOURCE_2
  75 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
  76 AC_SUBST(GLIB_GENMARSHAL)
  77
  78 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
  79 if test -z "$XSLTPROC"; then
  80   AC_MSG_ERROR([xsltproc (from libxslt) is required])
  81 fi
  82 AM_PATH_PYTHON([2.3])
  83
  84 EMPATHY_ARG_VALGRIND
  85
  86 # -----------------------------------------------------------
  87 # Pkg-Config dependency checks
  88 # -----------------------------------------------------------
  89
  90 PKG_CHECK_MODULES(LIBEMPATHY,
  91 [
  92    glib-2.0 >= $GLIB_REQUIRED
  93    gobject-2.0
  94    gio-2.0 >= $GLIB_REQUIRED
  95    gio-unix-2.0 >= $GLIB_REQUIRED
  96    libxml-2.0
  97    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
  98    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
  99    telepathy-farsight
 100    farsight2-0.10
 101    gstreamer-0.10
 102 ])
 103
 104 PKG_CHECK_MODULES(LIBEMPATHYGTK,
 105 [
 106    glib-2.0 >= $GLIB_REQUIRED
 107    gobject-2.0
 108    gio-2.0 >= $GLIB_REQUIRED
 109    gconf-2.0 >= $GCONF_REQUIRED
 110    x11
 111    gtk+-2.0 >= $GTK_REQUIRED
 112    libcanberra-gtk >= $LIBCANBERRA_GTK_REQUIRED
 113    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 114    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 115    farsight2-0.10
 116    gstreamer-0.10
 117    gstreamer-interfaces-0.10
 118 ])
 119
 120 PKG_CHECK_MODULES(EMPATHY,
 121 [
 122    glib-2.0 >= $GLIB_REQUIRED
 123    gobject-2.0
 124    gio-2.0 >= $GLIB_REQUIRED
 125    gdk-x11-2.0
 126    gtk+-2.0 >= $GTK_REQUIRED
 127    libebook-1.2
 128    dbus-glib-1
 129    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 130    libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 131    telepathy-farsight
 132    gstreamer-0.10
 133 ])
 134
 135 PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= $LIBNOTIFY_REQUIRED)
 136
 137 # -----------------------------------------------------------
 138 # Enable debug
 139 # -----------------------------------------------------------
 140
 141 AC_ARG_ENABLE(debug,
 142   AC_HELP_STRING([--disable-debug],[compile without debug code]),
 143     enable_debug=$enableval, enable_debug=yes )
 144
 145 if test x$enable_debug = xyes; then
 146   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 147 fi
 148
 149 # -----------------------------------------------------------
 150 # Language Support
 151 # -----------------------------------------------------------
 152
 153 GETTEXT_PACKAGE=empathy
 154 AC_SUBST(GETTEXT_PACKAGE)
 155 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 156
 157 AM_GLIB_GNU_GETTEXT
 158
 159 # -----------------------------------------------------------
 160 # NM integration
 161 # -----------------------------------------------------------
 162 AC_ARG_ENABLE(network-manager,
 163               AS_HELP_STRING([--enable-network-manager=@<:@no/yes/auto@:>@],
 164                              [build with network-manager support]), ,
 165                              enable_network_manager=auto)
 166
 167 if test "x$enable_network_manager" != "xno"; then
 168    PKG_CHECK_MODULES(NETWORK_MANAGER,
 169    [
 170       libnm_glib >= $NETWORK_MANAGER_REQUIRED
 171    ], have_nm="yes", have_nm="no")
 172
 173    if test "x$have_nm" = "xyes"; then
 174       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 175    fi
 176 else
 177    have_nm=no
 178 fi
 179
 180 if test "x$enable_network_manager" = "xyes" -a "x$have_nm" != "xyes"; then
 181    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 182 fi
 183 AM_CONDITIONAL(HAVE_NM, test "x$have_NM" = "xyes")
 184
 185 # -----------------------------------------------------------
 186 # Webkit
 187 # -----------------------------------------------------------
 188 AC_ARG_ENABLE(webkit,
 189               AS_HELP_STRING([--enable-webkit=@<:@no/yes/auto@:>@],
 190                              [build with webkit support]), ,
 191                              enable_webkit=auto)
 192
 193 if test "x$enable_webkit" != "xno"; then
 194    PKG_CHECK_MODULES(WEBKIT,
 195    [
 196       webkit-1.0 >= $WEBKIT_REQUIRED
 197    ], have_webkit="yes", have_webkit="no")
 198
 199    if test "x$have_webkit" = "xyes"; then
 200       AC_DEFINE(HAVE_WEBKIT, 1, [Define if you have libwebkitgtk])
 201    fi
 202 else
 203    have_webkit=no
 204 fi
 205
 206 if test "x$enable_webkit" = "xyes" -a "x$have_webkit" != "xyes"; then
 207    AC_MSG_ERROR([Couldn't find webkit dependencies.])
 208 fi
 209 AM_CONDITIONAL(HAVE_WEBKIT, test "x$have_webkit" = "xyes")
 210
 211 # -----------------------------------------------------------
 212 # spellchecking checks: enchant and iso-codes
 213 # -----------------------------------------------------------
 214 AC_ARG_ENABLE(spell,
 215               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 216                              [Enable spell checking]), ,
 217                              enable_spell=auto)
 218
 219 if test "x$enable_spell" != "xno"; then
 220    PKG_CHECK_MODULES(ENCHANT,
 221    [
 222       enchant >= $ENCHANT_REQUIRED,
 223       iso-codes >= $ISO_CODES_REQUIRED
 224    ], have_enchant="yes", have_enchant="no")
 225
 226    if test "x$have_enchant" = "xyes"; then
 227       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 228       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 229          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 230             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 231             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 232             result=yes
 233       else
 234             result=no
 235             have_enchant="no"
 236       fi
 237       AC_MSG_RESULT([$result])
 238    fi
 239 else
 240    have_enchant=no
 241 fi
 242
 243 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 244    AC_MSG_ERROR([Couldn't find spell dependencies.])
 245 fi
 246
 247 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 248
 249 # -----------------------------------------------------------
 250 # Map view checks: libchamplain
 251 # -----------------------------------------------------------
 252 AC_ARG_ENABLE(map,
 253               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 254                              [Enable map view]), ,
 255                              enable_map=auto)
 256
 257 if test "x$enable_map" != "xno"; then
 258    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 259    [
 260       champlain-0.3 >= $LIBCHAMPLAIN_REQUIRED,
 261       champlain-gtk-0.3 >= $LIBCHAMPLAIN_GTK_REQUIRED
 262       clutter-gtk-0.8 >= $CLUTTER_GTK_REQUIRED
 263    ], have_libchamplain="yes", have_libchamplain="no")
 264
 265    if test "x$have_libchamplain" = "xyes"; then
 266       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 267    fi
 268 else
 269    have_libchamplain=no
 270 fi
 271
 272 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 273    AC_MSG_ERROR([Couldn't find map view dependencies.])
 274 fi
 275
 276 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 277
 278 # -----------------------------------------------------------
 279 # location checks: geoclue
 280 # -----------------------------------------------------------
 281 AC_ARG_ENABLE(location,
 282               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 283                              [Enable location awareness]), ,
 284                              enable_location=auto)
 285
 286 if test "x$enable_location" != "xno"; then
 287    PKG_CHECK_MODULES(GEOCLUE,
 288    [
 289       geoclue >= $GEOCLUE_REQUIRED
 290    ], have_geoclue="yes", have_geoclue="no")
 291
 292    if test "x$have_geoclue" = "xyes"; then
 293       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 294    fi
 295 else
 296    have_geoclue="no"
 297 fi
 298
 299 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 300    AC_MSG_ERROR([Couldn't find location dependencies.])
 301 fi
 302
 303 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 304 AC_SUBST(GEOCLUE_CFLAGS)
 305 AC_SUBST(GEOCLUE_LIBS)
 306
 307 # -----------------------------------------------------------
 308 # Megaphone
 309 # -----------------------------------------------------------
 310 AC_ARG_ENABLE(megaphone,
 311               AS_HELP_STRING([--enable-megaphone=@<:@no/yes/auto@:>@],
 312                              [build megaphone applet]), ,
 313                              enable_megaphone=auto)
 314
 315 if test "x$enable_megaphone" != "xno"; then
 316    PKG_CHECK_MODULES(MEGAPHONE,
 317    [
 318       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 319       glib-2.0 >= $GLIB_REQUIRED
 320       gtk+-2.0 >= $GTK_REQUIRED
 321       gconf-2.0 >= $GCONF_REQUIRED
 322       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 323    ], have_megaphone="yes", have_megaphone="no")
 324 else
 325    have_megaphone=no
 326 fi
 327
 328 if test "x$enable_megaphone" = "xyes" -a "x$have_megaphone" != "xyes"; then
 329    AC_MSG_ERROR([Couldn't find megaphone dependencies.])
 330 fi
 331
 332 AM_CONDITIONAL(HAVE_MEGAPHONE, test "x$have_megaphone" = "xyes")
 333
 334 # -----------------------------------------------------------
 335 # Nothere
 336 # -----------------------------------------------------------
 337 AC_ARG_ENABLE(nothere,
 338               AS_HELP_STRING([--enable-nothere=@<:@no/yes/auto@:>@],
 339                              [build nothere applet]), ,
 340                              enable_nothere=auto)
 341
 342 if test "x$enable_nothere" != "xno"; then
 343    PKG_CHECK_MODULES(NOTHERE,
 344    [
 345       libpanelapplet-2.0 >= $LIBPANELAPPLET_REQUIRED
 346       glib-2.0 >= $GLIB_REQUIRED
 347       gtk+-2.0 >= $GTK_REQUIRED
 348       gconf-2.0 >= $GCONF_REQUIRED
 349       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 350    ], have_nothere="yes", have_nothere="no")
 351 else
 352    have_nothere=no
 353 fi
 354
 355 if test "x$enable_nothere" = "xyes" -a "x$have_nothere" != "xyes"; then
 356    AC_MSG_ERROR([Couldn't find nothere dependencies.])
 357 fi
 358
 359 AM_CONDITIONAL(HAVE_NOTHERE, test "x$have_nothere" = "xyes")
 360
 361 # -----------------------------------------------------------
 362 # Tests
 363 # -----------------------------------------------------------
 364 AC_ARG_ENABLE(tests,
 365               AS_HELP_STRING([--enable-tests=@<:@no/yes/auto@:>@],
 366                              [build tests]), ,
 367                              enable_tests=auto)
 368
 369 if test "x$enable_tests" != "xno"; then
 370    PKG_CHECK_MODULES(CHECK,
 371    [
 372       check >= 0.9.4
 373    ], have_check="yes", have_check="no")
 374 else
 375    have_check=no
 376 fi
 377
 378 if test "x$enable_tests" = "xyes" -a "x$have_check" != "xyes"; then
 379    AC_MSG_ERROR([Couldn't find check dependencies.])
 380 fi
 381
 382 AM_CONDITIONAL(HAVE_TESTS, test "x$have_check" = "xyes")
 383
 384 # -----------------------------------------------------------
 385 # Python Bindings
 386 # -----------------------------------------------------------
 387 AC_ARG_ENABLE(python,
 388               AS_HELP_STRING([--enable-python=@<:@no/yes/auto@:>@],
 389                              [build python bindings to libempathy and libempathy-gtk]), ,
 390                              enable_python=auto)
 391
 392 if test "x$enable_python" != "xno"; then
 393    PKG_CHECK_MODULES(PYTHON_BINDING,
 394    [
 395       pygtk-2.0,
 396       glib-2.0 >= $GLIB_REQUIRED
 397       gobject-2.0
 398       gconf-2.0 >= $GCONF_REQUIRED
 399       libxml-2.0
 400       libmissioncontrol >= $MISSION_CONTROL_REQUIRED
 401       gtk+-2.0 >= $GTK_REQUIRED
 402       gstreamer-0.10
 403       gstreamer-interfaces-0.10
 404       telepathy-farsight
 405    ], have_python="yes", have_python="no")
 406    if test "x$have_python" = "xyes" ; then
 407       AM_CHECK_PYTHON_HEADERS(,have_python="no")
 408       AC_CHECK_PROGS([PYGOBJECTCODEGEN], [pygobject-codegen-2.0 pygtk-codegen-2.0])
 409    fi
 410 else
 411    have_python=no
 412 fi
 413
 414 if test "x$enable_python" = "xyes" -a "x$have_python" != "xyes"; then
 415    AC_MSG_ERROR([Couldn't find python.])
 416 fi
 417
 418 AM_CONDITIONAL(HAVE_PYTHON, test "x$have_python" = "xyes")
 419
 420 # -----------------------------------------------------------
 421 # Coding style checks
 422 # -----------------------------------------------------------
 423 AC_ARG_ENABLE(coding-style-checks,
 424   AC_HELP_STRING([--disable-coding-style-checks],
 425                  [don't check coding style using grep]),
 426     [ENABLE_CODING_STYLE_CHECKS=$enableval], [ENABLE_CODING_STYLE_CHECKS=yes])
 427
 428 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 429 # -----------------------------------------------------------
 430
 431 SHAVE_INIT(.)
 432
 433 AC_OUTPUT([
 434    Makefile
 435    data/Makefile
 436    data/empathy.desktop.in
 437    data/icons/Makefile
 438    extensions/Makefile
 439    po/Makefile.in
 440    libempathy/Makefile
 441    libempathy/libempathy.pc
 442    libempathy-gtk/Makefile
 443    libempathy-gtk/libempathy-gtk.pc
 444    src/Makefile
 445    megaphone/Makefile
 446    megaphone/src/Makefile
 447    megaphone/data/Makefile
 448    nothere/Makefile
 449    nothere/src/Makefile
 450    nothere/data/Makefile
 451    docs/Makefile
 452    docs/libempathy/Makefile
 453    docs/libempathy/version.xml
 454    docs/libempathy-gtk/Makefile
 455    docs/libempathy-gtk/version.xml
 456    help/Makefile
 457    python/Makefile
 458    python/pyempathy/Makefile
 459    python/pyempathygtk/Makefile
 460    tests/Makefile
 461    tests/xml/Makefile
 462    tools/Makefile
 463    shave
 464    shave-libtool
 465 ])
 466
 467 echo "
 468 Configure summary:
 469
 470         Compiler....................:  ${CC}
 471         Compiler Flags..............:  ${CFLAGS}
 472         Prefix......................:  ${prefix}
 473         Shaved build................:  ${enable_shave}
 474         Tests.......................:  ${have_check}
 475         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 476
 477     Features:
 478         Spell checking (enchant)....:  ${have_enchant}
 479         Display maps (libchamplain).:  ${have_libchamplain}
 480         Location awareness (Geoclue):  ${have_geoclue}
 481         Adium themes (Webkit).......:  ${have_webkit}
 482         NetworkManager integration..:  ${have_nm}
 483
 484     Extras:
 485         Documentation...............:  ${enable_gtk_doc}
 486         Python bindings.............:  ${have_python}
 487         Megaphone applet............:  ${have_megaphone}
 488         Nothere applet..............:  ${have_nothere}
 489 "