configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [5])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.7.1
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.19.6
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58
  59 GSTREAMER_REQUIRED=0.10.32
  60 LIBSECRET_REQUIRED=0.5
  61 GCR_REQUIRED=2.91.4
  62 LIBCANBERRA_GTK_REQUIRED=0.25
  63 LIBNOTIFY_REQUIRED=0.7.0
  64 TELEPATHY_LOGGER=0.2.13
  65 WEBKIT_REQUIRED=1.3.13
  66 GOA_REQUIRED=3.5.1
  67
  68 # Optional deps
  69 ENCHANT_REQUIRED=1.2.0
  70 GEOCLUE_REQUIRED=0.12
  71 ISO_CODES_REQUIRED=0.35
  72 NAUTILUS_SENDTO_REQUIRED=2.90.0
  73 NETWORK_MANAGER_REQUIRED=0.7.0
  74 CHAMPLAIN_REQUIRED=0.12.1
  75 CHEESE_GTK_REQUIRED=3.4.0
  76 LIBACCOUNTS_REQUIRED=1.1
  77 LIBSIGNON_REQUIRED=1.1
  78 MC_PLUGINS_REQUIRED=5.13.0
  79
  80 # Use --enable-maintainer-mode to disable deprecated symbols,
  81 # disable single include and enable GSEAL. If this is not a released empathy,
  82 # maintainer mode is forced
  83 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  84 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  85 #GNOME_MAINTAINER_MODE_DEFINES
  86
  87 # egg-list-box
  88 prev_top_build_prefix=$ac_top_build_prefix
  89 prev_ac_configure_args=$ac_configure_args
  90 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
  91 ac_top_build_prefix=$prev_top_build_prefix
  92 ac_configure_args=$prev_ac_configure_args
  93
  94 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
  95 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
  96
  97 AC_CONFIG_MACRO_DIR([m4])
  98 AC_CONFIG_HEADERS([config.h])
  99 AC_CONFIG_SRCDIR([configure.ac])
 100 AC_CONFIG_AUX_DIR(.)
 101
 102 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 103
 104 # Support silent build rules. Disable
 105 # by either passing --disable-silent-rules to configure or passing V=1
 106 # to make
 107 AM_SILENT_RULES([yes])
 108
 109 # Check for programs
 110 AC_PROG_CC
 111 AC_HEADER_STDC
 112 AM_PROG_MKDIR_P
 113 AM_PATH_GLIB_2_0
 114 AC_PATH_XTRA
 115
 116 # Initialize libtool
 117 LT_PREREQ([2.2])
 118 LT_INIT
 119
 120 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 121 GLIB_GSETTINGS
 122 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 123 AC_SUBST(GLIB_GENMARSHAL)
 124
 125 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 126 if test -z "$XSLTPROC"; then
 127   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 128 fi
 129 AM_PATH_PYTHON([2.3])
 130
 131 EMPATHY_ARG_VALGRIND
 132
 133
 134 # -----------------------------------------------------------
 135 # Error flags
 136 # -----------------------------------------------------------
 137 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 138 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 139
 140 AC_ARG_ENABLE(Werror,
 141   AS_HELP_STRING([--disable-Werror],
 142                  [compile without -Werror (normally enabled in development builds)]),
 143     werror=$enableval, :)
 144
 145 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 146 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 147         wno_missing_field_initializers=yes,
 148         wno_missing_field_initializers=no)
 149 AS_COMPILER_FLAG(-Wno-unused-parameter,
 150         wno_unused_parameter=yes,
 151         wno_unused_parameter=no)
 152
 153 ifelse(empathy_released, 1, [],
 154     [
 155         if test x$werror = xyes; then
 156             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 157         fi
 158         if test x$wextra = xyes -a \
 159             x$wno_missing_field_initializers = xyes -a \
 160             x$wno_unused_parameter = xyes; then
 161             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 162         fi
 163     ])
 164
 165 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 166 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 167 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 168 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 169 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 170
 171 AC_SUBST(ERROR_CFLAGS)
 172
 173 AC_ARG_ENABLE(gprof,
 174             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 175             [build with support for gprof]),,
 176             [enable_gprof=no])
 177 if test "x$enable_gprof" != "xno" ; then
 178     CFLAGS="$CFLAGS -pg"
 179     LDFLAGS="$LDFLAGS -pg"
 180 fi
 181
 182 AC_SUBST(LDFLAGS)
 183
 184 # -----------------------------------------------------------
 185 # Pkg-Config dependency checks
 186 # -----------------------------------------------------------
 187
 188 AC_CHECK_LIBM
 189 AC_SUBST(LIBM)
 190
 191 PKG_CHECK_MODULES(EMPATHY,
 192 [
 193    dbus-glib-1
 194    folks >= $FOLKS_REQUIRED
 195    folks-telepathy >= $FOLKS_REQUIRED
 196    glib-2.0 >= $GLIB_REQUIRED
 197    gio-2.0 >= $GLIB_REQUIRED
 198    gio-unix-2.0 >= $GLIB_REQUIRED
 199    libsecret-1 >= $LIBSECRET_REQUIRED
 200    gnutls >= $GNUTLS_REQUIRED
 201    gmodule-export-2.0
 202    gobject-2.0
 203    gsettings-desktop-schemas
 204    libxml-2.0
 205    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 206    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 207    x11
 208    gtk+-3.0 >= $GTK_REQUIRED
 209    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 210    libnotify >= $LIBNOTIFY_REQUIRED
 211    gcr-3 >= $GCR_REQUIRED
 212    libpulse
 213    libpulse-mainloop-glib
 214    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 215    libsoup-2.4
 216    gee-1.0
 217 ])
 218
 219 # -----------------------------------------------------------
 220 # GStreamer
 221 # -----------------------------------------------------------
 222 AC_ARG_ENABLE(gst-1.0,
 223               AS_HELP_STRING([--enable-gst-1.0=@<:@no/yes/auto@:>@],
 224                              [build with GStreamer 1.0]), enable_gst1=yes,
 225                              enable_gst1=auto)
 226
 227 # Try to use GStreamer 1.à if available
 228 if test "x$enable_gst1" != "xno"; then
 229   PKG_CHECK_MODULES(EMPATHY_CALL,
 230   [
 231      farstream-0.2
 232      telepathy-farstream >= 0.4.999
 233      clutter-1.0 >= $CLUTTER_REQUIRED
 234      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 235      clutter-gst-2.0
 236   ], have_gst1="yes", have_gst1="no")
 237
 238   if test "x$have_gst1" = "xyes"; then
 239     AC_DEFINE(HAVE_GST1, 1, [Build with GStreamer 1.0])
 240   fi
 241 fi
 242
 243 if test "x$enable_gst1" = "xyes" -a "x$have_gst1" != "xyes"; then
 244    AC_MSG_ERROR([Could not find GStreamer 1.0 dependencies:
 245
 246 $EMPATHY_CALL_PKG_ERRORS])
 247 fi
 248
 249 if test "x$have_gst1" != "xyes"; then
 250   PKG_CHECK_MODULES(EMPATHY_CALL,
 251   [
 252      farstream-0.1
 253      telepathy-farstream >= 0.2.1
 254      clutter-1.0 >= $CLUTTER_REQUIRED
 255      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 256      clutter-gst-1.0 >= 1.5.2
 257      gstreamer-0.10 >= $GSTREAMER_REQUIRED
 258      gstreamer-interfaces-0.10
 259   ])
 260 fi
 261
 262 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 263    [Name of provider for accounts imported from GOA])
 264
 265 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 266     "im.telepathy.Account.Storage.UOA",
 267    [Name of provider for accounts imported from libaccounts])
 268
 269 # -----------------------------------------------------------
 270 # Enable debug
 271 # -----------------------------------------------------------
 272
 273 AC_ARG_ENABLE(debug,
 274   AS_HELP_STRING([--disable-debug],
 275                  [compile without debug code]),
 276     enable_debug=$enableval, enable_debug=yes )
 277
 278 if test x$enable_debug = xyes; then
 279   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 280 fi
 281
 282 # -----------------------------------------------------------
 283 # Language Support
 284 # -----------------------------------------------------------
 285 IT_PROG_INTLTOOL([0.50.0])
 286
 287 GETTEXT_PACKAGE=empathy
 288 AC_SUBST(GETTEXT_PACKAGE)
 289 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 290
 291 # -----------------------------------------------------------
 292 # gudev
 293 # -----------------------------------------------------------
 294 AC_ARG_ENABLE(gudev,
 295               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 296                              [build with gudev support]), ,
 297                              enable_gudev=auto)
 298
 299 if test "x$enable_gudev" != "xno"; then
 300
 301    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 302         have_gudev="yes", have_gudev="no")
 303
 304    if test "x$have_gudev" = "xyes"; then
 305       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 306    fi
 307 else
 308    have_gudev=no
 309 fi
 310
 311 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 312    AC_MSG_ERROR([Could not find gudev dependencies:
 313
 314 $UDEV_PKG_ERRORS])
 315 fi
 316 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 317
 318 # -----------------------------------------------------------
 319 # spellchecking checks: enchant and iso-codes
 320 # -----------------------------------------------------------
 321 AC_ARG_ENABLE(spell,
 322               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 323                              [Enable spell checking]), ,
 324                              enable_spell=auto)
 325
 326 if test "x$enable_spell" != "xno"; then
 327    PKG_CHECK_MODULES(ENCHANT,
 328    [
 329       enchant >= $ENCHANT_REQUIRED,
 330       iso-codes >= $ISO_CODES_REQUIRED
 331    ], have_enchant="yes", have_enchant="no")
 332
 333    if test "x$have_enchant" = "xyes"; then
 334       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 335       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 336          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 337             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 338             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 339             result=yes
 340       else
 341             result=no
 342             have_enchant="no"
 343       fi
 344       AC_MSG_RESULT([$result])
 345    fi
 346 else
 347    have_enchant=no
 348 fi
 349
 350 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 351    AC_MSG_ERROR([Could not find spell-checking dependencies:
 352
 353 $ENCHANT_PKG_ERRORS])
 354 fi
 355
 356 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 357
 358 # -----------------------------------------------------------
 359 # Map view checks: libchamplain
 360 # -----------------------------------------------------------
 361 AC_ARG_ENABLE(map,
 362               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 363                              [Enable map view]), ,
 364                              enable_map=auto)
 365
 366 if test "x$enable_map" != "xno"; then
 367
 368    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 369     [
 370        clutter-gtk-1.0
 371        champlain-gtk-0.12
 372        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 373     ], have_libchamplain="yes", have_libchamplain="no")
 374
 375    if test "x$have_libchamplain" = "xyes"; then
 376       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 377    fi
 378 else
 379    have_libchamplain=no
 380 fi
 381
 382 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 383    AC_MSG_ERROR([Could not find map view dependencies:
 384
 385 $LIBCHAMPLAIN_PKG_ERRORS])
 386 fi
 387
 388 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 389
 390 # -----------------------------------------------------------
 391 # location checks: geoclue
 392 # -----------------------------------------------------------
 393 AC_ARG_ENABLE(location,
 394               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 395                              [Enable location awareness]), ,
 396                              enable_location=auto)
 397
 398 if test "x$enable_location" != "xno"; then
 399    PKG_CHECK_MODULES(GEOCLUE,
 400    [
 401       geoclue >= $GEOCLUE_REQUIRED
 402    ], have_geoclue="yes", have_geoclue="no")
 403
 404    if test "x$have_geoclue" = "xyes"; then
 405       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 406    fi
 407 else
 408    have_geoclue="no"
 409 fi
 410
 411 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 412    AC_MSG_ERROR([Could not find location dependencies:
 413
 414 $GEOCLUE_PKG_ERRORS])
 415 fi
 416
 417 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 418 AC_SUBST(GEOCLUE_CFLAGS)
 419 AC_SUBST(GEOCLUE_LIBS)
 420
 421 # -----------------------------------------------------------
 422 # location checks: geocode-glib
 423 # -----------------------------------------------------------
 424 AC_ARG_ENABLE(geocode,
 425               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 426                              [Enable geocode support]), ,
 427                              enable_geocode=auto)
 428
 429 if test "x$enable_geocode" != "xno"; then
 430    PKG_CHECK_MODULES(GEOCODE,
 431    [
 432       geocode-glib
 433    ], have_geocode="yes", have_geocode="no")
 434
 435    if test "x$have_geocode" = "xyes"; then
 436       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 437    fi
 438 else
 439    have_geocode="no"
 440 fi
 441
 442 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 443    AC_MSG_ERROR([Could not find geocode dependencies:
 444
 445 $GEOCODE_PKG_ERRORS])
 446 fi
 447
 448 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 449 AC_SUBST(GEOCODE_CFLAGS)
 450 AC_SUBST(GEOCODE_LIBS)
 451
 452 # -----------------------------------------------------------
 453 # nautilus-sendto
 454 # -----------------------------------------------------------
 455 AC_ARG_ENABLE(nautilus-sendto,
 456               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 457                              [build nautilus-sendto plugin]), ,
 458                              enable_nautilus_sendto=auto)
 459
 460 if test "x$enable_nautilus_sendto" != "xno"; then
 461    PKG_CHECK_MODULES(NST,
 462     [
 463        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 464     ], have_nst="yes", have_nst="no")
 465 else
 466    have_nst=no
 467 fi
 468
 469 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 470    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 471
 472 $NST_PKG_ERRORS])
 473 fi
 474
 475 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 476
 477 # -----------------------------------------------------------
 478 # goa-mc-plugin
 479 # -----------------------------------------------------------
 480 AC_ARG_ENABLE(goa,
 481               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 482                              [build GOA MC plugin]), ,
 483                              enable_goa=auto)
 484
 485 if test "x$enable_goa" != "xno"; then
 486    PKG_CHECK_MODULES(GOA,
 487     [
 488        mission-control-plugins
 489        goa-1.0 >= $GOA_REQUIRED
 490     ], have_goa="yes", have_goa="no")
 491 else
 492    have_goa=no
 493 fi
 494
 495 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 496    AC_MSG_ERROR([Could not find GOA dependencies:
 497
 498 $GOA_PKG_ERRORS])
 499 fi
 500
 501 if test "x$have_goa" = "xyes"; then
 502    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 503 fi
 504
 505 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 506
 507 # Optional dependency for avatar selection
 508 AC_ARG_WITH([cheese],
 509             AS_HELP_STRING([--with-cheese],
 510                            [enable cheese webcam support]),,
 511             with_cheese=auto)
 512
 513 if test x"$with_cheese" != x"no" ; then
 514    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 515    if test x${have_cheese} = xyes; then
 516      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 517    fi
 518    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 519      AC_MSG_ERROR([Cheese configured but not found:
 520
 521 $CHEESE_PKG_ERRORS])
 522    fi
 523 else
 524    have_cheese=no
 525 fi
 526 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 527
 528 # -----------------------------------------------------------
 529 # ubuntu-online-accounts support
 530 # -----------------------------------------------------------
 531 AC_ARG_ENABLE(ubuntu-online-accounts,
 532               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 533                              [build Ubuntu Online Accounts plugins]), ,
 534                              enable_ubuntu_online_accounts=auto)
 535
 536 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 537    PKG_CHECK_MODULES(UOA,
 538     [
 539        account-plugin
 540        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 541        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 542        libsignon-glib >= $LIBSIGNON_REQUIRED
 543     ], have_uoa="yes", have_uoa="no")
 544
 545    # provider plugin dir
 546    AC_MSG_CHECKING([Accounts provider plugin dir])
 547    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 548
 549    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 550    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 551
 552    # app plugin dir
 553    AC_MSG_CHECKING([Accounts provider app plugin dir])
 554    ACCOUNTS_APP_PLUGIN_DIR=`pkg-config --variable=application_plugindir account-plugin`
 555
 556    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 557    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 558
 559    # provider files dir
 560    AC_MSG_CHECKING([Accounts provider files dir])
 561    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 562
 563    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 564    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 565
 566    # service files dir
 567    AC_MSG_CHECKING([Accounts service files dir])
 568    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 569
 570    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 571    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 572
 573    # application files dir
 574    AC_MSG_CHECKING([Accounts applications files dir])
 575    ACCOUNTS_APPLICATION_FILES_DIR=`pkg-config --variable=applicationfilesdir libaccounts-glib`
 576
 577    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 578    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 579
 580 else
 581    have_uoa=no
 582 fi
 583
 584 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 585    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 586
 587 $UOA_PKG_ERRORS])
 588 fi
 589
 590 if test "x$have_uoa" = "xyes"; then
 591    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 592 fi
 593
 594 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 595
 596 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 597    AC_MSG_CHECKING([Mission Control plugins dir])
 598    MISSION_CONTROL_PLUGINS_DIR=${libdir}/mission-control-plugins.`pkg-config --variable=MCP_ABI_VERSION mission-control-plugins`
 599
 600    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 601    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 602 fi
 603
 604
 605 # Help documentation
 606 YELP_HELP_INIT
 607
 608 # -----------------------------------------------------------
 609 # Coding style checks
 610 # -----------------------------------------------------------
 611 AC_ARG_ENABLE(coding-style-checks,
 612   AS_HELP_STRING([--disable-coding-style-checks],
 613                  [do not check coding style using grep]),
 614     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 615     [ENABLE_CODING_STYLE_CHECKS=yes])
 616
 617 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 618 # -----------------------------------------------------------
 619
 620 AC_CONFIG_FILES([
 621    Makefile
 622    data/Makefile
 623    data/empathy.desktop.in
 624    data/icons/Makefile
 625    data/themes/Makefile
 626    extensions/Makefile
 627    po/Makefile.in
 628    libempathy/Makefile
 629    libempathy-gtk/Makefile
 630    src/Makefile
 631    nautilus-sendto-plugin/Makefile
 632    goa-mc-plugin/Makefile
 633    ubuntu-online-accounts/Makefile
 634    ubuntu-online-accounts/mc-plugin/Makefile
 635    ubuntu-online-accounts/cc-plugins/Makefile
 636    ubuntu-online-accounts/cc-plugins/providers/Makefile
 637    ubuntu-online-accounts/cc-plugins/services/Makefile
 638    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 639    help/Makefile
 640    tests/Makefile
 641    tests/interactive/Makefile
 642    tests/xml/Makefile
 643    tests/certificates/Makefile
 644    tools/Makefile
 645 ])
 646 AC_OUTPUT
 647
 648 echo "
 649 Configure summary:
 650
 651         Compiler....................:  ${CC}
 652         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 653         Linker Flags................:  ${LDFLAGS}
 654         Prefix......................:  ${prefix}
 655         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 656         Use GStreamer 1.0...........:  ${have_gst1}
 657
 658     Features:
 659         Spell checking (enchant)....:  ${have_enchant}
 660         Display maps (libchamplain).:  ${have_libchamplain}
 661         Location awareness (Geoclue):  ${have_geoclue}
 662         Geocode support (Geocode)...:  ${have_geocode}
 663         Cheese webcam support ......:  ${have_cheese}
 664         Camera monitoring...........:  ${have_gudev}
 665
 666     Extras:
 667         Nautilus-sendto plugin......:  ${have_nst}
 668         GOA MC plugin...............:  ${have_goa}
 669         Ubuntu Online plugins.......:  ${have_uoa}
 670 "