configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [91])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.6
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.30.0
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_REQUIRED, GLIB_VERSION_2_30, [Prevent post 2.30 APIs])
  43
  44 GTK_REQUIRED=3.0.2
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_0, [Ignore post 3.0 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_REQUIRED, GDK_VERSION_3_0, [Prevent post 3.0 APIs])
  47
  48 GSTREAMER_REQUIRED=0.10.32
  49 KEYRING_REQUIRED=2.26.0
  50 GCR_REQUIRED=2.91.4
  51 LIBCANBERRA_GTK_REQUIRED=0.25
  52 LIBNOTIFY_REQUIRED=0.7.0
  53 TELEPATHY_FARSTREAM_REQUIRED=0.2.1
  54 TELEPATHY_GLIB_REQUIRED=0.17.5
  55 TELEPATHY_LOGGER=0.2.10
  56 WEBKIT_REQUIRED=1.3.13
  57 GOA_REQUIRED=3.3.0
  58
  59 # Optional deps
  60 CLUTTER_REQUIRED=1.7.14
  61 CLUTTER_GTK_REQUIRED=0.90.3
  62 ENCHANT_REQUIRED=1.2.0
  63 GEOCLUE_REQUIRED=0.11
  64 ISO_CODES_REQUIRED=0.35
  65 NAUTILUS_SENDTO_REQUIRED=2.90.0
  66 NETWORK_MANAGER_REQUIRED=0.7.0
  67 CHAMPLAIN_REQUIRED=0.12.1
  68
  69 # Use --enable-maintainer-mode to disable deprecated symbols,
  70 # disable single include and enable GSEAL. If this is not a released empathy,
  71 # maintainer mode is forced
  72 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  73 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  74 #GNOME_MAINTAINER_MODE_DEFINES
  75
  76 # FIXME: bgo #669673
  77 AC_DEFINE(CLUTTER_DISABLE_DEPRECATION_WARNINGS, 1, [Build with Clutter deprecated])
  78
  79 AC_CONFIG_MACRO_DIR([m4])
  80 AC_CONFIG_HEADERS([config.h])
  81 AC_CONFIG_SRCDIR([configure.ac])
  82 AC_CONFIG_AUX_DIR(.)
  83
  84 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  85
  86 # Support silent build rules. Disable
  87 # by either passing --disable-silent-rules to configure or passing V=1
  88 # to make
  89 AM_SILENT_RULES([yes])
  90
  91 # Check for programs
  92 AC_PROG_CC
  93 AC_HEADER_STDC
  94 AM_PROG_MKDIR_P
  95 AM_PATH_GLIB_2_0
  96 AC_PATH_XTRA
  97
  98 # Initialize libtool
  99 LT_PREREQ([2.2])
 100 LT_INIT
 101
 102 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 103 GLIB_GSETTINGS
 104 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 105 AC_SUBST(GLIB_GENMARSHAL)
 106
 107 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 108 if test -z "$XSLTPROC"; then
 109   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 110 fi
 111 AM_PATH_PYTHON([2.3])
 112
 113 EMPATHY_ARG_VALGRIND
 114
 115
 116 # -----------------------------------------------------------
 117 # Error flags
 118 # -----------------------------------------------------------
 119 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 120 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 121
 122 AC_ARG_ENABLE(Werror,
 123   AS_HELP_STRING([--disable-Werror],
 124                  [compile without -Werror (normally enabled in development builds)]),
 125     werror=$enableval, :)
 126
 127 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 128 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 129         wno_missing_field_initializers=yes,
 130         wno_missing_field_initializers=no)
 131 AS_COMPILER_FLAG(-Wno-unused-parameter,
 132         wno_unused_parameter=yes,
 133         wno_unused_parameter=no)
 134
 135 ifelse(empathy_released, 1, [],
 136     [
 137         if test x$werror = xyes; then
 138             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 139         fi
 140         if test x$wextra = xyes -a \
 141             x$wno_missing_field_initializers = xyes -a \
 142             x$wno_unused_parameter = xyes; then
 143             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 144         fi
 145     ])
 146
 147 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 148 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 149 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 150 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 151 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 152
 153 AC_SUBST(ERROR_CFLAGS)
 154
 155 AC_ARG_ENABLE(gprof,
 156             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 157             [build with support for gprof]),,
 158             [enable_gprof=no])
 159 if test "x$enable_gprof" != "xno" ; then
 160     CFLAGS="$CFLAGS -pg"
 161     LDFLAGS="$LDFLAGS -pg"
 162 fi
 163
 164 AC_SUBST(LDFLAGS)
 165
 166 # -----------------------------------------------------------
 167 # Pkg-Config dependency checks
 168 # -----------------------------------------------------------
 169
 170 AC_CHECK_LIBM
 171 AC_SUBST(LIBM)
 172
 173 PKG_CHECK_MODULES(EMPATHY,
 174 [
 175    dbus-glib-1
 176    folks >= $FOLKS_REQUIRED
 177    folks-telepathy >= $FOLKS_REQUIRED
 178    glib-2.0 >= $GLIB_REQUIRED
 179    gio-2.0 >= $GLIB_REQUIRED
 180    gio-unix-2.0 >= $GLIB_REQUIRED
 181    gnome-keyring-1 >= $KEYRING_REQUIRED
 182    gnutls >= $GNUTLS_REQUIRED
 183    gmodule-export-2.0
 184    gobject-2.0
 185    gsettings-desktop-schemas
 186    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 187    gstreamer-interfaces-0.10
 188    libxml-2.0
 189    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 190    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 191    x11
 192    gtk+-3.0 >= $GTK_REQUIRED
 193    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 194    libnotify >= $LIBNOTIFY_REQUIRED
 195    gcr-3 >= $GCR_REQUIRED
 196    libpulse
 197    libpulse-mainloop-glib
 198    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 199    libsoup-2.4
 200 ])
 201
 202 PKG_CHECK_MODULES(EMPATHY_CALL,
 203 [
 204    farstream-0.1
 205    telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 206    clutter-1.0 >= $CLUTTER_REQUIRED
 207    clutter-gtk-1.0
 208    clutter-gst-1.0
 209 ])
 210
 211 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 212    [Name of provider for accounts imported from GOA])
 213
 214 # -----------------------------------------------------------
 215 # Build empathy-av?
 216 # -----------------------------------------------------------
 217 AC_ARG_ENABLE(empathy-av,
 218             AS_HELP_STRING([--enable-empathy-av=@<:@no/yes@:>@],
 219             [build empathy-av (legacy call UI)]),,
 220             [enable_empathy_av=no])
 221 if test "x$enable_empathy_av" != "xno" ; then
 222    PKG_CHECK_MODULES(EMPATHY_AV,
 223    [
 224       farstream-0.1
 225       telepathy-farstream >= $TELEPATHY_FARSTREAM_REQUIRED
 226    ])
 227    AC_DEFINE(HAVE_EMPATHY_AV, 1, [Define if you have StreamedMedia channel support])
 228    have_empathy_av=yes
 229 fi
 230 AM_CONDITIONAL(HAVE_EMPATHY_AV, test "x$have_empathy_av" = "xyes")
 231
 232 # -----------------------------------------------------------
 233 # Call support in tp-logger
 234 # -----------------------------------------------------------
 235 AC_ARG_ENABLE(call-logs,
 236             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 237             [build with call logs support]),,
 238             [enable_call_logs=auto])
 239 if test "x$enable_call_logs" != "xno" ; then
 240    SAVE_CFLAGS=$CFLAGS
 241    SAVE_CPPFLAGS=$CPPFLAGS
 242    SAVE_LDFLAGS=$LDFLAGS
 243    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 244    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 245    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 246
 247    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 248       have_call_logs="yes", have_call_logs="no")
 249
 250    CFLAGS=$SAVE_CFLAGS
 251    CPPFLAGS=$SAVE_CPPFLAGS
 252    LDFLAGS=$SAVE_LDFLAGS
 253
 254    if test "x$have_call_logs" = "xyes"; then
 255       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 256    fi
 257 else
 258   have_call_logs=no
 259 fi
 260
 261 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 262    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 263                  built with --enable-call])
 264 fi
 265
 266 # -----------------------------------------------------------
 267 # evolution-data-server (about-me)
 268 # -----------------------------------------------------------
 269 AC_ARG_WITH(eds,
 270             AS_HELP_STRING([--with-eds],
 271                            [build with evolution-data-server support]),,
 272             [with_eds=yes])
 273 if test x"$with_eds" = x"yes" ; then
 274    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 275    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 276 fi
 277
 278 # -----------------------------------------------------------
 279 # Enable debug
 280 # -----------------------------------------------------------
 281
 282 AC_ARG_ENABLE(debug,
 283   AS_HELP_STRING([--disable-debug],
 284                  [compile without debug code]),
 285     enable_debug=$enableval, enable_debug=yes )
 286
 287 if test x$enable_debug = xyes; then
 288   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 289 fi
 290
 291 # -----------------------------------------------------------
 292 # Language Support
 293 # -----------------------------------------------------------
 294 IT_PROG_INTLTOOL([0.40.0])
 295
 296 AM_GNU_GETTEXT_VERSION([0.17])
 297 AM_GNU_GETTEXT([external])
 298
 299 GETTEXT_PACKAGE=empathy
 300 AC_SUBST(GETTEXT_PACKAGE)
 301 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 302
 303 # -----------------------------------------------------------
 304 # Connectivity integration
 305 # -----------------------------------------------------------
 306 AC_ARG_WITH(connectivity,
 307               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 308                              [build with connectivity support]), ,
 309                              with_connectivity=auto)
 310
 311 if test "x$with_connectivity" = "xno"; then
 312    have_nm=no
 313    have_connman=no
 314
 315 elif test "x$with_connectivity" = "xconnman"; then
 316    have_nm=no
 317
 318    PKG_CHECK_MODULES(CONNMAN,
 319    [
 320       dbus-glib-1
 321    ], have_connman="yes", have_connman="no")
 322
 323    if test "x$have_connman" = "xyes"; then
 324       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 325    fi
 326
 327 else
 328    have_connman=no
 329
 330    PKG_CHECK_MODULES(NETWORK_MANAGER,
 331    [
 332       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 333    ], have_nm="yes", have_nm="no")
 334
 335    if test "x$have_nm" = "xyes"; then
 336       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 337    fi
 338 fi
 339
 340 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 341    AC_MSG_ERROR([Couldn't find connman dependencies:
 342
 343 $CONNMAN_PKG_ERRORS])
 344 fi
 345
 346 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 347    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 348
 349 $NETWORK_MANAGER_PKG_ERRORS])
 350 fi
 351
 352 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 353 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 354
 355 # -----------------------------------------------------------
 356 # gudev
 357 # -----------------------------------------------------------
 358 AC_ARG_ENABLE(gudev,
 359               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 360                              [build with gudev support]), ,
 361                              enable_gudev=auto)
 362
 363 if test "x$enable_gudev" != "xno"; then
 364
 365    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 366         have_gudev="yes", have_gudev="no")
 367
 368    if test "x$have_gudev" = "xyes"; then
 369       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 370    fi
 371 else
 372    have_gudev=no
 373 fi
 374
 375 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 376    AC_MSG_ERROR([Could not find gudev dependencies:
 377
 378 $UDEV_PKG_ERRORS])
 379 fi
 380 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 381
 382 # -----------------------------------------------------------
 383 # spellchecking checks: enchant and iso-codes
 384 # -----------------------------------------------------------
 385 AC_ARG_ENABLE(spell,
 386               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 387                              [Enable spell checking]), ,
 388                              enable_spell=auto)
 389
 390 if test "x$enable_spell" != "xno"; then
 391    PKG_CHECK_MODULES(ENCHANT,
 392    [
 393       enchant >= $ENCHANT_REQUIRED,
 394       iso-codes >= $ISO_CODES_REQUIRED
 395    ], have_enchant="yes", have_enchant="no")
 396
 397    if test "x$have_enchant" = "xyes"; then
 398       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 399       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 400          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 401             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 402             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 403             result=yes
 404       else
 405             result=no
 406             have_enchant="no"
 407       fi
 408       AC_MSG_RESULT([$result])
 409    fi
 410 else
 411    have_enchant=no
 412 fi
 413
 414 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 415    AC_MSG_ERROR([Could not find spell-checking dependencies:
 416
 417 $ENCHANT_PKG_ERRORS])
 418 fi
 419
 420 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 421
 422 # -----------------------------------------------------------
 423 # Map view checks: libchamplain
 424 # -----------------------------------------------------------
 425 AC_ARG_ENABLE(map,
 426               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 427                              [Enable map view]), ,
 428                              enable_map=auto)
 429
 430 if test "x$enable_map" != "xno"; then
 431
 432    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 433     [
 434        clutter-gtk-1.0
 435        champlain-gtk-0.14
 436        champlain-0.14 >= $CHAMPLAIN_REQUIRED
 437     ], have_libchamplain="yes", have_libchamplain="no")
 438
 439    if test "x$have_libchamplain" = "xyes"; then
 440       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 441    fi
 442 else
 443    have_libchamplain=no
 444 fi
 445
 446 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 447    AC_MSG_ERROR([Could not find map view dependencies:
 448
 449 $LIBCHAMPLAIN_PKG_ERRORS])
 450 fi
 451
 452 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 453
 454 # -----------------------------------------------------------
 455 # location checks: geoclue
 456 # -----------------------------------------------------------
 457 AC_ARG_ENABLE(location,
 458               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 459                              [Enable location awareness]), ,
 460                              enable_location=auto)
 461
 462 if test "x$enable_location" != "xno"; then
 463    PKG_CHECK_MODULES(GEOCLUE,
 464    [
 465       geoclue >= $GEOCLUE_REQUIRED
 466    ], have_geoclue="yes", have_geoclue="no")
 467
 468    if test "x$have_geoclue" = "xyes"; then
 469       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 470    fi
 471 else
 472    have_geoclue="no"
 473 fi
 474
 475 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 476    AC_MSG_ERROR([Could not find location dependencies:
 477
 478 $GEOCLUE_PKG_ERRORS])
 479 fi
 480
 481 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 482 AC_SUBST(GEOCLUE_CFLAGS)
 483 AC_SUBST(GEOCLUE_LIBS)
 484
 485 # -----------------------------------------------------------
 486 # location checks: geocode-glib
 487 # -----------------------------------------------------------
 488 AC_ARG_ENABLE(geocode,
 489               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 490                              [Enable geocode support]), ,
 491                              enable_geocode=auto)
 492
 493 if test "x$enable_geocode" != "xno"; then
 494    PKG_CHECK_MODULES(GEOCODE,
 495    [
 496       geocode-glib
 497    ], have_geocode="yes", have_geocode="no")
 498
 499    if test "x$have_geocode" = "xyes"; then
 500       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 501    fi
 502 else
 503    have_geocode="no"
 504 fi
 505
 506 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 507    AC_MSG_ERROR([Could not find geocode dependencies:
 508
 509 $GEOCODE_PKG_ERRORS])
 510 fi
 511
 512 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 513 AC_SUBST(GEOCODE_CFLAGS)
 514 AC_SUBST(GEOCODE_LIBS)
 515
 516 # -----------------------------------------------------------
 517 # meego widgets support
 518 # -----------------------------------------------------------
 519 AC_ARG_ENABLE(meego,
 520               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 521                              [Enable meego widgets]), ,
 522                              enable_meego=no)
 523
 524 if test "x$enable_meego" != "xno"; then
 525     PKG_CHECK_MODULES(MEEGO,
 526     [
 527        mx-gtk-1.0
 528        gio-unix-2.0
 529     ], have_meego="yes", have_meego="no")
 530
 531     if test "x$have_meego" = "xyes"; then
 532        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 533     fi
 534 else
 535    have_meego="no"
 536 fi
 537
 538 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 539    AC_MSG_ERROR([Could not find meego dependencies:
 540
 541 $MEEGO_PKG_ERRORS])
 542 fi
 543
 544 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 545 AC_SUBST(MEEGO_CFLAGS)
 546 AC_SUBST(MEEGO_LIBS)
 547
 548 # -----------------------------------------------------------
 549 # nautilus-sendto
 550 # -----------------------------------------------------------
 551 AC_ARG_ENABLE(nautilus-sendto,
 552               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 553                              [build nautilus-sendto plugin]), ,
 554                              enable_nautilus_sendto=auto)
 555
 556 if test "x$enable_nautilus_sendto" != "xno"; then
 557    PKG_CHECK_MODULES(NST,
 558     [
 559        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 560     ], have_nst="yes", have_nst="no")
 561 else
 562    have_nst=no
 563 fi
 564
 565 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 566    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 567
 568 $NST_PKG_ERRORS])
 569 fi
 570
 571 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 572
 573 # -----------------------------------------------------------
 574 # goa-mc-plugin
 575 # -----------------------------------------------------------
 576 AC_ARG_ENABLE(goa,
 577               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 578                              [build GOA MC plugin]), ,
 579                              enable_goa=auto)
 580
 581 if test "x$enable_goa" != "xno"; then
 582    PKG_CHECK_MODULES(GOA,
 583     [
 584        mission-control-plugins
 585        goa-1.0 >= $GOA_REQUIRED
 586     ], have_goa="yes", have_goa="no")
 587
 588    AC_MSG_CHECKING([Mission Control plugins dir])
 589    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 590
 591    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 592    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 593 else
 594    have_goa=no
 595 fi
 596
 597 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 598    AC_MSG_ERROR([Could not find GOA dependencies.])
 599 fi
 600
 601 if test "x$have_goa" = "xyes"; then
 602    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 603 fi
 604
 605 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 606
 607 # Optional dependency for avatar selection
 608 AC_ARG_WITH([cheese],
 609             AS_HELP_STRING([--with-cheese],
 610                            [enable cheese webcam support]),,
 611             with_cheese=auto)
 612
 613 if test x"$with_cheese" != x"no" ; then
 614    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 615    if test x${have_cheese} = xyes; then
 616      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 617    fi
 618    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 619      AC_MSG_ERROR([Cheese configured but not found:
 620
 621 $CHEESE_PKG_ERRORS])
 622    fi
 623 else
 624    have_cheese=no
 625 fi
 626 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 627
 628 # Help documentation
 629 YELP_HELP_INIT
 630
 631 # -----------------------------------------------------------
 632 # Coding style checks
 633 # -----------------------------------------------------------
 634 AC_ARG_ENABLE(coding-style-checks,
 635   AS_HELP_STRING([--disable-coding-style-checks],
 636                  [do not check coding style using grep]),
 637     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 638     [ENABLE_CODING_STYLE_CHECKS=yes])
 639
 640 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 641 # -----------------------------------------------------------
 642
 643 AC_CONFIG_FILES([
 644    Makefile
 645    data/Makefile
 646    data/empathy.desktop.in
 647    data/empathy-accounts.desktop.in
 648    data/icons/Makefile
 649    extensions/Makefile
 650    po/Makefile.in
 651    libempathy/Makefile
 652    libempathy-gtk/Makefile
 653    src/Makefile
 654    nautilus-sendto-plugin/Makefile
 655    goa-mc-plugin/Makefile
 656    help/Makefile
 657    tests/Makefile
 658    tests/interactive/Makefile
 659    tests/xml/Makefile
 660    tools/Makefile
 661 ])
 662 AC_OUTPUT
 663
 664 echo "
 665 Configure summary:
 666
 667         Compiler....................:  ${CC}
 668         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 669         Linker Flags................:  ${LDFLAGS}
 670         Prefix......................:  ${prefix}
 671         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 672
 673     Features:
 674         Spell checking (enchant)....:  ${have_enchant}
 675         Display maps (libchamplain).:  ${have_libchamplain}
 676         Location awareness (Geoclue):  ${have_geoclue}
 677         Geocode support (Geocode)...:  ${have_geocode}
 678         Meego widgets...............:  ${have_meego}
 679         Cheese webcam support ......:  ${have_cheese}
 680         Camera monitoring...........:  ${have_gudev}
 681
 682     Connectivity:
 683         NetworkManager integration..:  ${have_nm}
 684         ConnMan integration.........:  ${have_connman}
 685
 686     Extras:
 687         Nautilus-sendto plugin......:  ${have_nst}
 688         GOA MC plugin...............:  ${have_goa}
 689         Salut E-D-S support.........:  ${with_eds}
 690         Exp. Call log support.......:  ${have_call_logs}
 691         empathy-av (legacy).........:  ${enable_empathy_av}
 692 "