configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [1])
   6 m4_define([empathy_micro_version], [5])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.0
  38 GLIB_REQUIRED=2.28.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.14
  47 TELEPATHY_GLIB_REQUIRED=0.15.3
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50
  51 # Optional deps
  52 CLUTTER_GTK_REQUIRED=0.90.3
  53 ENCHANT_REQUIRED=1.2.0
  54 GEOCLUE_REQUIRED=0.11
  55 ISO_CODES_REQUIRED=0.35
  56 LIBCHAMPLAIN_GTK_REQUIRED=0.7.1
  57 LIBCHAMPLAIN_REQUIRED=0.9
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60 GNOME_CONTROL_CENTER_REQUIRED=2.31.4
  61
  62 # Use --enable-maintainer-mode to disable deprecated symbols,
  63 # disable single include and enable GSEAL. If this is not a released empathy,
  64 # maintainer mode is forced
  65 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  66 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  67 #GNOME_MAINTAINER_MODE_DEFINES
  68
  69 # telepathy-yell
  70 prev_top_build_prefix=$ac_top_build_prefix
  71 prev_ac_configure_args=$ac_configure_args
  72 ac_configure_args="$ac_configure_args --disable-shared-library"
  73 AX_CONFIG_DIR([telepathy-yell])
  74 ac_top_build_prefix=$prev_top_build_prefix
  75 ac_configure_args=$prev_ac_configure_args
  76 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  77
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_HEADERS([config.h])
  80 AC_CONFIG_SRCDIR([configure.ac])
  81 AC_CONFIG_AUX_DIR(.)
  82
  83 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  84
  85 # Support silent build rules. Disable
  86 # by either passing --disable-silent-rules to configure or passing V=1
  87 # to make
  88 AM_SILENT_RULES([yes])
  89
  90 # Check for programs
  91 AC_PROG_CC
  92 AC_HEADER_STDC
  93 AM_PROG_MKDIR_P
  94 AM_PATH_GLIB_2_0
  95 AC_PATH_XTRA
  96
  97 # Initialize libtool
  98 LT_PREREQ([2.2])
  99 LT_INIT
 100
 101 GNOME_DOC_INIT([0.17.3])
 102 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 103 GLIB_GSETTINGS
 104 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 105 AC_SUBST(GLIB_GENMARSHAL)
 106
 107 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 108 if test -z "$XSLTPROC"; then
 109   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 110 fi
 111 AM_PATH_PYTHON([2.3])
 112
 113 EMPATHY_ARG_VALGRIND
 114
 115
 116 # -----------------------------------------------------------
 117 # Error flags
 118 # -----------------------------------------------------------
 119 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 120 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 121
 122 AC_ARG_ENABLE(Werror,
 123   AS_HELP_STRING([--disable-Werror],
 124                  [compile without -Werror (normally enabled in development builds)]),
 125     werror=$enableval, :)
 126
 127 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 128 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 129         wno_missing_field_initializers=yes,
 130         wno_missing_field_initializers=no)
 131 AS_COMPILER_FLAG(-Wno-unused-parameter,
 132         wno_unused_parameter=yes,
 133         wno_unused_parameter=no)
 134
 135 ifelse(empathy_released, 1, [],
 136     [
 137         if test x$werror = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 139         fi
 140         if test x$wextra = xyes -a \
 141             x$wno_missing_field_initializers = xyes -a \
 142             x$wno_unused_parameter = xyes; then
 143             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 144         fi
 145     ])
 146
 147 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 148 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 149 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 150 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 151 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 152
 153 AC_SUBST(ERROR_CFLAGS)
 154
 155 # -----------------------------------------------------------
 156 # Pkg-Config dependency checks
 157 # -----------------------------------------------------------
 158
 159 PKG_CHECK_MODULES(EMPATHY,
 160 [
 161    dbus-glib-1
 162    folks >= $FOLKS_REQUIRED
 163    folks-telepathy >= $FOLKS_REQUIRED
 164    glib-2.0 >= $GLIB_REQUIRED
 165    gio-2.0 >= $GLIB_REQUIRED
 166    gio-unix-2.0 >= $GLIB_REQUIRED
 167    gnome-keyring-1 >= $KEYRING_REQUIRED
 168    gnutls >= $GNUTLS_REQUIRED
 169    gmodule-export-2.0
 170    gobject-2.0
 171    gsettings-desktop-schemas
 172    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 173    gstreamer-interfaces-0.10
 174    libxml-2.0
 175    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 176    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 177    x11
 178    gtk+-3.0 >= $GTK_REQUIRED
 179    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 180    libnotify >= $LIBNOTIFY_REQUIRED
 181    gcr-3 >= $GCR_REQUIRED
 182    libpulse
 183    libpulse-mainloop-glib
 184    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 185 ])
 186
 187 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 188
 189 PKG_CHECK_MODULES(EMPATHY_AV,
 190 [
 191    farsight2-0.10
 192    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 193 ])
 194
 195 # -----------------------------------------------------------
 196 # Call interface
 197 # -----------------------------------------------------------
 198 AC_ARG_ENABLE(call,
 199             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 200             [build with Call interface support]),,
 201             [enable_call=auto])
 202 if test "x$enable_call" != "xno" ; then
 203    PKG_CHECK_MODULES(EMPATHY_CALL,
 204    [
 205       farsight2-0.10
 206       telepathy-farstream
 207       clutter-1.0
 208       clutter-gtk-1.0
 209       clutter-gst-1.0
 210    ], have_call="yes", have_call="no" )
 211
 212    if test "x$have_call" = "xyes"; then
 213       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 214    fi
 215 else
 216   have_call=no
 217 fi
 218
 219 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 220    AC_MSG_ERROR([Could not find Call handler dependencies.])
 221 fi
 222 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 223
 224
 225 # -----------------------------------------------------------
 226 # Call support in tp-logger
 227 # -----------------------------------------------------------
 228 AC_ARG_ENABLE(call-logs,
 229             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 230             [build with call logs support]),,
 231             [enable_call_logs=auto])
 232 if test "x$enable_call_logs" != "xno" ; then
 233    SAVE_CFLAGS=$CFLAGS
 234    SAVE_CPPFLAGS=$CPPFLAGS
 235    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 236    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 237
 238    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 239       have_call_logs="yes", have_call_logs="no")
 240
 241    CFLAGS=$SAVE_CFLAGS
 242    CPPFLAGS=$SAVE_CPPFLAGS
 243
 244    if test "x$have_call_logs" = "xyes"; then
 245       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 246    fi
 247 else
 248   have_call_logs=no
 249 fi
 250
 251 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 252    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 253                  built with --enable-call])
 254 fi
 255
 256 # -----------------------------------------------------------
 257 # evolution-data-server (about-me)
 258 # -----------------------------------------------------------
 259 AC_ARG_WITH(eds,
 260             AS_HELP_STRING([--with-eds],
 261                            [build with evolution-data-server support]),,
 262             [with_eds=yes])
 263 if test x"$with_eds" = x"yes" ; then
 264    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 265    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 266 fi
 267
 268 # -----------------------------------------------------------
 269 # Enable debug
 270 # -----------------------------------------------------------
 271
 272 AC_ARG_ENABLE(debug,
 273   AS_HELP_STRING([--disable-debug],
 274                  [compile without debug code]),
 275     enable_debug=$enableval, enable_debug=yes )
 276
 277 if test x$enable_debug = xyes; then
 278   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 279 fi
 280
 281 # -----------------------------------------------------------
 282 # Language Support
 283 # -----------------------------------------------------------
 284 IT_PROG_INTLTOOL([0.40.0])
 285
 286 AM_GNU_GETTEXT_VERSION([0.17])
 287 AM_GNU_GETTEXT([external])
 288
 289 GETTEXT_PACKAGE=empathy
 290 AC_SUBST(GETTEXT_PACKAGE)
 291 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 292
 293 # -----------------------------------------------------------
 294 # Connectivity integration
 295 # -----------------------------------------------------------
 296 AC_ARG_WITH(connectivity,
 297               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 298                              [build with connectivity support]), ,
 299                              with_connectivity=auto)
 300
 301 if test "x$with_connectivity" = "xno"; then
 302    have_nm=no
 303    have_connman=no
 304
 305 elif test "x$with_connectivity" = "xconnman"; then
 306    have_nm=no
 307
 308    PKG_CHECK_MODULES(CONNMAN,
 309    [
 310       dbus-glib-1
 311    ], have_connman="yes", have_connman="no")
 312
 313    if test "x$have_connman" = "xyes"; then
 314       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 315    fi
 316
 317 else
 318    have_connman=no
 319
 320    PKG_CHECK_MODULES(NETWORK_MANAGER,
 321    [
 322       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 323    ], have_nm="yes", have_nm="no")
 324
 325    if test "x$have_nm" = "xyes"; then
 326       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 327    fi
 328 fi
 329
 330 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 331    AC_MSG_ERROR([Couldn't find connman dependencies.])
 332 fi
 333
 334 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 335    AC_MSG_ERROR([Couldn't find libnm-glib dependencies.])
 336 fi
 337
 338 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 339 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 340
 341 # -----------------------------------------------------------
 342 # gudev
 343 # -----------------------------------------------------------
 344 AC_ARG_ENABLE(gudev,
 345               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 346                              [build with gudev support]), ,
 347                              enable_gudev=auto)
 348
 349 if test "x$enable_gudev" != "xno"; then
 350
 351    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 352         have_gudev="yes", have_gudev="no")
 353
 354    if test "x$have_gudev" = "xyes"; then
 355       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 356    fi
 357 else
 358    have_gudev=no
 359 fi
 360
 361 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 362    AC_MSG_ERROR([Could not find gudev dependencies.])
 363 fi
 364 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 365
 366 # -----------------------------------------------------------
 367 # spellchecking checks: enchant and iso-codes
 368 # -----------------------------------------------------------
 369 AC_ARG_ENABLE(spell,
 370               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 371                              [Enable spell checking]), ,
 372                              enable_spell=auto)
 373
 374 if test "x$enable_spell" != "xno"; then
 375    PKG_CHECK_MODULES(ENCHANT,
 376    [
 377       enchant >= $ENCHANT_REQUIRED,
 378       iso-codes >= $ISO_CODES_REQUIRED
 379    ], have_enchant="yes", have_enchant="no")
 380
 381    if test "x$have_enchant" = "xyes"; then
 382       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 383       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 384          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 385             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 386             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 387             result=yes
 388       else
 389             result=no
 390             have_enchant="no"
 391       fi
 392       AC_MSG_RESULT([$result])
 393    fi
 394 else
 395    have_enchant=no
 396 fi
 397
 398 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 399    AC_MSG_ERROR([Could not find spell dependencies.])
 400 fi
 401
 402 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 403
 404 # -----------------------------------------------------------
 405 # Map view checks: libchamplain
 406 # -----------------------------------------------------------
 407 AC_ARG_ENABLE(map,
 408               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 409                              [Enable map view]), ,
 410                              enable_map=auto)
 411
 412 if test "x$enable_map" != "xno"; then
 413
 414    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 415     [
 416        clutter-gtk-1.0
 417        champlain-gtk-0.10
 418        champlain-0.10
 419     ], have_libchamplain="yes", have_libchamplain="no")
 420
 421    if test "x$have_libchamplain" = "xyes"; then
 422       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 423    fi
 424 else
 425    have_libchamplain=no
 426 fi
 427
 428 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 429    AC_MSG_ERROR([Could not find map view dependencies.])
 430 fi
 431
 432 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 433
 434 # -----------------------------------------------------------
 435 # location checks: geoclue
 436 # -----------------------------------------------------------
 437 AC_ARG_ENABLE(location,
 438               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 439                              [Enable location awareness]), ,
 440                              enable_location=auto)
 441
 442 if test "x$enable_location" != "xno"; then
 443    PKG_CHECK_MODULES(GEOCLUE,
 444    [
 445       geoclue >= $GEOCLUE_REQUIRED
 446    ], have_geoclue="yes", have_geoclue="no")
 447
 448    if test "x$have_geoclue" = "xyes"; then
 449       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 450    fi
 451 else
 452    have_geoclue="no"
 453 fi
 454
 455 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 456    AC_MSG_ERROR([Could not find location dependencies.])
 457 fi
 458
 459 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 460 AC_SUBST(GEOCLUE_CFLAGS)
 461 AC_SUBST(GEOCLUE_LIBS)
 462
 463 # -----------------------------------------------------------
 464 # location checks: geocode-glib
 465 # -----------------------------------------------------------
 466 AC_ARG_ENABLE(geocode,
 467               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 468                              [Enable geocode support]), ,
 469                              enable_geocode=auto)
 470
 471 if test "x$enable_geocode" != "xno"; then
 472    PKG_CHECK_MODULES(GEOCODE,
 473    [
 474       geocode-glib
 475    ], have_geocode="yes", have_geocode="no")
 476
 477    if test "x$have_geocode" = "xyes"; then
 478       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 479    fi
 480 else
 481    have_geocode="no"
 482 fi
 483
 484 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 485    AC_MSG_ERROR([Could not find geocode dependencies.])
 486 fi
 487
 488 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 489 AC_SUBST(GEOCODE_CFLAGS)
 490 AC_SUBST(GEOCODE_LIBS)
 491
 492 # -----------------------------------------------------------
 493 # meego widgets support
 494 # -----------------------------------------------------------
 495 AC_ARG_ENABLE(meego,
 496               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 497                              [Enable meego widgets]), ,
 498                              enable_meego=no)
 499
 500 if test "x$enable_meego" != "xno"; then
 501     PKG_CHECK_MODULES(MEEGO,
 502     [
 503        mx-gtk-1.0
 504        gio-unix-2.0
 505     ], have_meego="yes", have_meego="no")
 506
 507     if test "x$have_meego" = "xyes"; then
 508        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 509     fi
 510 else
 511    have_meego="no"
 512 fi
 513
 514 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 515    AC_MSG_ERROR([Could not find meego dependencies.])
 516 fi
 517
 518 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 519 AC_SUBST(MEEGO_CFLAGS)
 520 AC_SUBST(MEEGO_LIBS)
 521
 522 # -----------------------------------------------------------
 523 # nautilus-sendto
 524 # -----------------------------------------------------------
 525 AC_ARG_ENABLE(nautilus-sendto,
 526               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 527                              [build nautilus-sendto plugin]), ,
 528                              enable_nautilus_sendto=auto)
 529
 530 if test "x$enable_nautilus_sendto" != "xno"; then
 531    PKG_CHECK_MODULES(NST,
 532     [
 533        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 534     ], have_nst="yes", have_nst="no")
 535 else
 536    have_nst=no
 537 fi
 538
 539 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 540    AC_MSG_ERROR([Could not find nautilus-sendto dependencies.])
 541 fi
 542
 543 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 544
 545 # -----------------------------------------------------------
 546 # new, single-window control center
 547 # -----------------------------------------------------------
 548 AC_ARG_ENABLE(control_center_embedding,
 549               AS_HELP_STRING([--enable-control-center-embedding=@<:@no/yes/auto@:>@],
 550                              [Enable support for single-window control center]),
 551                              , enable_control_center_embedding=auto)
 552
 553 if test "x$enable_control_center_embedding" != "xno"; then
 554
 555    PKG_CHECK_MODULES(CONTROL_CENTER_EMBEDDING, [libgnome-control-center >= GNOME_CONTROL_CENTER_REQUIRED],
 556         have_control_center_embedding="yes", have_control_center_embedding="no")
 557
 558    if test "x$have_control_center_embedding" = "xyes"; then
 559       AC_DEFINE(HAVE_CONTROL_CENTER_EMBEDDING, 1, [Define if you have the single-window control center])
 560
 561       AC_MSG_CHECKING([gnome-control-center extension dir])
 562       CONTROL_CENTER_EXTENSIONDIR=`$PKG_CONFIG --variable=extensiondir libgnome-control-center`
 563       if test "x$CONTROL_CENTER_EXTENSIONDIR" = "x"; then
 564           AC_MSG_ERROR([Could not determine extensiondir])
 565       else
 566           AC_MSG_RESULT([$CONTROL_CENTER_EXTENSIONDIR])
 567       fi
 568       AC_SUBST(CONTROL_CENTER_EXTENSIONDIR)
 569    fi
 570 else
 571    have_control_center_embedding="no"
 572 fi
 573
 574 if test "x$enable_control_center_embedding" = "xyes" -a "x$have_control_center_embedding" != "xyes"; then
 575    AC_MSG_ERROR([Could not find single-window control center dependencies.])
 576 fi
 577
 578 AM_CONDITIONAL(HAVE_CONTROL_CENTER_EMBEDDING, test "x$have_control_center_embedding" = "xyes")
 579 AC_SUBST(CONTROL_CENTER_EMBEDDING_CFLAGS)
 580 AC_SUBST(CONTROL_CENTER_EMBEDDING_LIBS)
 581
 582 # Optional dependency for avatar selection
 583 AC_ARG_WITH([cheese],
 584             AS_HELP_STRING([--with-cheese],
 585                            [enable cheese webcam support]),,
 586             with_cheese=auto)
 587
 588 if test x"$with_cheese" != x"no" ; then
 589    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 590    if test x${have_cheese} = xyes; then
 591      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 592    fi
 593    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 594      AC_MSG_ERROR([Cheese configured but not found])
 595    fi
 596 else
 597    have_cheese=no
 598 fi
 599 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 600
 601
 602 # -----------------------------------------------------------
 603 # Coding style checks
 604 # -----------------------------------------------------------
 605 AC_ARG_ENABLE(coding-style-checks,
 606   AS_HELP_STRING([--disable-coding-style-checks],
 607                  [do not check coding style using grep]),
 608     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 609     [ENABLE_CODING_STYLE_CHECKS=yes])
 610
 611 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 612 # -----------------------------------------------------------
 613
 614 AC_CONFIG_FILES([
 615    Makefile
 616    data/Makefile
 617    data/empathy.desktop.in
 618    data/empathy-accounts.desktop.in
 619    data/icons/Makefile
 620    extensions/Makefile
 621    po/Makefile.in
 622    libempathy/Makefile
 623    libempathy-gtk/Makefile
 624    src/Makefile
 625    nautilus-sendto-plugin/Makefile
 626    help/Makefile
 627    tests/Makefile
 628    tests/interactive/Makefile
 629    tests/xml/Makefile
 630    tools/Makefile
 631 ])
 632 AC_OUTPUT
 633
 634 echo "
 635 Configure summary:
 636
 637         Compiler....................:  ${CC}
 638         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 639         Prefix......................:  ${prefix}
 640         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 641
 642     Features:
 643         Spell checking (enchant)....:  ${have_enchant}
 644         Display maps (libchamplain).:  ${have_libchamplain}
 645         Location awareness (Geoclue):  ${have_geoclue}
 646         Geocode support (Geoclue)...:  ${have_geocode}
 647         Meego widgets...............:  ${have_meego}
 648         Control center embedding....:  ${have_control_center_embedding}
 649         Cheese webcam support ......:  ${have_cheese}
 650         Camera monitoring...........:  ${have_gudev}
 651
 652     Connectivity:
 653         NetworkManager integration..:  ${have_nm}
 654         ConnMan integration.........:  ${have_connman}
 655
 656     Extras:
 657         Nautilus-sendto plugin......:  ${have_nst}
 658         Salut E-D-S support.........:  ${with_eds}
 659         Exp. Call channel handler...:  ${have_call}
 660         Exp. Call log support.......:  ${have_call_logs}
 661 "